helm/software/components/content_pres/cicNotationPres.ml

   1 (* Copyright (C) 2004-2005, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://helm.cs.unibo.it/
  24  *)
  25
  26 (* $Id$ *)
  27
  28 open Printf
  29
  30 module Ast = CicNotationPt
  31 module Mpres = Mpresentation
  32
  33 type mathml_markup = boxml_markup Mpres.mpres
  34 and boxml_markup = mathml_markup Box.box
  35
  36 type markup = mathml_markup
  37
  38 let atop_attributes = [None, "linethickness", "0pt"]
  39
  40 let to_unicode = Utf8Macro.unicode_of_tex
  41
  42 let rec make_attributes l1 = function
  43   | [] -> []
  44   | hd :: tl ->
  45       (match hd with
  46       | None -> make_attributes (List.tl l1) tl
  47       | Some s ->
  48           let p,n = List.hd l1 in
  49           (p,n,s) :: make_attributes (List.tl l1) tl)
  50
  51 let box_of_mpres =
  52   function
  53   | Mpresentation.Mobject (attrs, box) ->
  54       assert (attrs = []);
  55       box
  56   | mpres -> Box.Object ([], mpres)
  57
  58 let mpres_of_box =
  59   function
  60   | Box.Object (attrs, mpres) ->
  61       assert (attrs = []);
  62       mpres
  63   | box -> Mpresentation.Mobject ([], box)
  64
  65 let rec genuine_math =
  66   function
  67   | Mpresentation.Mobject ([], obj) -> not (genuine_box obj)
  68   | _ -> true
  69 and genuine_box =
  70   function
  71   | Box.Object ([], mpres) -> not (genuine_math mpres)
  72   | _ -> true
  73
  74 let rec eligible_math =
  75   function
  76   | Mpresentation.Mobject ([], Box.Object ([], mpres)) -> eligible_math mpres
  77   | Mpresentation.Mobject ([], _) -> false
  78   | _ -> true
  79
  80 let rec promote_to_math =
  81   function
  82   | Mpresentation.Mobject ([], Box.Object ([], mpres)) -> promote_to_math mpres
  83   | math -> math
  84
  85 let small_skip =
  86   Mpresentation.Mspace (RenderingAttrs.small_skip_attributes `MathML)
  87
  88 let rec add_mpres_attributes new_attr = function
  89   | Mpresentation.Mobject (attr, box) ->
  90       Mpresentation.Mobject (attr, add_box_attributes new_attr box)
  91   | mpres ->
  92       Mpresentation.set_attr (new_attr @ Mpresentation.get_attr mpres) mpres
  93 and add_box_attributes new_attr = function
  94   | Box.Object (attr, mpres) ->
  95       Box.Object (attr, add_mpres_attributes new_attr mpres)
  96   | box -> Box.set_attr (new_attr @ Box.get_attr box) box
  97
  98 let box_of mathonly spec attrs children =
  99   match children with
 100     | [t] -> add_mpres_attributes attrs t
 101     | _ ->
 102         let kind, spacing, indent = spec in
 103         let dress children =
 104           if spacing then
 105             CicNotationUtil.dress small_skip children
 106           else
 107             children
 108         in
 109           if mathonly then Mpresentation.Mrow (attrs, dress children)
 110           else
 111             let attrs' =
 112               (if spacing then RenderingAttrs.spacing_attributes `BoxML else [])
 113               @ (if indent then RenderingAttrs.indent_attributes `BoxML else [])
 114               @ attrs
 115             in
 116               match kind with
 117                 | Ast.H ->
 118                     if List.for_all eligible_math children then
 119                       Mpresentation.Mrow (attrs',
 120                         dress (List.map promote_to_math children))
 121                     else
 122                       mpres_of_box (Box.H (attrs',
 123                         List.map box_of_mpres children))
 124 (*                 | Ast.H when List.for_all genuine_math children ->
 125                     Mpresentation.Mrow (attrs', dress children) *)
 126                 | Ast.V ->
 127                     mpres_of_box (Box.V (attrs',
 128                       List.map box_of_mpres children))
 129                 | Ast.HV ->
 130                     mpres_of_box (Box.HV (attrs',
 131                       List.map box_of_mpres children))
 132                 | Ast.HOV ->
 133                     mpres_of_box (Box.HOV (attrs',
 134                       List.map box_of_mpres children))
 135
 136 let open_paren        = Mpresentation.Mo ([], "(")
 137 let closed_paren      = Mpresentation.Mo ([], ")")
 138 let open_bracket      = Mpresentation.Mo ([], "[")
 139 let closed_bracket    = Mpresentation.Mo ([], "]")
 140 let open_brace        = Mpresentation.Mo ([], "{")
 141 let closed_brace      = Mpresentation.Mo ([], "}")
 142 let hidden_substs     = Mpresentation.Mtext ([], "{...}")
 143 let hidden_lctxt      = Mpresentation.Mtext ([], "[...]")
 144 let open_box_paren    = Box.Text ([], "(")
 145 let closed_box_paren  = Box.Text ([], ")")
 146 let semicolon         = Mpresentation.Mo ([], ";")
 147 let toggle_action children =
 148   Mpresentation.Maction ([None, "actiontype", "toggle"], children)
 149
 150 type child_pos = [ `Left | `Right | `Inner ]
 151
 152 let pp_assoc =
 153   function
 154   | Gramext.LeftA -> "LeftA"
 155   | Gramext.RightA -> "RightA"
 156   | Gramext.NonA -> "NonA"
 157
 158 let is_atomic t =
 159   let rec aux_mpres = function
 160     | Mpres.Mi _
 161     | Mpres.Mo _
 162     | Mpres.Mn _
 163     | Mpres.Ms _
 164     | Mpres.Mtext _
 165     | Mpres.Mspace _ -> true
 166     | Mpres.Mobject (_, box) -> aux_box box
 167     | Mpres.Maction (_, [mpres])
 168     | Mpres.Mrow (_, [mpres]) -> aux_mpres mpres
 169     | _ -> false
 170   and aux_box = function
 171     | Box.Space _
 172     | Box.Ink _
 173     | Box.Text _ -> true
 174     | Box.Object (_, mpres) -> aux_mpres mpres
 175     | Box.H (_, [box])
 176     | Box.V (_, [box])
 177     | Box.HV (_, [box])
 178     | Box.HOV (_, [box])
 179     | Box.Action (_, [box]) -> aux_box box
 180     | _ -> false
 181   in
 182   aux_mpres t
 183
 184 let add_parens child_prec curr_prec t =
 185 (*   eprintf
 186     ("add_parens: " ^^
 187     "child_prec = %d\nchild_assoc = %s\nchild_pos = %s\ncurr_prec= %d\n\n%!")
 188     child_prec (pp_assoc child_assoc) (CicNotationPp.pp_pos child_pos)
 189     curr_prec; *)
 190   if is_atomic t then t
 191   else if child_prec >= 0 && child_prec < curr_prec then
 192     begin (* parens should be added *)
 193 (*      prerr_endline "adding parens!";  *)
 194     match t with
 195     | Mpresentation.Mobject (_, box) ->
 196         mpres_of_box (Box.H ([], [ open_box_paren; box; closed_box_paren ]))
 197     | mpres -> Mpresentation.Mrow ([], [open_paren; t; closed_paren])
 198   end else
 199     t
 200
 201 let render ids_to_uris ?(prec=(-1)) =
 202   let module A = Ast in
 203   let module P = Mpresentation in
 204 (*   let use_unicode = true in *)
 205   let lookup_uri id =
 206     (try
 207       let uri = Hashtbl.find ids_to_uris id in
 208       Some (UriManager.string_of_uri uri)
 209     with Not_found -> None)
 210   in
 211   let make_href xmlattrs xref =
 212     let xref_uris =
 213       List.fold_right
 214         (fun xref uris ->
 215           match lookup_uri xref with
 216           | None -> uris
 217           | Some uri -> uri :: uris)
 218         !xref []
 219     in
 220     let xmlattrs_uris, xmlattrs =
 221       let xref_attrs, other_attrs =
 222         List.partition
 223           (function Some "xlink", "href", _ -> true | _ -> false)
 224           xmlattrs
 225       in
 226       List.map (fun (_, _, uri) -> uri) xref_attrs,
 227       other_attrs
 228     in
 229     let uris =
 230       match xmlattrs_uris @ xref_uris with
 231       | [] -> None
 232       | uris ->
 233           Some (String.concat " "
 234             (HExtlib.list_uniq (List.sort String.compare uris)))
 235     in
 236     let xrefs =
 237       match !xref with [] -> None | xrefs -> Some (String.concat " " xrefs)
 238     in
 239     xref := [];
 240     xmlattrs
 241     @ make_attributes [Some "helm", "xref"; Some "xlink", "href"]
 242         [xrefs; uris]
 243   in
 244   let make_xref xref =
 245     let xrefs =
 246       match !xref with [] -> None | xrefs -> Some (String.concat " " xrefs)
 247     in
 248     xref := [];
 249     make_attributes [Some "helm","xref"] [xrefs]
 250   in
 251   (* when mathonly is true no boxes should be generated, only mrows *)
 252   (* "xref" is  *)
 253   let rec aux xmlattrs mathonly xref  prec t =
 254     match t with
 255     | A.AttributedTerm _ ->
 256         aux_attributes xmlattrs mathonly xref  prec t
 257     | A.Num (literal, _) ->
 258         let attrs =
 259           (RenderingAttrs.number_attributes `MathML)
 260           @ make_href xmlattrs xref
 261         in
 262         Mpres.Mn (attrs, literal)
 263     | A.Symbol (literal, _) ->
 264         let attrs =
 265           (RenderingAttrs.symbol_attributes `MathML)
 266           @ make_href xmlattrs xref
 267         in
 268         Mpres.Mo (attrs, to_unicode literal)
 269     | A.Ident (literal, subst)
 270     | A.Uri (literal, subst) ->
 271         let attrs =
 272           (RenderingAttrs.ident_attributes `MathML)
 273           @ make_href xmlattrs xref
 274         in
 275         let name = Mpres.Mi (attrs, to_unicode literal) in
 276         (match subst with
 277         | Some []
 278         | None -> name
 279         | Some substs ->
 280             let substs' =
 281               box_of mathonly (A.H, false, false) []
 282                 (open_brace
 283                 :: (CicNotationUtil.dress semicolon
 284                     (List.map
 285                       (fun (name, t) ->
 286                         box_of mathonly (A.H, false, false) [] [
 287                           Mpres.Mi ([], name);
 288                           Mpres.Mo ([], to_unicode "\\def");
 289                           aux [] mathonly xref  prec t ])
 290                       substs))
 291                 @ [ closed_brace ])
 292             in
 293             let substs_maction = toggle_action [ hidden_substs; substs' ] in
 294             box_of mathonly (A.H, false, false) [] [ name; substs_maction ])
 295     | A.Meta(n, l) ->
 296         let local_context l =
 297           box_of mathonly (A.H, false, false) []
 298             ([ Mpres.Mtext ([], "[") ] @
 299             (CicNotationUtil.dress (Mpres.Mtext ([],  ";"))
 300               (List.map
 301                 (function
 302                 | None -> Mpres.Mtext ([],  "_")
 303                 | Some t -> aux xmlattrs mathonly xref  prec t) l)) @
 304              [ Mpres.Mtext ([], "]")])
 305         in
 306         let lctxt_maction = toggle_action [ hidden_lctxt; local_context l ] in
 307         box_of mathonly (A.H, false, false) []
 308           ([Mpres.Mtext ([], "?"^string_of_int n) ]
 309             @ (if l <> [] then [lctxt_maction] else []))
 310     | A.Literal l -> aux_literal xmlattrs xref prec l
 311     | A.UserInput -> Mpres.Mtext ([], "%")
 312     | A.Layout l -> aux_layout mathonly xref  prec l
 313     | A.Magic _
 314     | A.Variable _ -> assert false  (* should have been instantiated *)
 315     | t ->
 316         prerr_endline ("unexpected ast: " ^ CicNotationPp.pp_term t);
 317         assert false
 318   and aux_attributes xmlattrs mathonly xref  prec t =
 319     let reset = ref false in
 320     let inferred_level = ref None in
 321     let expected_level = ref None in
 322     let new_xref = ref [] in
 323     let new_xmlattrs = ref [] in
 324 (*     let reinit = ref false in *)
 325     let rec aux_attribute =
 326       function
 327       | A.AttributedTerm (attr, t) ->
 328           (match attr with
 329           | `Loc _
 330           | `Raw _ -> ()
 331           | `Level (-1) -> reset := true
 332           | `Level child_prec ->
 333               assert (!expected_level = None);
 334               expected_level := !inferred_level;
 335               inferred_level := Some child_prec
 336           | `IdRef xref -> new_xref := xref :: !new_xref
 337           | `XmlAttrs attrs -> new_xmlattrs := attrs @ !new_xmlattrs);
 338           aux_attribute t
 339       | t ->
 340           let prec =
 341             match !expected_level with
 342             | None -> prec
 343             | Some prec -> prec
 344           in
 345           (match !inferred_level with
 346           | None -> aux !new_xmlattrs mathonly new_xref prec t
 347           | Some child_prec ->
 348               let t' =
 349                 aux !new_xmlattrs mathonly new_xref child_prec t in
 350               if !reset
 351               then t'
 352               else add_parens child_prec prec t')
 353     in
 354     aux_attribute t
 355   and aux_literal xmlattrs xref prec l =
 356     let attrs = make_href xmlattrs xref in
 357     (match l with
 358     | `Symbol s -> Mpres.Mo (attrs, to_unicode s)
 359     | `Keyword s -> Mpres.Mtext (attrs, to_unicode s)
 360     | `Number s  -> Mpres.Mn (attrs, to_unicode s))
 361   and aux_layout mathonly xref  prec l =
 362     let attrs = make_xref xref in
 363     let invoke' t = aux [] true (ref [])  prec t in
 364       (* use the one below to reset precedence and associativity *)
 365     let invoke_reinit t = aux [] mathonly xref ~-1 t in
 366     match l with
 367     | A.Sub (t1, t2) -> Mpres.Msub (attrs, invoke' t1, invoke_reinit t2)
 368     | A.Sup (t1, t2) -> Mpres.Msup (attrs, invoke' t1, invoke_reinit t2)
 369     | A.Below (t1, t2) -> Mpres.Munder (attrs, invoke' t1, invoke_reinit t2)
 370     | A.Above (t1, t2) -> Mpres.Mover (attrs, invoke' t1, invoke_reinit t2)
 371     | A.Frac (t1, t2)
 372     | A.Over (t1, t2) ->
 373         Mpres.Mfrac (attrs, invoke_reinit t1, invoke_reinit t2)
 374     | A.Atop (t1, t2) ->
 375         Mpres.Mfrac (atop_attributes @ attrs, invoke_reinit t1,
 376           invoke_reinit t2)
 377     | A.Sqrt t -> Mpres.Msqrt (attrs, invoke_reinit t)
 378     | A.Root (t1, t2) ->
 379         Mpres.Mroot (attrs, invoke_reinit t1, invoke_reinit t2)
 380     | A.Box ((_, spacing, _) as kind, terms) ->
 381         let children =
 382           aux_children mathonly spacing xref  prec
 383             (CicNotationUtil.ungroup terms)
 384         in
 385         box_of mathonly kind attrs children
 386     | A.Group terms ->
 387         let children =
 388           aux_children mathonly false xref  prec
 389             (CicNotationUtil.ungroup terms)
 390         in
 391         box_of mathonly (A.H, false, false) attrs children
 392     | A.Break -> assert false (* TODO? *)
 393   and aux_children mathonly spacing xref  prec terms =
 394     let find_clusters =
 395       let rec aux_list first clusters acc =
 396         function
 397             [] when acc = [] -> List.rev clusters
 398           | [] -> aux_list first (List.rev acc :: clusters) [] []
 399           | (A.Layout A.Break) :: tl when acc = [] ->
 400               aux_list first clusters [] tl
 401           | (A.Layout A.Break) :: tl ->
 402               aux_list first (List.rev acc :: clusters) [] tl
 403           | [hd] ->
 404                 aux_list false clusters
 405                   (aux [] mathonly xref  prec hd :: acc) []
 406           | hd :: tl ->
 407                 aux_list false clusters
 408                   (aux [] mathonly xref  prec hd :: acc) tl
 409       in
 410         aux_list true [] []
 411     in
 412     let boxify_pres =
 413       function
 414           [t] -> t
 415         | tl -> box_of mathonly (A.H, spacing, false) [] tl
 416     in
 417       List.map boxify_pres (find_clusters terms)
 418   in
 419   aux [] false (ref []) prec
 420
 421 let rec print_box (t: boxml_markup) =
 422   Box.box2xml print_mpres t
 423 and print_mpres (t: mathml_markup) =
 424   Mpresentation.print_mpres print_box t
 425
 426 let print_xml = print_mpres
 427
 428 (* let render_to_boxml id_to_uri t =
 429   let xml_stream = print_box (box_of_mpres (render id_to_uri t)) in
 430   Xml.add_xml_declaration xml_stream *)
 431