helm/software/components/grafite_engine/grafiteEngine.ml

   1 (* Copyright (C) 2005, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://helm.cs.unibo.it/
  24  *)
  25
  26 (* $Id$ *)
  27
  28 module PEH = ProofEngineHelpers
  29
  30 exception Drop
  31 (* mo file name, ma file name *)
  32 exception IncludedFileNotCompiled of string * string
  33 exception Macro of
  34  GrafiteAst.loc *
  35   (Cic.context -> GrafiteTypes.status * (Cic.term,Cic.lazy_term) GrafiteAst.macro)
  36
  37 type 'a disambiguator_input = string * int * 'a
  38
  39 type options = {
  40   do_heavy_checks: bool ;
  41 }
  42
  43 (** create a ProofEngineTypes.mk_fresh_name_type function which uses given
  44   * names as long as they are available, then it fallbacks to name generation
  45   * using FreshNamesGenerator module *)
  46 let namer_of names =
  47   let len = List.length names in
  48   let count = ref 0 in
  49   fun metasenv context name ~typ ->
  50     if !count < len then begin
  51       let name = match List.nth names !count with
  52          | Some s -> Cic.Name s
  53          | None   -> Cic.Anonymous
  54       in
  55       incr count;
  56       name
  57     end else
  58       FreshNamesGenerator.mk_fresh_name ~subst:[] metasenv context name ~typ
  59
  60 let rec tactic_of_ast status ast =
  61   let module PET = ProofEngineTypes in
  62   match ast with
  63   (* Higher order tactics *)
  64   | GrafiteAst.Do (loc, n, tactic) ->
  65      Tacticals.do_tactic n (tactic_of_ast status tactic)
  66   | GrafiteAst.Seq (loc, tactics) ->  (* tac1; tac2; ... *)
  67      Tacticals.seq (List.map (tactic_of_ast status) tactics)
  68   | GrafiteAst.Repeat (loc, tactic) ->
  69      Tacticals.repeat_tactic (tactic_of_ast status tactic)
  70   | GrafiteAst.Then (loc, tactic, tactics) ->  (* tac; [ tac1 | ... ] *)
  71      Tacticals.thens
  72       (tactic_of_ast status tactic)
  73       (List.map (tactic_of_ast status) tactics)
  74   | GrafiteAst.First (loc, tactics) ->
  75      Tacticals.first (List.map (tactic_of_ast status) tactics)
  76   | GrafiteAst.Try (loc, tactic) ->
  77      Tacticals.try_tactic (tactic_of_ast status tactic)
  78   | GrafiteAst.Solve (loc, tactics) ->
  79      Tacticals.solve_tactics (List.map (tactic_of_ast status) tactics)
  80   | GrafiteAst.Progress (loc, tactic) ->
  81      Tacticals.progress_tactic (tactic_of_ast status tactic)
  82   (* First order tactics *)
  83   | GrafiteAst.Absurd (_, term) -> Tactics.absurd term
  84   | GrafiteAst.Apply (_, term) -> Tactics.apply term
  85   | GrafiteAst.ApplyRule (_, term) -> Tactics.apply term
  86   | GrafiteAst.ApplyP (_, term) -> Tactics.applyP term
  87   | GrafiteAst.ApplyS (_, term, params) ->
  88      Tactics.applyS ~term ~params ~dbd:(LibraryDb.instance ())
  89        ~automation_cache:status#automation_cache
  90   | GrafiteAst.Assumption _ -> Tactics.assumption
  91   | GrafiteAst.AutoBatch (_,params) ->
  92       Tactics.auto ~params ~dbd:(LibraryDb.instance ())
  93         ~automation_cache:status#automation_cache
  94   | GrafiteAst.Cases (_, what, pattern, (howmany, names)) ->
  95       Tactics.cases_intros ?howmany ~mk_fresh_name_callback:(namer_of names)
  96         ~pattern what
  97   | GrafiteAst.Change (_, pattern, with_what) ->
  98      Tactics.change ~pattern with_what
  99   | GrafiteAst.Clear (_,id) -> Tactics.clear id
 100   | GrafiteAst.ClearBody (_,id) -> Tactics.clearbody id
 101   | GrafiteAst.Compose (_,t1,t2,times,(howmany, names)) ->
 102       Tactics.compose times t1 t2 ?howmany
 103         ~mk_fresh_name_callback:(namer_of names)
 104   | GrafiteAst.Contradiction _ -> Tactics.contradiction
 105   | GrafiteAst.Constructor (_, n) -> Tactics.constructor n
 106   | GrafiteAst.Cut (_, ident, term) ->
 107      let names = match ident with None -> [] | Some id -> [Some id] in
 108      Tactics.cut ~mk_fresh_name_callback:(namer_of names) term
 109   | GrafiteAst.Decompose (_, names) ->
 110       let mk_fresh_name_callback = namer_of names in
 111       Tactics.decompose ~mk_fresh_name_callback ()
 112   | GrafiteAst.Demodulate (_, params) ->
 113       Tactics.demodulate
 114         ~dbd:(LibraryDb.instance ()) ~params
 115           ~automation_cache:status#automation_cache
 116   | GrafiteAst.Destruct (_,xterms) -> Tactics.destruct xterms
 117   | GrafiteAst.Elim (_, what, using, pattern, (depth, names)) ->
 118       Tactics.elim_intros ?using ?depth ~mk_fresh_name_callback:(namer_of names)
 119         ~pattern what
 120   | GrafiteAst.ElimType (_, what, using, (depth, names)) ->
 121       Tactics.elim_type ?using ?depth ~mk_fresh_name_callback:(namer_of names)
 122         what
 123   | GrafiteAst.Exact (_, term) -> Tactics.exact term
 124   | GrafiteAst.Exists _ -> Tactics.exists
 125   | GrafiteAst.Fail _ -> Tactics.fail
 126   | GrafiteAst.Fold (_, reduction_kind, term, pattern) ->
 127       let reduction =
 128         match reduction_kind with
 129         | `Normalize ->
 130             PET.const_lazy_reduction
 131               (CicReduction.normalize ~delta:false ~subst:[])
 132         | `Simpl -> PET.const_lazy_reduction ProofEngineReduction.simpl
 133         | `Unfold None ->
 134             PET.const_lazy_reduction (ProofEngineReduction.unfold ?what:None)
 135         | `Unfold (Some lazy_term) ->
 136            (fun context metasenv ugraph ->
 137              let what, metasenv, ugraph = lazy_term context metasenv ugraph in
 138              ProofEngineReduction.unfold ~what, metasenv, ugraph)
 139         | `Whd ->
 140             PET.const_lazy_reduction (CicReduction.whd ~delta:false ~subst:[])
 141       in
 142       Tactics.fold ~reduction ~term ~pattern
 143   | GrafiteAst.Fourier _ -> Tactics.fourier
 144   | GrafiteAst.FwdSimpl (_, hyp, names) ->
 145      Tactics.fwd_simpl ~mk_fresh_name_callback:(namer_of names)
 146       ~dbd:(LibraryDb.instance ()) hyp
 147   | GrafiteAst.Generalize (_,pattern,ident) ->
 148      let names = match ident with None -> [] | Some id -> [Some id] in
 149      Tactics.generalize ~mk_fresh_name_callback:(namer_of names) pattern
 150   | GrafiteAst.IdTac _ -> Tactics.id
 151   | GrafiteAst.Intros (_, (howmany, names)) ->
 152       PrimitiveTactics.intros_tac ?howmany
 153         ~mk_fresh_name_callback:(namer_of names) ()
 154   | GrafiteAst.Inversion (_, term) ->
 155       Tactics.inversion term
 156   | GrafiteAst.LApply (_, linear, how_many, to_what, what, ident) ->
 157       let names = match ident with None -> [] | Some id -> [Some id] in
 158       Tactics.lapply ~mk_fresh_name_callback:(namer_of names)
 159         ~linear ?how_many ~to_what what
 160   | GrafiteAst.Left _ -> Tactics.left
 161   | GrafiteAst.LetIn (loc,term,name) ->
 162       Tactics.letin term ~mk_fresh_name_callback:(namer_of [Some name])
 163   | GrafiteAst.Reduce (_, reduction_kind, pattern) ->
 164       (match reduction_kind with
 165          | `Normalize -> Tactics.normalize ~pattern
 166          | `Simpl -> Tactics.simpl ~pattern
 167          | `Unfold what -> Tactics.unfold ~pattern what
 168          | `Whd -> Tactics.whd ~pattern)
 169   | GrafiteAst.Reflexivity _ -> Tactics.reflexivity
 170   | GrafiteAst.Replace (_, pattern, with_what) ->
 171      Tactics.replace ~pattern ~with_what
 172   | GrafiteAst.Rewrite (_, direction, t, pattern, names) ->
 173      EqualityTactics.rewrite_tac ~direction ~pattern t
 174 (* to be replaced with ~mk_fresh_name_callback:(namer_of names) *)
 175      (List.map (function Some s -> s | None -> assert false) names)
 176   | GrafiteAst.Right _ -> Tactics.right
 177   | GrafiteAst.Ring _ -> Tactics.ring
 178   | GrafiteAst.Split _ -> Tactics.split
 179   | GrafiteAst.Symmetry _ -> Tactics.symmetry
 180   | GrafiteAst.Transitivity (_, term) -> Tactics.transitivity term
 181   (* Implementazioni Aggiunte *)
 182   | GrafiteAst.Assume (_, id, t) -> Declarative.assume id t
 183   | GrafiteAst.Suppose (_, t, id, t1) -> Declarative.suppose t id t1
 184   | GrafiteAst.By_just_we_proved (_, just, ty, id, t1) ->
 185      Declarative.by_just_we_proved ~dbd:(LibraryDb.instance())
 186       ~automation_cache:status#automation_cache just ty id t1
 187   | GrafiteAst.We_need_to_prove (_, t, id, t2) ->
 188      Declarative.we_need_to_prove t id t2
 189   | GrafiteAst.Bydone (_, t) ->
 190      Declarative.bydone ~dbd:(LibraryDb.instance())
 191       ~automation_cache:status#automation_cache t
 192   | GrafiteAst.We_proceed_by_cases_on (_, t, t1) ->
 193      Declarative.we_proceed_by_cases_on t t1
 194   | GrafiteAst.We_proceed_by_induction_on (_, t, t1) ->
 195      Declarative.we_proceed_by_induction_on t t1
 196   | GrafiteAst.Byinduction (_, t, id) -> Declarative.byinduction t id
 197   | GrafiteAst.Thesisbecomes (_, t) -> Declarative.thesisbecomes t
 198   | GrafiteAst.ExistsElim (_, just, id1, t1, id2, t2) ->
 199      Declarative.existselim ~dbd:(LibraryDb.instance())
 200       ~automation_cache:status#automation_cache just id1 t1 id2 t2
 201   | GrafiteAst.Case (_,id,params) -> Declarative.case id params
 202   | GrafiteAst.AndElim(_,just,id1,t1,id2,t2) ->
 203      Declarative.andelim ~dbd:(LibraryDb.instance ())
 204       ~automation_cache:status#automation_cache just id1 t1 id2 t2
 205   | GrafiteAst.RewritingStep (_,termine,t1,t2,cont) ->
 206      Declarative.rewritingstep ~dbd:(LibraryDb.instance ())
 207       ~automation_cache:status#automation_cache termine t1 t2 cont
 208
 209 let classify_tactic tactic =
 210   match tactic with
 211   (* tactics that can't close the goal (return a goal we want to "select") *)
 212   | GrafiteAst.Rewrite _
 213   | GrafiteAst.Split _
 214   | GrafiteAst.Replace _
 215   | GrafiteAst.Reduce _
 216   | GrafiteAst.IdTac _
 217   | GrafiteAst.Generalize _
 218   | GrafiteAst.Elim _
 219   | GrafiteAst.Cut _
 220   | GrafiteAst.Decompose _ -> true
 221   (* tactics like apply *)
 222   | _ -> false
 223
 224 let reorder_metasenv start refine tactic goals current_goal always_opens_a_goal=
 225 (*   let print_m name metasenv =
 226     prerr_endline (">>>>> " ^ name);
 227     prerr_endline (CicMetaSubst.ppmetasenv [] metasenv)
 228   in *)
 229   (* phase one calculates:
 230    *   new_goals_from_refine:  goals added by refine
 231    *   head_goal:              the first goal opened by ythe tactic
 232    *   other_goals:            other goals opened by the tactic
 233    *)
 234   let new_goals_from_refine = PEH.compare_metasenvs start refine in
 235   let new_goals_from_tactic = PEH.compare_metasenvs refine tactic in
 236   let head_goal, other_goals, goals =
 237     match goals with
 238     | [] -> None,[],goals
 239     | hd::tl ->
 240         (* assert (List.mem hd new_goals_from_tactic);
 241          * invalidato dalla goal_tac
 242          * *)
 243         Some hd, List.filter ((<>) hd) new_goals_from_tactic, List.filter ((<>)
 244         hd) goals
 245   in
 246   let produced_goals =
 247     match head_goal with
 248     | None -> new_goals_from_refine @ other_goals
 249     | Some x -> x :: new_goals_from_refine @ other_goals
 250   in
 251   (* extract the metas generated by refine and tactic *)
 252   let metas_for_tactic_head =
 253     match head_goal with
 254     | None -> []
 255     | Some head_goal -> List.filter (fun (n,_,_) -> n = head_goal) tactic in
 256   let metas_for_tactic_goals =
 257     List.map
 258       (fun x -> List.find (fun (metano,_,_) -> metano = x) tactic)
 259     goals
 260   in
 261   let metas_for_refine_goals =
 262     List.filter (fun (n,_,_) -> List.mem n new_goals_from_refine) tactic in
 263   let produced_metas, goals =
 264     let produced_metas =
 265       if always_opens_a_goal then
 266         metas_for_tactic_head @ metas_for_refine_goals @
 267           metas_for_tactic_goals
 268       else begin
 269 (*         print_m "metas_for_refine_goals" metas_for_refine_goals;
 270         print_m "metas_for_tactic_head" metas_for_tactic_head;
 271         print_m "metas_for_tactic_goals" metas_for_tactic_goals; *)
 272         metas_for_refine_goals @ metas_for_tactic_head @
 273           metas_for_tactic_goals
 274       end
 275     in
 276     let goals = List.map (fun (metano, _, _) -> metano)  produced_metas in
 277     produced_metas, goals
 278   in
 279   (* residual metas, preserving the original order *)
 280   let before, after =
 281     let rec split e =
 282       function
 283       | [] -> [],[]
 284       | (metano, _, _) :: tl when metano = e ->
 285           [], List.map (fun (x,_,_) -> x) tl
 286       | (metano, _, _) :: tl -> let b, a = split e tl in metano :: b, a
 287     in
 288     let find n metasenv =
 289       try
 290         Some (List.find (fun (metano, _, _) -> metano = n) metasenv)
 291       with Not_found -> None
 292     in
 293     let extract l =
 294       List.fold_right
 295         (fun n acc ->
 296           match find n tactic with
 297           | Some x -> x::acc
 298           | None -> acc
 299         ) l [] in
 300     let before_l, after_l = split current_goal start in
 301     let before_l =
 302       List.filter (fun x -> not (List.mem x produced_goals)) before_l in
 303     let after_l =
 304       List.filter (fun x -> not (List.mem x produced_goals)) after_l in
 305     let before = extract before_l in
 306     let after = extract after_l in
 307       before, after
 308   in
 309 (* |+   DEBUG CODE  +|
 310   print_m "BEGIN" start;
 311   prerr_endline ("goal was: " ^ string_of_int current_goal);
 312   prerr_endline ("and metas from refine are:");
 313   List.iter
 314     (fun t -> prerr_string (" " ^ string_of_int t))
 315   new_goals_from_refine;
 316   prerr_endline "";
 317   print_m "before" before;
 318   print_m "metas_for_tactic_head" metas_for_tactic_head;
 319   print_m "metas_for_refine_goals" metas_for_refine_goals;
 320   print_m "metas_for_tactic_goals" metas_for_tactic_goals;
 321   print_m "produced_metas" produced_metas;
 322   print_m "after" after;
 323 |+   FINE DEBUG CODE +| *)
 324   before @ produced_metas @ after, goals
 325
 326 let apply_tactic ~disambiguate_tactic (text,prefix_len,tactic) (status, goal) =
 327  let starting_metasenv = GrafiteTypes.get_proof_metasenv status in
 328  let before = List.map (fun g, _, _ -> g) starting_metasenv in
 329  let status, tactic = disambiguate_tactic status goal (text,prefix_len,tactic) in
 330  let metasenv_after_refinement =  GrafiteTypes.get_proof_metasenv status in
 331  let proof = GrafiteTypes.get_current_proof status in
 332  let proof_status = proof, goal in
 333  let always_opens_a_goal = classify_tactic tactic in
 334  let tactic = tactic_of_ast status tactic in
 335  let (proof, opened) = ProofEngineTypes.apply_tactic tactic proof_status in
 336  let after = ProofEngineTypes.goals_of_proof proof in
 337  let opened_goals, closed_goals = Tacticals.goals_diff ~before ~after ~opened in
 338  let proof, opened_goals =
 339   let uri, metasenv_after_tactic, subst, t, ty, attrs = proof in
 340   let reordered_metasenv, opened_goals =
 341     reorder_metasenv
 342      starting_metasenv
 343      metasenv_after_refinement metasenv_after_tactic
 344      opened goal always_opens_a_goal
 345   in
 346   let proof' = uri, reordered_metasenv, [], t, ty, attrs in
 347   proof', opened_goals
 348  in
 349  let incomplete_proof =
 350    match status#proof_status with
 351    | GrafiteTypes.Incomplete_proof p -> p
 352    | _ -> assert false
 353  in
 354   status#set_proof_status
 355    (GrafiteTypes.Incomplete_proof
 356      { incomplete_proof with GrafiteTypes.proof = proof }),
 357  opened_goals, closed_goals
 358
 359 let apply_atomic_tactical ~disambiguate_tactic ~patch (text,prefix_len,tactic) (status, goal) =
 360  let starting_metasenv = GrafiteTypes.get_proof_metasenv status in
 361  let before = List.map (fun g, _, _ -> g) starting_metasenv in
 362  let status, tactic = disambiguate_tactic status goal (text,prefix_len,tactic) in
 363  let metasenv_after_refinement =  GrafiteTypes.get_proof_metasenv status in
 364  let proof = GrafiteTypes.get_current_proof status in
 365  let proof_status = proof, goal in
 366  let always_opens_a_goal = classify_tactic tactic in
 367  let tactic = tactic_of_ast status tactic in
 368  let tactic = patch tactic in
 369  let (proof, opened) = ProofEngineTypes.apply_tactic tactic proof_status in
 370  let after = ProofEngineTypes.goals_of_proof proof in
 371  let opened_goals, closed_goals = Tacticals.goals_diff ~before ~after ~opened in
 372  let proof, opened_goals =
 373   let uri, metasenv_after_tactic, _subst, t, ty, attrs = proof in
 374   let reordered_metasenv, opened_goals =
 375     reorder_metasenv
 376      starting_metasenv
 377      metasenv_after_refinement metasenv_after_tactic
 378      opened goal always_opens_a_goal
 379   in
 380   let proof' = uri, reordered_metasenv, _subst, t, ty, attrs in
 381   proof', opened_goals
 382  in
 383  let incomplete_proof =
 384    match status#proof_status with
 385    | GrafiteTypes.Incomplete_proof p -> p
 386    | _ -> assert false
 387  in
 388   status#set_proof_status
 389    (GrafiteTypes.Incomplete_proof
 390      { incomplete_proof with GrafiteTypes.proof = proof }),
 391  opened_goals, closed_goals
 392 type eval_ast =
 393  {ea_go:
 394   'term 'lazy_term 'reduction 'obj 'ident.
 395   disambiguate_tactic:
 396    (GrafiteTypes.status ->
 397     ProofEngineTypes.goal ->
 398     (('term, 'lazy_term, 'reduction, 'ident) GrafiteAst.tactic)
 399     disambiguator_input ->
 400     GrafiteTypes.status *
 401    (Cic.term, Cic.lazy_term, Cic.lazy_term GrafiteAst.reduction, string) GrafiteAst.tactic) ->
 402
 403   disambiguate_command:
 404    (GrafiteTypes.status ->
 405     (('term,'obj) GrafiteAst.command) disambiguator_input ->
 406     GrafiteTypes.status * (Cic.term,Cic.obj) GrafiteAst.command) ->
 407
 408   disambiguate_macro:
 409    (GrafiteTypes.status ->
 410     (('term,'lazy_term) GrafiteAst.macro) disambiguator_input ->
 411     Cic.context -> GrafiteTypes.status * (Cic.term,Cic.lazy_term) GrafiteAst.macro) ->
 412
 413   ?do_heavy_checks:bool ->
 414   GrafiteTypes.status ->
 415   (('term, 'lazy_term, 'reduction, 'obj, 'ident) GrafiteAst.statement)
 416   disambiguator_input ->
 417   GrafiteTypes.status * [`Old of UriManager.uri list | `New of NUri.uri list]
 418  }
 419
 420 type 'a eval_command =
 421  {ec_go: 'term 'obj.
 422   disambiguate_command:
 423    (GrafiteTypes.status -> (('term,'obj) GrafiteAst.command) disambiguator_input ->
 424     GrafiteTypes.status * (Cic.term,Cic.obj) GrafiteAst.command) ->
 425   options -> GrafiteTypes.status ->
 426     (('term,'obj) GrafiteAst.command) disambiguator_input ->
 427    GrafiteTypes.status * [`Old of UriManager.uri list | `New of NUri.uri list]
 428  }
 429
 430 type 'a eval_comment =
 431  {ecm_go: 'term 'lazy_term 'reduction_kind 'obj 'ident.
 432   disambiguate_command:
 433    (GrafiteTypes.status -> (('term,'obj) GrafiteAst.command) disambiguator_input ->
 434     GrafiteTypes.status * (Cic.term,Cic.obj) GrafiteAst.command) ->
 435   options -> GrafiteTypes.status ->
 436     (('term,'lazy_term,'reduction_kind,'obj,'ident) GrafiteAst.comment) disambiguator_input ->
 437    GrafiteTypes.status * [`Old of UriManager.uri list | `New of NUri.uri list]
 438  }
 439
 440 type 'a eval_executable =
 441  {ee_go: 'term 'lazy_term 'reduction 'obj 'ident.
 442   disambiguate_tactic:
 443    (GrafiteTypes.status ->
 444     ProofEngineTypes.goal ->
 445     (('term, 'lazy_term, 'reduction, 'ident) GrafiteAst.tactic)
 446     disambiguator_input ->
 447     GrafiteTypes.status *
 448    (Cic.term, Cic.lazy_term, Cic.lazy_term GrafiteAst.reduction, string) GrafiteAst.tactic) ->
 449
 450   disambiguate_command:
 451    (GrafiteTypes.status ->
 452     (('term,'obj) GrafiteAst.command) disambiguator_input ->
 453     GrafiteTypes.status * (Cic.term,Cic.obj) GrafiteAst.command) ->
 454
 455   disambiguate_macro:
 456    (GrafiteTypes.status ->
 457     (('term,'lazy_term) GrafiteAst.macro) disambiguator_input ->
 458     Cic.context -> GrafiteTypes.status * (Cic.term,Cic.lazy_term) GrafiteAst.macro) ->
 459
 460   options ->
 461   GrafiteTypes.status ->
 462   (('term, 'lazy_term, 'reduction, 'obj, 'ident) GrafiteAst.code) disambiguator_input ->
 463   GrafiteTypes.status * [`Old of UriManager.uri list | `New of NUri.uri list]
 464  }
 465
 466 type 'a eval_from_moo =
 467  { efm_go: GrafiteTypes.status -> string -> GrafiteTypes.status }
 468
 469 let coercion_moo_statement_of (uri,arity, saturations,_) =
 470   GrafiteAst.Coercion
 471    (HExtlib.dummy_floc, CicUtil.term_of_uri uri, false, arity, saturations)
 472
 473 let basic_eval_unification_hint (t,n) status =
 474  NCicUnifHint.add_user_provided_hint status t n
 475 ;;
 476
 477 let inject_unification_hint =
 478  let basic_eval_unification_hint (t,n) ~refresh_uri_in_term =
 479   let t = refresh_uri_in_term t in basic_eval_unification_hint (t,n)
 480  in
 481   NRstatus.Serializer.register "unification_hints" basic_eval_unification_hint
 482 ;;
 483
 484 let eval_unification_hint status t n =
 485  let estatus = GrafiteTypes.get_estatus status in
 486  let metasenv,subst,estatus,t =
 487   GrafiteDisambiguate.disambiguate_nterm None estatus [] [] [] ("",0,t) in
 488  assert (metasenv=[]);
 489  let t = NCicUntrusted.apply_subst subst [] t in
 490  let status = GrafiteTypes.set_estatus estatus status in
 491  let estatus =
 492   basic_eval_unification_hint (t,n) (GrafiteTypes.get_estatus status) in
 493  let dump = inject_unification_hint (t,n)::estatus#dump in
 494  let estatus = estatus#set_dump dump in
 495  let status = GrafiteTypes.set_estatus estatus status in
 496   status,`Old []
 497 ;;
 498
 499 let add_coercions_of_lemmas lemmas status =
 500   let moo_content =
 501     HExtlib.filter_map
 502       (fun uri ->
 503         match CoercDb.is_a_coercion (Cic.Const (uri,[])) with
 504         | None -> None
 505         | Some (_,tgt,_,sat,_) ->
 506             let arity = match tgt with CoercDb.Fun n -> n | _ -> 0 in
 507             Some (coercion_moo_statement_of (uri,arity,sat,0)))
 508       lemmas
 509   in
 510   let status = GrafiteTypes.add_moo_content moo_content status in
 511    status#set_coercions (CoercDb.dump ()),
 512   lemmas
 513
 514 let eval_coercion status ~add_composites uri arity saturations =
 515  let uri =
 516    try CicUtil.uri_of_term uri
 517    with Invalid_argument _ ->
 518      raise (Invalid_argument "coercion can only be constants/constructors")
 519  in
 520  let status, lemmas =
 521   GrafiteSync.add_coercion ~add_composites
 522     ~pack_coercion_obj:CicRefine.pack_coercion_obj
 523    status uri arity saturations (GrafiteTypes.get_baseuri status) in
 524  let moo_content = coercion_moo_statement_of (uri,arity,saturations,0) in
 525  let status = GrafiteTypes.add_moo_content [moo_content] status in
 526   add_coercions_of_lemmas lemmas status
 527
 528 let eval_prefer_coercion status c =
 529  let uri =
 530    try CicUtil.uri_of_term c
 531    with Invalid_argument _ ->
 532      raise (Invalid_argument "coercion can only be constants/constructors")
 533  in
 534  let status = GrafiteSync.prefer_coercion status uri in
 535  let moo_content = GrafiteAst.PreferCoercion (HExtlib.dummy_floc,c) in
 536  let status = GrafiteTypes.add_moo_content [moo_content] status in
 537  status, `Old []
 538
 539 module MatitaStatus =
 540  struct
 541   type input_status = GrafiteTypes.status * ProofEngineTypes.goal
 542
 543   type output_status =
 544     GrafiteTypes.status * ProofEngineTypes.goal list * ProofEngineTypes.goal list
 545
 546   type tactic = input_status -> output_status
 547
 548   let mk_tactic tac = tac
 549   let apply_tactic tac = tac
 550   let goals (_, opened, closed) = opened, closed
 551   let get_stack (status, _) = GrafiteTypes.get_stack status
 552
 553   let set_stack stack (status, opened, closed) =
 554     GrafiteTypes.set_stack stack status, opened, closed
 555
 556   let inject (status, _) = (status, [], [])
 557   let focus goal (status, _, _) = (status, goal)
 558  end
 559
 560 module MatitaTacticals = Continuationals.Make(MatitaStatus)
 561
 562 let tactic_of_ast' tac =
 563  MatitaTacticals.Tactical (MatitaTacticals.Tactic (MatitaStatus.mk_tactic tac))
 564
 565 let punctuation_tactical_of_ast (text,prefix_len,punct) =
 566  match punct with
 567   | GrafiteAst.Dot _loc -> MatitaTacticals.Dot
 568   | GrafiteAst.Semicolon _loc -> MatitaTacticals.Semicolon
 569   | GrafiteAst.Branch _loc -> MatitaTacticals.Branch
 570   | GrafiteAst.Shift _loc -> MatitaTacticals.Shift
 571   | GrafiteAst.Pos (_loc, i) -> MatitaTacticals.Pos i
 572   | GrafiteAst.Merge _loc -> MatitaTacticals.Merge
 573   | GrafiteAst.Wildcard _loc -> MatitaTacticals.Wildcard
 574
 575 let non_punctuation_tactical_of_ast (text,prefix_len,punct) =
 576  match punct with
 577   | GrafiteAst.Focus (_loc,goals) -> MatitaTacticals.Focus goals
 578   | GrafiteAst.Unfocus _loc -> MatitaTacticals.Unfocus
 579   | GrafiteAst.Skip _loc -> MatitaTacticals.Tactical MatitaTacticals.Skip
 580
 581 let eval_tactical status tac =
 582   let status, _, _ = MatitaTacticals.eval tac (status, ~-1) in
 583   let status =  (* is proof completed? *)
 584     match status#proof_status with
 585     | GrafiteTypes.Incomplete_proof
 586        { GrafiteTypes.stack = stack; proof = proof }
 587       when Continuationals.Stack.is_empty stack ->
 588        status#set_proof_status (GrafiteTypes.Proof proof)
 589     | _ -> status
 590   in
 591   status
 592
 593 let add_obj = GrafiteSync.add_obj ~pack_coercion_obj:CicRefine.pack_coercion_obj
 594
 595 let eval_ng_punct (_text, _prefix_len, punct) =
 596   match punct with
 597   | GrafiteAst.Dot _ -> NTactics.dot_tac
 598   | GrafiteAst.Semicolon _ -> fun x -> x
 599   | GrafiteAst.Branch _ -> NTactics.branch_tac
 600   | GrafiteAst.Shift _ -> NTactics.shift_tac
 601   | GrafiteAst.Pos (_,l) -> NTactics.pos_tac l
 602   | GrafiteAst.Wildcard _ -> NTactics.wildcard_tac
 603   | GrafiteAst.Merge _ -> NTactics.merge_tac
 604 ;;
 605
 606 let rec eval_ng_tac (text, prefix_len, tac) =
 607   match tac with
 608   | GrafiteAst.NApply (_loc, t) -> NTactics.apply_tac (text,prefix_len,t)
 609   | GrafiteAst.NAssert (_loc, seqs) ->
 610      NTactics.assert_tac
 611       ((List.map
 612         (function (hyps,concl) ->
 613           List.map
 614            (function
 615               (id,`Decl t) -> id,`Decl (text,prefix_len,t)
 616              |(id,`Def (b,t))->id,`Def((text,prefix_len,b),(text,prefix_len,t))
 617            ) hyps,
 618           (text,prefix_len,concl))
 619        ) seqs)
 620   | GrafiteAst.NAuto (_loc, (l,a)) ->
 621       NTactics.auto_tac
 622         ~params:(List.map (fun x -> "",0,x) l,a)
 623   | GrafiteAst.NBranch _ -> NTactics.branch_tac
 624   | GrafiteAst.NCases (_loc, what, where) ->
 625       NTactics.cases_tac
 626         ~what:(text,prefix_len,what)
 627         ~where:(text,prefix_len,where)
 628   | GrafiteAst.NCase1 (_loc,n) -> NTactics.case1_tac n
 629   | GrafiteAst.NChange (_loc, pat, ww) ->
 630       NTactics.change_tac
 631        ~where:(text,prefix_len,pat) ~with_what:(text,prefix_len,ww)
 632   | GrafiteAst.NDot _ -> NTactics.dot_tac
 633   | GrafiteAst.NElim (_loc, what, where) ->
 634       NTactics.elim_tac
 635         ~what:(text,prefix_len,what)
 636         ~where:(text,prefix_len,where)
 637   | GrafiteAst.NFocus (_,l) -> NTactics.focus_tac l
 638   | GrafiteAst.NGeneralize (_loc, where) ->
 639       NTactics.generalize_tac ~where:(text,prefix_len,where)
 640   | GrafiteAst.NId _ -> (fun x -> x)
 641   | GrafiteAst.NIntro (_loc,n) -> NTactics.intro_tac n
 642   | GrafiteAst.NLetIn (_loc,where,what,name) ->
 643       NTactics.letin_tac ~where:(text,prefix_len,where)
 644         ~what:(text,prefix_len,what) name
 645   | GrafiteAst.NMerge _ -> NTactics.merge_tac
 646   | GrafiteAst.NPos (_,l) -> NTactics.pos_tac l
 647   | GrafiteAst.NReduce (_loc, reduction, where) ->
 648       NTactics.reduce_tac ~reduction ~where:(text,prefix_len,where)
 649   | GrafiteAst.NRewrite (_loc,dir,what,where) ->
 650      NTactics.rewrite_tac ~dir ~what:(text,prefix_len,what)
 651       ~where:(text,prefix_len,where)
 652   | GrafiteAst.NSemicolon _ -> fun x -> x
 653   | GrafiteAst.NShift _ -> NTactics.shift_tac
 654   | GrafiteAst.NSkip _ -> NTactics.skip_tac
 655   | GrafiteAst.NUnfocus _ -> NTactics.unfocus_tac
 656   | GrafiteAst.NWildcard _ -> NTactics.wildcard_tac
 657   | GrafiteAst.NTry (_,tac) -> NTactics.try_tac
 658       (eval_ng_tac (text, prefix_len, tac))
 659   | GrafiteAst.NAssumption _ -> NTactics.assumption_tac
 660 ;;
 661
 662 let subst_metasenv_and_fix_names s =
 663   let u,h,metasenv, subst,o = s#obj in
 664   let o =
 665     NCicUntrusted.map_obj_kind ~skip_body:true
 666      (NCicUntrusted.apply_subst subst []) o
 667   in
 668    s#set_obj (u,h,NCicUntrusted.apply_subst_metasenv subst metasenv,subst,o)
 669 ;;
 670
 671 let rec eval_ncommand opts status (text,prefix_len,cmd) =
 672   match cmd with
 673   | GrafiteAst.UnificationHint (loc, t, n) -> eval_unification_hint status t n
 674   | GrafiteAst.NQed loc ->
 675       (match status#ng_status with
 676        | GrafiteTypes.ProofMode estatus ->
 677           let uri,height,menv,subst,obj_kind = estatus#obj in
 678            if menv <> [] then
 679             raise
 680              (GrafiteTypes.Command_error"You can't Qed an incomplete theorem")
 681            else
 682             let obj_kind =
 683              NCicUntrusted.map_obj_kind
 684               (NCicUntrusted.apply_subst subst []) obj_kind in
 685             let height = NCicTypeChecker.height_of_obj_kind uri obj_kind in
 686             (* fix the height inside the object *)
 687             let rec fix () = function
 688               | NCic.Const (NReference.Ref (u,spec)) when NUri.eq u uri ->
 689                  NCic.Const (NReference.reference_of_spec u
 690                   (match spec with
 691                   | NReference.Def _ -> NReference.Def height
 692                   | NReference.Fix (i,j,_) -> NReference.Fix(i,j,height)
 693                   | NReference.CoFix _ -> NReference.CoFix height
 694                   | NReference.Ind _ | NReference.Con _
 695                   | NReference.Decl as s -> s))
 696               | t -> NCicUtils.map (fun _ () -> ()) () fix t
 697             in
 698             let obj_kind =
 699               match obj_kind with
 700               | NCic.Fixpoint _ ->
 701                   NCicUntrusted.map_obj_kind (fix ()) obj_kind
 702               | _ -> obj_kind
 703             in
 704             let obj = uri,height,[],[],obj_kind in
 705              NCicTypeChecker.typecheck_obj obj;
 706              let estatus = NCicLibrary.add_obj estatus uri obj in
 707              let objs = NCicElim.mk_elims obj in
 708              let timestamp,uris_rev =
 709                List.fold_left
 710                 (fun (estatus,uris_rev) (uri,_,_,_,_) as obj ->
 711                   NCicTypeChecker.typecheck_obj obj;
 712                   let estatus = NCicLibrary.add_obj estatus uri obj in
 713                    estatus,uri::uris_rev
 714                 ) (estatus,[]) objs in
 715              let uris = uri::List.rev uris_rev in
 716               status#set_ng_status
 717                (GrafiteTypes.CommandMode (estatus :> NEstatus.status)),`New uris
 718        | _ -> raise (GrafiteTypes.Command_error "Not in proof mode"))
 719   | GrafiteAst.NObj (loc,obj) ->
 720      let estatus =
 721        match status#ng_status with
 722        | GrafiteTypes.ProofMode _ -> assert false
 723        | GrafiteTypes.CommandMode es -> es
 724      in
 725      let estatus,obj =
 726       GrafiteDisambiguate.disambiguate_nobj estatus
 727        ~baseuri:(GrafiteTypes.get_baseuri status) (text,prefix_len,obj) in
 728      let uri,height,nmenv,nsubst,nobj = obj in
 729      let ninitial_stack = Continuationals.Stack.of_nmetasenv nmenv in
 730      let status =
 731       status#set_ng_status
 732        (GrafiteTypes.ProofMode
 733          (subst_metasenv_and_fix_names
 734            ((new NTacStatus.status obj ninitial_stack)#set_estatus estatus)))
 735      in
 736      (match nmenv with
 737          [] ->
 738           eval_ncommand opts status ("",0,GrafiteAst.NQed Stdpp.dummy_loc)
 739        | _ -> status,`New [])
 740   | GrafiteAst.NUnivConstraint (loc,strict,u1,u2) ->
 741       NCicEnvironment.add_constraint strict [false,u1] [false,u2];
 742       status, `New [u1;u2]
 743 ;;
 744
 745 let rec eval_command = {ec_go = fun ~disambiguate_command opts status
 746 (text,prefix_len,cmd) ->
 747  let status,cmd = disambiguate_command status (text,prefix_len,cmd) in
 748  let status,uris =
 749   match cmd with
 750   | GrafiteAst.Index (loc,None,uri) ->
 751         assert false (* TODO: for user input *)
 752   | GrafiteAst.Index (loc,Some key,uri) ->
 753       let universe =
 754         status#automation_cache.AutomationCache.univ
 755       in
 756       let universe = Universe.index universe key (CicUtil.term_of_uri uri) in
 757       let cache = {
 758         status#automation_cache with AutomationCache.univ = universe }
 759       in
 760       let status = status#set_automation_cache cache in
 761 (* debug
 762       let msg =
 763        let candidates = Universe.get_candidates status.GrafiteTypes.universe key in
 764        ("candidates for " ^ (CicPp.ppterm key) ^ " = " ^
 765           (String.concat "\n" (List.map CicPp.ppterm candidates)))
 766      in
 767      prerr_endline msg;
 768 *)
 769       let status = GrafiteTypes.add_moo_content [cmd] status in
 770       status,`Old []
 771   | GrafiteAst.Select (_,uri) as cmd ->
 772       if List.mem cmd status#moo_content_rev then status, `Old []
 773       else
 774        let cache =
 775          AutomationCache.add_term_to_active status#automation_cache
 776            [] [] [] (CicUtil.term_of_uri uri) None
 777        in
 778        let status = status#set_automation_cache cache in
 779        let status = GrafiteTypes.add_moo_content [cmd] status in
 780        status, `Old []
 781   | GrafiteAst.Pump (_,steps) ->
 782       let cache =
 783         AutomationCache.pump status#automation_cache steps
 784       in
 785       let status = status#set_automation_cache cache in
 786       status, `Old []
 787   | GrafiteAst.PreferCoercion (loc, coercion) ->
 788      eval_prefer_coercion status coercion
 789   | GrafiteAst.Coercion (loc, uri, add_composites, arity, saturations) ->
 790      let res,uris =
 791       eval_coercion status ~add_composites uri arity saturations
 792      in
 793       res,`Old uris
 794   | GrafiteAst.Inverter (loc, name, indty, params) ->
 795      let buri = GrafiteTypes.get_baseuri status in
 796      let uri = UriManager.uri_of_string (buri ^ "/" ^ name ^ ".con") in
 797      let indty_uri =
 798        try CicUtil.uri_of_term indty
 799        with Invalid_argument _ ->
 800          raise (Invalid_argument "not an inductive type to invert") in
 801      let res,uris =
 802       Inversion_principle.build_inverter ~add_obj status uri indty_uri params
 803      in
 804       res,`Old uris
 805   | GrafiteAst.Default (loc, what, uris) as cmd ->
 806      LibraryObjects.set_default what uris;
 807      GrafiteTypes.add_moo_content [cmd] status,`Old []
 808   | GrafiteAst.Drop loc -> raise Drop
 809   | GrafiteAst.Include (loc, _, baseuri) ->
 810      let moopath_rw, moopath_r =
 811        LibraryMisc.obj_file_of_baseuri
 812          ~must_exist:false ~baseuri ~writable:true,
 813        LibraryMisc.obj_file_of_baseuri
 814          ~must_exist:false ~baseuri ~writable:false
 815      in
 816      let moopath =
 817        if Sys.file_exists moopath_r then moopath_r else
 818          if Sys.file_exists moopath_rw then moopath_rw else
 819            raise (IncludedFileNotCompiled (moopath_rw,baseuri))
 820      in
 821      let status = eval_from_moo.efm_go status moopath in
 822      let estatus = GrafiteTypes.get_estatus status in
 823      let estatus =
 824        NRstatus.Serializer.require ~baseuri:(NUri.uri_of_string baseuri)
 825         estatus in
 826      let status = GrafiteTypes.set_estatus estatus status in
 827 (* debug
 828      let lt_uri = UriManager.uri_of_string "cic:/matita/nat/orders/lt.con" in
 829      let nat_uri = UriManager.uri_of_string "cic:/matita/nat/nat/nat.ind" in
 830      let nat = Cic.MutInd(nat_uri,0,[]) in
 831      let zero = Cic.MutConstruct(nat_uri,0,1,[]) in
 832      let succ = Cic.MutConstruct(nat_uri,0,2,[]) in
 833      let fake= Cic.Meta(-1,[]) in
 834      let term= Cic.Appl [Cic.Const (lt_uri,[]);zero;Cic.Appl[succ;zero]] in     let msg =
 835        let candidates = Universe.get_candidates status.GrafiteTypes.universe term in
 836        ("candidates for " ^ (CicPp.ppterm term) ^ " = " ^
 837           (String.concat "\n" (List.map CicPp.ppterm candidates)))
 838      in
 839      prerr_endline msg;
 840 *)
 841      status,`Old []
 842   | GrafiteAst.Print (_,"proofterm") ->
 843       let _,_,_,p,_, _ = GrafiteTypes.get_current_proof status in
 844       prerr_endline (Auto.pp_proofterm (Lazy.force p));
 845       status,`Old []
 846   | GrafiteAst.Print (_,_) -> status,`Old []
 847   | GrafiteAst.Qed loc ->
 848       let uri, metasenv, _subst, bo, ty, attrs =
 849         match status#proof_status with
 850         | GrafiteTypes.Proof (Some uri, metasenv, subst, body, ty, attrs) ->
 851             uri, metasenv, subst, body, ty, attrs
 852         | GrafiteTypes.Proof (None, metasenv, subst, body, ty, attrs) ->
 853             raise (GrafiteTypes.Command_error
 854               ("Someone allows to start a theorem without giving the "^
 855                "name/uri. This should be fixed!"))
 856         | _->
 857           raise
 858            (GrafiteTypes.Command_error "You can't Qed an incomplete theorem")
 859       in
 860       if metasenv <> [] then
 861         raise
 862          (GrafiteTypes.Command_error
 863            "Proof not completed! metasenv is not empty!");
 864       let name = UriManager.name_of_uri uri in
 865       let obj = Cic.Constant (name,Some (Lazy.force bo),ty,[],attrs) in
 866       let status, lemmas = add_obj uri obj status in
 867        status#set_proof_status GrafiteTypes.No_proof,
 868         (*CSC: I throw away the arities *)
 869         `Old (uri::lemmas)
 870   | GrafiteAst.Relation (loc, id, a, aeq, refl, sym, trans) ->
 871      Setoids.add_relation id a aeq refl sym trans;
 872      status, `Old [] (*CSC: TO BE FIXED *)
 873   | GrafiteAst.Set (loc, name, value) -> status, `Old []
 874 (*       GrafiteTypes.set_option status name value,[] *)
 875   | GrafiteAst.Obj (loc,obj) ->
 876      let ext,name =
 877       match obj with
 878          Cic.Constant (name,_,_,_,_)
 879        | Cic.CurrentProof (name,_,_,_,_,_) -> ".con",name
 880        | Cic.InductiveDefinition (types,_,_,_) ->
 881           ".ind",
 882           (match types with (name,_,_,_)::_ -> name | _ -> assert false)
 883        | _ -> assert false in
 884      let buri = GrafiteTypes.get_baseuri status in
 885      let uri = UriManager.uri_of_string (buri ^ "/" ^ name ^ ext) in
 886      let obj = CicRefine.pack_coercion_obj obj in
 887      let metasenv = GrafiteTypes.get_proof_metasenv status in
 888      match obj with
 889      | Cic.CurrentProof (_,metasenv',bo,ty,_, attrs) ->
 890          let name = UriManager.name_of_uri uri in
 891          if not(CicPp.check name ty) then
 892            HLog.warn ("Bad name: " ^ name);
 893          if opts.do_heavy_checks then
 894            begin
 895              let dbd = LibraryDb.instance () in
 896              let similar = Whelp.match_term ~dbd ty in
 897              let similar_len = List.length similar in
 898              if similar_len> 30 then
 899                (HLog.message
 900                  ("Duplicate check will compare your theorem with " ^
 901                    string_of_int similar_len ^
 902                    " theorems, this may take a while."));
 903              let convertible =
 904                List.filter (
 905                  fun u ->
 906                    let t = CicUtil.term_of_uri u in
 907                    let ty',g =
 908                      CicTypeChecker.type_of_aux'
 909                        metasenv' [] t CicUniv.oblivion_ugraph
 910                    in
 911                    fst(CicReduction.are_convertible [] ty' ty g))
 912                similar
 913              in
 914              (match convertible with
 915              | [] -> ()
 916              | x::_ ->
 917                  HLog.warn
 918                  ("Theorem already proved: " ^ UriManager.string_of_uri x ^
 919                   "\nPlease use a variant."));
 920            end;
 921          let _subst = [] in
 922          let initial_proof = (Some uri, metasenv', _subst, lazy bo, ty, attrs) in
 923          let initial_stack = Continuationals.Stack.of_metasenv metasenv' in
 924           status#set_proof_status
 925            (GrafiteTypes.Incomplete_proof
 926             { GrafiteTypes.proof = initial_proof; stack = initial_stack }),
 927           `Old []
 928      | _ ->
 929          if metasenv <> [] then
 930           raise (GrafiteTypes.Command_error (
 931             "metasenv not empty while giving a definition with body: " ^
 932             CicMetaSubst.ppmetasenv [] metasenv));
 933          let status, lemmas = add_obj uri obj status in
 934          let status,new_lemmas = add_coercions_of_lemmas lemmas status in
 935           status#set_proof_status GrafiteTypes.No_proof,
 936            `Old (uri::new_lemmas@lemmas)
 937  in
 938   match status#proof_status with
 939      GrafiteTypes.Intermediate _ ->
 940       status#set_proof_status GrafiteTypes.No_proof,uris
 941    | _ -> status,uris
 942
 943 } and eval_executable = {ee_go = fun ~disambiguate_tactic ~disambiguate_command
 944 ~disambiguate_macro opts status (text,prefix_len,ex) ->
 945   match ex with
 946   | GrafiteAst.Tactic (_(*loc*), Some tac, punct) ->
 947      let tac = apply_tactic ~disambiguate_tactic (text,prefix_len,tac) in
 948      let status = eval_tactical status (tactic_of_ast' tac) in
 949      (* CALL auto on every goal, easy way of testing it
 950      let auto =
 951        GrafiteAst.AutoBatch
 952          (loc, ([],["depth","2";"timeout","1";"type","1"])) in
 953      (try
 954        let auto = apply_tactic ~disambiguate_tactic ("",0,auto) in
 955        let _ = eval_tactical status (tactic_of_ast' auto) in
 956        print_endline "GOOD"; ()
 957      with ProofEngineTypes.Fail _ -> print_endline "BAD" | _ -> ());*)
 958       eval_tactical status
 959        (punctuation_tactical_of_ast (text,prefix_len,punct)),`Old []
 960   | GrafiteAst.Tactic (_, None, punct) ->
 961       eval_tactical status
 962        (punctuation_tactical_of_ast (text,prefix_len,punct)),`Old []
 963   | GrafiteAst.NTactic (_(*loc*), tacl) ->
 964       (match status#ng_status with
 965       | GrafiteTypes.CommandMode _ -> assert false
 966       | GrafiteTypes.ProofMode nstatus ->
 967          let nstatus =
 968           List.fold_left
 969             (fun nstatus tac ->
 970               let nstatus = eval_ng_tac (text,prefix_len,tac) nstatus in
 971               subst_metasenv_and_fix_names nstatus)
 972             nstatus tacl
 973          in
 974           status#set_ng_status (GrafiteTypes.ProofMode nstatus),
 975          `New [])
 976   | GrafiteAst.NonPunctuationTactical (_, tac, punct) ->
 977      let status =
 978       eval_tactical status
 979        (non_punctuation_tactical_of_ast (text,prefix_len,tac))
 980      in
 981       eval_tactical status
 982        (punctuation_tactical_of_ast (text,prefix_len,punct)),`Old []
 983   | GrafiteAst.Command (_, cmd) ->
 984       eval_command.ec_go ~disambiguate_command opts status (text,prefix_len,cmd)
 985   | GrafiteAst.NCommand (_, cmd) ->
 986       eval_ncommand opts status (text,prefix_len,cmd)
 987   | GrafiteAst.Macro (loc, macro) ->
 988      raise (Macro (loc,disambiguate_macro status (text,prefix_len,macro)))
 989
 990 } and eval_from_moo = {efm_go = fun status fname ->
 991   let ast_of_cmd cmd =
 992     ("",0,GrafiteAst.Executable (HExtlib.dummy_floc,
 993       GrafiteAst.Command (HExtlib.dummy_floc,
 994         cmd)))
 995   in
 996   let moo = GrafiteMarshal.load_moo fname in
 997   List.fold_left
 998     (fun status ast ->
 999       let ast = ast_of_cmd ast in
1000       let status,lemmas =
1001        eval_ast.ea_go
1002          ~disambiguate_tactic:(fun status _ (_,_,tactic) -> status,tactic)
1003          ~disambiguate_command:(fun status (_,_,cmd) -> status,cmd)
1004          ~disambiguate_macro:(fun _ _ -> assert false)
1005          status ast
1006       in
1007        assert (lemmas=`Old []);
1008        status)
1009     status moo
1010 } and eval_ast = {ea_go = fun ~disambiguate_tactic ~disambiguate_command
1011 ~disambiguate_macro ?(do_heavy_checks=false) status
1012 (text,prefix_len,st)
1013 ->
1014   let opts = { do_heavy_checks = do_heavy_checks ; } in
1015   match st with
1016   | GrafiteAst.Executable (_,ex) ->
1017      eval_executable.ee_go ~disambiguate_tactic ~disambiguate_command
1018       ~disambiguate_macro opts status (text,prefix_len,ex)
1019   | GrafiteAst.Comment (_,c) ->
1020       eval_comment.ecm_go ~disambiguate_command opts status (text,prefix_len,c)
1021 } and eval_comment = { ecm_go = fun ~disambiguate_command opts status (text,prefix_len,c) ->
1022     status, `Old []
1023 }
1024 ;;
1025
1026
1027 let eval_ast = eval_ast.ea_go