helm/software/components/disambiguation/multiPassDisambiguator.ml

   1 (* Copyright (C) 2004-2005, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://helm.cs.unibo.it/
  24  *)
  25
  26 (* $Id$ *)
  27
  28 open Printf
  29
  30 let debug = false;;
  31 let debug_print s =
  32  if debug then prerr_endline (Lazy.force s);;
  33
  34 exception Ambiguous_input
  35 (* the integer is an offset to be added to each location *)
  36 exception DisambiguationError of
  37  int *
  38  ((Stdpp.location list * string * string) list *
  39   (DisambiguateTypes.domain_item * string) list *
  40   (Stdpp.location * string) Lazy.t * bool) list list
  41   (** parameters are: option name, error message *)
  42
  43 let mono_uris_callback ~selection_mode ?ok
  44           ?(enable_button_for_non_vars = true) ~title ~msg ~id =
  45  if Helm_registry.get_opt_default Helm_registry.get_bool ~default:true
  46       "matita.auto_disambiguation"
  47  then
  48   function l -> l
  49  else
  50   raise Ambiguous_input
  51
  52 let mono_interp_callback _ _ _ = raise Ambiguous_input
  53
  54 let _choose_uris_callback = ref mono_uris_callback
  55 let _choose_interp_callback = ref mono_interp_callback
  56 let set_choose_uris_callback f = _choose_uris_callback := f
  57 let set_choose_interp_callback f = _choose_interp_callback := f
  58
  59 module Callbacks =
  60   struct
  61     let interactive_user_uri_choice = !_choose_uris_callback
  62
  63     let interactive_interpretation_choice interp =
  64       !_choose_interp_callback interp
  65
  66     let input_or_locate_uri ~(title:string) ?id () = None
  67       (* Zack: I try to avoid using this callback. I therefore assume that
  68       * the presence of an identifier that can't be resolved via "locate"
  69       * query is a syntax error *)
  70   end
  71
  72 module Disambiguator = Disambiguate.Make (Callbacks)
  73
  74 (* implement module's API *)
  75
  76 let only_one_pass = ref false;;
  77
  78 let passes () = (* <fresh_instances?, aliases, coercions?> *)
  79  if !only_one_pass then
  80   [ (true, `Mono, false) ]
  81  else
  82   [ (true, `Mono, false);
  83     (true, `Multi, false);
  84     (true, `Mono, true);
  85     (true, `Multi, true);
  86     (true, `Library, false);
  87       (* for demo to reduce the number of interpretations *)
  88     (true, `Library, true);
  89   ]
  90 ;;
  91
  92 let drop_aliases ?(minimize_instances=false) ~description_of_alias
  93  (choices, user_asked)
  94 =
  95  let module D = DisambiguateTypes in
  96  let compare ci1 ci2 = description_of_alias ci1 = description_of_alias ci2 in
  97  let minimize d =
  98   if not minimize_instances then
  99    d
 100   else
 101    let rec aux =
 102     function
 103        [] -> []
 104      | (D.Symbol (s,n),ci1) as he::tl when n > 0 ->
 105          if
 106           List.for_all
 107            (function
 108                (D.Symbol (s2,_),ci2) -> s2 <> s || compare ci1 ci2
 109              | _ -> true
 110            ) d
 111          then
 112           (D.Symbol (s,0),ci1)::(aux tl)
 113          else
 114           he::(aux tl)
 115      | (D.Num n,ci1) as he::tl when n > 0 ->
 116          if
 117           List.for_all
 118            (function (D.Num _,ci2) -> compare ci1 ci2 | _ -> true) d
 119          then
 120           (D.Num 0,ci1)::(aux tl)
 121          else
 122           he::(aux tl)
 123       | he::tl -> he::(aux tl)
 124    in
 125     aux d
 126  in
 127   (List.map (fun (d, a, b, c, e) -> minimize d, a, b, c, e) choices),
 128   user_asked
 129
 130 let drop_aliases_and_clear_diff (choices, user_asked) =
 131   (List.map (fun (_, a, b, c, d) -> [], a, b, c, d) choices),
 132   user_asked
 133
 134 let disambiguate_thing ~description_of_alias ~passes ~aliases ~universe ~f thing
 135 =
 136   assert (universe <> None);
 137   let library = false, DisambiguateTypes.Environment.empty, None in
 138   let multi_aliases = false, DisambiguateTypes.Environment.empty, universe in
 139   let mono_aliases = true, aliases, Some DisambiguateTypes.Environment.empty in
 140   let passes =
 141     List.map
 142      (function (fresh_instances,env,use_coercions) ->
 143        fresh_instances,
 144        (match env with `Mono -> mono_aliases | `Multi -> multi_aliases |
 145        `Library -> library),
 146        use_coercions) passes in
 147   let try_pass (fresh_instances, (_, aliases, universe), use_coercions) =
 148     f ~fresh_instances ~aliases ~universe ~use_coercions thing
 149   in
 150   let set_aliases (instances,(use_mono_aliases,_,_),_) (_, user_asked as res) =
 151    if use_mono_aliases then
 152     drop_aliases ~minimize_instances:true ~description_of_alias res (* one shot aliases *)
 153    else if user_asked then
 154     drop_aliases ~minimize_instances:true ~description_of_alias res (* one shot aliases *)
 155    else
 156     drop_aliases_and_clear_diff res
 157   in
 158   let rec aux i errors passes =
 159   debug_print (lazy ("Pass: " ^ string_of_int i));
 160    match passes with
 161       [ pass ] ->
 162         (try
 163           set_aliases pass (try_pass pass)
 164          with Disambiguate.NoWellTypedInterpretation (offset,newerrors) ->
 165           raise (DisambiguationError (offset, errors @ [newerrors])))
 166     | hd :: tl ->
 167         (try
 168           set_aliases hd (try_pass hd)
 169         with Disambiguate.NoWellTypedInterpretation (_offset,newerrors) ->
 170          aux (i+1) (errors @ [newerrors]) tl)
 171     | [] -> assert false
 172   in
 173    aux 1 [] passes
 174
 175 let disambiguate_thing ~passes ~freshen_thing ~context ~metasenv ~subst
 176   ~string_context_of_context ~initial_ugraph ~hint ~mk_implicit
 177   ~description_of_alias ~aliases ~universe ~lookup_in_library ~uri ~pp_thing
 178   ~domain_of_thing ~interpretate_thing ~refine_thing ~localization_tbl thing
 179  =
 180   let f ~fresh_instances ~aliases ~universe ~use_coercions (txt,len,thing) =
 181     let thing = if fresh_instances then freshen_thing thing else thing
 182     in
 183      Disambiguator.disambiguate_thing
 184       ~context ~metasenv ~subst ~use_coercions ~string_context_of_context
 185       ~initial_ugraph ~hint ~mk_implicit ~description_of_alias
 186       ~aliases ~universe ~lookup_in_library
 187       ~uri ~pp_thing ~domain_of_thing ~interpretate_thing ~refine_thing
 188       ~localization_tbl (txt,len,thing)
 189   in
 190   disambiguate_thing ~description_of_alias ~passes ~aliases ~universe ~f thing