helm/software/components/extlib/hExtlib.ml

   1 (* Copyright (C) 2005, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://cs.unibo.it/helm/.
  24  *)
  25
  26 (* $Id$ *)
  27
  28 (** PROFILING *)
  29
  30 let profiling_enabled = ref false ;; (* ComponentsConf.profiling *)
  31
  32 let something_profiled = ref false
  33
  34 let _ =
  35   if !something_profiled then
  36     at_exit
  37       (fun _ ->
  38         prerr_endline
  39          (Printf.sprintf "!! %39s ---------- --------- --------- ---------"
  40            (String.make 39 '-'));
  41         prerr_endline
  42          (Printf.sprintf "!! %-39s %10s %9s %9s %9s"
  43            "function" "#calls" "total" "max" "average"))
  44
  45 let profiling_printings = ref (fun _ -> true)
  46 let set_profiling_printings f = profiling_printings := f
  47
  48 type profiler = { profile : 'a 'b. ('a -> 'b) -> 'a -> 'b }
  49 let profile ?(enable = true) s =
  50  if !profiling_enabled && enable then
  51    let total = ref 0.0 in
  52    let calls = ref 0 in
  53    let max = ref 0.0 in
  54    let profile f x =
  55     if not !profiling_enabled then f x else
  56     let before = Unix.gettimeofday () in
  57     try
  58      incr calls;
  59      let res = f x in
  60      let after = Unix.gettimeofday () in
  61      let delta = after -. before in
  62       total := !total +. delta;
  63       if delta > !max then max := delta;
  64       res
  65     with
  66      exc ->
  67       let after = Unix.gettimeofday () in
  68       let delta = after -. before in
  69        total := !total +. delta;
  70        if delta > !max then max := delta;
  71        raise exc
  72    in
  73    at_exit
  74     (fun () ->
  75       if !profiling_printings s && !calls <> 0 then
  76        begin
  77         something_profiled := true;
  78         prerr_endline
  79          (Printf.sprintf "!! %-39s %10d %9.4f %9.4f %9.4f"
  80          s !calls !total !max (!total /. (float_of_int !calls)))
  81        end);
  82    { profile = profile }
  83  else
  84    { profile = fun f x -> f x }
  85
  86 (** {2 Optional values} *)
  87
  88 let map_option f = function None -> None | Some v -> Some (f v)
  89 let iter_option f = function None -> () | Some v -> f v
  90 let unopt = function None -> failwith "unopt: None" | Some v -> v
  91
  92 (** {2 String processing} *)
  93
  94 let split ?(sep = ' ') s =
  95   let pieces = ref [] in
  96   let rec aux idx =
  97     match (try Some (String.index_from s idx sep) with Not_found -> None) with
  98     | Some pos ->
  99         pieces := String.sub s idx (pos - idx) :: !pieces;
 100         aux (pos + 1)
 101     | None -> pieces := String.sub s idx (String.length s - idx) :: !pieces
 102   in
 103   aux 0;
 104   List.rev !pieces
 105
 106 let trim_blanks s =
 107   let rec find_left idx =
 108     match s.[idx] with
 109     | ' ' | '\t' | '\r' | '\n' -> find_left (idx + 1)
 110     | _ -> idx
 111   in
 112   let rec find_right idx =
 113     match s.[idx] with
 114     | ' ' | '\t' | '\r' | '\n' -> find_right (idx - 1)
 115     | _ -> idx
 116   in
 117   let s_len = String.length s in
 118   let left, right = find_left 0, find_right (s_len - 1) in
 119   String.sub s left (right - left + 1)
 120
 121 (** {2 Char processing} *)
 122
 123 let is_alpha c =
 124   let code = Char.code c in
 125   (code >= 65 && code <= 90) || (code >= 97 && code <= 122)
 126
 127 let is_digit c =
 128   let code = Char.code c in
 129   code >= 48 && code <= 57
 130
 131 let is_blank c =
 132   let code = Char.code c in
 133   code = 9 || code = 10 || code = 13 || code = 32
 134
 135 let is_alphanum c = is_alpha c || is_digit c
 136
 137 (** {2 List processing} *)
 138
 139 let flatten_map f l =
 140   List.flatten (List.map f l)
 141 ;;
 142
 143 let list_mapi f l =
 144   let rec aux k = function
 145     | [] -> []
 146     | h::tl -> f h k :: aux (k+1) tl
 147   in
 148      aux 0 l
 149 ;;
 150
 151 let list_mapi_acc f a l =
 152   let rec aux k a res = function
 153     | [] -> a, List.rev res
 154     | h::tl -> let a,h = f h k a in aux (k+1) a (h::res) tl
 155   in
 156    aux 0 a [] l
 157 ;;
 158
 159 let list_index p =
 160  let rec aux n =
 161   function
 162      [] -> None
 163    | he::_ when p he -> Some (n,he)
 164    | _::tl -> aux (n + 1) tl
 165  in
 166   aux 0
 167 ;;
 168
 169 let rec list_iter_default2 f l1 def l2 =
 170   match l1,l2 with
 171     | [], _ -> ()
 172     | a::ta, b::tb -> f a b; list_iter_default2 f ta def tb
 173     | a::ta, [] -> f a def; list_iter_default2 f ta def []
 174 ;;
 175
 176 let rec list_forall_default3 f l1 l2 def l3 =
 177   match l1,l2,l3 with
 178     | [], [], _ -> true
 179     | [], _, _
 180     | _, [], _ -> raise (Invalid_argument "list_forall_default3")
 181     | a::ta, b::tb, c::tc -> f a b c && list_forall_default3 f ta tb def tc
 182     | a::ta, b::tb, [] -> f a b def && list_forall_default3 f ta tb def []
 183 ;;
 184
 185 exception FailureAt of int;;
 186
 187 let list_forall_default3_var f l1 l2 def l3 =
 188   let rec aux f l1 l2 def l3 i =
 189     match l1,l2,l3 with
 190       | [], [], _ -> true
 191       | [], _, _
 192       | _, [], _ -> raise (Invalid_argument "list_forall_default3")
 193       | a::ta, b::tb, c::tc ->
 194           if f a b c then aux f ta tb def tc (i+1)
 195           else raise (FailureAt i)
 196       | a::ta, b::tb, [] ->
 197           if f a b def then aux f ta tb def [] (i+1)
 198           else raise (FailureAt i)
 199   in aux f l1 l2 def l3 0
 200 ;;
 201
 202 let sharing_map f l =
 203   let unchanged = ref true in
 204   let rec aux b = function
 205     | [] as t -> unchanged := b; t
 206     | he::tl ->
 207         let he1 = f he in
 208         he1 :: aux (b && he1 == he) tl
 209   in
 210   let l1 = aux true l in
 211   if !unchanged then l else l1
 212 ;;
 213
 214 let sharing_map_acc f acc l =
 215   let unchanged = ref true in
 216   let final_acc = ref acc in
 217   let rec aux b acc = function
 218     | [] as t -> unchanged := b; final_acc := acc; t
 219     | he::tl ->
 220         let acc, he1 = f acc he in
 221         he1 :: aux (b && he1 == he) acc tl
 222   in
 223   let l1 = aux true acc l in
 224   !final_acc, if !unchanged then l else l1
 225 ;;
 226
 227 let rec list_uniq ?(eq=(=)) = function
 228   | [] -> []
 229   | h::[] -> [h]
 230   | h1::h2::tl when eq h1 h2 -> list_uniq ~eq (h2 :: tl)
 231   | h1::tl (* when h1 <> h2 *) -> h1 :: list_uniq ~eq tl
 232
 233 let rec filter_map f =
 234   function
 235   | [] -> []
 236   | hd :: tl ->
 237       (match f hd with
 238       | None -> filter_map f tl
 239       | Some v -> v :: filter_map f tl)
 240
 241 let filter_map_acc f acc l =
 242   let acc, res =
 243    List.fold_left
 244     (fun (acc, res) t ->
 245        match f acc t with
 246        | None -> acc, res
 247        | Some (acc, x) -> acc, x::res)
 248     (acc,[]) l
 249   in
 250    acc, List.rev res
 251 ;;
 252
 253 let filter_map_monad f acc l =
 254   let acc, res =
 255    List.fold_left
 256     (fun (acc, res) t ->
 257        match f acc t with
 258        | acc, None -> acc, res
 259        | acc, Some x -> acc, x::res)
 260     (acc,[]) l
 261   in
 262    acc, List.rev res
 263 ;;
 264
 265 let list_rev_map_filter f l =
 266    let rec aux a = function
 267       | []       -> a
 268       | hd :: tl ->
 269          begin match f hd with
 270             | None   -> aux a tl
 271             | Some b -> aux (b :: a) tl
 272          end
 273    in
 274    aux [] l
 275
 276 let list_rev_map_filter_fold f v l =
 277    let rec aux v a = function
 278       | []       -> v, a
 279       | hd :: tl ->
 280          begin match f v hd with
 281             | v, None   -> aux v a tl
 282             | v, Some b -> aux v (b :: a) tl
 283          end
 284    in
 285    aux v [] l
 286
 287 let list_concat ?(sep = []) =
 288   let rec aux acc =
 289     function
 290     | [] -> []
 291     | [ last ] -> List.flatten (List.rev (last :: acc))
 292     | hd :: tl -> aux ([sep; hd] @ acc) tl
 293   in
 294   aux []
 295
 296 let list_iter_sep ~sep f =
 297   let rec aux =
 298     function
 299     | [] -> ()
 300     | [ last ] -> f last
 301     | hd :: tl -> f hd; sep (); aux tl
 302   in
 303   aux
 304
 305 let rec list_findopt f l =
 306   let rec aux k = function
 307     | [] -> None
 308     | x::tl ->
 309         (match f x k with
 310         | None -> aux (succ k) tl
 311         | Some _ as rc -> rc)
 312   in
 313   aux 0 l
 314
 315 let split_nth n l =
 316   let rec aux acc n l =
 317     match n, l with
 318     | 0, _ -> List.rev acc, l
 319     | n, [] -> raise (Failure "HExtlib.split_nth")
 320     | n, hd :: tl -> aux (hd :: acc) (n - 1) tl in
 321   aux [] n l
 322
 323 let list_last l =
 324   let l = List.rev l in
 325   try List.hd l with exn -> raise (Failure "HExtlib.list_last")
 326 ;;
 327
 328 let rec list_assoc_all a = function
 329    | []                      -> []
 330    | (x, y) :: tl when x = a -> y :: list_assoc_all a tl
 331    | _ :: tl                 -> list_assoc_all a tl
 332 ;;
 333
 334 (** {2 File predicates} *)
 335
 336 let is_dir fname =
 337   try
 338     (Unix.stat fname).Unix.st_kind = Unix.S_DIR
 339   with Unix.Unix_error _ -> false
 340
 341 let writable_dir path =
 342   try
 343     let file = path ^ "/prova_matita" in
 344     let oc = open_out file in
 345     close_out oc;
 346     Sys.remove file;
 347     true
 348   with Sys_error _ -> false
 349
 350
 351 let is_regular fname =
 352   try
 353     (Unix.stat fname).Unix.st_kind = Unix.S_REG
 354   with Unix.Unix_error _ -> false
 355
 356 let is_executable fname =
 357   try
 358     let stat = (Unix.stat fname) in
 359     stat.Unix.st_kind = Unix.S_REG &&
 360     (stat.Unix.st_perm land 0o001 > 0)
 361   with Unix.Unix_error _ -> false
 362
 363 let chmod mode filename =
 364    Unix.chmod filename mode
 365
 366 let mkdir path =
 367   let components = split ~sep:'/' path in
 368   let rec aux where = function
 369     | [] -> ()
 370     | piece::tl ->
 371         let path =
 372           if where = "" then piece else where ^ "/" ^ piece in
 373         (try
 374           Unix.mkdir path 0o755; chmod 0o2775 path
 375         with
 376         | Unix.Unix_error (Unix.EEXIST,_,_) -> ()
 377         | Unix.Unix_error (e,_,_) ->
 378             raise
 379               (Failure
 380                 ("Unix.mkdir " ^ path ^ " 0o2775 :" ^ (Unix.error_message e))));
 381         aux path tl
 382   in
 383   let where = if path.[0] = '/' then "/" else "" in
 384   aux where components
 385
 386 (** {2 Filesystem} *)
 387
 388 let input_file fname =
 389   let size = (Unix.stat fname).Unix.st_size in
 390   let buf = Buffer.create size in
 391   let ic = open_in fname in
 392   Buffer.add_channel buf ic size;
 393   close_in ic;
 394   Buffer.contents buf
 395
 396 let input_all ic =
 397   let size = 10240 in
 398   let buf = Buffer.create size in
 399   let s = String.create size in
 400   (try
 401     while true do
 402       let bytes = input ic s 0 size in
 403       if bytes = 0 then raise End_of_file
 404       else Buffer.add_substring buf s 0 bytes
 405     done
 406   with End_of_file -> ());
 407   Buffer.contents buf
 408
 409 let output_file ~filename ~text =
 410   let oc = open_out filename in
 411   output_string oc text;
 412   close_out oc;
 413   chmod 0o664 filename
 414
 415 let blank_split s =
 416   let len = String.length s in
 417   let buf = Buffer.create 0 in
 418   let rec aux acc i =
 419     if i >= len
 420     then begin
 421       if Buffer.length buf > 0
 422       then List.rev (Buffer.contents buf :: acc)
 423       else List.rev acc
 424     end else begin
 425       if is_blank s.[i] then
 426         if Buffer.length buf > 0 then begin
 427           let s = Buffer.contents buf in
 428           Buffer.clear buf;
 429           aux (s :: acc) (i + 1)
 430         end else
 431           aux acc (i + 1)
 432       else begin
 433         Buffer.add_char buf s.[i];
 434         aux acc (i + 1)
 435       end
 436     end
 437   in
 438   aux [] 0
 439
 440   (* Rules: * "~name" -> home dir of "name"
 441    * "~" -> value of $HOME if defined, home dir of the current user otherwise *)
 442 let tilde_expand s =
 443   let get_home login = (Unix.getpwnam login).Unix.pw_dir in
 444   let expand_one s =
 445     let len = String.length s in
 446     if len > 0 && s.[0] = '~' then begin
 447       let login_len = ref 1 in
 448       while !login_len < len && is_alphanum (s.[!login_len]) do
 449         incr login_len
 450       done;
 451       let login = String.sub s 1 (!login_len - 1) in
 452       try
 453         let home =
 454           if login = "" then
 455             try Sys.getenv "HOME" with Not_found -> get_home (Unix.getlogin ())
 456           else
 457             get_home login
 458         in
 459         home ^ String.sub s !login_len (len - !login_len)
 460       with Not_found | Invalid_argument _ -> s
 461     end else
 462       s
 463   in
 464   String.concat " " (List.map expand_one (blank_split s))
 465
 466 let find ?(test = fun _ -> true) path =
 467   let rec aux acc todo =
 468     match todo with
 469     | [] -> acc
 470     | path :: tl ->
 471         try
 472           let handle = Unix.opendir path in
 473           let dirs = ref [] in
 474           let matching_files = ref [] in
 475           (try
 476             while true do
 477               match Unix.readdir handle with
 478               | "." | ".." -> ()
 479               | entry ->
 480                   let qentry = path ^ "/" ^ entry in
 481                   (try
 482                     if is_dir qentry then
 483                       dirs := qentry :: !dirs
 484                     else if test qentry then
 485                       matching_files := qentry :: !matching_files;
 486                   with Unix.Unix_error _ -> ())
 487             done
 488           with End_of_file -> Unix.closedir handle);
 489           aux (!matching_files @ acc) (!dirs @ tl)
 490         with Unix.Unix_error _ -> aux acc tl
 491   in
 492   aux [] [path]
 493
 494 let safe_remove fname = if Sys.file_exists fname then Sys.remove fname
 495
 496 let is_dir_empty d =
 497  try
 498   let od = Unix.opendir d in
 499   let rec aux () =
 500    let name = Unix.readdir od in
 501    if name <> "." && name <> ".." then false else aux () in
 502   let res = try aux () with End_of_file -> true in
 503    Unix.closedir od;
 504    res
 505  with
 506   Unix.Unix_error _ -> true (* raised by Unix.opendir, we hope :-) *)
 507
 508 let safe_rmdir d = try Unix.rmdir d with Unix.Unix_error _ -> ()
 509
 510 let rec rmdir_descend d =
 511   if is_dir_empty d then
 512     begin
 513       safe_rmdir d;
 514       rmdir_descend (Filename.dirname d)
 515     end
 516
 517
 518 (** {2 Exception handling} *)
 519
 520 let finally at_end f arg =
 521   let res =
 522     try f arg
 523     with exn -> at_end (); raise exn
 524   in
 525   at_end ();
 526   res
 527
 528 (** {2 Localized exceptions } *)
 529
 530 exception Localized of Stdpp.location * exn
 531
 532 let loc_of_floc floc = Stdpp.first_pos floc, Stdpp.last_pos floc;;
 533
 534 let floc_of_loc (loc_begin, loc_end) =
 535  Stdpp.make_loc (loc_begin, loc_end)
 536
 537 let dummy_floc = floc_of_loc (0, 0)
 538
 539 let raise_localized_exception ~offset floc exn =
 540  let x, y = loc_of_floc floc in
 541  let x = offset + x in
 542  let y = offset + y in
 543  let floc = floc_of_loc (x,y) in
 544   raise (Localized (floc, exn))
 545
 546 let estimate_size x =
 547   4 * (String.length (Marshal.to_string x [])) / 1024
 548
 549 let normalize_path s =
 550   let s = Str.global_replace (Str.regexp "//") "/" s in
 551   let l = Str.split (Str.regexp "/") s in
 552   let rec aux acc = function
 553     | [] -> acc
 554     | he::"."::tl -> aux acc (he::tl)
 555     | he::".."::tl when he <> ".." -> aux [] (acc @ tl)
 556     | he::tl -> aux (acc@[he]) tl
 557   in
 558   (if Str.string_match (Str.regexp "^/") s 0 then "/" else "") ^
 559   String.concat "/" (aux [] l)
 560   ^ (if Str.string_match (Str.regexp "/$") s 0 then "/" else "")
 561 ;;
 562
 563 let find_in paths path =
 564    let rec aux = function
 565    | [] -> raise (Failure "find_in")
 566    | p :: tl ->
 567       let path = normalize_path (p ^ "/" ^ path) in
 568        try
 569          if (Unix.stat path).Unix.st_kind = Unix.S_REG then path
 570          else aux tl
 571        with Unix.Unix_error _ ->
 572                aux tl
 573    in
 574    try
 575      aux paths
 576    with Unix.Unix_error _ | Failure _ ->
 577      raise
 578        (Failure "find_in")
 579 ;;
 580
 581 let is_prefix_of_aux d1 d2 =
 582   let len1 = String.length d1 in
 583   let len2 = String.length d2 in
 584   if len2 < len1 then
 585     false, len1, len2
 586   else
 587     let pref = String.sub d2 0 len1 in
 588     pref = d1 && (len1 = len2 || d1.[len1-1] = '/' || d2.[len1] = '/'), len1, len2
 589
 590 let is_prefix_of d1 d2 =
 591   let b,_,_ = is_prefix_of_aux d1 d2 in b
 592 ;;
 593
 594 let chop_prefix prefix s =
 595   let b,lp,ls = is_prefix_of_aux prefix s in
 596   if b then
 597     String.sub s lp (ls - lp)
 598   else
 599     s
 600 ;;
 601
 602 let touch s =
 603   try close_out(open_out s) with Sys_error _ -> ()
 604 ;;
 605
 606 let rec mk_list x = function
 607   | 0 -> []
 608   | n -> x :: mk_list x (n-1)
 609 ;;
 610
 611 let list_seq start stop =
 612   if start > stop then [] else
 613   let rec aux pos =
 614     if pos = stop then []
 615     else pos :: (aux (pos+1))
 616   in
 617     aux start
 618 ;;
 619
 620 let rec list_skip n l =
 621   match n,l with
 622   | 0,_ -> l
 623   | n,_::l -> list_skip (n-1) l
 624   | _, [] -> assert false
 625 ;;
 626