helm/software/components/extlib/hExtlib.ml

   1 (* Copyright (C) 2005, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://cs.unibo.it/helm/.
  24  *)
  25
  26 (* $Id$ *)
  27
  28 (** PROFILING *)
  29
  30 let profiling_enabled = ref false ;; (* ComponentsConf.profiling *)
  31
  32 let something_profiled = ref false
  33
  34 let _ =
  35   if !something_profiled then
  36     at_exit
  37       (fun _ ->
  38         prerr_endline
  39          (Printf.sprintf "!! %39s ---------- --------- --------- ---------"
  40            (String.make 39 '-'));
  41         prerr_endline
  42          (Printf.sprintf "!! %-39s %10s %9s %9s %9s"
  43            "function" "#calls" "total" "max" "average"))
  44
  45 let profiling_printings = ref (fun _ -> true)
  46 let set_profiling_printings f = profiling_printings := f
  47
  48 type profiler = { profile : 'a 'b. ('a -> 'b) -> 'a -> 'b }
  49 let profile ?(enable = true) s =
  50  if !profiling_enabled && enable then
  51    let total = ref 0.0 in
  52    let calls = ref 0 in
  53    let max = ref 0.0 in
  54    let profile f x =
  55     if not !profiling_enabled then f x else
  56     let before = Unix.gettimeofday () in
  57     try
  58      incr calls;
  59      let res = f x in
  60      let after = Unix.gettimeofday () in
  61      let delta = after -. before in
  62       total := !total +. delta;
  63       if delta > !max then max := delta;
  64       res
  65     with
  66      exc ->
  67       let after = Unix.gettimeofday () in
  68       let delta = after -. before in
  69        total := !total +. delta;
  70        if delta > !max then max := delta;
  71        raise exc
  72    in
  73    at_exit
  74     (fun () ->
  75       if !profiling_printings s && !calls <> 0 then
  76        begin
  77         something_profiled := true;
  78         prerr_endline
  79          (Printf.sprintf "!! %-39s %10d %9.4f %9.4f %9.4f"
  80          s !calls !total !max (!total /. (float_of_int !calls)))
  81        end);
  82    { profile = profile }
  83  else
  84    { profile = fun f x -> f x }
  85
  86 (** {2 Optional values} *)
  87
  88 let map_option f = function None -> None | Some v -> Some (f v)
  89 let iter_option f = function None -> () | Some v -> f v
  90 let unopt = function None -> failwith "unopt: None" | Some v -> v
  91
  92 (** {2 String processing} *)
  93
  94 let split ?(sep = ' ') s =
  95   let pieces = ref [] in
  96   let rec aux idx =
  97     match (try Some (String.index_from s idx sep) with Not_found -> None) with
  98     | Some pos ->
  99         pieces := String.sub s idx (pos - idx) :: !pieces;
 100         aux (pos + 1)
 101     | None -> pieces := String.sub s idx (String.length s - idx) :: !pieces
 102   in
 103   aux 0;
 104   List.rev !pieces
 105
 106 let trim_blanks s =
 107   let rec find_left idx =
 108     match s.[idx] with
 109     | ' ' | '\t' | '\r' | '\n' -> find_left (idx + 1)
 110     | _ -> idx
 111   in
 112   let rec find_right idx =
 113     match s.[idx] with
 114     | ' ' | '\t' | '\r' | '\n' -> find_right (idx - 1)
 115     | _ -> idx
 116   in
 117   let s_len = String.length s in
 118   let left, right = find_left 0, find_right (s_len - 1) in
 119   String.sub s left (right - left + 1)
 120
 121 (** {2 Char processing} *)
 122
 123 let is_alpha c =
 124   let code = Char.code c in
 125   (code >= 65 && code <= 90) || (code >= 97 && code <= 122)
 126
 127 let is_digit c =
 128   let code = Char.code c in
 129   code >= 48 && code <= 57
 130
 131 let is_blank c =
 132   let code = Char.code c in
 133   code = 9 || code = 10 || code = 13 || code = 32
 134
 135 let is_alphanum c = is_alpha c || is_digit c
 136
 137 (** {2 List processing} *)
 138
 139 let flatten_map f l =
 140   List.flatten (List.map f l)
 141 ;;
 142
 143 let list_mapi f l =
 144   let rec aux k = function
 145     | [] -> []
 146     | h::tl -> f h k :: aux (k+1) tl
 147   in
 148      aux 0 l
 149 ;;
 150
 151 let list_index p =
 152  let rec aux n =
 153   function
 154      [] -> None
 155    | he::_ when p he -> Some (n,he)
 156    | _::tl -> aux (n + 1) tl
 157  in
 158   aux 0
 159 ;;
 160
 161 let rec list_iter_default2 f l1 def l2 =
 162   match l1,l2 with
 163     | [], _ -> ()
 164     | a::ta, b::tb -> f a b; list_iter_default2 f ta def tb
 165     | a::ta, [] -> f a def; list_iter_default2 f ta def []
 166 ;;
 167
 168 let rec list_forall_default3 f l1 l2 def l3 =
 169   match l1,l2,l3 with
 170     | [], [], _ -> true
 171     | [], _, _
 172     | _, [], _ -> raise (Invalid_argument "list_forall_default3")
 173     | a::ta, b::tb, c::tc -> f a b c && list_forall_default3 f ta tb def tc
 174     | a::ta, b::tb, [] -> f a b def && list_forall_default3 f ta tb def []
 175 ;;
 176
 177 exception FailureAt of int;;
 178
 179 let list_forall_default3_var f l1 l2 def l3 =
 180   let rec aux f l1 l2 def l3 i =
 181     match l1,l2,l3 with
 182       | [], [], _ -> true
 183       | [], _, _
 184       | _, [], _ -> raise (Invalid_argument "list_forall_default3")
 185       | a::ta, b::tb, c::tc ->
 186           if f a b c then aux f ta tb def tc (i+1)
 187           else raise (FailureAt i)
 188       | a::ta, b::tb, [] ->
 189           if f a b def then aux f ta tb def [] (i+1)
 190           else raise (FailureAt i)
 191   in aux f l1 l2 def l3 0
 192 ;;
 193
 194 let sharing_map f l =
 195   let unchanged = ref true in
 196   let rec aux b = function
 197     | [] as t -> unchanged := b; t
 198     | he::tl ->
 199         let he1 = f he in
 200         he1 :: aux (b && he1 == he) tl
 201   in
 202   let l1 = aux true l in
 203   if !unchanged then l else l1
 204 ;;
 205
 206 let rec list_uniq ?(eq=(=)) = function
 207   | [] -> []
 208   | h::[] -> [h]
 209   | h1::h2::tl when eq h1 h2 -> list_uniq ~eq (h2 :: tl)
 210   | h1::tl (* when h1 <> h2 *) -> h1 :: list_uniq ~eq tl
 211
 212 let rec filter_map f =
 213   function
 214   | [] -> []
 215   | hd :: tl ->
 216       (match f hd with
 217       | None -> filter_map f tl
 218       | Some v -> v :: filter_map f tl)
 219
 220 let list_rev_map_filter f l =
 221    let rec aux a = function
 222       | []       -> a
 223       | hd :: tl ->
 224          begin match f hd with
 225             | None   -> aux a tl
 226             | Some b -> aux (b :: a) tl
 227          end
 228    in
 229    aux [] l
 230
 231 let list_rev_map_filter_fold f v l =
 232    let rec aux v a = function
 233       | []       -> v, a
 234       | hd :: tl ->
 235          begin match f v hd with
 236             | v, None   -> aux v a tl
 237             | v, Some b -> aux v (b :: a) tl
 238          end
 239    in
 240    aux v [] l
 241
 242 let list_concat ?(sep = []) =
 243   let rec aux acc =
 244     function
 245     | [] -> []
 246     | [ last ] -> List.flatten (List.rev (last :: acc))
 247     | hd :: tl -> aux ([sep; hd] @ acc) tl
 248   in
 249   aux []
 250
 251 let list_iter_sep ~sep f =
 252   let rec aux =
 253     function
 254     | [] -> ()
 255     | [ last ] -> f last
 256     | hd :: tl -> f hd; sep (); aux tl
 257   in
 258   aux
 259
 260 let rec list_findopt f l =
 261   let rec aux k = function
 262     | [] -> None
 263     | x::tl ->
 264         (match f x k with
 265         | None -> aux (succ k) tl
 266         | Some _ as rc -> rc)
 267   in
 268   aux 0 l
 269
 270 let split_nth n l =
 271   let rec aux acc n l =
 272     match n, l with
 273     | 0, _ -> List.rev acc, l
 274     | n, [] -> raise (Failure "HExtlib.split_nth")
 275     | n, hd :: tl -> aux (hd :: acc) (n - 1) tl in
 276   aux [] n l
 277
 278 let list_last l =
 279   let l = List.rev l in
 280   try List.hd l with exn -> raise (Failure "HExtlib.list_last")
 281 ;;
 282
 283 let rec list_assoc_all a = function
 284    | []                      -> []
 285    | (x, y) :: tl when x = a -> y :: list_assoc_all a tl
 286    | _ :: tl                 -> list_assoc_all a tl
 287 ;;
 288
 289 (** {2 File predicates} *)
 290
 291 let is_dir fname =
 292   try
 293     (Unix.stat fname).Unix.st_kind = Unix.S_DIR
 294   with Unix.Unix_error _ -> false
 295
 296 let writable_dir path =
 297   try
 298     let file = path ^ "/prova_matita" in
 299     let oc = open_out file in
 300     close_out oc;
 301     Sys.remove file;
 302     true
 303   with Sys_error _ -> false
 304
 305
 306 let is_regular fname =
 307   try
 308     (Unix.stat fname).Unix.st_kind = Unix.S_REG
 309   with Unix.Unix_error _ -> false
 310
 311 let is_executable fname =
 312   try
 313     let stat = (Unix.stat fname) in
 314     stat.Unix.st_kind = Unix.S_REG &&
 315     (stat.Unix.st_perm land 0o001 > 0)
 316   with Unix.Unix_error _ -> false
 317
 318 let chmod mode filename =
 319    Unix.chmod filename mode
 320
 321 let mkdir path =
 322   let components = split ~sep:'/' path in
 323   let rec aux where = function
 324     | [] -> ()
 325     | piece::tl ->
 326         let path =
 327           if where = "" then piece else where ^ "/" ^ piece in
 328         (try
 329           Unix.mkdir path 0o755; chmod 0o2775 path
 330         with
 331         | Unix.Unix_error (Unix.EEXIST,_,_) -> ()
 332         | Unix.Unix_error (e,_,_) ->
 333             raise
 334               (Failure
 335                 ("Unix.mkdir " ^ path ^ " 0o2775 :" ^ (Unix.error_message e))));
 336         aux path tl
 337   in
 338   let where = if path.[0] = '/' then "/" else "" in
 339   aux where components
 340
 341 (** {2 Filesystem} *)
 342
 343 let input_file fname =
 344   let size = (Unix.stat fname).Unix.st_size in
 345   let buf = Buffer.create size in
 346   let ic = open_in fname in
 347   Buffer.add_channel buf ic size;
 348   close_in ic;
 349   Buffer.contents buf
 350
 351 let input_all ic =
 352   let size = 10240 in
 353   let buf = Buffer.create size in
 354   let s = String.create size in
 355   (try
 356     while true do
 357       let bytes = input ic s 0 size in
 358       if bytes = 0 then raise End_of_file
 359       else Buffer.add_substring buf s 0 bytes
 360     done
 361   with End_of_file -> ());
 362   Buffer.contents buf
 363
 364 let output_file ~filename ~text =
 365   let oc = open_out filename in
 366   output_string oc text;
 367   close_out oc;
 368   chmod 0o664 filename
 369
 370 let blank_split s =
 371   let len = String.length s in
 372   let buf = Buffer.create 0 in
 373   let rec aux acc i =
 374     if i >= len
 375     then begin
 376       if Buffer.length buf > 0
 377       then List.rev (Buffer.contents buf :: acc)
 378       else List.rev acc
 379     end else begin
 380       if is_blank s.[i] then
 381         if Buffer.length buf > 0 then begin
 382           let s = Buffer.contents buf in
 383           Buffer.clear buf;
 384           aux (s :: acc) (i + 1)
 385         end else
 386           aux acc (i + 1)
 387       else begin
 388         Buffer.add_char buf s.[i];
 389         aux acc (i + 1)
 390       end
 391     end
 392   in
 393   aux [] 0
 394
 395   (* Rules: * "~name" -> home dir of "name"
 396    * "~" -> value of $HOME if defined, home dir of the current user otherwise *)
 397 let tilde_expand s =
 398   let get_home login = (Unix.getpwnam login).Unix.pw_dir in
 399   let expand_one s =
 400     let len = String.length s in
 401     if len > 0 && s.[0] = '~' then begin
 402       let login_len = ref 1 in
 403       while !login_len < len && is_alphanum (s.[!login_len]) do
 404         incr login_len
 405       done;
 406       let login = String.sub s 1 (!login_len - 1) in
 407       try
 408         let home =
 409           if login = "" then
 410             try Sys.getenv "HOME" with Not_found -> get_home (Unix.getlogin ())
 411           else
 412             get_home login
 413         in
 414         home ^ String.sub s !login_len (len - !login_len)
 415       with Not_found | Invalid_argument _ -> s
 416     end else
 417       s
 418   in
 419   String.concat " " (List.map expand_one (blank_split s))
 420
 421 let find ?(test = fun _ -> true) path =
 422   let rec aux acc todo =
 423     match todo with
 424     | [] -> acc
 425     | path :: tl ->
 426         try
 427           let handle = Unix.opendir path in
 428           let dirs = ref [] in
 429           let matching_files = ref [] in
 430           (try
 431             while true do
 432               match Unix.readdir handle with
 433               | "." | ".." -> ()
 434               | entry ->
 435                   let qentry = path ^ "/" ^ entry in
 436                   (try
 437                     if is_dir qentry then
 438                       dirs := qentry :: !dirs
 439                     else if test qentry then
 440                       matching_files := qentry :: !matching_files;
 441                   with Unix.Unix_error _ -> ())
 442             done
 443           with End_of_file -> Unix.closedir handle);
 444           aux (!matching_files @ acc) (!dirs @ tl)
 445         with Unix.Unix_error _ -> aux acc tl
 446   in
 447   aux [] [path]
 448
 449 let safe_remove fname = if Sys.file_exists fname then Sys.remove fname
 450
 451 let is_dir_empty d =
 452  try
 453   let od = Unix.opendir d in
 454   let rec aux () =
 455    let name = Unix.readdir od in
 456    if name <> "." && name <> ".." then false else aux () in
 457   let res = try aux () with End_of_file -> true in
 458    Unix.closedir od;
 459    res
 460  with
 461   Unix.Unix_error _ -> true (* raised by Unix.opendir, we hope :-) *)
 462
 463 let safe_rmdir d = try Unix.rmdir d with Unix.Unix_error _ -> ()
 464
 465 let rec rmdir_descend d =
 466   if is_dir_empty d then
 467     begin
 468       safe_rmdir d;
 469       rmdir_descend (Filename.dirname d)
 470     end
 471
 472
 473 (** {2 Exception handling} *)
 474
 475 let finally at_end f arg =
 476   let res =
 477     try f arg
 478     with exn -> at_end (); raise exn
 479   in
 480   at_end ();
 481   res
 482
 483 (** {2 Localized exceptions } *)
 484
 485 exception Localized of Stdpp.location * exn
 486
 487 let loc_of_floc floc = Stdpp.first_pos floc, Stdpp.last_pos floc;;
 488
 489 let floc_of_loc (loc_begin, loc_end) =
 490  Stdpp.make_loc (loc_begin, loc_end)
 491
 492 let dummy_floc = floc_of_loc (0, 0)
 493
 494 let raise_localized_exception ~offset floc exn =
 495  let x, y = loc_of_floc floc in
 496  let x = offset + x in
 497  let y = offset + y in
 498  let floc = floc_of_loc (x,y) in
 499   raise (Localized (floc, exn))
 500
 501 let estimate_size x =
 502   4 * (String.length (Marshal.to_string x [])) / 1024
 503
 504 let normalize_path s =
 505   let s = Str.global_replace (Str.regexp "//") "/" s in
 506   let l = Str.split (Str.regexp "/") s in
 507   let rec aux acc = function
 508     | [] -> acc
 509     | he::"."::tl -> aux acc (he::tl)
 510     | he::".."::tl when he <> ".." -> aux [] (acc @ tl)
 511     | he::tl -> aux (acc@[he]) tl
 512   in
 513   (if Str.string_match (Str.regexp "^/") s 0 then "/" else "") ^
 514   String.concat "/" (aux [] l)
 515   ^ (if Str.string_match (Str.regexp "/$") s 0 then "/" else "")
 516 ;;
 517
 518 let find_in paths path =
 519    let rec aux = function
 520    | [] -> raise (Failure "find_in")
 521    | p :: tl ->
 522       let path = normalize_path (p ^ "/" ^ path) in
 523        try
 524          if (Unix.stat path).Unix.st_kind = Unix.S_REG then path
 525          else aux tl
 526        with Unix.Unix_error _ ->
 527                aux tl
 528    in
 529    try
 530      aux paths
 531    with Unix.Unix_error _ | Failure _ ->
 532      raise
 533        (Failure "find_in")
 534 ;;
 535
 536 let is_prefix_of_aux d1 d2 =
 537   let len1 = String.length d1 in
 538   let len2 = String.length d2 in
 539   if len2 < len1 then
 540     false, len1, len2
 541   else
 542     let pref = String.sub d2 0 len1 in
 543     pref = d1 && (len1 = len2 || d1.[len1-1] = '/' || d2.[len1] = '/'), len1, len2
 544
 545 let is_prefix_of d1 d2 =
 546   let b,_,_ = is_prefix_of_aux d1 d2 in b
 547 ;;
 548
 549 let chop_prefix prefix s =
 550   let b,lp,ls = is_prefix_of_aux prefix s in
 551   if b then
 552     String.sub s lp (ls - lp)
 553   else
 554     s
 555 ;;
 556
 557 let touch s =
 558   try close_out(open_out s) with Sys_error _ -> ()
 559 ;;
 560
 561 let rec mk_list x = function
 562   | 0 -> []
 563   | n -> x :: mk_list x (n-1)
 564 ;;
 565
 566 let list_seq start stop =
 567   if start > stop then [] else
 568   let rec aux pos =
 569     if pos = stop then []
 570     else pos :: (aux (pos+1))
 571   in
 572     aux start
 573 ;;
 574
 575 let rec list_skip n l =
 576   match n,l with
 577   | 0,_ -> l
 578   | n,_::l -> list_skip (n-1) l
 579   | _, [] -> assert false
 580 ;;
 581