helm/software/components/grafite/grafiteAstPp.ml

   1 (* Copyright (C) 2004, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://helm.cs.unibo.it/
  24  *)
  25
  26 (* $Id$ *)
  27
  28 open GrafiteAst
  29
  30 let tactical_terminator = ""
  31 let tactic_terminator = tactical_terminator
  32 let command_terminator = tactical_terminator
  33
  34 let pp_idents idents =
  35    let map = function Some s -> s | None -> "_" in
  36    "(" ^ String.concat " " (List.map map idents) ^ ")"
  37 let pp_hyps idents = String.concat " " idents
  38
  39 let pp_reduction_kind ~term_pp = function
  40   | `Normalize -> "normalize"
  41   | `Reduce -> "reduce"
  42   | `Simpl -> "simplify"
  43   | `Unfold (Some t) -> "unfold " ^ term_pp t
  44   | `Unfold None -> "unfold"
  45   | `Whd -> "whd"
  46
  47 let pp_tactic_pattern ~map_unicode_to_tex ~term_pp ~lazy_term_pp (what, hyp, goal) =
  48   if what = None && hyp = [] && goal = None then "" else
  49   let what_text =
  50     match what with
  51     | None -> ""
  52     | Some t -> Printf.sprintf "in match (%s) " (lazy_term_pp t) in
  53   let hyp_text =
  54     String.concat " "
  55       (List.map (fun (name, p) -> Printf.sprintf "%s:(%s)" name (term_pp p)) hyp) in
  56   let goal_text =
  57     match goal with
  58     | None -> ""
  59     | Some t ->
  60        let vdash = if map_unicode_to_tex then "\\vdash" else "⊢" in
  61         Printf.sprintf "%s (%s)" vdash (term_pp t)
  62   in
  63    Printf.sprintf "%sin %s%s" what_text hyp_text goal_text
  64
  65 let pp_intros_specs s = function
  66    | None, []         -> ""
  67    | Some num, []     -> Printf.sprintf " %s%i" s num
  68    | None, idents     -> Printf.sprintf " %s%s" s (pp_idents idents)
  69    | Some num, idents -> Printf.sprintf " %s%i %s" s num (pp_idents idents)
  70
  71 let pp_terms ~term_pp terms = String.concat ", " (List.map term_pp terms)
  72
  73 let opt_string_pp = function
  74    | None -> ""
  75    | Some what -> what ^ " "
  76
  77 let pp_auto_params ~term_pp (univ, params) =
  78    String.concat " "
  79      (List.map (fun (k,v) -> if v <> "" then k ^ "=" ^ v else k) params) ^
  80    if univ <> [] then
  81      (if params <> [] then " " else "") ^ "by " ^
  82      String.concat " " (List.map term_pp univ)
  83    else ""
  84 ;;
  85
  86 let pp_just ~term_pp =
  87  function
  88     `Term term -> "exact " ^ term_pp term
  89   | `Auto params -> pp_auto_params ~term_pp params
  90 ;;
  91
  92 let pp_ntactic ~map_unicode_to_tex = function
  93   | NApply (_,t) -> "napply " ^ CicNotationPp.pp_term t
  94 ;;
  95
  96 let rec pp_tactic ~map_unicode_to_tex ~term_pp ~lazy_term_pp =
  97  let pp_terms = pp_terms ~term_pp in
  98  let pp_tactics = pp_tactics ~map_unicode_to_tex ~term_pp ~lazy_term_pp in
  99  let pp_reduction_kind = pp_reduction_kind ~term_pp in
 100  let pp_tactic_pattern =
 101   pp_tactic_pattern ~map_unicode_to_tex ~lazy_term_pp ~term_pp in
 102  let rec pp_tactic =
 103   function
 104   (* Higher order tactics *)
 105   | Do (_, count, tac) ->
 106       Printf.sprintf "do %d %s" count (pp_tactic tac)
 107   | Repeat (_, tac) -> "repeat " ^ pp_tactic tac
 108   | Seq (_, tacs) -> pp_tactics ~sep:"; " tacs
 109   | Then (_, tac, tacs) ->
 110       Printf.sprintf "%s; [%s]" (pp_tactic tac)
 111         (pp_tactics ~sep:" | " tacs)
 112   | First (_, tacs) ->
 113      Printf.sprintf "tries [%s]" (pp_tactics ~sep:" | " tacs)
 114   | Try (_, tac) -> "try " ^ pp_tactic tac
 115   | Solve (_, tac) ->
 116      Printf.sprintf "solve [%s]" (pp_tactics ~sep:" | " tac)
 117   | Progress (_, tac) -> "progress " ^ pp_tactic tac
 118   (* First order tactics *)
 119   | Absurd (_, term) -> "absurd" ^ term_pp term
 120   | Apply (_, term) -> "apply " ^ term_pp term
 121   | ApplyRule (_, term) -> "apply rule " ^ term_pp term
 122   | ApplyP (_, term) -> "applyP " ^ term_pp term
 123   | ApplyS (_, term, params) ->
 124      "applyS " ^ term_pp term ^ pp_auto_params ~term_pp params
 125   | AutoBatch (_,params) -> "autobatch " ^
 126       pp_auto_params ~term_pp params
 127   | Assumption _ -> "assumption"
 128   | Cases (_, term, pattern, specs) ->
 129       Printf.sprintf "cases %s %s%s"
 130       (term_pp term)
 131       (pp_tactic_pattern pattern)
 132       (pp_intros_specs "names " specs)
 133   | Change (_, where, with_what) ->
 134       Printf.sprintf "change %s with %s" (pp_tactic_pattern where) (lazy_term_pp with_what)
 135   | Clear (_,ids) -> Printf.sprintf "clear %s" (pp_hyps ids)
 136   | ClearBody (_,id) -> Printf.sprintf "clearbody %s" (pp_hyps [id])
 137   | Constructor (_,n) -> "constructor " ^ string_of_int n
 138   | Compose (_,t1, t2, times, intro_specs) ->
 139       Printf.sprintf "compose %s%s %s%s"
 140         (if times > 0 then string_of_int times ^ " " else "")
 141         (term_pp t1) (match t2 with None -> "" | Some t2 -> "with "^term_pp t2)
 142         (pp_intros_specs " as " intro_specs)
 143   | Contradiction _ -> "contradiction"
 144   | Cut (_, ident, term) ->
 145      "cut " ^ term_pp term ^
 146       (match ident with None -> "" | Some id -> " as " ^ id)
 147   | Decompose (_, names) ->
 148       Printf.sprintf "decompose%s"
 149       (pp_intros_specs "names " (None, names))
 150   | Demodulate (_, params) -> "demodulate " ^ pp_auto_params ~term_pp params
 151   | Destruct (_, None) -> "destruct"
 152   | Destruct (_, Some terms) -> "destruct " ^ pp_terms terms
 153   | Elim (_, what, using, pattern, specs) ->
 154       Printf.sprintf "elim %s%s %s%s"
 155       (term_pp what)
 156       (match using with None -> "" | Some term -> " using " ^ term_pp term)
 157       (pp_tactic_pattern pattern)
 158       (pp_intros_specs "names " specs)
 159   | ElimType (_, term, using, specs) ->
 160       Printf.sprintf "elim type %s%s%s"
 161       (term_pp term)
 162       (match using with None -> "" | Some term -> " using " ^ term_pp term)
 163       (pp_intros_specs "names " specs)
 164   | Exact (_, term) -> "exact " ^ term_pp term
 165   | Exists _ -> "exists"
 166   | Fold (_, kind, term, pattern) ->
 167       Printf.sprintf "fold %s %s %s" (pp_reduction_kind kind)
 168        (lazy_term_pp term) (pp_tactic_pattern pattern)
 169   | FwdSimpl (_, hyp, names) ->
 170       Printf.sprintf "fwd %s%s" hyp (pp_intros_specs "names " (None, names))
 171   | Generalize (_, pattern, ident) ->
 172      Printf.sprintf "generalize %s%s" (pp_tactic_pattern pattern)
 173       (match ident with None -> "" | Some id -> " as " ^ id)
 174   | Fail _ -> "fail"
 175   | Fourier _ -> "fourier"
 176   | IdTac _ -> "id"
 177   | Intros (_, specs) -> Printf.sprintf "intros%s" (pp_intros_specs "" specs)
 178   | Inversion (_, term) -> "inversion " ^ term_pp term
 179   | LApply (_, linear, level_opt, terms, term, ident_opt) ->
 180       Printf.sprintf "lapply %s%s%s%s%s"
 181         (if linear then " linear " else "")
 182         (match level_opt with None -> "" | Some i -> " depth = " ^ string_of_int i ^ " ")
 183         (term_pp term)
 184         (match terms with [] -> "" | _ -> " to " ^ pp_terms terms)
 185         (match ident_opt with None -> "" | Some ident -> " as " ^ ident)
 186   | Left _ -> "left"
 187   | LetIn (_, term, ident) ->
 188      Printf.sprintf "letin %s \\def %s" ident (term_pp term)
 189   | Reduce (_, kind, pat) ->
 190       Printf.sprintf "%s %s" (pp_reduction_kind kind) (pp_tactic_pattern pat)
 191   | Reflexivity _ -> "reflexivity"
 192   | Replace (_, pattern, t) ->
 193       Printf.sprintf "replace %s with %s" (pp_tactic_pattern pattern) (lazy_term_pp t)
 194   | Rewrite (_, pos, t, pattern, names) ->
 195       Printf.sprintf "rewrite %s %s %s%s"
 196         (if pos = `LeftToRight then ">" else "<")
 197         (term_pp t)
 198         (pp_tactic_pattern pattern)
 199         (if names = [] then "" else " as " ^ pp_idents names)
 200   | Right _ -> "right"
 201   | Ring _ -> "ring"
 202   | Split _ -> "split"
 203   | Symmetry _ -> "symmetry"
 204   | Transitivity (_, term) -> "transitivity " ^ term_pp term
 205   (* Tattiche Aggiunte *)
 206   | Assume (_, ident , term) -> "assume" ^ ident ^ ":" ^ term_pp term
 207   | Suppose (_, term, ident,term1) -> "suppose" ^ term_pp term ^ "("  ^ ident ^ ")" ^ (match term1 with None -> " " | Some term1 -> term_pp term1)
 208   | Bydone (_, just) ->  pp_just ~term_pp just ^ "done"
 209   | By_just_we_proved (_, just, term1, ident, term2) -> pp_just ~term_pp just  ^ "we proved" ^ term_pp term1 ^ (match ident with None -> "" | Some ident -> "(" ^ident^ ")") ^
 210        (match term2 with  None -> " " | Some term2 -> term_pp term2)
 211   | We_need_to_prove (_, term, ident, term1) -> "we need to prove" ^ term_pp term ^ (match ident with None -> "" | Some ident -> "(" ^ ident ^ ")") ^ (match term1 with None -> " " | Some term1 -> term_pp term1)
 212   | We_proceed_by_cases_on (_, term, term1) -> "we proceed by cases on" ^ term_pp term ^ "to prove" ^ term_pp term1
 213   | We_proceed_by_induction_on (_, term, term1) -> "we proceed by induction on" ^ term_pp term ^ "to prove" ^ term_pp term1
 214   | Byinduction (_, term, ident) -> "by induction hypothesis we know" ^ term_pp term ^ "(" ^ ident ^ ")"
 215   | Thesisbecomes (_, term) -> "the thesis becomes " ^ term_pp term
 216   | ExistsElim (_, just, ident, term, ident1, term1) -> pp_just ~term_pp just ^ "let " ^ ident ^ ":" ^ term_pp term ^ "such that " ^ lazy_term_pp term1 ^ "(" ^ ident1 ^ ")"
 217   | AndElim (_, just, ident1, term1, ident2, term2) -> pp_just ~term_pp just ^ "we have " ^ term_pp term1 ^ " (" ^ ident1 ^ ") " ^ "and " ^ term_pp term2 ^ " (" ^ ident2 ^ ")"
 218   | RewritingStep (_, term, term1, term2, cont) ->
 219       (match term with
 220       | None -> " "
 221       | Some (None,term) -> "conclude " ^ term_pp term
 222       | Some (Some name,term) ->
 223           "obtain (" ^ name ^ ") " ^ term_pp term)
 224       ^ "=" ^
 225       term_pp term1 ^
 226       (match term2 with
 227       | `Auto params -> pp_auto_params ~term_pp params
 228       | `Term term2 -> " exact " ^ term_pp term2
 229       | `Proof -> " proof"
 230       | `SolveWith term -> " using " ^ term_pp term)
 231       ^ (if cont then " done" else "")
 232   | Case (_, id, args) ->
 233      "case" ^ id ^
 234        String.concat " "
 235         (List.map (function (id,term) -> "(" ^ id ^ ": " ^ term_pp term ^  ")")
 236           args)
 237  in pp_tactic
 238
 239 and pp_tactics ~map_unicode_to_tex ~term_pp ~lazy_term_pp ~sep tacs =
 240   String.concat sep
 241    (List.map (pp_tactic ~map_unicode_to_tex ~lazy_term_pp ~term_pp) tacs)
 242
 243  let pp_search_kind = function
 244   | `Locate -> "locate"
 245   | `Hint -> "hint"
 246   | `Match -> "match"
 247   | `Elim -> "elim"
 248   | `Instance -> "instance"
 249
 250 let pp_arg ~term_pp arg =
 251   let s = term_pp arg in
 252    if s = "" || (s.[0] = '(' && s.[String.length s - 1] = ')') then
 253      (* _nice_ heuristic *)
 254      s
 255    else
 256      "(" ^ s ^ ")"
 257
 258 let pp_macro ~term_pp ~lazy_term_pp =
 259   let term_pp = pp_arg ~term_pp in
 260   let style_pp = function
 261      | Declarative         -> ""
 262      | Procedural None     -> "procedural "
 263      | Procedural (Some i) -> Printf.sprintf "procedural %u " i
 264   in
 265   let prefix_pp prefix =
 266      if prefix = "" then "" else Printf.sprintf " \"%s\"" prefix
 267   in
 268   let flavour_pp = function
 269      | None                   -> ""
 270      | Some `Definition       -> " as definition"
 271      | Some `MutualDefinition -> " as mutual"
 272      | Some `Fact             -> " as fact"
 273      | Some `Lemma            -> " as lemma"
 274      | Some `Remark           -> " as remark"
 275      | Some `Theorem          -> " as theorem"
 276      | Some `Variant          -> " as variant"
 277      | Some `Axiom            -> " as axiom"
 278   in
 279   let pp_reduction_kind = pp_reduction_kind ~term_pp:lazy_term_pp in
 280   function
 281   (* Whelp *)
 282   | WInstance (_, term) -> "whelp instance " ^ term_pp term
 283   | WHint (_, t) -> "whelp hint " ^ term_pp t
 284   | WLocate (_, s) -> "whelp locate \"" ^ s ^ "\""
 285   | WElim (_, t) -> "whelp elim " ^ term_pp t
 286   | WMatch (_, term) -> "whelp match " ^ term_pp term
 287   (* real macros *)
 288   | Eval (_, kind, term) ->
 289       Printf.sprintf "eval %s on %s" (pp_reduction_kind kind) (term_pp term)
 290   | Check (_, term) -> Printf.sprintf "check %s" (term_pp term)
 291   | Hint (_, true) -> "hint rewrite"
 292   | Hint (_, false) -> "hint"
 293   | AutoInteractive (_,params) -> "auto " ^ pp_auto_params ~term_pp params
 294   | Inline (_, style, suri, prefix, flavour) ->
 295       Printf.sprintf "inline %s\"%s\"%s%s" (style_pp style) suri (prefix_pp prefix) (flavour_pp flavour)
 296
 297 let pp_associativity = function
 298   | Gramext.LeftA -> "left associative"
 299   | Gramext.RightA -> "right associative"
 300   | Gramext.NonA -> "non associative"
 301
 302 let pp_precedence i = Printf.sprintf "with precedence %d" i
 303
 304 let pp_dir_opt = function
 305   | None -> ""
 306   | Some `LeftToRight -> "> "
 307   | Some `RightToLeft -> "< "
 308
 309 let pp_default what uris =
 310   Printf.sprintf "default \"%s\" %s" what
 311     (String.concat " " (List.map UriManager.string_of_uri uris))
 312
 313 let pp_coercion ~term_pp t do_composites arity saturations=
 314    Printf.sprintf "coercion %s %d %d %s"
 315     (term_pp t) arity saturations
 316     (if do_composites then "" else "nocomposites")
 317
 318 let pp_command ~term_pp ~obj_pp = function
 319   | Index (_,_,uri) -> "Indexing " ^ UriManager.string_of_uri uri
 320   | Coercion (_, t, do_composites, i, j) ->
 321      pp_coercion ~term_pp t do_composites i j
 322   | PreferCoercion (_,t) ->
 323      "prefer coercion " ^ term_pp t
 324   | UnificationHint (_,t, n) ->
 325       "unification hint " ^ string_of_int n ^ " " ^ term_pp t
 326   | Default (_,what,uris) -> pp_default what uris
 327   | Drop _ -> "drop"
 328   | Include (_,path) -> "include \"" ^ path ^ "\""
 329   | Obj (_,obj) -> obj_pp obj
 330   | Qed _ -> "qed"
 331   | Relation (_,id,a,aeq,refl,sym,trans) ->
 332      "relation " ^ term_pp aeq ^ " on " ^ term_pp a ^
 333      (match refl with
 334          Some r -> " reflexivity proved by " ^ term_pp r
 335        | None -> "") ^
 336      (match sym with
 337          Some r -> " symmetry proved by " ^ term_pp r
 338        | None -> "") ^
 339      (match trans with
 340          Some r -> " transitivity proved by " ^ term_pp r
 341        | None -> "")
 342   | Print (_,s) -> "print " ^ s
 343   | Set (_, name, value) -> Printf.sprintf "set \"%s\" \"%s\"" name value
 344   | NObj (_,o) -> "not supported"
 345
 346 let pp_punctuation_tactical =
 347   function
 348   | Dot _ -> "."
 349   | Semicolon _ -> ";"
 350   | Branch _ -> "["
 351   | Shift _ -> "|"
 352   | Pos (_, i) -> Printf.sprintf "%s:" (String.concat "," (List.map string_of_int i))
 353   | Wildcard _ -> "*:"
 354   | Merge _ -> "]"
 355
 356 let pp_non_punctuation_tactical =
 357   function
 358   | Focus (_, goals) ->
 359       Printf.sprintf "focus %s" (String.concat " " (List.map string_of_int goals))
 360   | Unfocus _ -> "unfocus"
 361   | Skip _ -> "skip"
 362
 363 let pp_executable ~map_unicode_to_tex ~term_pp ~lazy_term_pp ~obj_pp =
 364   function
 365   | Macro (_, macro) -> pp_macro ~term_pp ~lazy_term_pp macro ^ "."
 366   | Tactic (_, Some tac, punct) ->
 367       pp_tactic ~map_unicode_to_tex ~term_pp ~lazy_term_pp tac
 368       ^ pp_punctuation_tactical punct
 369   | Tactic (_, None, punct) ->
 370      pp_punctuation_tactical punct
 371   | NTactic (_,Some tac, punct) ->
 372      pp_ntactic ~map_unicode_to_tex tac
 373      ^ pp_punctuation_tactical punct
 374   | NTactic (_,None, punct) ->
 375      pp_punctuation_tactical punct
 376   | NonPunctuationTactical (_, tac, punct) ->
 377      pp_non_punctuation_tactical tac
 378      ^ pp_punctuation_tactical punct
 379   | Command (_, cmd) -> pp_command ~term_pp ~obj_pp cmd ^ "."
 380
 381 let pp_comment ~map_unicode_to_tex ~term_pp ~lazy_term_pp ~obj_pp =
 382   function
 383   | Note (_,"") -> Printf.sprintf "\n"
 384   | Note (_,str) -> Printf.sprintf "\n(* %s *)" str
 385   | Code (_,code) ->
 386       Printf.sprintf "\n(** %s. **)" (pp_executable ~map_unicode_to_tex ~term_pp ~lazy_term_pp ~obj_pp code)
 387
 388 let pp_statement ~term_pp ~lazy_term_pp ~obj_pp =
 389   function
 390   | Executable (_, ex) -> pp_executable ~lazy_term_pp ~term_pp ~obj_pp ex
 391   | Comment (_, c) -> pp_comment ~term_pp ~lazy_term_pp ~obj_pp c