helm/software/components/content_pres/termContentPres.ml

   1 (* Copyright (C) 2004-2005, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://helm.cs.unibo.it/
  24  *)
  25
  26 (* $Id$ *)
  27
  28 open Printf
  29
  30 module Ast = CicNotationPt
  31 module Env = CicNotationEnv
  32
  33 let debug = false
  34 let debug_print s = if debug then prerr_endline (Lazy.force s) else ()
  35
  36 type pattern_id = int
  37 type pretty_printer_id = pattern_id
  38
  39 let resolve_binder = function
  40   | `Lambda -> "\\lambda"
  41   | `Pi -> "\\Pi"
  42   | `Forall -> "\\forall"
  43   | `Exists -> "\\exists"
  44
  45 let add_level_info prec t = Ast.AttributedTerm (`Level prec, t)
  46
  47 let rec top_pos t = add_level_info ~-1 t
  48
  49 let rec remove_level_info =
  50   function
  51   | Ast.AttributedTerm (`Level _, t) -> remove_level_info t
  52   | Ast.AttributedTerm (a, t) -> Ast.AttributedTerm (a, remove_level_info t)
  53   | t -> t
  54
  55 let add_xml_attrs attrs t =
  56   if attrs = [] then t else Ast.AttributedTerm (`XmlAttrs attrs, t)
  57
  58 let add_keyword_attrs =
  59   add_xml_attrs (RenderingAttrs.keyword_attributes `MathML)
  60
  61 let box kind spacing indent content =
  62   Ast.Layout (Ast.Box ((kind, spacing, indent), content))
  63
  64 let hbox = box Ast.H
  65 let vbox = box Ast.V
  66 let hvbox = box Ast.HV
  67 let hovbox = box Ast.HOV
  68 let break = Ast.Layout Ast.Break
  69 let space = Ast.Literal (`Symbol " ")
  70 let builtin_symbol s = Ast.Literal (`Symbol s)
  71 let keyword k = add_keyword_attrs (Ast.Literal (`Keyword k))
  72
  73 let number s =
  74   add_xml_attrs (RenderingAttrs.number_attributes `MathML)
  75     (Ast.Literal (`Number s))
  76
  77 let ident i =
  78   add_xml_attrs (RenderingAttrs.ident_attributes `MathML) (Ast.Ident (i, None))
  79
  80 let ident_w_href href i =
  81   match href with
  82   | None -> ident i
  83   | Some href ->
  84       let href = UriManager.string_of_uri href in
  85       add_xml_attrs [Some "xlink", "href", href] (ident i)
  86
  87 let binder_symbol s =
  88   add_xml_attrs (RenderingAttrs.builtin_symbol_attributes `MathML)
  89     (builtin_symbol s)
  90
  91 let string_of_sort_kind = function
  92   | `Prop -> "Prop"
  93   | `Set -> "Set"
  94   | `CProp _ -> "CProp"
  95   | `Type _ -> "Type"
  96   | `NType s -> "Type[" ^ s ^ "]"
  97   | `NCProp s -> "CProp[" ^ s ^ "]"
  98
  99 let map_space f l =
 100  HExtlib.list_concat
 101   ~sep:[space] (List.map (fun x -> [f x]) l)
 102 ;;
 103
 104 let pp_ast0 t k =
 105   let rec aux =
 106     function
 107     | Ast.Appl ts ->
 108         let rec aux_args level =
 109           function
 110           | [] -> []
 111           | [ last ] ->
 112               [ Ast.AttributedTerm (`Level level,k last) ]
 113           | hd :: tl ->
 114               (Ast.AttributedTerm (`Level level, k hd)) :: aux_args 71 tl
 115         in
 116         add_level_info Ast.apply_prec
 117           (hovbox true true (CicNotationUtil.dress break (aux_args 70 ts)))
 118     | Ast.Binder (binder_kind, (id, ty), body) ->
 119         add_level_info Ast.binder_prec
 120           (hvbox false true
 121             [ binder_symbol (resolve_binder binder_kind);
 122               k id; builtin_symbol ":"; aux_ty ty; break;
 123               builtin_symbol "."; k body ])
 124     | Ast.Case (what, indty_opt, outty_opt, patterns) ->
 125         let outty_box =
 126           match outty_opt with
 127           | None -> []
 128           | Some outty ->
 129               [ space; keyword "return"; space; break; remove_level_info (k outty)]
 130         in
 131         let indty_box =
 132           match indty_opt with
 133           | None -> []
 134           | Some (indty, href) -> [ space; keyword "in"; space; break; ident_w_href href indty ]
 135         in
 136         let match_box =
 137           hvbox false false [
 138            hvbox false true [
 139             hvbox false true [keyword "match"; space; break; top_pos (k what)];
 140             break;
 141             hvbox false true indty_box;
 142             break;
 143             hvbox false true outty_box
 144            ];
 145            break;
 146            space;
 147            keyword "with";
 148            space
 149          ]
 150         in
 151         let mk_case_pattern =
 152          function
 153             Ast.Pattern (head, href, vars) ->
 154              hvbox true true (ident_w_href href head ::
 155                List.flatten (List.map (fun x -> [break;x]) (map_space aux_var vars)))
 156           | Ast.Wildcard -> builtin_symbol "_"
 157         in
 158         let patterns' =
 159           List.map
 160             (fun (lhs, rhs) ->
 161               remove_level_info
 162                 (hovbox false true [
 163                   mk_case_pattern lhs; break; builtin_symbol "\\Rightarrow";
 164                   break; top_pos (k rhs) ]))
 165             patterns
 166         in
 167         let patterns'' =
 168           let rec aux_patterns = function
 169             | [] -> assert false
 170             | [ last ] ->
 171                 [ break;
 172                   hbox false false [
 173                     builtin_symbol "|";
 174                     last; builtin_symbol "]" ] ]
 175             | hd :: tl ->
 176                 [ break; hbox false false [ builtin_symbol "|"; hd ] ]
 177                 @ aux_patterns tl
 178           in
 179           match patterns' with
 180           | [] ->
 181               [ hbox false false [ builtin_symbol "["; builtin_symbol "]" ] ]
 182           | [ one ] ->
 183               [ hbox false false [
 184                 builtin_symbol "["; one; builtin_symbol "]" ] ]
 185           | hd :: tl ->
 186               hbox false false [ builtin_symbol "["; hd ]
 187               :: aux_patterns tl
 188         in
 189         add_level_info Ast.simple_prec
 190           (hvbox false false [
 191             hvbox false false ([match_box]); break;
 192             hbox false false [ hvbox false false patterns'' ] ])
 193     | Ast.Cast (bo, ty) ->
 194         add_level_info Ast.simple_prec
 195           (hvbox false true [
 196             builtin_symbol "("; top_pos (k bo); break; builtin_symbol ":";
 197             top_pos (k ty); builtin_symbol ")"])
 198     | Ast.LetIn (var, s, t) ->
 199         add_level_info Ast.let_in_prec
 200           (hvbox false true [
 201             hvbox false true [
 202               keyword "let"; space;
 203               hvbox false true [
 204                 aux_var var; space;
 205                 builtin_symbol "\\def"; break; top_pos (k s) ];
 206               break; space; keyword "in"; space ];
 207             break;
 208             k t ])
 209     | Ast.LetRec (rec_kind, funs, where) ->
 210         let rec_op =
 211           match rec_kind with `Inductive -> "rec" | `CoInductive -> "corec"
 212         in
 213         let mk_fun (args, (name,ty), body, rec_param) =
 214          List.flatten (List.map (fun x -> [aux_var x; space]) args),
 215           k name, HExtlib.map_option k ty, k body, fst (List.nth args rec_param)
 216         in
 217         let mk_funs = List.map mk_fun in
 218         let fst_fun, tl_funs =
 219           match mk_funs funs with hd :: tl -> hd, tl | [] -> assert false
 220         in
 221         let fst_row =
 222           let (params, name, ty, body, rec_param) = fst_fun in
 223           hvbox false true ([
 224             keyword "let";
 225             space;
 226             keyword rec_op;
 227             space;
 228             name;
 229             space] @
 230             params @
 231             [keyword "on" ; space ; rec_param ;space ] @
 232             (match ty with None -> [] | Some ty -> [builtin_symbol ":"; ty]) @
 233             [ builtin_symbol "\\def";
 234             break;
 235             top_pos body ])
 236         in
 237         let tl_rows =
 238           List.map
 239             (fun (params, name, ty, body, rec_param) ->
 240               [ break;
 241                 hvbox false true ([
 242                   keyword "and";
 243                   name] @
 244                   params @
 245                   [space; keyword "on" ; space; rec_param ;space ] @
 246                   (match ty with
 247                       None -> []
 248                     | Some ty -> [builtin_symbol ":"; ty]) @
 249                   [ builtin_symbol "\\def"; break; body ])])
 250             tl_funs
 251         in
 252         add_level_info Ast.let_in_prec
 253           ((hvbox false false
 254             (fst_row :: List.flatten tl_rows
 255              @ [ break; keyword "in"; break; k where ])))
 256     | Ast.Implicit -> builtin_symbol "?"
 257     | Ast.Meta (n, l) ->
 258         let local_context l =
 259             List.map (function None -> None | Some t -> Some (k t)) l
 260         in
 261         Ast.Meta(n, local_context l)
 262     | Ast.Sort sort -> aux_sort sort
 263     | Ast.Num _
 264     | Ast.Symbol _
 265     | Ast.Ident (_, None) | Ast.Ident (_, Some [])
 266     | Ast.Uri (_, None) | Ast.Uri (_, Some [])
 267     | Ast.Literal _
 268     | Ast.UserInput as leaf -> leaf
 269     | t -> CicNotationUtil.visit_ast ~special_k k t
 270   and aux_sort sort_kind =
 271     add_xml_attrs (RenderingAttrs.keyword_attributes `MathML)
 272       (Ast.Ident (string_of_sort_kind sort_kind, None))
 273   and aux_ty = function
 274     | None -> builtin_symbol "?"
 275     | Some ty -> k ty
 276   and aux_var = function
 277     | name, Some ty ->
 278         hvbox false true [
 279           builtin_symbol "("; name; builtin_symbol ":"; break; k ty;
 280           builtin_symbol ")" ]
 281     | name, None -> name
 282   and special_k = function
 283     | Ast.AttributedTerm (attrs, t) -> Ast.AttributedTerm (attrs, k t)
 284     | t ->
 285         prerr_endline ("unexpected special: " ^ CicNotationPp.pp_term t);
 286         assert false
 287   in
 288   aux t
 289
 290   (* persistent state *)
 291
 292 let initial_level1_patterns21 () = Hashtbl.create 211
 293 let level1_patterns21 = ref (initial_level1_patterns21 ())
 294 let compiled21 = ref None
 295 let pattern21_matrix = ref []
 296 let counter = ref ~-1
 297
 298 let stack = ref [];;
 299
 300 let push () =
 301   stack := (!counter,!level1_patterns21,!compiled21,!pattern21_matrix)::!stack;
 302   counter := ~-1;
 303   level1_patterns21 := initial_level1_patterns21 ();
 304   compiled21 := None;
 305   pattern21_matrix := []
 306 ;;
 307
 308 let pop () =
 309  match !stack with
 310     [] -> assert false
 311   | (ocounter,olevel1_patterns21,ocompiled21,opatterns21_matrix)::old ->
 312      stack := old;
 313      counter := ocounter;
 314      level1_patterns21 := olevel1_patterns21;
 315      compiled21 := ocompiled21;
 316      pattern21_matrix := opatterns21_matrix
 317 ;;
 318
 319 let get_compiled21 () =
 320   match !compiled21 with
 321   | None -> assert false
 322   | Some f -> Lazy.force f
 323
 324 let set_compiled21 f = compiled21 := Some f
 325
 326 let add_idrefs =
 327   List.fold_right (fun idref t -> Ast.AttributedTerm (`IdRef idref, t))
 328
 329 let instantiate21 idrefs env l1 =
 330   let rec subst_singleton pos env =
 331     function
 332       Ast.AttributedTerm (attr, t) ->
 333         Ast.AttributedTerm (attr, subst_singleton pos env t)
 334     | t -> CicNotationUtil.group (subst pos env t)
 335   and subst pos env = function
 336     | Ast.AttributedTerm (attr, t) ->
 337 (*         prerr_endline ("loosing attribute " ^ CicNotationPp.pp_attribute attr); *)
 338         subst pos env t
 339     | Ast.Variable var ->
 340         let name, expected_ty = CicNotationEnv.declaration_of_var var in
 341         let ty, value =
 342           try
 343             List.assoc name env
 344           with Not_found ->
 345             prerr_endline ("name " ^ name ^ " not found in environment");
 346             assert false
 347         in
 348         assert (CicNotationEnv.well_typed ty value); (* INVARIANT *)
 349         (* following assertion should be a conditional that makes this
 350          * instantiation fail *)
 351         if not (CicNotationEnv.well_typed expected_ty value) then
 352          begin
 353           prerr_endline ("The variable " ^ name ^ " is used with the wrong type in the notation declaration");
 354           assert false
 355          end;
 356         let value = CicNotationEnv.term_of_value value in
 357         let value =
 358           match expected_ty with
 359           | Env.TermType l -> Ast.AttributedTerm (`Level l,value)
 360           | _ -> value
 361         in
 362         [ value ]
 363     | Ast.Magic m -> subst_magic pos env m
 364     | Ast.Literal l as t ->
 365         let t = add_idrefs idrefs t in
 366         (match l with
 367         | `Keyword k -> [ add_keyword_attrs t ]
 368         | _ -> [ t ])
 369     | Ast.Layout l -> [ Ast.Layout (subst_layout pos env l) ]
 370     | t -> [ CicNotationUtil.visit_ast (subst_singleton pos env) t ]
 371   and subst_magic pos env = function
 372     | Ast.List0 (p, sep_opt)
 373     | Ast.List1 (p, sep_opt) ->
 374         let rec_decls = CicNotationEnv.declarations_of_term p in
 375         let rec_values =
 376           List.map (fun (n, _) -> CicNotationEnv.lookup_list env n) rec_decls
 377         in
 378         let values = CicNotationUtil.ncombine rec_values in
 379         let sep =
 380           match sep_opt with
 381             | None -> []
 382             | Some l -> [ Ast.Literal l; break; space ]
 383         in
 384         let rec instantiate_list acc = function
 385           | [] -> List.rev acc
 386           | value_set :: [] ->
 387               let env = CicNotationEnv.combine rec_decls value_set in
 388               instantiate_list (CicNotationUtil.group (subst pos env p) :: acc)
 389                 []
 390           | value_set :: tl ->
 391               let env = CicNotationEnv.combine rec_decls value_set in
 392               let terms = subst pos env p in
 393               instantiate_list (CicNotationUtil.group (terms @ sep) :: acc) tl
 394         in
 395         if values = [] then []
 396         else [hovbox false false (instantiate_list [] values)]
 397     | Ast.Opt p ->
 398         let opt_decls = CicNotationEnv.declarations_of_term p in
 399         let env =
 400           let rec build_env = function
 401             | [] -> []
 402             | (name, ty) :: tl ->
 403                   (* assumption: if one of the value is None then all are *)
 404                 (match CicNotationEnv.lookup_opt env name with
 405                 | None -> raise Exit
 406                 | Some v -> (name, (ty, v)) :: build_env tl)
 407           in
 408           try build_env opt_decls with Exit -> []
 409         in
 410           begin
 411             match env with
 412               | [] -> []
 413               | _ -> subst pos env p
 414           end
 415     | _ -> assert false (* impossible *)
 416   and subst_layout pos env = function
 417     | Ast.Box (kind, tl) ->
 418         let tl' = subst_children pos env tl in
 419         Ast.Box (kind, List.concat tl')
 420     | l -> CicNotationUtil.visit_layout (subst_singleton pos env) l
 421   and subst_children pos env =
 422     function
 423     | [] -> []
 424     | [ child ] ->
 425         let pos' =
 426           match pos with
 427           | `Inner -> `Right
 428           | `Left -> `Left
 429 (*           | `None -> assert false *)
 430           | `Right -> `Right
 431         in
 432         [ subst pos' env child ]
 433     | hd :: tl ->
 434         let pos' =
 435           match pos with
 436           | `Inner -> `Inner
 437           | `Left -> `Inner
 438 (*           | `None -> assert false *)
 439           | `Right -> `Right
 440         in
 441         (subst pos env hd) :: subst_children pos' env tl
 442   in
 443     subst_singleton `Left env l1
 444
 445 let rec pp_ast1 term =
 446   let rec pp_value = function
 447     | CicNotationEnv.NumValue _ as v -> v
 448     | CicNotationEnv.StringValue _ as v -> v
 449 (*     | CicNotationEnv.TermValue t when t == term -> CicNotationEnv.TermValue (pp_ast0 t pp_ast1) *)
 450     | CicNotationEnv.TermValue t -> CicNotationEnv.TermValue (pp_ast1 t)
 451     | CicNotationEnv.OptValue None as v -> v
 452     | CicNotationEnv.OptValue (Some v) ->
 453         CicNotationEnv.OptValue (Some (pp_value v))
 454     | CicNotationEnv.ListValue vl ->
 455         CicNotationEnv.ListValue (List.map pp_value vl)
 456   in
 457   let ast_env_of_env env =
 458     List.map (fun (var, (ty, value)) -> (var, (ty, pp_value value))) env
 459   in
 460 (* prerr_endline ("pattern matching from 2 to 1 on term " ^ CicNotationPp.pp_term term); *)
 461   match term with
 462   | Ast.AttributedTerm (attrs, term') ->
 463       Ast.AttributedTerm (attrs, pp_ast1 term')
 464   | _ ->
 465       (match (get_compiled21 ()) term with
 466       | None -> pp_ast0 term pp_ast1
 467       | Some (env, ctors, pid) ->
 468           let idrefs =
 469             List.flatten (List.map CicNotationUtil.get_idrefs ctors)
 470           in
 471           let l1 =
 472             try
 473               Hashtbl.find !level1_patterns21 pid
 474             with Not_found -> assert false
 475           in
 476           instantiate21 idrefs (ast_env_of_env env) l1)
 477
 478 let load_patterns21 t =
 479   set_compiled21 (lazy (Content2presMatcher.Matcher21.compiler t))
 480
 481 let pp_ast ast =
 482   debug_print (lazy "pp_ast <-");
 483   let ast' = pp_ast1 ast in
 484   debug_print (lazy ("pp_ast -> " ^ CicNotationPp.pp_term ast'));
 485   ast'
 486
 487 exception Pretty_printer_not_found
 488
 489 let fill_pos_info l1_pattern = l1_pattern
 490 (*   let rec aux toplevel pos =
 491     function
 492     | Ast.Layout l ->
 493         (match l
 494
 495     | Ast.Magic m ->
 496         Ast.Box (
 497     | Ast.Variable _ as t -> add_pos_info pos t
 498     | t -> t
 499   in
 500   aux true l1_pattern *)
 501
 502 let fresh_id =
 503   fun () ->
 504     incr counter;
 505     !counter
 506
 507 let add_pretty_printer l2 (CicNotationParser.CL1P (l1,precedence)) =
 508   let id = fresh_id () in
 509   let l1' = add_level_info precedence (fill_pos_info l1) in
 510   let l2' = CicNotationUtil.strip_attributes l2 in
 511   Hashtbl.add !level1_patterns21 id l1';
 512   pattern21_matrix := (l2', id) :: !pattern21_matrix;
 513   load_patterns21 !pattern21_matrix;
 514   id
 515
 516 let remove_pretty_printer id =
 517   (try
 518     Hashtbl.remove !level1_patterns21 id;
 519   with Not_found -> raise Pretty_printer_not_found);
 520   pattern21_matrix := List.filter (fun (_, id') -> id <> id') !pattern21_matrix;
 521   load_patterns21 !pattern21_matrix
 522
 523   (* presentation -> content *)
 524
 525 let unopt_names names env =
 526   let rec aux acc = function
 527     | (name, (ty, v)) :: tl when List.mem name names ->
 528         (match ty, v with
 529         | Env.OptType ty, Env.OptValue (Some v) ->
 530             aux ((name, (ty, v)) :: acc) tl
 531         | _ -> assert false)
 532     | hd :: tl -> aux (hd :: acc) tl
 533     | [] -> acc
 534   in
 535   aux [] env
 536
 537 let head_names names env =
 538   let rec aux acc = function
 539     | (name, (ty, v)) :: tl when List.mem name names ->
 540         (match ty, v with
 541         | Env.ListType ty, Env.ListValue (v :: _) ->
 542             aux ((name, (ty, v)) :: acc) tl
 543         | Env.TermType _, Env.TermValue _  ->
 544             aux ((name, (ty, v)) :: acc) tl
 545         | _ -> assert false)
 546     | _ :: tl -> aux acc tl
 547       (* base pattern may contain only meta names, thus we trash all others *)
 548     | [] -> acc
 549   in
 550   aux [] env
 551
 552 let tail_names names env =
 553   let rec aux acc = function
 554     | (name, (ty, v)) :: tl when List.mem name names ->
 555         (match ty, v with
 556         | Env.ListType ty, Env.ListValue (_ :: vtl) ->
 557             aux ((name, (Env.ListType ty, Env.ListValue vtl)) :: acc) tl
 558         | Env.TermType _, Env.TermValue _  ->
 559             aux ((name, (ty, v)) :: acc) tl
 560         | _ -> assert false)
 561     | binding :: tl -> aux (binding :: acc) tl
 562     | [] -> acc
 563   in
 564   aux [] env
 565
 566 let instantiate_level2 env term =
 567 (*   prerr_endline ("istanzio: " ^ CicNotationPp.pp_term term); *)
 568   let fresh_env = ref [] in
 569   let lookup_fresh_name n =
 570     try
 571       List.assoc n !fresh_env
 572     with Not_found ->
 573       let new_name = CicNotationUtil.fresh_name () in
 574       fresh_env := (n, new_name) :: !fresh_env;
 575       new_name
 576   in
 577   let rec aux env term =
 578 (*    prerr_endline ("ENV " ^ CicNotationPp.pp_env env); *)
 579     match term with
 580     | Ast.AttributedTerm (a, term) -> (*Ast.AttributedTerm (a, *)aux env term
 581     | Ast.Appl terms -> Ast.Appl (List.map (aux env) terms)
 582     | Ast.Binder (binder, var, body) ->
 583         Ast.Binder (binder, aux_capture_var env var, aux env body)
 584     | Ast.Case (term, indty, outty_opt, patterns) ->
 585         Ast.Case (aux env term, indty, aux_opt env outty_opt,
 586           List.map (aux_branch env) patterns)
 587     | Ast.LetIn (var, t1, t3) ->
 588         Ast.LetIn (aux_capture_var env var, aux env t1, aux env t3)
 589     | Ast.LetRec (kind, definitions, body) ->
 590         Ast.LetRec (kind, List.map (aux_definition env) definitions,
 591           aux env body)
 592     | Ast.Uri (name, None) -> Ast.Uri (name, None)
 593     | Ast.Uri (name, Some substs) ->
 594         Ast.Uri (name, Some (aux_substs env substs))
 595     | Ast.Ident (name, Some substs) ->
 596         Ast.Ident (name, Some (aux_substs env substs))
 597     | Ast.Meta (index, substs) -> Ast.Meta (index, aux_meta_substs env substs)
 598
 599     | Ast.Implicit
 600     | Ast.Ident _
 601     | Ast.Num _
 602     | Ast.Sort _
 603     | Ast.Symbol _
 604     | Ast.UserInput -> term
 605
 606     | Ast.Magic magic -> aux_magic env magic
 607     | Ast.Variable var -> aux_variable env var
 608
 609     | Ast.Cast (t, ty) -> Ast.Cast (aux env t, aux env ty)
 610
 611     | _ -> assert false
 612   and aux_opt env = function
 613     | Some term -> Some (aux env term)
 614     | None -> None
 615   and aux_capture_var env (name, ty_opt) = (aux env name, aux_opt env ty_opt)
 616   and aux_branch env (pattern, term) =
 617     (aux_pattern env pattern, aux env term)
 618   and aux_pattern env =
 619    function
 620       Ast.Pattern (head, hrefs, vars) ->
 621        Ast.Pattern (head, hrefs, List.map (aux_capture_var env) vars)
 622     | Ast.Wildcard -> Ast.Wildcard
 623   and aux_definition env (params, var, term, i) =
 624     (List.map (aux_capture_var env) params, aux_capture_var env var, aux env term, i)
 625   and aux_substs env substs =
 626     List.map (fun (name, term) -> (name, aux env term)) substs
 627   and aux_meta_substs env meta_substs = List.map (aux_opt env) meta_substs
 628   and aux_variable env = function
 629     | Ast.NumVar name -> Ast.Num (Env.lookup_num env name, 0)
 630     | Ast.IdentVar name -> Ast.Ident (Env.lookup_string env name, None)
 631     | Ast.TermVar (name,(Ast.Level l|Ast.Self l)) ->
 632         Ast.AttributedTerm (`Level l,Env.lookup_term env name)
 633     | Ast.FreshVar name -> Ast.Ident (lookup_fresh_name name, None)
 634     | Ast.Ascription (term, name) -> assert false
 635   and aux_magic env = function
 636     | Ast.Default (some_pattern, none_pattern) ->
 637         let some_pattern_names = CicNotationUtil.names_of_term some_pattern in
 638         let none_pattern_names = CicNotationUtil.names_of_term none_pattern in
 639         let opt_names =
 640           List.filter
 641             (fun name -> not (List.mem name none_pattern_names))
 642             some_pattern_names
 643         in
 644         (match opt_names with
 645         | [] -> assert false (* some pattern must contain at least 1 name *)
 646         | (name :: _) as names ->
 647             (match Env.lookup_value env name with
 648             | Env.OptValue (Some _) ->
 649                 (* assumption: if "name" above is bound to Some _, then all
 650                  * names returned by "meta_names_of" are bound to Some _ as well
 651                  *)
 652                 aux (unopt_names names env) some_pattern
 653             | Env.OptValue None -> aux env none_pattern
 654             | _ ->
 655                 prerr_endline (sprintf
 656                   "lookup of %s in env %s did not return an optional value"
 657                   name (CicNotationPp.pp_env env));
 658                 assert false))
 659     | Ast.Fold (`Left, base_pattern, names, rec_pattern) ->
 660         let acc_name = List.hd names in (* names can't be empty, cfr. parser *)
 661         let meta_names =
 662           List.filter ((<>) acc_name)
 663             (CicNotationUtil.names_of_term rec_pattern)
 664         in
 665         (match meta_names with
 666         | [] -> assert false (* as above *)
 667         | (name :: _) as names ->
 668             let rec instantiate_fold_left acc env' =
 669               match Env.lookup_value env' name with
 670               | Env.ListValue (_ :: _) ->
 671                   instantiate_fold_left
 672                     (let acc_binding =
 673                       acc_name, (Env.TermType 0, Env.TermValue acc)
 674                      in
 675                      aux (acc_binding :: head_names names env') rec_pattern)
 676                     (tail_names names env')
 677               | Env.ListValue [] -> acc
 678               | _ -> assert false
 679             in
 680             instantiate_fold_left (aux env base_pattern) env)
 681     | Ast.Fold (`Right, base_pattern, names, rec_pattern) ->
 682         let acc_name = List.hd names in (* names can't be empty, cfr. parser *)
 683         let meta_names =
 684           List.filter ((<>) acc_name)
 685             (CicNotationUtil.names_of_term rec_pattern)
 686         in
 687         (match meta_names with
 688         | [] -> assert false (* as above *)
 689         | (name :: _) as names ->
 690             let rec instantiate_fold_right env' =
 691               match Env.lookup_value env' name with
 692               | Env.ListValue (_ :: _) ->
 693                   let acc = instantiate_fold_right (tail_names names env') in
 694                   let acc_binding =
 695                     acc_name, (Env.TermType 0, Env.TermValue acc)
 696                   in
 697                   aux (acc_binding :: head_names names env') rec_pattern
 698               | Env.ListValue [] -> aux env base_pattern
 699               | _ -> assert false
 700             in
 701             instantiate_fold_right env)
 702     | Ast.If (_, p_true, p_false) as t ->
 703         aux env (CicNotationUtil.find_branch (Ast.Magic t))
 704     | Ast.Fail -> assert false
 705     | _ -> assert false
 706   in
 707   aux env term
 708
 709   (* initialization *)
 710
 711 let _ = load_patterns21 []
 712
 713
 714