helm/software/components/grafite/grafiteAstPp.ml

   1 (* Copyright (C) 2004, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://helm.cs.unibo.it/
  24  *)
  25
  26 (* $Id$ *)
  27
  28 open GrafiteAst
  29
  30 let tactical_terminator = ""
  31 let tactic_terminator = tactical_terminator
  32 let command_terminator = tactical_terminator
  33
  34 let pp_idents idents =
  35    let map = function Some s -> s | None -> "_" in
  36    "(" ^ String.concat " " (List.map map idents) ^ ")"
  37 let pp_hyps idents = String.concat " " idents
  38
  39 let pp_reduction_kind ~term_pp = function
  40   | `Normalize -> "normalize"
  41   | `Reduce -> "reduce"
  42   | `Simpl -> "simplify"
  43   | `Unfold (Some t) -> "unfold " ^ term_pp t
  44   | `Unfold None -> "unfold"
  45   | `Whd -> "whd"
  46
  47 let pp_tactic_pattern ~map_unicode_to_tex ~term_pp ~lazy_term_pp (what, hyp, goal) =
  48   if what = None && hyp = [] && goal = None then "" else
  49   let what_text =
  50     match what with
  51     | None -> ""
  52     | Some t -> Printf.sprintf "in match (%s) " (lazy_term_pp t) in
  53   let hyp_text =
  54     String.concat " "
  55       (List.map (fun (name, p) -> Printf.sprintf "%s:(%s)" name (term_pp p)) hyp) in
  56   let goal_text =
  57     match goal with
  58     | None -> ""
  59     | Some t ->
  60        let vdash = if map_unicode_to_tex then "\\vdash" else "⊢" in
  61         Printf.sprintf "%s (%s)" vdash (term_pp t)
  62   in
  63    Printf.sprintf "%sin %s%s" what_text hyp_text goal_text
  64
  65 let pp_intros_specs s = function
  66    | None, []         -> ""
  67    | Some num, []     -> Printf.sprintf " %s%i" s num
  68    | None, idents     -> Printf.sprintf " %s%s" s (pp_idents idents)
  69    | Some num, idents -> Printf.sprintf " %s%i %s" s num (pp_idents idents)
  70
  71 let pp_terms ~term_pp terms = String.concat ", " (List.map term_pp terms)
  72
  73 let opt_string_pp = function
  74    | None -> ""
  75    | Some what -> what ^ " "
  76
  77 let pp_auto_params ~term_pp (univ, params) =
  78    String.concat " "
  79      (List.map (fun (k,v) -> if v <> "" then k ^ "=" ^ v else k) params) ^
  80    if univ <> [] then
  81      (if params <> [] then " " else "") ^ "by " ^
  82      String.concat " " (List.map term_pp univ)
  83    else ""
  84 ;;
  85
  86 let pp_just ~term_pp =
  87  function
  88     `Term term -> "exact " ^ term_pp term
  89   | `Auto params -> pp_auto_params ~term_pp params
  90 ;;
  91
  92 let pp_ntactic ~map_unicode_to_tex = function
  93   | NApply (_,t) -> "napply " ^ CicNotationPp.pp_term t
  94   | NCases (_,what,where) -> "ncases " ^ CicNotationPp.pp_term what ^
  95       assert false ^ " " ^ assert false
  96   | NCase1 (_,n) -> "*" ^ n ^ ":"
  97   | NChange (_,what,wwhat) -> "nchange " ^ assert false ^
  98       " with " ^ CicNotationPp.pp_term wwhat
  99   | NElim (_,what,where) -> "nelim " ^ CicNotationPp.pp_term what ^
 100       assert false ^ " " ^ assert false
 101   | NId _ -> "nid"
 102   | NIntro (_,n) -> "#" ^ n
 103   | NRewrite (_,dir,n,where) -> "nrewrite" ^ assert false
 104   | NAuto (_,(l,flgs)) ->
 105       "nauto" ^
 106         (if l <> [] then (" by " ^
 107          (String.concat "," (List.map CicNotationPp.pp_term l))) else "") ^
 108         String.concat " " (List.map (fun a,b -> a ^ "=" ^ b) flgs)
 109   | NReduce _ | NGeneralize _ | NLetIn _ | NAssert _ -> assert false
 110 ;;
 111
 112 let rec pp_tactic ~map_unicode_to_tex ~term_pp ~lazy_term_pp =
 113  let pp_terms = pp_terms ~term_pp in
 114  let pp_tactics = pp_tactics ~map_unicode_to_tex ~term_pp ~lazy_term_pp in
 115  let pp_reduction_kind = pp_reduction_kind ~term_pp in
 116  let pp_tactic_pattern =
 117   pp_tactic_pattern ~map_unicode_to_tex ~lazy_term_pp ~term_pp in
 118  let rec pp_tactic =
 119   function
 120   (* Higher order tactics *)
 121   | Do (_, count, tac) ->
 122       Printf.sprintf "do %d %s" count (pp_tactic tac)
 123   | Repeat (_, tac) -> "repeat " ^ pp_tactic tac
 124   | Seq (_, tacs) -> pp_tactics ~sep:"; " tacs
 125   | Then (_, tac, tacs) ->
 126       Printf.sprintf "%s; [%s]" (pp_tactic tac)
 127         (pp_tactics ~sep:" | " tacs)
 128   | First (_, tacs) ->
 129      Printf.sprintf "tries [%s]" (pp_tactics ~sep:" | " tacs)
 130   | Try (_, tac) -> "try " ^ pp_tactic tac
 131   | Solve (_, tac) ->
 132      Printf.sprintf "solve [%s]" (pp_tactics ~sep:" | " tac)
 133   | Progress (_, tac) -> "progress " ^ pp_tactic tac
 134   (* First order tactics *)
 135   | Absurd (_, term) -> "absurd" ^ term_pp term
 136   | Apply (_, term) -> "apply " ^ term_pp term
 137   | ApplyRule (_, term) -> "apply rule " ^ term_pp term
 138   | ApplyP (_, term) -> "applyP " ^ term_pp term
 139   | ApplyS (_, term, params) ->
 140      "applyS " ^ term_pp term ^ pp_auto_params ~term_pp params
 141   | AutoBatch (_,params) -> "autobatch " ^
 142       pp_auto_params ~term_pp params
 143   | Assumption _ -> "assumption"
 144   | Cases (_, term, pattern, specs) ->
 145       Printf.sprintf "cases %s %s%s"
 146       (term_pp term)
 147       (pp_tactic_pattern pattern)
 148       (pp_intros_specs "names " specs)
 149   | Change (_, where, with_what) ->
 150       Printf.sprintf "change %s with %s" (pp_tactic_pattern where) (lazy_term_pp with_what)
 151   | Clear (_,ids) -> Printf.sprintf "clear %s" (pp_hyps ids)
 152   | ClearBody (_,id) -> Printf.sprintf "clearbody %s" (pp_hyps [id])
 153   | Constructor (_,n) -> "constructor " ^ string_of_int n
 154   | Compose (_,t1, t2, times, intro_specs) ->
 155       Printf.sprintf "compose %s%s %s%s"
 156         (if times > 0 then string_of_int times ^ " " else "")
 157         (term_pp t1) (match t2 with None -> "" | Some t2 -> "with "^term_pp t2)
 158         (pp_intros_specs " as " intro_specs)
 159   | Contradiction _ -> "contradiction"
 160   | Cut (_, ident, term) ->
 161      "cut " ^ term_pp term ^
 162       (match ident with None -> "" | Some id -> " as " ^ id)
 163   | Decompose (_, names) ->
 164       Printf.sprintf "decompose%s"
 165       (pp_intros_specs "names " (None, names))
 166   | Demodulate (_, params) -> "demodulate " ^ pp_auto_params ~term_pp params
 167   | Destruct (_, None) -> "destruct"
 168   | Destruct (_, Some terms) -> "destruct " ^ pp_terms terms
 169   | Elim (_, what, using, pattern, specs) ->
 170       Printf.sprintf "elim %s%s %s%s"
 171       (term_pp what)
 172       (match using with None -> "" | Some term -> " using " ^ term_pp term)
 173       (pp_tactic_pattern pattern)
 174       (pp_intros_specs "names " specs)
 175   | ElimType (_, term, using, specs) ->
 176       Printf.sprintf "elim type %s%s%s"
 177       (term_pp term)
 178       (match using with None -> "" | Some term -> " using " ^ term_pp term)
 179       (pp_intros_specs "names " specs)
 180   | Exact (_, term) -> "exact " ^ term_pp term
 181   | Exists _ -> "exists"
 182   | Fold (_, kind, term, pattern) ->
 183       Printf.sprintf "fold %s %s %s" (pp_reduction_kind kind)
 184        (lazy_term_pp term) (pp_tactic_pattern pattern)
 185   | FwdSimpl (_, hyp, names) ->
 186       Printf.sprintf "fwd %s%s" hyp (pp_intros_specs "names " (None, names))
 187   | Generalize (_, pattern, ident) ->
 188      Printf.sprintf "generalize %s%s" (pp_tactic_pattern pattern)
 189       (match ident with None -> "" | Some id -> " as " ^ id)
 190   | Fail _ -> "fail"
 191   | Fourier _ -> "fourier"
 192   | IdTac _ -> "id"
 193   | Intros (_, specs) -> Printf.sprintf "intros%s" (pp_intros_specs "" specs)
 194   | Inversion (_, term) -> "inversion " ^ term_pp term
 195   | LApply (_, linear, level_opt, terms, term, ident_opt) ->
 196       Printf.sprintf "lapply %s%s%s%s%s"
 197         (if linear then " linear " else "")
 198         (match level_opt with None -> "" | Some i -> " depth = " ^ string_of_int i ^ " ")
 199         (term_pp term)
 200         (match terms with [] -> "" | _ -> " to " ^ pp_terms terms)
 201         (match ident_opt with None -> "" | Some ident -> " as " ^ ident)
 202   | Left _ -> "left"
 203   | LetIn (_, term, ident) ->
 204      Printf.sprintf "letin %s \\def %s" ident (term_pp term)
 205   | Reduce (_, kind, pat) ->
 206       Printf.sprintf "%s %s" (pp_reduction_kind kind) (pp_tactic_pattern pat)
 207   | Reflexivity _ -> "reflexivity"
 208   | Replace (_, pattern, t) ->
 209       Printf.sprintf "replace %s with %s" (pp_tactic_pattern pattern) (lazy_term_pp t)
 210   | Rewrite (_, pos, t, pattern, names) ->
 211       Printf.sprintf "rewrite %s %s %s%s"
 212         (if pos = `LeftToRight then ">" else "<")
 213         (term_pp t)
 214         (pp_tactic_pattern pattern)
 215         (if names = [] then "" else " as " ^ pp_idents names)
 216   | Right _ -> "right"
 217   | Ring _ -> "ring"
 218   | Split _ -> "split"
 219   | Symmetry _ -> "symmetry"
 220   | Transitivity (_, term) -> "transitivity " ^ term_pp term
 221   (* Tattiche Aggiunte *)
 222   | Assume (_, ident , term) -> "assume" ^ ident ^ ":" ^ term_pp term
 223   | Suppose (_, term, ident,term1) -> "suppose" ^ term_pp term ^ "("  ^ ident ^ ")" ^ (match term1 with None -> " " | Some term1 -> term_pp term1)
 224   | Bydone (_, just) ->  pp_just ~term_pp just ^ "done"
 225   | By_just_we_proved (_, just, term1, ident, term2) -> pp_just ~term_pp just  ^ "we proved" ^ term_pp term1 ^ (match ident with None -> "" | Some ident -> "(" ^ident^ ")") ^
 226        (match term2 with  None -> " " | Some term2 -> term_pp term2)
 227   | We_need_to_prove (_, term, ident, term1) -> "we need to prove" ^ term_pp term ^ (match ident with None -> "" | Some ident -> "(" ^ ident ^ ")") ^ (match term1 with None -> " " | Some term1 -> term_pp term1)
 228   | We_proceed_by_cases_on (_, term, term1) -> "we proceed by cases on" ^ term_pp term ^ "to prove" ^ term_pp term1
 229   | We_proceed_by_induction_on (_, term, term1) -> "we proceed by induction on" ^ term_pp term ^ "to prove" ^ term_pp term1
 230   | Byinduction (_, term, ident) -> "by induction hypothesis we know" ^ term_pp term ^ "(" ^ ident ^ ")"
 231   | Thesisbecomes (_, term) -> "the thesis becomes " ^ term_pp term
 232   | ExistsElim (_, just, ident, term, ident1, term1) -> pp_just ~term_pp just ^ "let " ^ ident ^ ":" ^ term_pp term ^ "such that " ^ lazy_term_pp term1 ^ "(" ^ ident1 ^ ")"
 233   | AndElim (_, just, ident1, term1, ident2, term2) -> pp_just ~term_pp just ^ "we have " ^ term_pp term1 ^ " (" ^ ident1 ^ ") " ^ "and " ^ term_pp term2 ^ " (" ^ ident2 ^ ")"
 234   | RewritingStep (_, term, term1, term2, cont) ->
 235       (match term with
 236       | None -> " "
 237       | Some (None,term) -> "conclude " ^ term_pp term
 238       | Some (Some name,term) ->
 239           "obtain (" ^ name ^ ") " ^ term_pp term)
 240       ^ "=" ^
 241       term_pp term1 ^
 242       (match term2 with
 243       | `Auto params -> pp_auto_params ~term_pp params
 244       | `Term term2 -> " exact " ^ term_pp term2
 245       | `Proof -> " proof"
 246       | `SolveWith term -> " using " ^ term_pp term)
 247       ^ (if cont then " done" else "")
 248   | Case (_, id, args) ->
 249      "case" ^ id ^
 250        String.concat " "
 251         (List.map (function (id,term) -> "(" ^ id ^ ": " ^ term_pp term ^  ")")
 252           args)
 253  in pp_tactic
 254
 255 and pp_tactics ~map_unicode_to_tex ~term_pp ~lazy_term_pp ~sep tacs =
 256   String.concat sep
 257    (List.map (pp_tactic ~map_unicode_to_tex ~lazy_term_pp ~term_pp) tacs)
 258
 259  let pp_search_kind = function
 260   | `Locate -> "locate"
 261   | `Hint -> "hint"
 262   | `Match -> "match"
 263   | `Elim -> "elim"
 264   | `Instance -> "instance"
 265
 266 let pp_arg ~term_pp arg =
 267   let s = term_pp arg in
 268    if s = "" || (s.[0] = '(' && s.[String.length s - 1] = ')') then
 269      (* _nice_ heuristic *)
 270      s
 271    else
 272      "(" ^ s ^ ")"
 273
 274 let pp_macro ~term_pp ~lazy_term_pp =
 275   let term_pp = pp_arg ~term_pp in
 276   let flavour_pp = function
 277      | `Definition       -> "definition"
 278      | `Fact             -> "fact"
 279      | `Lemma            -> "lemma"
 280      | `Remark           -> "remark"
 281      | `Theorem          -> "theorem"
 282      | `Variant          -> "variant"
 283      | `Axiom            -> "axiom"
 284      | `MutualDefinition -> assert false
 285   in
 286   let pp_inline_params l =
 287      let pp_param = function
 288         | IPPrefix prefix -> "prefix = \"" ^ prefix ^ "\""
 289         | IPAs flavour  -> flavour_pp flavour
 290         | IPCoercions   -> "coercions"
 291         | IPDebug debug -> "debug = " ^ string_of_int debug
 292         | IPProcedural  -> "procedural"
 293         | IPNoDefaults  -> "nodefaults"
 294         | IPDepth depth -> "depth = " ^ string_of_int depth
 295         | IPLevel level -> "level = " ^ string_of_int level
 296         | IPComments    -> "comments"
 297         | IPCR          -> "cr"
 298      in
 299      let s = String.concat " " (List.map pp_param l) in
 300      if s = "" then s else " " ^ s
 301   in
 302   let pp_reduction_kind = pp_reduction_kind ~term_pp:lazy_term_pp in
 303   function
 304   (* Whelp *)
 305   | WInstance (_, term) -> "whelp instance " ^ term_pp term
 306   | WHint (_, t) -> "whelp hint " ^ term_pp t
 307   | WLocate (_, s) -> "whelp locate \"" ^ s ^ "\""
 308   | WElim (_, t) -> "whelp elim " ^ term_pp t
 309   | WMatch (_, term) -> "whelp match " ^ term_pp term
 310   (* real macros *)
 311   | Eval (_, kind, term) ->
 312       Printf.sprintf "eval %s on %s" (pp_reduction_kind kind) (term_pp term)
 313   | Check (_, term) -> Printf.sprintf "check %s" (term_pp term)
 314   | Hint (_, true) -> "hint rewrite"
 315   | Hint (_, false) -> "hint"
 316   | AutoInteractive (_,params) -> "auto " ^ pp_auto_params ~term_pp params
 317   | Inline (_, suri, params) ->
 318       Printf.sprintf "inline \"%s\"%s" suri (pp_inline_params params)
 319
 320 let pp_associativity = function
 321   | Gramext.LeftA -> "left associative"
 322   | Gramext.RightA -> "right associative"
 323   | Gramext.NonA -> "non associative"
 324
 325 let pp_precedence i = Printf.sprintf "with precedence %d" i
 326
 327 let pp_dir_opt = function
 328   | None -> ""
 329   | Some `LeftToRight -> "> "
 330   | Some `RightToLeft -> "< "
 331
 332 let pp_default what uris =
 333   Printf.sprintf "default \"%s\" %s" what
 334     (String.concat " " (List.map UriManager.string_of_uri uris))
 335
 336 let pp_coercion ~term_pp t do_composites arity saturations=
 337    Printf.sprintf "coercion %s %d %d %s"
 338     (term_pp t) arity saturations
 339     (if do_composites then "" else "nocomposites")
 340
 341 let pp_command ~term_pp ~obj_pp = function
 342   | Index (_,_,uri) -> "Indexing " ^ UriManager.string_of_uri uri
 343   | Select (_,uri) -> "Selecting " ^ UriManager.string_of_uri uri
 344   | Coercion (_, t, do_composites, i, j) ->
 345      pp_coercion ~term_pp t do_composites i j
 346   | PreferCoercion (_,t) ->
 347      "prefer coercion " ^ term_pp t
 348   | Inverter (_,n,ty,params) ->
 349      "inverter " ^ n ^ " for " ^ term_pp ty ^ " " ^ List.fold_left (fun acc x -> acc ^ (match x with true -> "%" | _ -> "?")) "" params
 350   | UnificationHint (_,t, n) ->
 351       "unification hint " ^ string_of_int n ^ " " ^ term_pp t
 352   | Default (_,what,uris) -> pp_default what uris
 353   | Drop _ -> "drop"
 354   | Include (_,true,path) -> "include \"" ^ path ^ "\""
 355   | Include (_,false,path) -> "include source \"" ^ path ^ "\""
 356   | Obj (_,obj) -> obj_pp obj
 357   | Qed _ -> "qed"
 358   | Relation (_,id,a,aeq,refl,sym,trans) ->
 359      "relation " ^ term_pp aeq ^ " on " ^ term_pp a ^
 360      (match refl with
 361          Some r -> " reflexivity proved by " ^ term_pp r
 362        | None -> "") ^
 363      (match sym with
 364          Some r -> " symmetry proved by " ^ term_pp r
 365        | None -> "") ^
 366      (match trans with
 367          Some r -> " transitivity proved by " ^ term_pp r
 368        | None -> "")
 369   | Print (_,s) -> "print " ^ s
 370   | Set (_, name, value) -> Printf.sprintf "set \"%s\" \"%s\"" name value
 371   | NObj (_,_)
 372   | NUnivConstraint (_) -> "not supported"
 373   | NQed (_) -> "nqed"
 374   | Pump (_) -> "not supported"
 375
 376 let pp_punctuation_tactical =
 377   function
 378   | Dot _ -> "."
 379   | Semicolon _ -> ";"
 380   | Branch _ -> "["
 381   | Shift _ -> "|"
 382   | Pos (_, i) -> Printf.sprintf "%s:" (String.concat "," (List.map string_of_int i))
 383   | Wildcard _ -> "*:"
 384   | Merge _ -> "]"
 385
 386 let pp_non_punctuation_tactical =
 387   function
 388   | Focus (_, goals) ->
 389       Printf.sprintf "focus %s" (String.concat " " (List.map string_of_int goals))
 390   | Unfocus _ -> "unfocus"
 391   | Skip _ -> "skip"
 392
 393 let pp_executable ~map_unicode_to_tex ~term_pp ~lazy_term_pp ~obj_pp =
 394   function
 395   | Macro (_, macro) -> pp_macro ~term_pp ~lazy_term_pp macro ^ "."
 396   | Tactic (_, Some tac, punct) ->
 397       pp_tactic ~map_unicode_to_tex ~term_pp ~lazy_term_pp tac
 398       ^ pp_punctuation_tactical punct
 399   | Tactic (_, None, punct) ->
 400      pp_punctuation_tactical punct
 401   | NTactic (_,tac, punct) ->
 402      pp_ntactic ~map_unicode_to_tex tac
 403      ^ pp_punctuation_tactical punct
 404   | NonPunctuationTactical (_, tac, punct) ->
 405      pp_non_punctuation_tactical tac
 406      ^ pp_punctuation_tactical punct
 407   | NNonPunctuationTactical (_, tac, punct) ->
 408      pp_non_punctuation_tactical tac
 409      ^ pp_punctuation_tactical punct
 410   | Command (_, cmd) -> pp_command ~term_pp ~obj_pp cmd ^ "."
 411
 412 let pp_comment ~map_unicode_to_tex ~term_pp ~lazy_term_pp ~obj_pp =
 413   function
 414   | Note (_,"") -> Printf.sprintf "\n"
 415   | Note (_,str) -> Printf.sprintf "\n(* %s *)" str
 416   | Code (_,code) ->
 417       Printf.sprintf "\n(** %s. **)" (pp_executable ~map_unicode_to_tex ~term_pp ~lazy_term_pp ~obj_pp code)
 418
 419 let pp_statement ~term_pp ~lazy_term_pp ~obj_pp =
 420   function
 421   | Executable (_, ex) -> pp_executable ~lazy_term_pp ~term_pp ~obj_pp ex
 422   | Comment (_, c) -> pp_comment ~term_pp ~lazy_term_pp ~obj_pp c