helm/software/components/grafite/grafiteAstPp.ml

   1 (* Copyright (C) 2004, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://helm.cs.unibo.it/
  24  *)
  25
  26 (* $Id$ *)
  27
  28 open GrafiteAst
  29
  30 let tactical_terminator = ""
  31 let tactic_terminator = tactical_terminator
  32 let command_terminator = tactical_terminator
  33
  34 let pp_idents idents =
  35    let map = function Some s -> s | None -> "_" in
  36    "(" ^ String.concat " " (List.map map idents) ^ ")"
  37 let pp_hyps idents = String.concat " " idents
  38
  39 let pp_reduction_kind ~term_pp = function
  40   | `Normalize -> "normalize"
  41   | `Reduce -> "reduce"
  42   | `Simpl -> "simplify"
  43   | `Unfold (Some t) -> "unfold " ^ term_pp t
  44   | `Unfold None -> "unfold"
  45   | `Whd -> "whd"
  46
  47 let pp_tactic_pattern ~map_unicode_to_tex ~term_pp ~lazy_term_pp (what, hyp, goal) =
  48   if what = None && hyp = [] && goal = None then "" else
  49   let what_text =
  50     match what with
  51     | None -> ""
  52     | Some t -> Printf.sprintf "in match (%s) " (lazy_term_pp t) in
  53   let hyp_text =
  54     String.concat " "
  55       (List.map (fun (name, p) -> Printf.sprintf "%s:(%s)" name (term_pp p)) hyp) in
  56   let goal_text =
  57     match goal with
  58     | None -> ""
  59     | Some t ->
  60        let vdash = if map_unicode_to_tex then "\\vdash" else "⊢" in
  61         Printf.sprintf "%s (%s)" vdash (term_pp t)
  62   in
  63    Printf.sprintf "%sin %s%s" what_text hyp_text goal_text
  64
  65 let pp_intros_specs s = function
  66    | None, []         -> ""
  67    | Some num, []     -> Printf.sprintf " %s%i" s num
  68    | None, idents     -> Printf.sprintf " %s%s" s (pp_idents idents)
  69    | Some num, idents -> Printf.sprintf " %s%i %s" s num (pp_idents idents)
  70
  71 let pp_terms ~term_pp terms = String.concat ", " (List.map term_pp terms)
  72
  73 let opt_string_pp = function
  74    | None -> ""
  75    | Some what -> what ^ " "
  76
  77 let pp_auto_params ~term_pp (univ, params) =
  78    String.concat " "
  79      (List.map (fun (k,v) -> if v <> "" then k ^ "=" ^ v else k) params) ^
  80    if univ <> [] then
  81      (if params <> [] then " " else "") ^ "by " ^
  82      String.concat " " (List.map term_pp univ)
  83    else ""
  84 ;;
  85
  86 let pp_just ~term_pp =
  87  function
  88     `Term term -> "exact " ^ term_pp term
  89   | `Auto params -> pp_auto_params ~term_pp params
  90 ;;
  91
  92 let rec pp_tactic ~map_unicode_to_tex ~term_pp ~lazy_term_pp =
  93  let pp_terms = pp_terms ~term_pp in
  94  let pp_tactics = pp_tactics ~map_unicode_to_tex ~term_pp ~lazy_term_pp in
  95  let pp_reduction_kind = pp_reduction_kind ~term_pp in
  96  let pp_tactic_pattern =
  97   pp_tactic_pattern ~map_unicode_to_tex ~lazy_term_pp ~term_pp in
  98  let rec pp_tactic =
  99   function
 100   (* Higher order tactics *)
 101   | Do (_, count, tac) ->
 102       Printf.sprintf "do %d %s" count (pp_tactic tac)
 103   | Repeat (_, tac) -> "repeat " ^ pp_tactic tac
 104   | Seq (_, tacs) -> pp_tactics ~sep:"; " tacs
 105   | Then (_, tac, tacs) ->
 106       Printf.sprintf "%s; [%s]" (pp_tactic tac)
 107         (pp_tactics ~sep:" | " tacs)
 108   | First (_, tacs) ->
 109      Printf.sprintf "tries [%s]" (pp_tactics ~sep:" | " tacs)
 110   | Try (_, tac) -> "try " ^ pp_tactic tac
 111   | Solve (_, tac) ->
 112      Printf.sprintf "solve [%s]" (pp_tactics ~sep:" | " tac)
 113   | Progress (_, tac) -> "progress " ^ pp_tactic tac
 114   (* First order tactics *)
 115   | Absurd (_, term) -> "absurd" ^ term_pp term
 116   | Apply (_, term) -> "apply " ^ term_pp term
 117   | ApplyP (_, term) -> "applyP " ^ term_pp term
 118   | ApplyS (_, term, params) ->
 119      "applyS " ^ term_pp term ^ pp_auto_params ~term_pp params
 120   | AutoBatch (_,params) -> "autobatch " ^
 121       pp_auto_params ~term_pp params
 122   | Assumption _ -> "assumption"
 123   | Cases (_, term, pattern, specs) -> Printf.sprintf "cases " ^ term_pp term ^
 124       pp_tactic_pattern pattern ^
 125       pp_intros_specs "names " specs
 126   | Change (_, where, with_what) ->
 127       Printf.sprintf "change %s with %s" (pp_tactic_pattern where) (lazy_term_pp with_what)
 128   | Clear (_,ids) -> Printf.sprintf "clear %s" (pp_hyps ids)
 129   | ClearBody (_,id) -> Printf.sprintf "clearbody %s" (pp_hyps [id])
 130   | Constructor (_,n) -> "constructor " ^ string_of_int n
 131   | Compose (_,t1, t2, times, intro_specs) ->
 132       Printf.sprintf "compose %s%s %s%s"
 133         (if times > 0 then string_of_int times ^ " " else "")
 134         (term_pp t1) (match t2 with None -> "" | Some t2 -> "with "^term_pp t2)
 135         (pp_intros_specs " as " intro_specs)
 136   | Contradiction _ -> "contradiction"
 137   | Cut (_, ident, term) ->
 138      "cut " ^ term_pp term ^
 139       (match ident with None -> "" | Some id -> " as " ^ id)
 140   | Decompose (_, names) ->
 141       Printf.sprintf "decompose%s"
 142       (pp_intros_specs "names " (None, names))
 143   | Demodulate (_, params) -> "demodulate " ^ pp_auto_params ~term_pp params
 144   | Destruct (_, None) -> "destruct"
 145   | Destruct (_, Some terms) -> "destruct " ^ pp_terms terms
 146   | Elim (_, what, using, pattern, specs) ->
 147       Printf.sprintf "elim %s%s %s%s"
 148       (term_pp what)
 149       (match using with None -> "" | Some term -> " using " ^ term_pp term)
 150       (pp_tactic_pattern pattern)
 151       (pp_intros_specs "names " specs)
 152   | ElimType (_, term, using, specs) ->
 153       Printf.sprintf "elim type %s%s%s"
 154       (term_pp term)
 155       (match using with None -> "" | Some term -> " using " ^ term_pp term)
 156       (pp_intros_specs "names " specs)
 157   | Exact (_, term) -> "exact " ^ term_pp term
 158   | Exists _ -> "exists"
 159   | Fold (_, kind, term, pattern) ->
 160       Printf.sprintf "fold %s %s %s" (pp_reduction_kind kind)
 161        (lazy_term_pp term) (pp_tactic_pattern pattern)
 162   | FwdSimpl (_, hyp, names) ->
 163       Printf.sprintf "fwd %s%s" hyp (pp_intros_specs "names " (None, names))
 164   | Generalize (_, pattern, ident) ->
 165      Printf.sprintf "generalize %s%s" (pp_tactic_pattern pattern)
 166       (match ident with None -> "" | Some id -> " as " ^ id)
 167   | Fail _ -> "fail"
 168   | Fourier _ -> "fourier"
 169   | IdTac _ -> "id"
 170   | Intros (_, specs) -> Printf.sprintf "intros%s" (pp_intros_specs "" specs)
 171   | Inversion (_, term) -> "inversion " ^ term_pp term
 172   | LApply (_, linear, level_opt, terms, term, ident_opt) ->
 173       Printf.sprintf "lapply %s%s%s%s%s"
 174         (if linear then " linear " else "")
 175         (match level_opt with None -> "" | Some i -> " depth = " ^ string_of_int i ^ " ")
 176         (term_pp term)
 177         (match terms with [] -> "" | _ -> " to " ^ pp_terms terms)
 178         (match ident_opt with None -> "" | Some ident -> " as " ^ ident)
 179   | Left _ -> "left"
 180   | LetIn (_, term, ident) ->
 181      Printf.sprintf "letin %s \\def %s" ident (term_pp term)
 182   | Reduce (_, kind, pat) ->
 183       Printf.sprintf "%s %s" (pp_reduction_kind kind) (pp_tactic_pattern pat)
 184   | Reflexivity _ -> "reflexivity"
 185   | Replace (_, pattern, t) ->
 186       Printf.sprintf "replace %s with %s" (pp_tactic_pattern pattern) (lazy_term_pp t)
 187   | Rewrite (_, pos, t, pattern, names) ->
 188       Printf.sprintf "rewrite %s %s %s%s"
 189         (if pos = `LeftToRight then ">" else "<")
 190         (term_pp t)
 191         (pp_tactic_pattern pattern)
 192         (if names = [] then "" else " as " ^ pp_idents names)
 193   | Right _ -> "right"
 194   | Ring _ -> "ring"
 195   | Split _ -> "split"
 196   | Symmetry _ -> "symmetry"
 197   | Transitivity (_, term) -> "transitivity " ^ term_pp term
 198   (* Tattiche Aggiunte *)
 199   | Assume (_, ident , term) -> "assume" ^ ident ^ ":" ^ term_pp term
 200   | Suppose (_, term, ident,term1) -> "suppose" ^ term_pp term ^ "("  ^ ident ^ ")" ^ (match term1 with None -> " " | Some term1 -> term_pp term1)
 201   | Bydone (_, just) ->  pp_just ~term_pp just ^ "done"
 202   | By_just_we_proved (_, just, term1, ident, term2) -> pp_just ~term_pp just  ^ "we proved" ^ term_pp term1 ^ (match ident with None -> "" | Some ident -> "(" ^ident^ ")") ^
 203        (match term2 with  None -> " " | Some term2 -> term_pp term2)
 204   | We_need_to_prove (_, term, ident, term1) -> "we need to prove" ^ term_pp term ^ (match ident with None -> "" | Some ident -> "(" ^ ident ^ ")") ^ (match term1 with None -> " " | Some term1 -> term_pp term1)
 205   | We_proceed_by_cases_on (_, term, term1) -> "we proceed by cases on" ^ term_pp term ^ "to prove" ^ term_pp term1
 206   | We_proceed_by_induction_on (_, term, term1) -> "we proceed by induction on" ^ term_pp term ^ "to prove" ^ term_pp term1
 207   | Byinduction (_, term, ident) -> "by induction hypothesis we know" ^ term_pp term ^ "(" ^ ident ^ ")"
 208   | Thesisbecomes (_, term) -> "the thesis becomes " ^ term_pp term
 209   | ExistsElim (_, just, ident, term, ident1, term1) -> pp_just ~term_pp just ^ "let " ^ ident ^ ":" ^ term_pp term ^ "such that " ^ lazy_term_pp term1 ^ "(" ^ ident1 ^ ")"
 210   | AndElim (_, just, ident1, term1, ident2, term2) -> pp_just ~term_pp just ^ "we have " ^ term_pp term1 ^ " (" ^ ident1 ^ ") " ^ "and " ^ term_pp term2 ^ " (" ^ ident2 ^ ")"
 211   | RewritingStep (_, term, term1, term2, cont) ->
 212       (match term with
 213       | None -> " "
 214       | Some (None,term) -> "conclude " ^ term_pp term
 215       | Some (Some name,term) ->
 216           "obtain (" ^ name ^ ") " ^ term_pp term)
 217       ^ "=" ^
 218       term_pp term1 ^
 219       (match term2 with
 220       | `Auto params -> pp_auto_params ~term_pp params
 221       | `Term term2 -> " exact " ^ term_pp term2
 222       | `Proof -> " proof"
 223       | `SolveWith term -> " using " ^ term_pp term)
 224       ^ (if cont then " done" else "")
 225   | Case (_, id, args) ->
 226      "case" ^ id ^
 227        String.concat " "
 228         (List.map (function (id,term) -> "(" ^ id ^ ": " ^ term_pp term ^  ")")
 229           args)
 230  in pp_tactic
 231
 232 and pp_tactics ~map_unicode_to_tex ~term_pp ~lazy_term_pp ~sep tacs =
 233   String.concat sep
 234    (List.map (pp_tactic ~map_unicode_to_tex ~lazy_term_pp ~term_pp) tacs)
 235
 236  let pp_search_kind = function
 237   | `Locate -> "locate"
 238   | `Hint -> "hint"
 239   | `Match -> "match"
 240   | `Elim -> "elim"
 241   | `Instance -> "instance"
 242
 243 let pp_arg ~term_pp arg =
 244   let s = term_pp arg in
 245    if s = "" || (s.[0] = '(' && s.[String.length s - 1] = ')') then
 246      (* _nice_ heuristic *)
 247      s
 248    else
 249      "(" ^ s ^ ")"
 250
 251 let pp_macro ~term_pp =
 252   let term_pp = pp_arg ~term_pp in
 253   let style_pp = function
 254      | Declarative         -> ""
 255      | Procedural None     -> "procedural "
 256      | Procedural (Some i) -> Printf.sprintf "procedural %u " i
 257   in
 258   let prefix_pp prefix =
 259      if prefix = "" then "" else Printf.sprintf " \"%s\"" prefix
 260   in
 261   let flavour_pp = function
 262      | None                   -> ""
 263      | Some `Definition       -> " as definition"
 264      | Some `MutualDefinition -> " as mutual"
 265      | Some `Fact             -> " as fact"
 266      | Some `Lemma            -> " as lemma"
 267      | Some `Remark           -> " as remark"
 268      | Some `Theorem          -> " as theorem"
 269      | Some `Variant          -> " as variant"
 270      | Some `Axiom            -> " as axiom"
 271   in
 272   function
 273   (* Whelp *)
 274   | WInstance (_, term) -> "whelp instance " ^ term_pp term
 275   | WHint (_, t) -> "whelp hint " ^ term_pp t
 276   | WLocate (_, s) -> "whelp locate \"" ^ s ^ "\""
 277   | WElim (_, t) -> "whelp elim " ^ term_pp t
 278   | WMatch (_, term) -> "whelp match " ^ term_pp term
 279   (* real macros *)
 280   | Check (_, term) -> Printf.sprintf "check %s" (term_pp term)
 281   | Hint (_, true) -> "hint rewrite"
 282   | Hint (_, false) -> "hint"
 283   | AutoInteractive (_,params) -> "auto " ^ pp_auto_params ~term_pp params
 284   | Inline (_, style, suri, prefix, flavour) ->
 285       Printf.sprintf "inline %s\"%s\"%s%s" (style_pp style) suri (prefix_pp prefix) (flavour_pp flavour)
 286
 287 let pp_associativity = function
 288   | Gramext.LeftA -> "left associative"
 289   | Gramext.RightA -> "right associative"
 290   | Gramext.NonA -> "non associative"
 291
 292 let pp_precedence i = Printf.sprintf "with precedence %d" i
 293
 294 let pp_dir_opt = function
 295   | None -> ""
 296   | Some `LeftToRight -> "> "
 297   | Some `RightToLeft -> "< "
 298
 299 let pp_default what uris =
 300   Printf.sprintf "default \"%s\" %s" what
 301     (String.concat " " (List.map UriManager.string_of_uri uris))
 302
 303 let pp_coercion ~term_pp t do_composites arity saturations=
 304    Printf.sprintf "coercion %s %d %d %s"
 305     (term_pp t) arity saturations
 306     (if do_composites then "" else "nocomposites")
 307
 308 let pp_command ~term_pp ~obj_pp = function
 309   | Index (_,_,uri) -> "Indexing " ^ UriManager.string_of_uri uri
 310   | Coercion (_, t, do_composites, i, j) ->
 311      pp_coercion ~term_pp t do_composites i j
 312   | Default (_,what,uris) -> pp_default what uris
 313   | Drop _ -> "drop"
 314   | Include (_,path) -> "include \"" ^ path ^ "\""
 315   | Obj (_,obj) -> obj_pp obj
 316   | Qed _ -> "qed"
 317   | Relation (_,id,a,aeq,refl,sym,trans) ->
 318      "relation " ^ term_pp aeq ^ " on " ^ term_pp a ^
 319      (match refl with
 320          Some r -> " reflexivity proved by " ^ term_pp r
 321        | None -> "") ^
 322      (match sym with
 323          Some r -> " symmetry proved by " ^ term_pp r
 324        | None -> "") ^
 325      (match trans with
 326          Some r -> " transitivity proved by " ^ term_pp r
 327        | None -> "")
 328   | Print (_,s) -> "print " ^ s
 329   | Set (_, name, value) -> Printf.sprintf "set \"%s\" \"%s\"" name value
 330
 331 let pp_punctuation_tactical ~term_pp ~lazy_term_pp =
 332   function
 333   | Dot _ -> "."
 334   | Semicolon _ -> ";"
 335   | Branch _ -> "["
 336   | Shift _ -> "|"
 337   | Pos (_, i) -> Printf.sprintf "%s:" (String.concat "," (List.map string_of_int i))
 338   | Wildcard _ -> "*:"
 339   | Merge _ -> "]"
 340
 341 let pp_non_punctuation_tactical ~term_pp ~lazy_term_pp =
 342   function
 343   | Focus (_, goals) ->
 344       Printf.sprintf "focus %s" (String.concat " " (List.map string_of_int goals))
 345   | Unfocus _ -> "unfocus"
 346   | Skip _ -> "skip"
 347
 348 let pp_executable ~map_unicode_to_tex ~term_pp ~lazy_term_pp ~obj_pp =
 349   function
 350   | Macro (_, macro) -> pp_macro ~term_pp macro ^ "."
 351   | Tactic (_, Some tac, punct) ->
 352       pp_tactic ~map_unicode_to_tex ~lazy_term_pp ~term_pp tac
 353       ^ pp_punctuation_tactical ~lazy_term_pp ~term_pp punct
 354   | Tactic (_, None, punct) ->
 355      pp_punctuation_tactical ~lazy_term_pp ~term_pp punct
 356   | NonPunctuationTactical (_, tac, punct) ->
 357      pp_non_punctuation_tactical ~lazy_term_pp ~term_pp tac
 358      ^ pp_punctuation_tactical ~lazy_term_pp ~term_pp punct
 359   | Command (_, cmd) -> pp_command ~term_pp ~obj_pp cmd ^ "."
 360
 361 let pp_comment ~map_unicode_to_tex ~term_pp ~lazy_term_pp ~obj_pp =
 362   function
 363   | Note (_,"") -> Printf.sprintf "\n"
 364   | Note (_,str) -> Printf.sprintf "\n(* %s *)" str
 365   | Code (_,code) ->
 366       Printf.sprintf "\n(** %s. **)" (pp_executable ~map_unicode_to_tex ~term_pp ~lazy_term_pp ~obj_pp code)
 367
 368 let pp_statement ~term_pp ~lazy_term_pp ~obj_pp =
 369   function
 370   | Executable (_, ex) -> pp_executable ~lazy_term_pp ~term_pp ~obj_pp ex
 371   | Comment (_, c) -> pp_comment ~term_pp ~lazy_term_pp ~obj_pp c