helm/software/components/extlib/hExtlib.ml

   1 (* Copyright (C) 2005, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://cs.unibo.it/helm/.
  24  *)
  25
  26 (* $Id$ *)
  27
  28 (** PROFILING *)
  29
  30 let profiling_enabled = ref false ;; (* ComponentsConf.profiling *)
  31
  32 let something_profiled = ref false
  33
  34 let _ =
  35   if !something_profiled then
  36     at_exit
  37       (fun _ ->
  38         prerr_endline
  39          (Printf.sprintf "!! %39s ---------- --------- --------- ---------"
  40            (String.make 39 '-'));
  41         prerr_endline
  42          (Printf.sprintf "!! %-39s %10s %9s %9s %9s"
  43            "function" "#calls" "total" "max" "average"))
  44
  45 let profiling_printings = ref (fun _ -> true)
  46 let set_profiling_printings f = profiling_printings := f
  47
  48 type profiler = { profile : 'a 'b. ('a -> 'b) -> 'a -> 'b }
  49 let profile ?(enable = true) s =
  50  if !profiling_enabled && enable then
  51    let total = ref 0.0 in
  52    let calls = ref 0 in
  53    let max = ref 0.0 in
  54    let profile f x =
  55     if not !profiling_enabled then f x else
  56     let before = Unix.gettimeofday () in
  57     try
  58      incr calls;
  59      let res = f x in
  60      let after = Unix.gettimeofday () in
  61      let delta = after -. before in
  62       total := !total +. delta;
  63       if delta > !max then max := delta;
  64       res
  65     with
  66      exc ->
  67       let after = Unix.gettimeofday () in
  68       let delta = after -. before in
  69        total := !total +. delta;
  70        if delta > !max then max := delta;
  71        raise exc
  72    in
  73    at_exit
  74     (fun () ->
  75       if !profiling_printings s && !calls <> 0 then
  76        begin
  77         something_profiled := true;
  78         prerr_endline
  79          (Printf.sprintf "!! %-39s %10d %9.4f %9.4f %9.4f"
  80          s !calls !total !max (!total /. (float_of_int !calls)))
  81        end);
  82    { profile = profile }
  83  else
  84    { profile = fun f x -> f x }
  85
  86 (** {2 Optional values} *)
  87
  88 let map_option f = function None -> None | Some v -> Some (f v)
  89 let iter_option f = function None -> () | Some v -> f v
  90 let unopt = function None -> failwith "unopt: None" | Some v -> v
  91
  92 (** {2 String processing} *)
  93
  94 let split ?(sep = ' ') s =
  95   let pieces = ref [] in
  96   let rec aux idx =
  97     match (try Some (String.index_from s idx sep) with Not_found -> None) with
  98     | Some pos ->
  99         pieces := String.sub s idx (pos - idx) :: !pieces;
 100         aux (pos + 1)
 101     | None -> pieces := String.sub s idx (String.length s - idx) :: !pieces
 102   in
 103   aux 0;
 104   List.rev !pieces
 105
 106 let trim_blanks s =
 107   let rec find_left idx =
 108     match s.[idx] with
 109     | ' ' | '\t' | '\r' | '\n' -> find_left (idx + 1)
 110     | _ -> idx
 111   in
 112   let rec find_right idx =
 113     match s.[idx] with
 114     | ' ' | '\t' | '\r' | '\n' -> find_right (idx - 1)
 115     | _ -> idx
 116   in
 117   let s_len = String.length s in
 118   let left, right = find_left 0, find_right (s_len - 1) in
 119   String.sub s left (right - left + 1)
 120
 121 (** {2 Char processing} *)
 122
 123 let is_alpha c =
 124   let code = Char.code c in
 125   (code >= 65 && code <= 90) || (code >= 97 && code <= 122)
 126
 127 let is_digit c =
 128   let code = Char.code c in
 129   code >= 48 && code <= 57
 130
 131 let is_blank c =
 132   let code = Char.code c in
 133   code = 9 || code = 10 || code = 13 || code = 32
 134
 135 let is_alphanum c = is_alpha c || is_digit c
 136
 137 (** {2 List processing} *)
 138
 139 let flatten_map f l =
 140   List.flatten (List.map f l)
 141 ;;
 142
 143 let list_mapi f l =
 144   let rec aux k = function
 145     | [] -> []
 146     | h::tl -> f h k :: aux (k+1) tl
 147   in
 148      aux 0 l
 149 ;;
 150
 151 let list_mapi_acc f a l =
 152   let rec aux k a res = function
 153     | [] -> a, List.rev res
 154     | h::tl -> let a,h = f h k a in aux (k+1) a (h::res) tl
 155   in
 156    aux 0 a [] l
 157 ;;
 158
 159 let list_index p =
 160  let rec aux n =
 161   function
 162      [] -> None
 163    | he::_ when p he -> Some (n,he)
 164    | _::tl -> aux (n + 1) tl
 165  in
 166   aux 0
 167 ;;
 168
 169 let rec list_iter_default2 f l1 def l2 =
 170   match l1,l2 with
 171     | [], _ -> ()
 172     | a::ta, b::tb -> f a b; list_iter_default2 f ta def tb
 173     | a::ta, [] -> f a def; list_iter_default2 f ta def []
 174 ;;
 175
 176 let rec list_forall_default3 f l1 l2 def l3 =
 177   match l1,l2,l3 with
 178     | [], [], _ -> true
 179     | [], _, _
 180     | _, [], _ -> raise (Invalid_argument "list_forall_default3")
 181     | a::ta, b::tb, c::tc -> f a b c && list_forall_default3 f ta tb def tc
 182     | a::ta, b::tb, [] -> f a b def && list_forall_default3 f ta tb def []
 183 ;;
 184
 185 exception FailureAt of int;;
 186
 187 let list_forall_default3_var f l1 l2 def l3 =
 188   let rec aux f l1 l2 def l3 i =
 189     match l1,l2,l3 with
 190       | [], [], _ -> true
 191       | [], _, _
 192       | _, [], _ -> raise (Invalid_argument "list_forall_default3")
 193       | a::ta, b::tb, c::tc ->
 194           if f a b c then aux f ta tb def tc (i+1)
 195           else raise (FailureAt i)
 196       | a::ta, b::tb, [] ->
 197           if f a b def then aux f ta tb def [] (i+1)
 198           else raise (FailureAt i)
 199   in aux f l1 l2 def l3 0
 200 ;;
 201
 202 let sharing_map f l =
 203   let unchanged = ref true in
 204   let rec aux b = function
 205     | [] as t -> unchanged := b; t
 206     | he::tl ->
 207         let he1 = f he in
 208         he1 :: aux (b && he1 == he) tl
 209   in
 210   let l1 = aux true l in
 211   if !unchanged then l else l1
 212 ;;
 213
 214 let sharing_map_acc f acc l =
 215   let unchanged = ref true in
 216   let final_acc = ref acc in
 217   let rec aux b acc = function
 218     | [] as t -> unchanged := b; final_acc := acc; t
 219     | he::tl ->
 220         let acc, he1 = f acc he in
 221         he1 :: aux (b && he1 == he) acc tl
 222   in
 223   let l1 = aux true acc l in
 224   !final_acc, if !unchanged then l else l1
 225 ;;
 226
 227 let rec list_uniq ?(eq=(=)) = function
 228   | [] -> []
 229   | h::[] -> [h]
 230   | h1::h2::tl when eq h1 h2 -> list_uniq ~eq (h2 :: tl)
 231   | h1::tl (* when h1 <> h2 *) -> h1 :: list_uniq ~eq tl
 232
 233 let rec filter_map f =
 234   function
 235   | [] -> []
 236   | hd :: tl ->
 237       (match f hd with
 238       | None -> filter_map f tl
 239       | Some v -> v :: filter_map f tl)
 240
 241 let filter_map_acc f acc l =
 242   let acc, res =
 243    List.fold_left
 244     (fun (acc, res) t ->
 245        match f acc t with
 246        | None -> acc, res
 247        | Some (acc, x) -> acc, x::res)
 248     (acc,[]) l
 249   in
 250    acc, List.rev res
 251 ;;
 252
 253 let filter_map_monad f acc l =
 254   let acc, res =
 255    List.fold_left
 256     (fun (acc, res) t ->
 257        match f acc t with
 258        | acc, None -> acc, res
 259        | acc, Some x -> acc, x::res)
 260     (acc,[]) l
 261   in
 262    acc, List.rev res
 263 ;;
 264
 265 let list_rev_map_filter f l =
 266    let rec aux a = function
 267       | []       -> a
 268       | hd :: tl ->
 269          begin match f hd with
 270             | None   -> aux a tl
 271             | Some b -> aux (b :: a) tl
 272          end
 273    in
 274    aux [] l
 275
 276 let list_rev_map_filter_fold f v l =
 277    let rec aux v a = function
 278       | []       -> v, a
 279       | hd :: tl ->
 280          begin match f v hd with
 281             | v, None   -> aux v a tl
 282             | v, Some b -> aux v (b :: a) tl
 283          end
 284    in
 285    aux v [] l
 286
 287 let list_concat ?(sep = []) =
 288   let rec aux acc =
 289     function
 290     | [] -> []
 291     | [ last ] -> List.flatten (List.rev (last :: acc))
 292     | hd :: tl -> aux ([sep; hd] @ acc) tl
 293   in
 294   aux []
 295
 296 let list_iter_sep ~sep f =
 297   let rec aux =
 298     function
 299     | [] -> ()
 300     | [ last ] -> f last
 301     | hd :: tl -> f hd; sep (); aux tl
 302   in
 303   aux
 304
 305 let rec list_findopt f l =
 306   let rec aux k = function
 307     | [] -> None
 308     | x::tl ->
 309         (match f x k with
 310         | None -> aux (succ k) tl
 311         | Some _ as rc -> rc)
 312   in
 313   aux 0 l
 314
 315 let split_nth n l =
 316   let rec aux acc n l =
 317     match n, l with
 318     | 0, _ -> List.rev acc, l
 319     | n, [] -> raise (Failure "HExtlib.split_nth")
 320     | n, hd :: tl -> aux (hd :: acc) (n - 1) tl in
 321   aux [] n l
 322
 323 let list_last l =
 324   let l = List.rev l in
 325   try List.hd l with exn -> raise (Failure "HExtlib.list_last")
 326 ;;
 327
 328 let rec list_assoc_all a = function
 329    | []                      -> []
 330    | (x, y) :: tl when x = a -> y :: list_assoc_all a tl
 331    | _ :: tl                 -> list_assoc_all a tl
 332 ;;
 333
 334 let rec rm_assoc n = function
 335   | [] -> assert false
 336   | (x,i)::tl when n=x -> i,tl
 337   | p::tl -> let i,tl = rm_assoc n tl in i,p::tl
 338 ;;
 339
 340 (* naif implementation of the union-find merge operation
 341    canonicals maps elements to canonicals
 342    elements maps canonicals to the classes *)
 343 let merge canonicals elements n m =
 344   let cn,canonicals = rm_assoc n canonicals in
 345   let cm,canonicals = rm_assoc m canonicals in
 346   if cn=cm then (n,cm)::(m,cm)::canonicals, elements
 347   else
 348     let ln,elements = rm_assoc cn elements in
 349     let lm,elements = rm_assoc cm elements in
 350     let canonicals =
 351       (n,cm)::(m,cm)::List.map
 352         (fun ((x,xc) as p)  ->
 353            if xc = cn then (x,cm) else p) canonicals
 354     in
 355     let elements = (cm,ln@lm)::elements
 356     in
 357       canonicals,elements
 358 ;;
 359
 360 (* f x gives the direct dependencies of x;
 361    x must not belong to (f x) and (f x) must
 362    be a subset of l *)
 363 let clusters f l =
 364   let canonicals = List.map (fun x -> (x,x)) l in
 365   let elements = List.map (fun x -> (x,[x])) l in
 366   let _,elements =
 367     List.fold_left
 368      (fun (canonicals,elements) x ->
 369        let dep = f x in
 370          List.fold_left
 371            (fun (canonicals,elements) d ->
 372               merge canonicals elements d x)
 373            (canonicals,elements) dep)
 374      (canonicals,elements) l
 375   in
 376     List.map snd elements
 377 ;;
 378
 379 (** {2 File predicates} *)
 380
 381 let is_dir fname =
 382   try
 383     (Unix.stat fname).Unix.st_kind = Unix.S_DIR
 384   with Unix.Unix_error _ -> false
 385
 386 let writable_dir path =
 387   try
 388     let file = path ^ "/prova_matita" in
 389     let oc = open_out file in
 390     close_out oc;
 391     Sys.remove file;
 392     true
 393   with Sys_error _ -> false
 394
 395
 396 let is_regular fname =
 397   try
 398     (Unix.stat fname).Unix.st_kind = Unix.S_REG
 399   with Unix.Unix_error _ -> false
 400
 401 let is_executable fname =
 402   try
 403     let stat = (Unix.stat fname) in
 404     stat.Unix.st_kind = Unix.S_REG &&
 405     (stat.Unix.st_perm land 0o001 > 0)
 406   with Unix.Unix_error _ -> false
 407
 408 let chmod mode filename =
 409    Unix.chmod filename mode
 410
 411 let mkdir path =
 412   let components = split ~sep:'/' path in
 413   let rec aux where = function
 414     | [] -> ()
 415     | piece::tl ->
 416         let path =
 417           if where = "" then piece else where ^ "/" ^ piece in
 418         (try
 419           Unix.mkdir path 0o755; chmod 0o2775 path
 420         with
 421         | Unix.Unix_error (Unix.EEXIST,_,_) -> ()
 422         | Unix.Unix_error (e,_,_) ->
 423             raise
 424               (Failure
 425                 ("Unix.mkdir " ^ path ^ " 0o2775 :" ^ (Unix.error_message e))));
 426         aux path tl
 427   in
 428   let where = if path.[0] = '/' then "/" else "" in
 429   aux where components
 430
 431 (** {2 Filesystem} *)
 432
 433 let input_file fname =
 434   let size = (Unix.stat fname).Unix.st_size in
 435   let buf = Buffer.create size in
 436   let ic = open_in fname in
 437   Buffer.add_channel buf ic size;
 438   close_in ic;
 439   Buffer.contents buf
 440
 441 let input_all ic =
 442   let size = 10240 in
 443   let buf = Buffer.create size in
 444   let s = String.create size in
 445   (try
 446     while true do
 447       let bytes = input ic s 0 size in
 448       if bytes = 0 then raise End_of_file
 449       else Buffer.add_substring buf s 0 bytes
 450     done
 451   with End_of_file -> ());
 452   Buffer.contents buf
 453
 454 let output_file ~filename ~text =
 455   let oc = open_out filename in
 456   output_string oc text;
 457   close_out oc;
 458   chmod 0o664 filename
 459
 460 let blank_split s =
 461   let len = String.length s in
 462   let buf = Buffer.create 0 in
 463   let rec aux acc i =
 464     if i >= len
 465     then begin
 466       if Buffer.length buf > 0
 467       then List.rev (Buffer.contents buf :: acc)
 468       else List.rev acc
 469     end else begin
 470       if is_blank s.[i] then
 471         if Buffer.length buf > 0 then begin
 472           let s = Buffer.contents buf in
 473           Buffer.clear buf;
 474           aux (s :: acc) (i + 1)
 475         end else
 476           aux acc (i + 1)
 477       else begin
 478         Buffer.add_char buf s.[i];
 479         aux acc (i + 1)
 480       end
 481     end
 482   in
 483   aux [] 0
 484
 485   (* Rules: * "~name" -> home dir of "name"
 486    * "~" -> value of $HOME if defined, home dir of the current user otherwise *)
 487 let tilde_expand s =
 488   let get_home login = (Unix.getpwnam login).Unix.pw_dir in
 489   let expand_one s =
 490     let len = String.length s in
 491     if len > 0 && s.[0] = '~' then begin
 492       let login_len = ref 1 in
 493       while !login_len < len && is_alphanum (s.[!login_len]) do
 494         incr login_len
 495       done;
 496       let login = String.sub s 1 (!login_len - 1) in
 497       try
 498         let home =
 499           if login = "" then
 500             try Sys.getenv "HOME" with Not_found -> get_home (Unix.getlogin ())
 501           else
 502             get_home login
 503         in
 504         home ^ String.sub s !login_len (len - !login_len)
 505       with Not_found | Invalid_argument _ -> s
 506     end else
 507       s
 508   in
 509   String.concat " " (List.map expand_one (blank_split s))
 510
 511 let find ?(test = fun _ -> true) path =
 512   let rec aux acc todo =
 513     match todo with
 514     | [] -> acc
 515     | path :: tl ->
 516         try
 517           let handle = Unix.opendir path in
 518           let dirs = ref [] in
 519           let matching_files = ref [] in
 520           (try
 521             while true do
 522               match Unix.readdir handle with
 523               | "." | ".." -> ()
 524               | entry ->
 525                   let qentry = path ^ "/" ^ entry in
 526                   (try
 527                     if is_dir qentry then
 528                       dirs := qentry :: !dirs
 529                     else if test qentry then
 530                       matching_files := qentry :: !matching_files;
 531                   with Unix.Unix_error _ -> ())
 532             done
 533           with End_of_file -> Unix.closedir handle);
 534           aux (!matching_files @ acc) (!dirs @ tl)
 535         with Unix.Unix_error _ -> aux acc tl
 536   in
 537   aux [] [path]
 538
 539 let safe_remove fname = if Sys.file_exists fname then Sys.remove fname
 540
 541 let is_dir_empty d =
 542  try
 543   let od = Unix.opendir d in
 544   let rec aux () =
 545    let name = Unix.readdir od in
 546    if name <> "." && name <> ".." then false else aux () in
 547   let res = try aux () with End_of_file -> true in
 548    Unix.closedir od;
 549    res
 550  with
 551   Unix.Unix_error _ -> true (* raised by Unix.opendir, we hope :-) *)
 552
 553 let safe_rmdir d = try Unix.rmdir d with Unix.Unix_error _ -> ()
 554
 555 let rec rmdir_descend d =
 556   if is_dir_empty d then
 557     begin
 558       safe_rmdir d;
 559       rmdir_descend (Filename.dirname d)
 560     end
 561
 562
 563 (** {2 Exception handling} *)
 564
 565 let finally at_end f arg =
 566   let res =
 567     try f arg
 568     with exn -> at_end (); raise exn
 569   in
 570   at_end ();
 571   res
 572
 573 (** {2 Localized exceptions } *)
 574
 575 exception Localized of Stdpp.location * exn
 576
 577 let loc_of_floc floc = Stdpp.first_pos floc, Stdpp.last_pos floc;;
 578
 579 let floc_of_loc (loc_begin, loc_end) =
 580  Stdpp.make_loc (loc_begin, loc_end)
 581
 582 let dummy_floc = floc_of_loc (0, 0)
 583
 584 let raise_localized_exception ~offset floc exn =
 585  let x, y = loc_of_floc floc in
 586  let x = offset + x in
 587  let y = offset + y in
 588  let floc = floc_of_loc (x,y) in
 589   raise (Localized (floc, exn))
 590
 591 let estimate_size x =
 592   4 * (String.length (Marshal.to_string x [])) / 1024
 593
 594 let normalize_path s =
 595   let s = Str.global_replace (Str.regexp "//") "/" s in
 596   let l = Str.split (Str.regexp "/") s in
 597   let rec aux acc = function
 598     | [] -> acc
 599     | he::"."::tl -> aux acc (he::tl)
 600     | he::".."::tl when he <> ".." -> aux [] (acc @ tl)
 601     | he::tl -> aux (acc@[he]) tl
 602   in
 603   (if Str.string_match (Str.regexp "^/") s 0 then "/" else "") ^
 604   String.concat "/" (aux [] l)
 605   ^ (if Str.string_match (Str.regexp "/$") s 0 then "/" else "")
 606 ;;
 607
 608 let find_in paths path =
 609    let rec aux = function
 610    | [] -> raise (Failure "find_in")
 611    | p :: tl ->
 612       let path = normalize_path (p ^ "/" ^ path) in
 613        try
 614          if (Unix.stat path).Unix.st_kind = Unix.S_REG then path
 615          else aux tl
 616        with Unix.Unix_error _ ->
 617                aux tl
 618    in
 619    try
 620      aux paths
 621    with Unix.Unix_error _ | Failure _ ->
 622      raise
 623        (Failure "find_in")
 624 ;;
 625
 626 let is_prefix_of_aux d1 d2 =
 627   let len1 = String.length d1 in
 628   let len2 = String.length d2 in
 629   if len2 < len1 then
 630     false, len1, len2
 631   else
 632     let pref = String.sub d2 0 len1 in
 633     pref = d1 && (len1 = len2 || d1.[len1-1] = '/' || d2.[len1] = '/'), len1, len2
 634
 635 let is_prefix_of d1 d2 =
 636   let b,_,_ = is_prefix_of_aux d1 d2 in b
 637 ;;
 638
 639 let chop_prefix prefix s =
 640   let b,lp,ls = is_prefix_of_aux prefix s in
 641   if b then
 642     String.sub s lp (ls - lp)
 643   else
 644     s
 645 ;;
 646
 647 let touch s =
 648   try close_out(open_out s) with Sys_error _ -> ()
 649 ;;
 650
 651 let rec mk_list x = function
 652   | 0 -> []
 653   | n -> x :: mk_list x (n-1)
 654 ;;
 655
 656 let list_seq start stop =
 657   if start > stop then [] else
 658   let rec aux pos =
 659     if pos = stop then []
 660     else pos :: (aux (pos+1))
 661   in
 662     aux start
 663 ;;
 664
 665 let rec list_skip n l =
 666   match n,l with
 667   | 0,_ -> l
 668   | n,_::l -> list_skip (n-1) l
 669   | _, [] -> assert false
 670 ;;
 671