helm/software/components/content_pres/termContentPres.ml

   1 (* Copyright (C) 2004-2005, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://helm.cs.unibo.it/
  24  *)
  25
  26 (* $Id$ *)
  27
  28 open Printf
  29
  30 module Ast = CicNotationPt
  31 module Env = CicNotationEnv
  32
  33 let debug = false
  34 let debug_print s = if debug then prerr_endline (Lazy.force s) else ()
  35
  36 type pattern_id = int
  37 type pretty_printer_id = pattern_id
  38
  39 let resolve_binder = function
  40   | `Lambda -> "\\lambda"
  41   | `Pi -> "\\Pi"
  42   | `Forall -> "\\forall"
  43   | `Exists -> "\\exists"
  44
  45 let add_level_info prec t = Ast.AttributedTerm (`Level prec, t)
  46
  47 let rec top_pos t = add_level_info ~-1 t
  48
  49 let rec remove_level_info =
  50   function
  51   | Ast.AttributedTerm (`Level _, t) -> remove_level_info t
  52   | Ast.AttributedTerm (a, t) -> Ast.AttributedTerm (a, remove_level_info t)
  53   | t -> t
  54
  55 let add_xml_attrs attrs t =
  56   if attrs = [] then t else Ast.AttributedTerm (`XmlAttrs attrs, t)
  57
  58 let add_keyword_attrs =
  59   add_xml_attrs (RenderingAttrs.keyword_attributes `MathML)
  60
  61 let box kind spacing indent content =
  62   Ast.Layout (Ast.Box ((kind, spacing, indent), content))
  63
  64 let hbox = box Ast.H
  65 let vbox = box Ast.V
  66 let hvbox = box Ast.HV
  67 let hovbox = box Ast.HOV
  68 let break = Ast.Layout Ast.Break
  69 let space = Ast.Literal (`Symbol " ")
  70 let builtin_symbol s = Ast.Literal (`Symbol s)
  71 let keyword k = add_keyword_attrs (Ast.Literal (`Keyword k))
  72
  73 let number s =
  74   add_xml_attrs (RenderingAttrs.number_attributes `MathML)
  75     (Ast.Literal (`Number s))
  76
  77 let ident i =
  78   add_xml_attrs (RenderingAttrs.ident_attributes `MathML) (Ast.Ident (i, None))
  79
  80 let ident_w_href href i =
  81   match href with
  82   | None -> ident i
  83   | Some href ->
  84       let href = UriManager.string_of_uri href in
  85       add_xml_attrs [Some "xlink", "href", href] (ident i)
  86
  87 let binder_symbol s =
  88   add_xml_attrs (RenderingAttrs.builtin_symbol_attributes `MathML)
  89     (builtin_symbol s)
  90
  91 let string_of_sort_kind = function
  92   | `Prop -> "Prop"
  93   | `Set -> "Set"
  94   | `CProp _ -> "CProp"
  95   | `Type _ -> "Type"
  96
  97 let pp_ast0 t k =
  98   let rec aux =
  99     function
 100     | Ast.Appl ts ->
 101         let rec aux_args level =
 102           function
 103           | [] -> []
 104           | [ last ] ->
 105               [ Ast.AttributedTerm (`Level level,k last) ]
 106           | hd :: tl ->
 107               (Ast.AttributedTerm (`Level level, k hd)) :: aux_args 71 tl
 108         in
 109         add_level_info Ast.apply_prec
 110           (hovbox true true (CicNotationUtil.dress break (aux_args 70 ts)))
 111     | Ast.Binder (binder_kind, (id, ty), body) ->
 112         add_level_info Ast.binder_prec
 113           (hvbox false true
 114             [ binder_symbol (resolve_binder binder_kind);
 115               k id; builtin_symbol ":"; aux_ty ty; break;
 116               builtin_symbol "."; k body ])
 117     | Ast.Case (what, indty_opt, outty_opt, patterns) ->
 118         let outty_box =
 119           match outty_opt with
 120           | None -> []
 121           | Some outty ->
 122               [ space; keyword "return"; space; break; remove_level_info (k outty)]
 123         in
 124         let indty_box =
 125           match indty_opt with
 126           | None -> []
 127           | Some (indty, href) -> [ space; keyword "in"; space; break; ident_w_href href indty ]
 128         in
 129         let match_box =
 130           hvbox false false [
 131            hvbox false true [
 132             hvbox false true [keyword "match"; space; break; top_pos (k what)];
 133             break;
 134             hvbox false true indty_box;
 135             break;
 136             hvbox false true outty_box
 137            ];
 138            break;
 139            space;
 140            keyword "with";
 141            space
 142          ]
 143         in
 144         let mk_case_pattern =
 145          function
 146             Ast.Pattern (head, href, vars) ->
 147              hbox true false (ident_w_href href head :: List.map aux_var vars)
 148           | Ast.Wildcard -> builtin_symbol "_"
 149         in
 150         let patterns' =
 151           List.map
 152             (fun (lhs, rhs) ->
 153               remove_level_info
 154                 (hvbox false true [
 155                   hbox false true [
 156                     mk_case_pattern lhs; builtin_symbol "\\Rightarrow" ];
 157                   break; top_pos (k rhs) ]))
 158             patterns
 159         in
 160         let patterns'' =
 161           let rec aux_patterns = function
 162             | [] -> assert false
 163             | [ last ] ->
 164                 [ break;
 165                   hbox false false [
 166                     builtin_symbol "|";
 167                     last; builtin_symbol "]" ] ]
 168             | hd :: tl ->
 169                 [ break; hbox false false [ builtin_symbol "|"; hd ] ]
 170                 @ aux_patterns tl
 171           in
 172           match patterns' with
 173           | [] ->
 174               [ hbox false false [ builtin_symbol "["; builtin_symbol "]" ] ]
 175           | [ one ] ->
 176               [ hbox false false [
 177                 builtin_symbol "["; one; builtin_symbol "]" ] ]
 178           | hd :: tl ->
 179               hbox false false [ builtin_symbol "["; hd ]
 180               :: aux_patterns tl
 181         in
 182         add_level_info Ast.simple_prec
 183           (hvbox false false [
 184             hvbox false false ([match_box]); break;
 185             hbox false false [ hvbox false false patterns'' ] ])
 186     | Ast.Cast (bo, ty) ->
 187         add_level_info Ast.simple_prec
 188           (hvbox false true [
 189             builtin_symbol "("; top_pos (k bo); break; builtin_symbol ":";
 190             top_pos (k ty); builtin_symbol ")"])
 191     | Ast.LetIn (var, s, t) ->
 192         add_level_info Ast.let_in_prec
 193           (hvbox false true [
 194             hvbox false true [
 195               keyword "let"; space;
 196               hvbox false true [
 197                 aux_var var; space;
 198                 builtin_symbol "\\def"; break; top_pos (k s) ];
 199               break; space; keyword "in" ];
 200             break;
 201             k t ])
 202     | Ast.LetRec (rec_kind, funs, where) ->
 203         let rec_op =
 204           match rec_kind with `Inductive -> "rec" | `CoInductive -> "corec"
 205         in
 206         let mk_fun (args, (name,ty), body, rec_param) =
 207          List.map aux_var args ,k name, HExtlib.map_option k ty, k body,
 208            fst (List.nth args rec_param)
 209         in
 210         let mk_funs = List.map mk_fun in
 211         let fst_fun, tl_funs =
 212           match mk_funs funs with hd :: tl -> hd, tl | [] -> assert false
 213         in
 214         let fst_row =
 215           let (params, name, ty, body, rec_param) = fst_fun in
 216           hvbox false true ([
 217             keyword "let";
 218             space;
 219             keyword rec_op;
 220             space;
 221             name] @
 222             params @
 223             [space; keyword "on" ; space ; rec_param ;space ] @
 224             (match ty with None -> [] | Some ty -> [builtin_symbol ":"; ty]) @
 225             [ builtin_symbol "\\def";
 226             break;
 227             top_pos body ])
 228         in
 229         let tl_rows =
 230           List.map
 231             (fun (params, name, ty, body, rec_param) ->
 232               [ break;
 233                 hvbox false true ([
 234                   keyword "and";
 235                   name] @
 236                   params @
 237                   [space; keyword "on" ; space; rec_param ;space ] @
 238                   (match ty with
 239                       None -> []
 240                     | Some ty -> [builtin_symbol ":"; ty]) @
 241                   [ builtin_symbol "\\def"; break; body ])])
 242             tl_funs
 243         in
 244         add_level_info Ast.let_in_prec
 245           ((hvbox false false
 246             (fst_row :: List.flatten tl_rows
 247              @ [ break; keyword "in"; break; k where ])))
 248     | Ast.Implicit -> builtin_symbol "?"
 249     | Ast.Meta (n, l) ->
 250         let local_context l =
 251             List.map (function None -> None | Some t -> Some (k t)) l
 252         in
 253         Ast.Meta(n, local_context l)
 254     | Ast.Sort sort -> aux_sort sort
 255     | Ast.Num _
 256     | Ast.Symbol _
 257     | Ast.Ident (_, None) | Ast.Ident (_, Some [])
 258     | Ast.Uri (_, None) | Ast.Uri (_, Some [])
 259     | Ast.Literal _
 260     | Ast.UserInput as leaf -> leaf
 261     | t -> CicNotationUtil.visit_ast ~special_k k t
 262   and aux_sort sort_kind =
 263     add_xml_attrs (RenderingAttrs.keyword_attributes `MathML)
 264       (Ast.Ident (string_of_sort_kind sort_kind, None))
 265   and aux_ty = function
 266     | None -> builtin_symbol "?"
 267     | Some ty -> k ty
 268   and aux_var = function
 269     | name, Some ty ->
 270         hvbox false true [
 271           builtin_symbol "("; name; builtin_symbol ":"; break; k ty;
 272           builtin_symbol ")" ]
 273     | name, None -> name
 274   and special_k = function
 275     | Ast.AttributedTerm (attrs, t) -> Ast.AttributedTerm (attrs, k t)
 276     | t ->
 277         prerr_endline ("unexpected special: " ^ CicNotationPp.pp_term t);
 278         assert false
 279   in
 280   aux t
 281
 282   (* persistent state *)
 283
 284 let level1_patterns21 = Hashtbl.create 211
 285
 286 let compiled21 = ref None
 287
 288 let pattern21_matrix = ref []
 289
 290 let get_compiled21 () =
 291   match !compiled21 with
 292   | None -> assert false
 293   | Some f -> Lazy.force f
 294
 295 let set_compiled21 f = compiled21 := Some f
 296
 297 let add_idrefs =
 298   List.fold_right (fun idref t -> Ast.AttributedTerm (`IdRef idref, t))
 299
 300 let instantiate21 idrefs env l1 =
 301   let rec subst_singleton pos env =
 302     function
 303       Ast.AttributedTerm (attr, t) ->
 304         Ast.AttributedTerm (attr, subst_singleton pos env t)
 305     | t -> CicNotationUtil.group (subst pos env t)
 306   and subst pos env = function
 307     | Ast.AttributedTerm (attr, t) ->
 308 (*         prerr_endline ("loosing attribute " ^ CicNotationPp.pp_attribute attr); *)
 309         subst pos env t
 310     | Ast.Variable var ->
 311         let name, expected_ty = CicNotationEnv.declaration_of_var var in
 312         let ty, value =
 313           try
 314             List.assoc name env
 315           with Not_found ->
 316             prerr_endline ("name " ^ name ^ " not found in environment");
 317             assert false
 318         in
 319         assert (CicNotationEnv.well_typed ty value); (* INVARIANT *)
 320         (* following assertion should be a conditional that makes this
 321          * instantiation fail *)
 322         assert (CicNotationEnv.well_typed expected_ty value);
 323         let value = CicNotationEnv.term_of_value value in
 324         let value =
 325           match expected_ty with
 326           | Env.TermType l -> Ast.AttributedTerm (`Level l,value)
 327           | _ -> value
 328         in
 329         [ value ]
 330     | Ast.Magic m -> subst_magic pos env m
 331     | Ast.Literal l as t ->
 332         let t = add_idrefs idrefs t in
 333         (match l with
 334         | `Keyword k -> [ add_keyword_attrs t ]
 335         | _ -> [ t ])
 336     | Ast.Layout l -> [ Ast.Layout (subst_layout pos env l) ]
 337     | t -> [ CicNotationUtil.visit_ast (subst_singleton pos env) t ]
 338   and subst_magic pos env = function
 339     | Ast.List0 (p, sep_opt)
 340     | Ast.List1 (p, sep_opt) ->
 341         let rec_decls = CicNotationEnv.declarations_of_term p in
 342         let rec_values =
 343           List.map (fun (n, _) -> CicNotationEnv.lookup_list env n) rec_decls
 344         in
 345         let values = CicNotationUtil.ncombine rec_values in
 346         let sep =
 347           match sep_opt with
 348             | None -> []
 349             | Some l -> [ Ast.Literal l ]
 350         in
 351         let rec instantiate_list acc = function
 352           | [] -> List.rev acc
 353           | value_set :: [] ->
 354               let env = CicNotationEnv.combine rec_decls value_set in
 355               instantiate_list (CicNotationUtil.group (subst pos env p) :: acc)
 356                 []
 357           | value_set :: tl ->
 358               let env = CicNotationEnv.combine rec_decls value_set in
 359               let terms = subst pos env p in
 360               instantiate_list (CicNotationUtil.group (terms @ sep) :: acc) tl
 361         in
 362         instantiate_list [] values
 363     | Ast.Opt p ->
 364         let opt_decls = CicNotationEnv.declarations_of_term p in
 365         let env =
 366           let rec build_env = function
 367             | [] -> []
 368             | (name, ty) :: tl ->
 369                   (* assumption: if one of the value is None then all are *)
 370                 (match CicNotationEnv.lookup_opt env name with
 371                 | None -> raise Exit
 372                 | Some v -> (name, (ty, v)) :: build_env tl)
 373           in
 374           try build_env opt_decls with Exit -> []
 375         in
 376           begin
 377             match env with
 378               | [] -> []
 379               | _ -> subst pos env p
 380           end
 381     | _ -> assert false (* impossible *)
 382   and subst_layout pos env = function
 383     | Ast.Box (kind, tl) ->
 384         let tl' = subst_children pos env tl in
 385         Ast.Box (kind, List.concat tl')
 386     | l -> CicNotationUtil.visit_layout (subst_singleton pos env) l
 387   and subst_children pos env =
 388     function
 389     | [] -> []
 390     | [ child ] ->
 391         let pos' =
 392           match pos with
 393           | `Inner -> `Right
 394           | `Left -> `Left
 395 (*           | `None -> assert false *)
 396           | `Right -> `Right
 397         in
 398         [ subst pos' env child ]
 399     | hd :: tl ->
 400         let pos' =
 401           match pos with
 402           | `Inner -> `Inner
 403           | `Left -> `Inner
 404 (*           | `None -> assert false *)
 405           | `Right -> `Right
 406         in
 407         (subst pos env hd) :: subst_children pos' env tl
 408   in
 409     subst_singleton `Left env l1
 410
 411 let rec pp_ast1 term =
 412   let rec pp_value = function
 413     | CicNotationEnv.NumValue _ as v -> v
 414     | CicNotationEnv.StringValue _ as v -> v
 415 (*     | CicNotationEnv.TermValue t when t == term -> CicNotationEnv.TermValue (pp_ast0 t pp_ast1) *)
 416     | CicNotationEnv.TermValue t -> CicNotationEnv.TermValue (pp_ast1 t)
 417     | CicNotationEnv.OptValue None as v -> v
 418     | CicNotationEnv.OptValue (Some v) ->
 419         CicNotationEnv.OptValue (Some (pp_value v))
 420     | CicNotationEnv.ListValue vl ->
 421         CicNotationEnv.ListValue (List.map pp_value vl)
 422   in
 423   let ast_env_of_env env =
 424     List.map (fun (var, (ty, value)) -> (var, (ty, pp_value value))) env
 425   in
 426 (* prerr_endline ("pattern matching from 2 to 1 on term " ^ CicNotationPp.pp_term term); *)
 427   match term with
 428   | Ast.AttributedTerm (attrs, term') ->
 429       Ast.AttributedTerm (attrs, pp_ast1 term')
 430   | _ ->
 431       (match (get_compiled21 ()) term with
 432       | None -> pp_ast0 term pp_ast1
 433       | Some (env, ctors, pid) ->
 434           let idrefs =
 435             List.flatten (List.map CicNotationUtil.get_idrefs ctors)
 436           in
 437           let l1 =
 438             try
 439               Hashtbl.find level1_patterns21 pid
 440             with Not_found -> assert false
 441           in
 442           instantiate21 idrefs (ast_env_of_env env) l1)
 443
 444 let load_patterns21 t =
 445   set_compiled21 (lazy (Content2presMatcher.Matcher21.compiler t))
 446
 447 let pp_ast ast =
 448   debug_print (lazy "pp_ast <-");
 449   let ast' = pp_ast1 ast in
 450   debug_print (lazy ("pp_ast -> " ^ CicNotationPp.pp_term ast'));
 451   ast'
 452
 453 exception Pretty_printer_not_found
 454
 455 let fill_pos_info l1_pattern = l1_pattern
 456 (*   let rec aux toplevel pos =
 457     function
 458     | Ast.Layout l ->
 459         (match l
 460
 461     | Ast.Magic m ->
 462         Ast.Box (
 463     | Ast.Variable _ as t -> add_pos_info pos t
 464     | t -> t
 465   in
 466   aux true l1_pattern *)
 467
 468 let counter = ref ~-1
 469 let reset () =
 470   counter := ~-1;
 471   Hashtbl.clear level1_patterns21
 472 ;;
 473 let fresh_id =
 474   fun () ->
 475     incr counter;
 476     !counter
 477
 478 let add_pretty_printer l2 (CicNotationParser.CL1P (l1,precedence)) =
 479   let id = fresh_id () in
 480   let l1' = add_level_info precedence (fill_pos_info l1) in
 481   let l2' = CicNotationUtil.strip_attributes l2 in
 482   Hashtbl.add level1_patterns21 id l1';
 483   pattern21_matrix := (l2', id) :: !pattern21_matrix;
 484   load_patterns21 !pattern21_matrix;
 485   id
 486
 487 let remove_pretty_printer id =
 488   (try
 489     Hashtbl.remove level1_patterns21 id;
 490   with Not_found -> raise Pretty_printer_not_found);
 491   pattern21_matrix := List.filter (fun (_, id') -> id <> id') !pattern21_matrix;
 492   load_patterns21 !pattern21_matrix
 493
 494   (* presentation -> content *)
 495
 496 let unopt_names names env =
 497   let rec aux acc = function
 498     | (name, (ty, v)) :: tl when List.mem name names ->
 499         (match ty, v with
 500         | Env.OptType ty, Env.OptValue (Some v) ->
 501             aux ((name, (ty, v)) :: acc) tl
 502         | _ -> assert false)
 503     | hd :: tl -> aux (hd :: acc) tl
 504     | [] -> acc
 505   in
 506   aux [] env
 507
 508 let head_names names env =
 509   let rec aux acc = function
 510     | (name, (ty, v)) :: tl when List.mem name names ->
 511         (match ty, v with
 512         | Env.ListType ty, Env.ListValue (v :: _) ->
 513             aux ((name, (ty, v)) :: acc) tl
 514         | _ -> assert false)
 515     | _ :: tl -> aux acc tl
 516       (* base pattern may contain only meta names, thus we trash all others *)
 517     | [] -> acc
 518   in
 519   aux [] env
 520
 521 let tail_names names env =
 522   let rec aux acc = function
 523     | (name, (ty, v)) :: tl when List.mem name names ->
 524         (match ty, v with
 525         | Env.ListType ty, Env.ListValue (_ :: vtl) ->
 526             aux ((name, (Env.ListType ty, Env.ListValue vtl)) :: acc) tl
 527         | _ -> assert false)
 528     | binding :: tl -> aux (binding :: acc) tl
 529     | [] -> acc
 530   in
 531   aux [] env
 532
 533 let instantiate_level2 env term =
 534 (*   prerr_endline ("istanzio: " ^ CicNotationPp.pp_term term); *)
 535   let fresh_env = ref [] in
 536   let lookup_fresh_name n =
 537     try
 538       List.assoc n !fresh_env
 539     with Not_found ->
 540       let new_name = CicNotationUtil.fresh_name () in
 541       fresh_env := (n, new_name) :: !fresh_env;
 542       new_name
 543   in
 544   let rec aux env term =
 545 (*    prerr_endline ("ENV " ^ CicNotationPp.pp_env env); *)
 546     match term with
 547     | Ast.AttributedTerm (a, term) -> (*Ast.AttributedTerm (a, *)aux env term
 548     | Ast.Appl terms -> Ast.Appl (List.map (aux env) terms)
 549     | Ast.Binder (binder, var, body) ->
 550         Ast.Binder (binder, aux_capture_var env var, aux env body)
 551     | Ast.Case (term, indty, outty_opt, patterns) ->
 552         Ast.Case (aux env term, indty, aux_opt env outty_opt,
 553           List.map (aux_branch env) patterns)
 554     | Ast.LetIn (var, t1, t3) ->
 555         Ast.LetIn (aux_capture_var env var, aux env t1, aux env t3)
 556     | Ast.LetRec (kind, definitions, body) ->
 557         Ast.LetRec (kind, List.map (aux_definition env) definitions,
 558           aux env body)
 559     | Ast.Uri (name, None) -> Ast.Uri (name, None)
 560     | Ast.Uri (name, Some substs) ->
 561         Ast.Uri (name, Some (aux_substs env substs))
 562     | Ast.Ident (name, Some substs) ->
 563         Ast.Ident (name, Some (aux_substs env substs))
 564     | Ast.Meta (index, substs) -> Ast.Meta (index, aux_meta_substs env substs)
 565
 566     | Ast.Implicit
 567     | Ast.Ident _
 568     | Ast.Num _
 569     | Ast.Sort _
 570     | Ast.Symbol _
 571     | Ast.UserInput -> term
 572
 573     | Ast.Magic magic -> aux_magic env magic
 574     | Ast.Variable var -> aux_variable env var
 575
 576     | _ -> assert false
 577   and aux_opt env = function
 578     | Some term -> Some (aux env term)
 579     | None -> None
 580   and aux_capture_var env (name, ty_opt) = (aux env name, aux_opt env ty_opt)
 581   and aux_branch env (pattern, term) =
 582     (aux_pattern env pattern, aux env term)
 583   and aux_pattern env =
 584    function
 585       Ast.Pattern (head, hrefs, vars) ->
 586        Ast.Pattern (head, hrefs, List.map (aux_capture_var env) vars)
 587     | Ast.Wildcard -> Ast.Wildcard
 588   and aux_definition env (params, var, term, i) =
 589     (List.map (aux_capture_var env) params, aux_capture_var env var, aux env term, i)
 590   and aux_substs env substs =
 591     List.map (fun (name, term) -> (name, aux env term)) substs
 592   and aux_meta_substs env meta_substs = List.map (aux_opt env) meta_substs
 593   and aux_variable env = function
 594     | Ast.NumVar name -> Ast.Num (Env.lookup_num env name, 0)
 595     | Ast.IdentVar name -> Ast.Ident (Env.lookup_string env name, None)
 596     | Ast.TermVar (name,(Ast.Level l|Ast.Self l)) ->
 597         Ast.AttributedTerm (`Level l,Env.lookup_term env name)
 598     | Ast.FreshVar name -> Ast.Ident (lookup_fresh_name name, None)
 599     | Ast.Ascription (term, name) -> assert false
 600   and aux_magic env = function
 601     | Ast.Default (some_pattern, none_pattern) ->
 602         let some_pattern_names = CicNotationUtil.names_of_term some_pattern in
 603         let none_pattern_names = CicNotationUtil.names_of_term none_pattern in
 604         let opt_names =
 605           List.filter
 606             (fun name -> not (List.mem name none_pattern_names))
 607             some_pattern_names
 608         in
 609         (match opt_names with
 610         | [] -> assert false (* some pattern must contain at least 1 name *)
 611         | (name :: _) as names ->
 612             (match Env.lookup_value env name with
 613             | Env.OptValue (Some _) ->
 614                 (* assumption: if "name" above is bound to Some _, then all
 615                  * names returned by "meta_names_of" are bound to Some _ as well
 616                  *)
 617                 aux (unopt_names names env) some_pattern
 618             | Env.OptValue None -> aux env none_pattern
 619             | _ ->
 620                 prerr_endline (sprintf
 621                   "lookup of %s in env %s did not return an optional value"
 622                   name (CicNotationPp.pp_env env));
 623                 assert false))
 624     | Ast.Fold (`Left, base_pattern, names, rec_pattern) ->
 625         let acc_name = List.hd names in (* names can't be empty, cfr. parser *)
 626         let meta_names =
 627           List.filter ((<>) acc_name)
 628             (CicNotationUtil.names_of_term rec_pattern)
 629         in
 630         (match meta_names with
 631         | [] -> assert false (* as above *)
 632         | (name :: _) as names ->
 633             let rec instantiate_fold_left acc env' =
 634               match Env.lookup_value env' name with
 635               | Env.ListValue (_ :: _) ->
 636                   instantiate_fold_left
 637                     (let acc_binding =
 638                       acc_name, (Env.TermType 0, Env.TermValue acc)
 639                      in
 640                      aux (acc_binding :: head_names names env') rec_pattern)
 641                     (tail_names names env')
 642               | Env.ListValue [] -> acc
 643               | _ -> assert false
 644             in
 645             instantiate_fold_left (aux env base_pattern) env)
 646     | Ast.Fold (`Right, base_pattern, names, rec_pattern) ->
 647         let acc_name = List.hd names in (* names can't be empty, cfr. parser *)
 648         let meta_names =
 649           List.filter ((<>) acc_name)
 650             (CicNotationUtil.names_of_term rec_pattern)
 651         in
 652         (match meta_names with
 653         | [] -> assert false (* as above *)
 654         | (name :: _) as names ->
 655             let rec instantiate_fold_right env' =
 656               match Env.lookup_value env' name with
 657               | Env.ListValue (_ :: _) ->
 658                   let acc = instantiate_fold_right (tail_names names env') in
 659                   let acc_binding =
 660                     acc_name, (Env.TermType 0, Env.TermValue acc)
 661                   in
 662                   aux (acc_binding :: head_names names env') rec_pattern
 663               | Env.ListValue [] -> aux env base_pattern
 664               | _ -> assert false
 665             in
 666             instantiate_fold_right env)
 667     | Ast.If (_, p_true, p_false) as t ->
 668         aux env (CicNotationUtil.find_branch (Ast.Magic t))
 669     | Ast.Fail -> assert false
 670     | _ -> assert false
 671   in
 672   aux env term
 673
 674   (* initialization *)
 675
 676 let _ = load_patterns21 []
 677
 678
 679