helm/software/components/content_pres/termContentPres.ml

   1 (* Copyright (C) 2004-2005, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://helm.cs.unibo.it/
  24  *)
  25
  26 (* $Id$ *)
  27
  28 open Printf
  29
  30 module Ast = CicNotationPt
  31 module Env = CicNotationEnv
  32
  33 let debug = false
  34 let debug_print s = if debug then prerr_endline (Lazy.force s) else ()
  35
  36 type pattern_id = int
  37 type pretty_printer_id = pattern_id
  38
  39 let resolve_binder = function
  40   | `Lambda -> "\\lambda"
  41   | `Pi -> "\\Pi"
  42   | `Forall -> "\\forall"
  43   | `Exists -> "\\exists"
  44
  45 let add_level_info prec t = Ast.AttributedTerm (`Level prec, t)
  46
  47 let rec top_pos t = add_level_info ~-1 t
  48
  49 let rec remove_level_info =
  50   function
  51   | Ast.AttributedTerm (`Level _, t) -> remove_level_info t
  52   | Ast.AttributedTerm (a, t) -> Ast.AttributedTerm (a, remove_level_info t)
  53   | t -> t
  54
  55 let add_xml_attrs attrs t =
  56   if attrs = [] then t else Ast.AttributedTerm (`XmlAttrs attrs, t)
  57
  58 let add_keyword_attrs =
  59   add_xml_attrs (RenderingAttrs.keyword_attributes `MathML)
  60
  61 let box kind spacing indent content =
  62   Ast.Layout (Ast.Box ((kind, spacing, indent), content))
  63
  64 let hbox = box Ast.H
  65 let vbox = box Ast.V
  66 let hvbox = box Ast.HV
  67 let hovbox = box Ast.HOV
  68 let break = Ast.Layout Ast.Break
  69 let space = Ast.Literal (`Symbol " ")
  70 let builtin_symbol s = Ast.Literal (`Symbol s)
  71 let keyword k = add_keyword_attrs (Ast.Literal (`Keyword k))
  72
  73 let number s =
  74   add_xml_attrs (RenderingAttrs.number_attributes `MathML)
  75     (Ast.Literal (`Number s))
  76
  77 let ident i =
  78   add_xml_attrs (RenderingAttrs.ident_attributes `MathML) (Ast.Ident (i, None))
  79
  80 let ident_w_href href i =
  81   match href with
  82   | None -> ident i
  83   | Some href ->
  84       let href = UriManager.string_of_uri href in
  85       add_xml_attrs [Some "xlink", "href", href] (ident i)
  86
  87 let binder_symbol s =
  88   add_xml_attrs (RenderingAttrs.builtin_symbol_attributes `MathML)
  89     (builtin_symbol s)
  90
  91 let string_of_sort_kind = function
  92   | `Prop -> "Prop"
  93   | `Set -> "Set"
  94   | `CProp _ -> "CProp"
  95   | `Type _ -> "Type"
  96
  97 let pp_ast0 t k =
  98   let rec aux =
  99     function
 100     | Ast.Appl ts ->
 101         let rec aux_args pos =
 102           function
 103           | [] -> []
 104           | [ last ] ->
 105               let last = k last in
 106               [ last ]
 107           | hd :: tl ->
 108               (k hd) :: aux_args `Inner tl
 109         in
 110         add_level_info Ast.apply_prec
 111           (hovbox true true (CicNotationUtil.dress break (aux_args `Left ts)))
 112     | Ast.Binder (binder_kind, (id, ty), body) ->
 113         add_level_info Ast.binder_prec
 114           (hvbox false true
 115             [ binder_symbol (resolve_binder binder_kind);
 116               k id; builtin_symbol ":"; aux_ty ty; break;
 117               builtin_symbol "."; k body ])
 118     | Ast.Case (what, indty_opt, outty_opt, patterns) ->
 119         let outty_box =
 120           match outty_opt with
 121           | None -> []
 122           | Some outty ->
 123               [ space; keyword "return"; space; break; remove_level_info (k outty)]
 124         in
 125         let indty_box =
 126           match indty_opt with
 127           | None -> []
 128           | Some (indty, href) -> [ space; keyword "in"; space; break; ident_w_href href indty ]
 129         in
 130         let match_box =
 131           hvbox false false [
 132            hvbox false true [
 133             hvbox false true [keyword "match"; space; break; top_pos (k what)];
 134             break;
 135             hvbox false true indty_box;
 136             break;
 137             hvbox false true outty_box
 138            ];
 139            break;
 140            space;
 141            keyword "with";
 142            space
 143          ]
 144         in
 145         let mk_case_pattern =
 146          function
 147             Ast.Pattern (head, href, vars) ->
 148              hbox true false (ident_w_href href head :: List.map aux_var vars)
 149           | Ast.Wildcard -> builtin_symbol "_"
 150         in
 151         let patterns' =
 152           List.map
 153             (fun (lhs, rhs) ->
 154               remove_level_info
 155                 (hvbox false true [
 156                   hbox false true [
 157                     mk_case_pattern lhs; builtin_symbol "\\Rightarrow" ];
 158                   break; top_pos (k rhs) ]))
 159             patterns
 160         in
 161         let patterns'' =
 162           let rec aux_patterns = function
 163             | [] -> assert false
 164             | [ last ] ->
 165                 [ break;
 166                   hbox false false [
 167                     builtin_symbol "|";
 168                     last; builtin_symbol "]" ] ]
 169             | hd :: tl ->
 170                 [ break; hbox false false [ builtin_symbol "|"; hd ] ]
 171                 @ aux_patterns tl
 172           in
 173           match patterns' with
 174           | [] ->
 175               [ hbox false false [ builtin_symbol "["; builtin_symbol "]" ] ]
 176           | [ one ] ->
 177               [ hbox false false [
 178                 builtin_symbol "["; one; builtin_symbol "]" ] ]
 179           | hd :: tl ->
 180               hbox false false [ builtin_symbol "["; hd ]
 181               :: aux_patterns tl
 182         in
 183         add_level_info Ast.simple_prec
 184           (hvbox false false [
 185             hvbox false false ([match_box]); break;
 186             hbox false false [ hvbox false false patterns'' ] ])
 187     | Ast.Cast (bo, ty) ->
 188         add_level_info Ast.simple_prec
 189           (hvbox false true [
 190             builtin_symbol "("; top_pos (k bo); break; builtin_symbol ":";
 191             top_pos (k ty); builtin_symbol ")"])
 192     | Ast.LetIn (var, s, t) ->
 193         add_level_info Ast.let_in_prec
 194           (hvbox false true [
 195             hvbox false true [
 196               keyword "let"; space;
 197               hvbox false true [
 198                 aux_var var; space;
 199                 builtin_symbol "\\def"; break; top_pos (k s) ];
 200               break; space; keyword "in" ];
 201             break;
 202             k t ])
 203     | Ast.LetRec (rec_kind, funs, where) ->
 204         let rec_op =
 205           match rec_kind with `Inductive -> "rec" | `CoInductive -> "corec"
 206         in
 207         let mk_fun (args, (name,ty), body, rec_param) =
 208          List.map aux_var args ,k name, HExtlib.map_option k ty, k body,
 209            fst (List.nth args rec_param)
 210         in
 211         let mk_funs = List.map mk_fun in
 212         let fst_fun, tl_funs =
 213           match mk_funs funs with hd :: tl -> hd, tl | [] -> assert false
 214         in
 215         let fst_row =
 216           let (params, name, ty, body, rec_param) = fst_fun in
 217           hvbox false true ([
 218             keyword "let";
 219             space;
 220             keyword rec_op;
 221             space;
 222             name] @
 223             params @
 224             [space; keyword "on" ; space ; rec_param ;space ] @
 225             (match ty with None -> [] | Some ty -> [builtin_symbol ":"; ty]) @
 226             [ builtin_symbol "\\def";
 227             break;
 228             top_pos body ])
 229         in
 230         let tl_rows =
 231           List.map
 232             (fun (params, name, ty, body, rec_param) ->
 233               [ break;
 234                 hvbox false true ([
 235                   keyword "and";
 236                   name] @
 237                   params @
 238                   [space; keyword "on" ; space; rec_param ;space ] @
 239                   (match ty with
 240                       None -> []
 241                     | Some ty -> [builtin_symbol ":"; ty]) @
 242                   [ builtin_symbol "\\def"; break; body ])])
 243             tl_funs
 244         in
 245         add_level_info Ast.let_in_prec
 246           ((hvbox false false
 247             (fst_row :: List.flatten tl_rows
 248              @ [ break; keyword "in"; break; k where ])))
 249     | Ast.Implicit -> builtin_symbol "?"
 250     | Ast.Meta (n, l) ->
 251         let local_context l =
 252             List.map (function None -> None | Some t -> Some (k t)) l
 253         in
 254         Ast.Meta(n, local_context l)
 255     | Ast.Sort sort -> aux_sort sort
 256     | Ast.Num _
 257     | Ast.Symbol _
 258     | Ast.Ident (_, None) | Ast.Ident (_, Some [])
 259     | Ast.Uri (_, None) | Ast.Uri (_, Some [])
 260     | Ast.Literal _
 261     | Ast.UserInput as leaf -> leaf
 262     | t -> CicNotationUtil.visit_ast ~special_k k t
 263   and aux_sort sort_kind =
 264     add_xml_attrs (RenderingAttrs.keyword_attributes `MathML)
 265       (Ast.Ident (string_of_sort_kind sort_kind, None))
 266   and aux_ty = function
 267     | None -> builtin_symbol "?"
 268     | Some ty -> k ty
 269   and aux_var = function
 270     | name, Some ty ->
 271         hvbox false true [
 272           builtin_symbol "("; name; builtin_symbol ":"; break; k ty;
 273           builtin_symbol ")" ]
 274     | name, None -> name
 275   and special_k = function
 276     | Ast.AttributedTerm (attrs, t) -> Ast.AttributedTerm (attrs, k t)
 277     | t ->
 278         prerr_endline ("unexpected special: " ^ CicNotationPp.pp_term t);
 279         assert false
 280   in
 281   aux t
 282
 283   (* persistent state *)
 284
 285 let level1_patterns21 = Hashtbl.create 211
 286
 287 let compiled21 = ref None
 288
 289 let pattern21_matrix = ref []
 290
 291 let get_compiled21 () =
 292   match !compiled21 with
 293   | None -> assert false
 294   | Some f -> Lazy.force f
 295
 296 let set_compiled21 f = compiled21 := Some f
 297
 298 let add_idrefs =
 299   List.fold_right (fun idref t -> Ast.AttributedTerm (`IdRef idref, t))
 300
 301 let instantiate21 idrefs env l1 =
 302   let rec subst_singleton pos env =
 303     function
 304       Ast.AttributedTerm (attr, t) ->
 305         Ast.AttributedTerm (attr, subst_singleton pos env t)
 306     | t -> CicNotationUtil.group (subst pos env t)
 307   and subst pos env = function
 308     | Ast.AttributedTerm (attr, t) ->
 309 (*         prerr_endline ("loosing attribute " ^ CicNotationPp.pp_attribute attr); *)
 310         subst pos env t
 311     | Ast.Variable var ->
 312         let name, expected_ty = CicNotationEnv.declaration_of_var var in
 313         let ty, value =
 314           try
 315             List.assoc name env
 316           with Not_found ->
 317             prerr_endline ("name " ^ name ^ " not found in environment");
 318             assert false
 319         in
 320         assert (CicNotationEnv.well_typed ty value); (* INVARIANT *)
 321         (* following assertion should be a conditional that makes this
 322          * instantiation fail *)
 323         assert (CicNotationEnv.well_typed expected_ty value);
 324         let value = CicNotationEnv.term_of_value value in
 325         let value =
 326           match expected_ty with
 327           | Env.TermType (Some l) ->
 328               Ast.AttributedTerm (`Level l,value)
 329           | _ -> value
 330         in
 331         [ value ]
 332     | Ast.Magic m -> subst_magic pos env m
 333     | Ast.Literal l as t ->
 334         let t = add_idrefs idrefs t in
 335         (match l with
 336         | `Keyword k -> [ add_keyword_attrs t ]
 337         | _ -> [ t ])
 338     | Ast.Layout l -> [ Ast.Layout (subst_layout pos env l) ]
 339     | t -> [ CicNotationUtil.visit_ast (subst_singleton pos env) t ]
 340   and subst_magic pos env = function
 341     | Ast.List0 (p, sep_opt)
 342     | Ast.List1 (p, sep_opt) ->
 343         let rec_decls = CicNotationEnv.declarations_of_term p in
 344         let rec_values =
 345           List.map (fun (n, _) -> CicNotationEnv.lookup_list env n) rec_decls
 346         in
 347         let values = CicNotationUtil.ncombine rec_values in
 348         let sep =
 349           match sep_opt with
 350             | None -> []
 351             | Some l -> [ Ast.Literal l ]
 352         in
 353         let rec instantiate_list acc = function
 354           | [] -> List.rev acc
 355           | value_set :: [] ->
 356               let env = CicNotationEnv.combine rec_decls value_set in
 357               instantiate_list (CicNotationUtil.group (subst pos env p) :: acc)
 358                 []
 359           | value_set :: tl ->
 360               let env = CicNotationEnv.combine rec_decls value_set in
 361               let terms = subst pos env p in
 362               instantiate_list (CicNotationUtil.group (terms @ sep) :: acc) tl
 363         in
 364         instantiate_list [] values
 365     | Ast.Opt p ->
 366         let opt_decls = CicNotationEnv.declarations_of_term p in
 367         let env =
 368           let rec build_env = function
 369             | [] -> []
 370             | (name, ty) :: tl ->
 371                   (* assumption: if one of the value is None then all are *)
 372                 (match CicNotationEnv.lookup_opt env name with
 373                 | None -> raise Exit
 374                 | Some v -> (name, (ty, v)) :: build_env tl)
 375           in
 376           try build_env opt_decls with Exit -> []
 377         in
 378           begin
 379             match env with
 380               | [] -> []
 381               | _ -> subst pos env p
 382           end
 383     | _ -> assert false (* impossible *)
 384   and subst_layout pos env = function
 385     | Ast.Box (kind, tl) ->
 386         let tl' = subst_children pos env tl in
 387         Ast.Box (kind, List.concat tl')
 388     | l -> CicNotationUtil.visit_layout (subst_singleton pos env) l
 389   and subst_children pos env =
 390     function
 391     | [] -> []
 392     | [ child ] ->
 393         let pos' =
 394           match pos with
 395           | `Inner -> `Right
 396           | `Left -> `Left
 397 (*           | `None -> assert false *)
 398           | `Right -> `Right
 399         in
 400         [ subst pos' env child ]
 401     | hd :: tl ->
 402         let pos' =
 403           match pos with
 404           | `Inner -> `Inner
 405           | `Left -> `Inner
 406 (*           | `None -> assert false *)
 407           | `Right -> `Right
 408         in
 409         (subst pos env hd) :: subst_children pos' env tl
 410   in
 411     subst_singleton `Left env l1
 412
 413 let rec pp_ast1 term =
 414   let rec pp_value = function
 415     | CicNotationEnv.NumValue _ as v -> v
 416     | CicNotationEnv.StringValue _ as v -> v
 417 (*     | CicNotationEnv.TermValue t when t == term -> CicNotationEnv.TermValue (pp_ast0 t pp_ast1) *)
 418     | CicNotationEnv.TermValue t -> CicNotationEnv.TermValue (pp_ast1 t)
 419     | CicNotationEnv.OptValue None as v -> v
 420     | CicNotationEnv.OptValue (Some v) ->
 421         CicNotationEnv.OptValue (Some (pp_value v))
 422     | CicNotationEnv.ListValue vl ->
 423         CicNotationEnv.ListValue (List.map pp_value vl)
 424   in
 425   let ast_env_of_env env =
 426     List.map (fun (var, (ty, value)) -> (var, (ty, pp_value value))) env
 427   in
 428 (* prerr_endline ("pattern matching from 2 to 1 on term " ^ CicNotationPp.pp_term term); *)
 429   match term with
 430   | Ast.AttributedTerm (attrs, term') ->
 431       Ast.AttributedTerm (attrs, pp_ast1 term')
 432   | _ ->
 433       (match (get_compiled21 ()) term with
 434       | None -> pp_ast0 term pp_ast1
 435       | Some (env, ctors, pid) ->
 436           let idrefs =
 437             List.flatten (List.map CicNotationUtil.get_idrefs ctors)
 438           in
 439           let l1 =
 440             try
 441               Hashtbl.find level1_patterns21 pid
 442             with Not_found -> assert false
 443           in
 444           instantiate21 idrefs (ast_env_of_env env) l1)
 445
 446 let load_patterns21 t =
 447   set_compiled21 (lazy (Content2presMatcher.Matcher21.compiler t))
 448
 449 let pp_ast ast =
 450   debug_print (lazy "pp_ast <-");
 451   let ast' = pp_ast1 ast in
 452   debug_print (lazy ("pp_ast -> " ^ CicNotationPp.pp_term ast'));
 453   ast'
 454
 455 exception Pretty_printer_not_found
 456
 457 let fill_pos_info l1_pattern = l1_pattern
 458 (*   let rec aux toplevel pos =
 459     function
 460     | Ast.Layout l ->
 461         (match l
 462
 463     | Ast.Magic m ->
 464         Ast.Box (
 465     | Ast.Variable _ as t -> add_pos_info pos t
 466     | t -> t
 467   in
 468   aux true l1_pattern *)
 469
 470 let counter = ref ~-1
 471 let reset () =
 472   counter := ~-1;
 473   Hashtbl.clear level1_patterns21
 474 ;;
 475 let fresh_id =
 476   fun () ->
 477     incr counter;
 478     !counter
 479
 480 let add_pretty_printer l2 (CicNotationParser.CL1P (l1,precedence)) =
 481   let id = fresh_id () in
 482   let l1' = add_level_info precedence (fill_pos_info l1) in
 483   let l2' = CicNotationUtil.strip_attributes l2 in
 484   Hashtbl.add level1_patterns21 id l1';
 485   pattern21_matrix := (l2', id) :: !pattern21_matrix;
 486   load_patterns21 !pattern21_matrix;
 487   id
 488
 489 let remove_pretty_printer id =
 490   (try
 491     Hashtbl.remove level1_patterns21 id;
 492   with Not_found -> raise Pretty_printer_not_found);
 493   pattern21_matrix := List.filter (fun (_, id') -> id <> id') !pattern21_matrix;
 494   load_patterns21 !pattern21_matrix
 495
 496   (* presentation -> content *)
 497
 498 let unopt_names names env =
 499   let rec aux acc = function
 500     | (name, (ty, v)) :: tl when List.mem name names ->
 501         (match ty, v with
 502         | Env.OptType ty, Env.OptValue (Some v) ->
 503             aux ((name, (ty, v)) :: acc) tl
 504         | _ -> assert false)
 505     | hd :: tl -> aux (hd :: acc) tl
 506     | [] -> acc
 507   in
 508   aux [] env
 509
 510 let head_names names env =
 511   let rec aux acc = function
 512     | (name, (ty, v)) :: tl when List.mem name names ->
 513         (match ty, v with
 514         | Env.ListType ty, Env.ListValue (v :: _) ->
 515             aux ((name, (ty, v)) :: acc) tl
 516         | _ -> assert false)
 517     | _ :: tl -> aux acc tl
 518       (* base pattern may contain only meta names, thus we trash all others *)
 519     | [] -> acc
 520   in
 521   aux [] env
 522
 523 let tail_names names env =
 524   let rec aux acc = function
 525     | (name, (ty, v)) :: tl when List.mem name names ->
 526         (match ty, v with
 527         | Env.ListType ty, Env.ListValue (_ :: vtl) ->
 528             aux ((name, (Env.ListType ty, Env.ListValue vtl)) :: acc) tl
 529         | _ -> assert false)
 530     | binding :: tl -> aux (binding :: acc) tl
 531     | [] -> acc
 532   in
 533   aux [] env
 534
 535 let instantiate_level2 env term =
 536   let fresh_env = ref [] in
 537   let lookup_fresh_name n =
 538     try
 539       List.assoc n !fresh_env
 540     with Not_found ->
 541       let new_name = CicNotationUtil.fresh_name () in
 542       fresh_env := (n, new_name) :: !fresh_env;
 543       new_name
 544   in
 545   let rec aux env term =
 546 (*    prerr_endline ("ENV " ^ CicNotationPp.pp_env env); *)
 547     match term with
 548     | Ast.AttributedTerm (_, term) -> aux env term
 549     | Ast.Appl terms -> Ast.Appl (List.map (aux env) terms)
 550     | Ast.Binder (binder, var, body) ->
 551         Ast.Binder (binder, aux_capture_var env var, aux env body)
 552     | Ast.Case (term, indty, outty_opt, patterns) ->
 553         Ast.Case (aux env term, indty, aux_opt env outty_opt,
 554           List.map (aux_branch env) patterns)
 555     | Ast.LetIn (var, t1, t3) ->
 556         Ast.LetIn (aux_capture_var env var, aux env t1, aux env t3)
 557     | Ast.LetRec (kind, definitions, body) ->
 558         Ast.LetRec (kind, List.map (aux_definition env) definitions,
 559           aux env body)
 560     | Ast.Uri (name, None) -> Ast.Uri (name, None)
 561     | Ast.Uri (name, Some substs) ->
 562         Ast.Uri (name, Some (aux_substs env substs))
 563     | Ast.Ident (name, Some substs) ->
 564         Ast.Ident (name, Some (aux_substs env substs))
 565     | Ast.Meta (index, substs) -> Ast.Meta (index, aux_meta_substs env substs)
 566
 567     | Ast.Implicit
 568     | Ast.Ident _
 569     | Ast.Num _
 570     | Ast.Sort _
 571     | Ast.Symbol _
 572     | Ast.UserInput -> term
 573
 574     | Ast.Magic magic -> aux_magic env magic
 575     | Ast.Variable var -> aux_variable env var
 576
 577     | _ -> assert false
 578   and aux_opt env = function
 579     | Some term -> Some (aux env term)
 580     | None -> None
 581   and aux_capture_var env (name, ty_opt) = (aux env name, aux_opt env ty_opt)
 582   and aux_branch env (pattern, term) =
 583     (aux_pattern env pattern, aux env term)
 584   and aux_pattern env =
 585    function
 586       Ast.Pattern (head, hrefs, vars) ->
 587        Ast.Pattern (head, hrefs, List.map (aux_capture_var env) vars)
 588     | Ast.Wildcard -> Ast.Wildcard
 589   and aux_definition env (params, var, term, i) =
 590     (List.map (aux_capture_var env) params, aux_capture_var env var, aux env term, i)
 591   and aux_substs env substs =
 592     List.map (fun (name, term) -> (name, aux env term)) substs
 593   and aux_meta_substs env meta_substs = List.map (aux_opt env) meta_substs
 594   and aux_variable env = function
 595     | Ast.NumVar name -> Ast.Num (Env.lookup_num env name, 0)
 596     | Ast.IdentVar name -> Ast.Ident (Env.lookup_string env name, None)
 597     | Ast.TermVar (name,None) ->
 598         Env.lookup_term env name
 599     | Ast.TermVar (name,Some l) ->
 600         Ast.AttributedTerm (`Level l,Env.lookup_term env name)
 601     | Ast.FreshVar name -> Ast.Ident (lookup_fresh_name name, None)
 602     | Ast.Ascription (term, name) -> assert false
 603   and aux_magic env = function
 604     | Ast.Default (some_pattern, none_pattern) ->
 605         let some_pattern_names = CicNotationUtil.names_of_term some_pattern in
 606         let none_pattern_names = CicNotationUtil.names_of_term none_pattern in
 607         let opt_names =
 608           List.filter
 609             (fun name -> not (List.mem name none_pattern_names))
 610             some_pattern_names
 611         in
 612         (match opt_names with
 613         | [] -> assert false (* some pattern must contain at least 1 name *)
 614         | (name :: _) as names ->
 615             (match Env.lookup_value env name with
 616             | Env.OptValue (Some _) ->
 617                 (* assumption: if "name" above is bound to Some _, then all
 618                  * names returned by "meta_names_of" are bound to Some _ as well
 619                  *)
 620                 aux (unopt_names names env) some_pattern
 621             | Env.OptValue None -> aux env none_pattern
 622             | _ ->
 623                 prerr_endline (sprintf
 624                   "lookup of %s in env %s did not return an optional value"
 625                   name (CicNotationPp.pp_env env));
 626                 assert false))
 627     | Ast.Fold (`Left, base_pattern, names, rec_pattern) ->
 628         let acc_name = List.hd names in (* names can't be empty, cfr. parser *)
 629         let meta_names =
 630           List.filter ((<>) acc_name)
 631             (CicNotationUtil.names_of_term rec_pattern)
 632         in
 633         (match meta_names with
 634         | [] -> assert false (* as above *)
 635         | (name :: _) as names ->
 636             let rec instantiate_fold_left acc env' =
 637               match Env.lookup_value env' name with
 638               | Env.ListValue (_ :: _) ->
 639                   instantiate_fold_left
 640                     (let acc_binding =
 641                       acc_name, (Env.TermType None, Env.TermValue acc)
 642                      in
 643                      aux (acc_binding :: head_names names env') rec_pattern)
 644                     (tail_names names env')
 645               | Env.ListValue [] -> acc
 646               | _ -> assert false
 647             in
 648             instantiate_fold_left (aux env base_pattern) env)
 649     | Ast.Fold (`Right, base_pattern, names, rec_pattern) ->
 650         let acc_name = List.hd names in (* names can't be empty, cfr. parser *)
 651         let meta_names =
 652           List.filter ((<>) acc_name)
 653             (CicNotationUtil.names_of_term rec_pattern)
 654         in
 655         (match meta_names with
 656         | [] -> assert false (* as above *)
 657         | (name :: _) as names ->
 658             let rec instantiate_fold_right env' =
 659               match Env.lookup_value env' name with
 660               | Env.ListValue (_ :: _) ->
 661                   let acc = instantiate_fold_right (tail_names names env') in
 662                   let acc_binding =
 663                     acc_name, (Env.TermType None, Env.TermValue acc)
 664                   in
 665                   aux (acc_binding :: head_names names env') rec_pattern
 666               | Env.ListValue [] -> aux env base_pattern
 667               | _ -> assert false
 668             in
 669             instantiate_fold_right env)
 670     | Ast.If (_, p_true, p_false) as t ->
 671         aux env (CicNotationUtil.find_branch (Ast.Magic t))
 672     | Ast.Fail -> assert false
 673     | _ -> assert false
 674   in
 675   aux env term
 676
 677   (* initialization *)
 678
 679 let _ = load_patterns21 []
 680
 681
 682