helm/software/components/grafite_engine/grafiteEngine.ml

   1 (* Copyright (C) 2005, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://helm.cs.unibo.it/
  24  *)
  25
  26 (* $Id$ *)
  27
  28 module PEH = ProofEngineHelpers
  29
  30 exception Drop
  31 (* mo file name, ma file name *)
  32 exception IncludedFileNotCompiled of string * string
  33 exception Macro of
  34  GrafiteAst.loc *
  35   (Cic.context -> GrafiteTypes.status * (Cic.term,Cic.lazy_term) GrafiteAst.macro)
  36
  37 type 'a disambiguator_input = string * int * 'a
  38
  39 type options = {
  40   do_heavy_checks: bool ;
  41 }
  42
  43 (** create a ProofEngineTypes.mk_fresh_name_type function which uses given
  44   * names as long as they are available, then it fallbacks to name generation
  45   * using FreshNamesGenerator module *)
  46 let namer_of names =
  47   let len = List.length names in
  48   let count = ref 0 in
  49   fun metasenv context name ~typ ->
  50     if !count < len then begin
  51       let name = match List.nth names !count with
  52          | Some s -> Cic.Name s
  53          | None   -> Cic.Anonymous
  54       in
  55       incr count;
  56       name
  57     end else
  58       FreshNamesGenerator.mk_fresh_name ~subst:[] metasenv context name ~typ
  59
  60 let rec tactic_of_ast status ast =
  61   let module PET = ProofEngineTypes in
  62   match ast with
  63   (* Higher order tactics *)
  64   | GrafiteAst.Do (loc, n, tactic) ->
  65      Tacticals.do_tactic n (tactic_of_ast status tactic)
  66   | GrafiteAst.Seq (loc, tactics) ->  (* tac1; tac2; ... *)
  67      Tacticals.seq (List.map (tactic_of_ast status) tactics)
  68   | GrafiteAst.Repeat (loc, tactic) ->
  69      Tacticals.repeat_tactic (tactic_of_ast status tactic)
  70   | GrafiteAst.Then (loc, tactic, tactics) ->  (* tac; [ tac1 | ... ] *)
  71      Tacticals.thens
  72       (tactic_of_ast status tactic)
  73       (List.map (tactic_of_ast status) tactics)
  74   | GrafiteAst.First (loc, tactics) ->
  75      Tacticals.first (List.map (tactic_of_ast status) tactics)
  76   | GrafiteAst.Try (loc, tactic) ->
  77      Tacticals.try_tactic (tactic_of_ast status tactic)
  78   | GrafiteAst.Solve (loc, tactics) ->
  79      Tacticals.solve_tactics (List.map (tactic_of_ast status) tactics)
  80   | GrafiteAst.Progress (loc, tactic) ->
  81      Tacticals.progress_tactic (tactic_of_ast status tactic)
  82   (* First order tactics *)
  83   | GrafiteAst.Absurd (_, term) -> Tactics.absurd term
  84   | GrafiteAst.Apply (_, term) -> Tactics.apply term
  85   | GrafiteAst.ApplyRule (_, term) -> Tactics.apply term
  86   | GrafiteAst.ApplyP (_, term) -> Tactics.applyP term
  87   | GrafiteAst.ApplyS (_, term, params) ->
  88      Tactics.applyS ~term ~params ~dbd:(LibraryDb.instance ())
  89        ~automation_cache:status.GrafiteTypes.automation_cache
  90   | GrafiteAst.Assumption _ -> Tactics.assumption
  91   | GrafiteAst.AutoBatch (_,params) ->
  92       Tactics.auto ~params ~dbd:(LibraryDb.instance ())
  93         ~automation_cache:status.GrafiteTypes.automation_cache
  94   | GrafiteAst.Cases (_, what, pattern, (howmany, names)) ->
  95       Tactics.cases_intros ?howmany ~mk_fresh_name_callback:(namer_of names)
  96         ~pattern what
  97   | GrafiteAst.Change (_, pattern, with_what) ->
  98      Tactics.change ~pattern with_what
  99   | GrafiteAst.Clear (_,id) -> Tactics.clear id
 100   | GrafiteAst.ClearBody (_,id) -> Tactics.clearbody id
 101   | GrafiteAst.Compose (_,t1,t2,times,(howmany, names)) ->
 102       Tactics.compose times t1 t2 ?howmany
 103         ~mk_fresh_name_callback:(namer_of names)
 104   | GrafiteAst.Contradiction _ -> Tactics.contradiction
 105   | GrafiteAst.Constructor (_, n) -> Tactics.constructor n
 106   | GrafiteAst.Cut (_, ident, term) ->
 107      let names = match ident with None -> [] | Some id -> [Some id] in
 108      Tactics.cut ~mk_fresh_name_callback:(namer_of names) term
 109   | GrafiteAst.Decompose (_, names) ->
 110       let mk_fresh_name_callback = namer_of names in
 111       Tactics.decompose ~mk_fresh_name_callback ()
 112   | GrafiteAst.Demodulate (_, params) ->
 113       Tactics.demodulate
 114         ~dbd:(LibraryDb.instance ()) ~params
 115           ~automation_cache:status.GrafiteTypes.automation_cache
 116   | GrafiteAst.Destruct (_,xterms) -> Tactics.destruct xterms
 117   | GrafiteAst.Elim (_, what, using, pattern, (depth, names)) ->
 118       Tactics.elim_intros ?using ?depth ~mk_fresh_name_callback:(namer_of names)
 119         ~pattern what
 120   | GrafiteAst.ElimType (_, what, using, (depth, names)) ->
 121       Tactics.elim_type ?using ?depth ~mk_fresh_name_callback:(namer_of names)
 122         what
 123   | GrafiteAst.Exact (_, term) -> Tactics.exact term
 124   | GrafiteAst.Exists _ -> Tactics.exists
 125   | GrafiteAst.Fail _ -> Tactics.fail
 126   | GrafiteAst.Fold (_, reduction_kind, term, pattern) ->
 127       let reduction =
 128         match reduction_kind with
 129         | `Normalize ->
 130             PET.const_lazy_reduction
 131               (CicReduction.normalize ~delta:false ~subst:[])
 132         | `Simpl -> PET.const_lazy_reduction ProofEngineReduction.simpl
 133         | `Unfold None ->
 134             PET.const_lazy_reduction (ProofEngineReduction.unfold ?what:None)
 135         | `Unfold (Some lazy_term) ->
 136            (fun context metasenv ugraph ->
 137              let what, metasenv, ugraph = lazy_term context metasenv ugraph in
 138              ProofEngineReduction.unfold ~what, metasenv, ugraph)
 139         | `Whd ->
 140             PET.const_lazy_reduction (CicReduction.whd ~delta:false ~subst:[])
 141       in
 142       Tactics.fold ~reduction ~term ~pattern
 143   | GrafiteAst.Fourier _ -> Tactics.fourier
 144   | GrafiteAst.FwdSimpl (_, hyp, names) ->
 145      Tactics.fwd_simpl ~mk_fresh_name_callback:(namer_of names)
 146       ~dbd:(LibraryDb.instance ()) hyp
 147   | GrafiteAst.Generalize (_,pattern,ident) ->
 148      let names = match ident with None -> [] | Some id -> [Some id] in
 149      Tactics.generalize ~mk_fresh_name_callback:(namer_of names) pattern
 150   | GrafiteAst.IdTac _ -> Tactics.id
 151   | GrafiteAst.Intros (_, (howmany, names)) ->
 152       PrimitiveTactics.intros_tac ?howmany
 153         ~mk_fresh_name_callback:(namer_of names) ()
 154   | GrafiteAst.Inversion (_, term) ->
 155       Tactics.inversion term
 156   | GrafiteAst.LApply (_, linear, how_many, to_what, what, ident) ->
 157       let names = match ident with None -> [] | Some id -> [Some id] in
 158       Tactics.lapply ~mk_fresh_name_callback:(namer_of names)
 159         ~linear ?how_many ~to_what what
 160   | GrafiteAst.Left _ -> Tactics.left
 161   | GrafiteAst.LetIn (loc,term,name) ->
 162       Tactics.letin term ~mk_fresh_name_callback:(namer_of [Some name])
 163   | GrafiteAst.Reduce (_, reduction_kind, pattern) ->
 164       (match reduction_kind with
 165          | `Normalize -> Tactics.normalize ~pattern
 166          | `Simpl -> Tactics.simpl ~pattern
 167          | `Unfold what -> Tactics.unfold ~pattern what
 168          | `Whd -> Tactics.whd ~pattern)
 169   | GrafiteAst.Reflexivity _ -> Tactics.reflexivity
 170   | GrafiteAst.Replace (_, pattern, with_what) ->
 171      Tactics.replace ~pattern ~with_what
 172   | GrafiteAst.Rewrite (_, direction, t, pattern, names) ->
 173      EqualityTactics.rewrite_tac ~direction ~pattern t
 174 (* to be replaced with ~mk_fresh_name_callback:(namer_of names) *)
 175      (List.map (function Some s -> s | None -> assert false) names)
 176   | GrafiteAst.Right _ -> Tactics.right
 177   | GrafiteAst.Ring _ -> Tactics.ring
 178   | GrafiteAst.Split _ -> Tactics.split
 179   | GrafiteAst.Symmetry _ -> Tactics.symmetry
 180   | GrafiteAst.Transitivity (_, term) -> Tactics.transitivity term
 181   (* Implementazioni Aggiunte *)
 182   | GrafiteAst.Assume (_, id, t) -> Declarative.assume id t
 183   | GrafiteAst.Suppose (_, t, id, t1) -> Declarative.suppose t id t1
 184   | GrafiteAst.By_just_we_proved (_, just, ty, id, t1) ->
 185      Declarative.by_just_we_proved ~dbd:(LibraryDb.instance())
 186       ~automation_cache:status.GrafiteTypes.automation_cache just ty id t1
 187   | GrafiteAst.We_need_to_prove (_, t, id, t2) ->
 188      Declarative.we_need_to_prove t id t2
 189   | GrafiteAst.Bydone (_, t) ->
 190      Declarative.bydone ~dbd:(LibraryDb.instance())
 191       ~automation_cache:status.GrafiteTypes.automation_cache t
 192   | GrafiteAst.We_proceed_by_cases_on (_, t, t1) ->
 193      Declarative.we_proceed_by_cases_on t t1
 194   | GrafiteAst.We_proceed_by_induction_on (_, t, t1) ->
 195      Declarative.we_proceed_by_induction_on t t1
 196   | GrafiteAst.Byinduction (_, t, id) -> Declarative.byinduction t id
 197   | GrafiteAst.Thesisbecomes (_, t) -> Declarative.thesisbecomes t
 198   | GrafiteAst.ExistsElim (_, just, id1, t1, id2, t2) ->
 199      Declarative.existselim ~dbd:(LibraryDb.instance())
 200       ~automation_cache:status.GrafiteTypes.automation_cache just id1 t1 id2 t2
 201   | GrafiteAst.Case (_,id,params) -> Declarative.case id params
 202   | GrafiteAst.AndElim(_,just,id1,t1,id2,t2) ->
 203      Declarative.andelim ~dbd:(LibraryDb.instance ())
 204       ~automation_cache:status.GrafiteTypes.automation_cache just id1 t1 id2 t2
 205   | GrafiteAst.RewritingStep (_,termine,t1,t2,cont) ->
 206      Declarative.rewritingstep ~dbd:(LibraryDb.instance ())
 207       ~automation_cache:status.GrafiteTypes.automation_cache termine t1 t2 cont
 208
 209 let classify_tactic tactic =
 210   match tactic with
 211   (* tactics that can't close the goal (return a goal we want to "select") *)
 212   | GrafiteAst.Rewrite _
 213   | GrafiteAst.Split _
 214   | GrafiteAst.Replace _
 215   | GrafiteAst.Reduce _
 216   | GrafiteAst.IdTac _
 217   | GrafiteAst.Generalize _
 218   | GrafiteAst.Elim _
 219   | GrafiteAst.Cut _
 220   | GrafiteAst.Decompose _ -> true
 221   (* tactics like apply *)
 222   | _ -> false
 223
 224 let reorder_metasenv start refine tactic goals current_goal always_opens_a_goal=
 225 (*   let print_m name metasenv =
 226     prerr_endline (">>>>> " ^ name);
 227     prerr_endline (CicMetaSubst.ppmetasenv [] metasenv)
 228   in *)
 229   (* phase one calculates:
 230    *   new_goals_from_refine:  goals added by refine
 231    *   head_goal:              the first goal opened by ythe tactic
 232    *   other_goals:            other goals opened by the tactic
 233    *)
 234   let new_goals_from_refine = PEH.compare_metasenvs start refine in
 235   let new_goals_from_tactic = PEH.compare_metasenvs refine tactic in
 236   let head_goal, other_goals, goals =
 237     match goals with
 238     | [] -> None,[],goals
 239     | hd::tl ->
 240         (* assert (List.mem hd new_goals_from_tactic);
 241          * invalidato dalla goal_tac
 242          * *)
 243         Some hd, List.filter ((<>) hd) new_goals_from_tactic, List.filter ((<>)
 244         hd) goals
 245   in
 246   let produced_goals =
 247     match head_goal with
 248     | None -> new_goals_from_refine @ other_goals
 249     | Some x -> x :: new_goals_from_refine @ other_goals
 250   in
 251   (* extract the metas generated by refine and tactic *)
 252   let metas_for_tactic_head =
 253     match head_goal with
 254     | None -> []
 255     | Some head_goal -> List.filter (fun (n,_,_) -> n = head_goal) tactic in
 256   let metas_for_tactic_goals =
 257     List.map
 258       (fun x -> List.find (fun (metano,_,_) -> metano = x) tactic)
 259     goals
 260   in
 261   let metas_for_refine_goals =
 262     List.filter (fun (n,_,_) -> List.mem n new_goals_from_refine) tactic in
 263   let produced_metas, goals =
 264     let produced_metas =
 265       if always_opens_a_goal then
 266         metas_for_tactic_head @ metas_for_refine_goals @
 267           metas_for_tactic_goals
 268       else begin
 269 (*         print_m "metas_for_refine_goals" metas_for_refine_goals;
 270         print_m "metas_for_tactic_head" metas_for_tactic_head;
 271         print_m "metas_for_tactic_goals" metas_for_tactic_goals; *)
 272         metas_for_refine_goals @ metas_for_tactic_head @
 273           metas_for_tactic_goals
 274       end
 275     in
 276     let goals = List.map (fun (metano, _, _) -> metano)  produced_metas in
 277     produced_metas, goals
 278   in
 279   (* residual metas, preserving the original order *)
 280   let before, after =
 281     let rec split e =
 282       function
 283       | [] -> [],[]
 284       | (metano, _, _) :: tl when metano = e ->
 285           [], List.map (fun (x,_,_) -> x) tl
 286       | (metano, _, _) :: tl -> let b, a = split e tl in metano :: b, a
 287     in
 288     let find n metasenv =
 289       try
 290         Some (List.find (fun (metano, _, _) -> metano = n) metasenv)
 291       with Not_found -> None
 292     in
 293     let extract l =
 294       List.fold_right
 295         (fun n acc ->
 296           match find n tactic with
 297           | Some x -> x::acc
 298           | None -> acc
 299         ) l [] in
 300     let before_l, after_l = split current_goal start in
 301     let before_l =
 302       List.filter (fun x -> not (List.mem x produced_goals)) before_l in
 303     let after_l =
 304       List.filter (fun x -> not (List.mem x produced_goals)) after_l in
 305     let before = extract before_l in
 306     let after = extract after_l in
 307       before, after
 308   in
 309 (* |+   DEBUG CODE  +|
 310   print_m "BEGIN" start;
 311   prerr_endline ("goal was: " ^ string_of_int current_goal);
 312   prerr_endline ("and metas from refine are:");
 313   List.iter
 314     (fun t -> prerr_string (" " ^ string_of_int t))
 315   new_goals_from_refine;
 316   prerr_endline "";
 317   print_m "before" before;
 318   print_m "metas_for_tactic_head" metas_for_tactic_head;
 319   print_m "metas_for_refine_goals" metas_for_refine_goals;
 320   print_m "metas_for_tactic_goals" metas_for_tactic_goals;
 321   print_m "produced_metas" produced_metas;
 322   print_m "after" after;
 323 |+   FINE DEBUG CODE +| *)
 324   before @ produced_metas @ after, goals
 325
 326 let apply_tactic ~disambiguate_tactic (text,prefix_len,tactic) (status, goal) =
 327  let starting_metasenv = GrafiteTypes.get_proof_metasenv status in
 328  let before = List.map (fun g, _, _ -> g) starting_metasenv in
 329  let status, tactic = disambiguate_tactic status goal (text,prefix_len,tactic) in
 330  let metasenv_after_refinement =  GrafiteTypes.get_proof_metasenv status in
 331  let proof = GrafiteTypes.get_current_proof status in
 332  let proof_status = proof, goal in
 333  let always_opens_a_goal = classify_tactic tactic in
 334  let tactic = tactic_of_ast status tactic in
 335  let (proof, opened) = ProofEngineTypes.apply_tactic tactic proof_status in
 336  let after = ProofEngineTypes.goals_of_proof proof in
 337  let opened_goals, closed_goals = Tacticals.goals_diff ~before ~after ~opened in
 338  let proof, opened_goals =
 339   let uri, metasenv_after_tactic, subst, t, ty, attrs = proof in
 340   let reordered_metasenv, opened_goals =
 341     reorder_metasenv
 342      starting_metasenv
 343      metasenv_after_refinement metasenv_after_tactic
 344      opened goal always_opens_a_goal
 345   in
 346   let proof' = uri, reordered_metasenv, [], t, ty, attrs in
 347   proof', opened_goals
 348  in
 349  let incomplete_proof =
 350    match status.GrafiteTypes.proof_status with
 351    | GrafiteTypes.Incomplete_proof p -> p
 352    | _ -> assert false
 353  in
 354  { status with GrafiteTypes.proof_status =
 355     GrafiteTypes.Incomplete_proof
 356      { incomplete_proof with GrafiteTypes.proof = proof } },
 357  opened_goals, closed_goals
 358
 359 let apply_atomic_tactical ~disambiguate_tactic ~patch (text,prefix_len,tactic) (status, goal) =
 360  let starting_metasenv = GrafiteTypes.get_proof_metasenv status in
 361  let before = List.map (fun g, _, _ -> g) starting_metasenv in
 362  let status, tactic = disambiguate_tactic status goal (text,prefix_len,tactic) in
 363  let metasenv_after_refinement =  GrafiteTypes.get_proof_metasenv status in
 364  let proof = GrafiteTypes.get_current_proof status in
 365  let proof_status = proof, goal in
 366  let always_opens_a_goal = classify_tactic tactic in
 367  let tactic = tactic_of_ast status tactic in
 368  let tactic = patch tactic in
 369  let (proof, opened) = ProofEngineTypes.apply_tactic tactic proof_status in
 370  let after = ProofEngineTypes.goals_of_proof proof in
 371  let opened_goals, closed_goals = Tacticals.goals_diff ~before ~after ~opened in
 372  let proof, opened_goals =
 373   let uri, metasenv_after_tactic, _subst, t, ty, attrs = proof in
 374   let reordered_metasenv, opened_goals =
 375     reorder_metasenv
 376      starting_metasenv
 377      metasenv_after_refinement metasenv_after_tactic
 378      opened goal always_opens_a_goal
 379   in
 380   let proof' = uri, reordered_metasenv, _subst, t, ty, attrs in
 381   proof', opened_goals
 382  in
 383  let incomplete_proof =
 384    match status.GrafiteTypes.proof_status with
 385    | GrafiteTypes.Incomplete_proof p -> p
 386    | _ -> assert false
 387  in
 388  { status with GrafiteTypes.proof_status =
 389     GrafiteTypes.Incomplete_proof
 390      { incomplete_proof with GrafiteTypes.proof = proof } },
 391  opened_goals, closed_goals
 392 type eval_ast =
 393  {ea_go:
 394   'term 'lazy_term 'reduction 'obj 'ident.
 395   disambiguate_tactic:
 396    (GrafiteTypes.status ->
 397     ProofEngineTypes.goal ->
 398     (('term, 'lazy_term, 'reduction, 'ident) GrafiteAst.tactic)
 399     disambiguator_input ->
 400     GrafiteTypes.status *
 401    (Cic.term, Cic.lazy_term, Cic.lazy_term GrafiteAst.reduction, string) GrafiteAst.tactic) ->
 402
 403   disambiguate_command:
 404    (GrafiteTypes.status ->
 405     (('term,'obj) GrafiteAst.command) disambiguator_input ->
 406     GrafiteTypes.status * (Cic.term,Cic.obj) GrafiteAst.command) ->
 407
 408   disambiguate_macro:
 409    (GrafiteTypes.status ->
 410     (('term,'lazy_term) GrafiteAst.macro) disambiguator_input ->
 411     Cic.context -> GrafiteTypes.status * (Cic.term,Cic.lazy_term) GrafiteAst.macro) ->
 412
 413   ?do_heavy_checks:bool ->
 414   GrafiteTypes.status ->
 415   (('term, 'lazy_term, 'reduction, 'obj, 'ident) GrafiteAst.statement)
 416   disambiguator_input ->
 417   GrafiteTypes.status * [`Old of UriManager.uri list | `New of NUri.uri list]
 418  }
 419
 420 type 'a eval_command =
 421  {ec_go: 'term 'obj.
 422   disambiguate_command:
 423    (GrafiteTypes.status -> (('term,'obj) GrafiteAst.command) disambiguator_input ->
 424     GrafiteTypes.status * (Cic.term,Cic.obj) GrafiteAst.command) ->
 425   options -> GrafiteTypes.status ->
 426     (('term,'obj) GrafiteAst.command) disambiguator_input ->
 427    GrafiteTypes.status * [`Old of UriManager.uri list | `New of NUri.uri list]
 428  }
 429
 430 type 'a eval_comment =
 431  {ecm_go: 'term 'lazy_term 'reduction_kind 'obj 'ident.
 432   disambiguate_command:
 433    (GrafiteTypes.status -> (('term,'obj) GrafiteAst.command) disambiguator_input ->
 434     GrafiteTypes.status * (Cic.term,Cic.obj) GrafiteAst.command) ->
 435   options -> GrafiteTypes.status ->
 436     (('term,'lazy_term,'reduction_kind,'obj,'ident) GrafiteAst.comment) disambiguator_input ->
 437    GrafiteTypes.status * [`Old of UriManager.uri list | `New of NUri.uri list]
 438  }
 439
 440 type 'a eval_executable =
 441  {ee_go: 'term 'lazy_term 'reduction 'obj 'ident.
 442   disambiguate_tactic:
 443    (GrafiteTypes.status ->
 444     ProofEngineTypes.goal ->
 445     (('term, 'lazy_term, 'reduction, 'ident) GrafiteAst.tactic)
 446     disambiguator_input ->
 447     GrafiteTypes.status *
 448    (Cic.term, Cic.lazy_term, Cic.lazy_term GrafiteAst.reduction, string) GrafiteAst.tactic) ->
 449
 450   disambiguate_command:
 451    (GrafiteTypes.status ->
 452     (('term,'obj) GrafiteAst.command) disambiguator_input ->
 453     GrafiteTypes.status * (Cic.term,Cic.obj) GrafiteAst.command) ->
 454
 455   disambiguate_macro:
 456    (GrafiteTypes.status ->
 457     (('term,'lazy_term) GrafiteAst.macro) disambiguator_input ->
 458     Cic.context -> GrafiteTypes.status * (Cic.term,Cic.lazy_term) GrafiteAst.macro) ->
 459
 460   options ->
 461   GrafiteTypes.status ->
 462   (('term, 'lazy_term, 'reduction, 'obj, 'ident) GrafiteAst.code) disambiguator_input ->
 463   GrafiteTypes.status * [`Old of UriManager.uri list | `New of NUri.uri list]
 464  }
 465
 466 type 'a eval_from_moo =
 467  { efm_go: GrafiteTypes.status -> string -> GrafiteTypes.status }
 468
 469 let coercion_moo_statement_of (uri,arity, saturations,_) =
 470   GrafiteAst.Coercion
 471    (HExtlib.dummy_floc, CicUtil.term_of_uri uri, false, arity, saturations)
 472
 473 let eval_unification_hint status t n =
 474  let aux status =
 475   let hstatus =
 476    NCicUnifHint.add_user_provided_hint (status.NRstatus.uhint_db) t n
 477   in
 478    { status with NRstatus.uhint_db = hstatus } in
 479  let rstatus = aux (GrafiteTypes.get_rstatus status) in
 480  let status = GrafiteTypes.set_rstatus rstatus status in
 481  let dump = GrafiteTypes.get_dump status in
 482  let dump = fun status -> aux (dump status) in
 483  let status = GrafiteTypes.set_dump dump status in
 484   status,`Old []
 485 ;;
 486
 487 let add_coercions_of_lemmas lemmas status =
 488   let moo_content =
 489     HExtlib.filter_map
 490       (fun uri ->
 491         match CoercDb.is_a_coercion (Cic.Const (uri,[])) with
 492         | None -> None
 493         | Some (_,tgt,_,sat,_) ->
 494             let arity = match tgt with CoercDb.Fun n -> n | _ -> 0 in
 495             Some (coercion_moo_statement_of (uri,arity,sat,0)))
 496       lemmas
 497   in
 498   let status = GrafiteTypes.add_moo_content moo_content status in
 499   {status with GrafiteTypes.coercions = CoercDb.dump () },
 500   lemmas
 501
 502 let eval_coercion status ~add_composites uri arity saturations =
 503  let uri =
 504    try CicUtil.uri_of_term uri
 505    with Invalid_argument _ ->
 506      raise (Invalid_argument "coercion can only be constants/constructors")
 507  in
 508  let status, lemmas =
 509   GrafiteSync.add_coercion ~add_composites
 510     ~pack_coercion_obj:CicRefine.pack_coercion_obj
 511    status uri arity saturations (GrafiteTypes.get_baseuri status) in
 512  let moo_content = coercion_moo_statement_of (uri,arity,saturations,0) in
 513  let status = GrafiteTypes.add_moo_content [moo_content] status in
 514   add_coercions_of_lemmas lemmas status
 515
 516 let eval_prefer_coercion status c =
 517  let uri =
 518    try CicUtil.uri_of_term c
 519    with Invalid_argument _ ->
 520      raise (Invalid_argument "coercion can only be constants/constructors")
 521  in
 522  let status = GrafiteSync.prefer_coercion status uri in
 523  let moo_content = GrafiteAst.PreferCoercion (HExtlib.dummy_floc,c) in
 524  let status = GrafiteTypes.add_moo_content [moo_content] status in
 525  status, `Old []
 526
 527 module MatitaStatus =
 528  struct
 529   type input_status = GrafiteTypes.status * ProofEngineTypes.goal
 530
 531   type output_status =
 532     GrafiteTypes.status * ProofEngineTypes.goal list * ProofEngineTypes.goal list
 533
 534   type tactic = input_status -> output_status
 535
 536   let mk_tactic tac = tac
 537   let apply_tactic tac = tac
 538   let goals (_, opened, closed) = opened, closed
 539   let get_stack (status, _) = GrafiteTypes.get_stack status
 540
 541   let set_stack stack (status, opened, closed) =
 542     GrafiteTypes.set_stack stack status, opened, closed
 543
 544   let inject (status, _) = (status, [], [])
 545   let focus goal (status, _, _) = (status, goal)
 546  end
 547
 548 module MatitaTacticals = Continuationals.Make(MatitaStatus)
 549
 550 let tactic_of_ast' tac =
 551  MatitaTacticals.Tactical (MatitaTacticals.Tactic (MatitaStatus.mk_tactic tac))
 552
 553 let punctuation_tactical_of_ast (text,prefix_len,punct) =
 554  match punct with
 555   | GrafiteAst.Dot _loc -> MatitaTacticals.Dot
 556   | GrafiteAst.Semicolon _loc -> MatitaTacticals.Semicolon
 557   | GrafiteAst.Branch _loc -> MatitaTacticals.Branch
 558   | GrafiteAst.Shift _loc -> MatitaTacticals.Shift
 559   | GrafiteAst.Pos (_loc, i) -> MatitaTacticals.Pos i
 560   | GrafiteAst.Merge _loc -> MatitaTacticals.Merge
 561   | GrafiteAst.Wildcard _loc -> MatitaTacticals.Wildcard
 562
 563 let non_punctuation_tactical_of_ast (text,prefix_len,punct) =
 564  match punct with
 565   | GrafiteAst.Focus (_loc,goals) -> MatitaTacticals.Focus goals
 566   | GrafiteAst.Unfocus _loc -> MatitaTacticals.Unfocus
 567   | GrafiteAst.Skip _loc -> MatitaTacticals.Tactical MatitaTacticals.Skip
 568
 569 let eval_tactical status tac =
 570   let status, _, _ = MatitaTacticals.eval tac (status, ~-1) in
 571   let status =  (* is proof completed? *)
 572     match status.GrafiteTypes.proof_status with
 573     | GrafiteTypes.Incomplete_proof
 574        { GrafiteTypes.stack = stack; proof = proof }
 575       when Continuationals.Stack.is_empty stack ->
 576         { status with GrafiteTypes.proof_status = GrafiteTypes.Proof proof }
 577     | _ -> status
 578   in
 579   status
 580
 581 let add_obj = GrafiteSync.add_obj ~pack_coercion_obj:CicRefine.pack_coercion_obj
 582
 583 let eval_ng_punct (_text, _prefix_len, punct) =
 584   match punct with
 585   | GrafiteAst.Dot _ -> NTactics.dot_tac
 586   | GrafiteAst.Semicolon _ -> fun x -> x
 587   | GrafiteAst.Branch _ -> NTactics.branch_tac
 588   | GrafiteAst.Shift _ -> NTactics.shift_tac
 589   | GrafiteAst.Pos (_,l) -> NTactics.pos_tac l
 590   | GrafiteAst.Wildcard _ -> NTactics.wildcard_tac
 591   | GrafiteAst.Merge _ -> NTactics.merge_tac
 592 ;;
 593
 594 let eval_ng_tac (text, prefix_len, tac) =
 595   match tac with
 596   | GrafiteAst.NApply (_loc, t) -> NTactics.apply_tac (text,prefix_len,t)
 597   | GrafiteAst.NAssert (_loc, seqs) ->
 598      NTactics.assert_tac
 599       ((List.map
 600         (function (hyps,concl) ->
 601           List.map
 602            (function
 603               (id,`Decl t) -> id,`Decl (text,prefix_len,t)
 604              |(id,`Def (b,t))->id,`Def((text,prefix_len,b),(text,prefix_len,t))
 605            ) hyps,
 606           (text,prefix_len,concl))
 607        ) seqs)
 608   | GrafiteAst.NAuto (_loc, (l,a)) ->
 609       NTactics.auto_tac
 610         ~params:(List.map (fun x -> "",0,x) l,a)
 611   | GrafiteAst.NBranch _ -> NTactics.branch_tac
 612   | GrafiteAst.NCases (_loc, what, where) ->
 613       NTactics.cases_tac
 614         ~what:(text,prefix_len,what)
 615         ~where:(text,prefix_len,where)
 616   | GrafiteAst.NCase1 (_loc,n) -> NTactics.case1_tac n
 617   | GrafiteAst.NChange (_loc, pat, ww) ->
 618       NTactics.change_tac
 619        ~where:(text,prefix_len,pat) ~with_what:(text,prefix_len,ww)
 620   | GrafiteAst.NDot _ -> NTactics.dot_tac
 621   | GrafiteAst.NElim (_loc, what, where) ->
 622       NTactics.elim_tac
 623         ~what:(text,prefix_len,what)
 624         ~where:(text,prefix_len,where)
 625   | GrafiteAst.NFocus (_,l) -> NTactics.focus_tac l
 626   | GrafiteAst.NGeneralize (_loc, where) ->
 627       NTactics.generalize_tac ~where:(text,prefix_len,where)
 628   | GrafiteAst.NId _ -> (fun x -> x)
 629   | GrafiteAst.NIntro (_loc,n) -> NTactics.intro_tac n
 630   | GrafiteAst.NLetIn (_loc,where,what,name) ->
 631       NTactics.letin_tac ~where:(text,prefix_len,where)
 632         ~what:(text,prefix_len,what) name
 633   | GrafiteAst.NMerge _ -> NTactics.merge_tac
 634   | GrafiteAst.NPos (_,l) -> NTactics.pos_tac l
 635   | GrafiteAst.NReduce (_loc, reduction, where) ->
 636       NTactics.reduce_tac ~reduction ~where:(text,prefix_len,where)
 637   | GrafiteAst.NRewrite (_loc,dir,what,where) ->
 638      NTactics.rewrite_tac ~dir ~what:(text,prefix_len,what)
 639       ~where:(text,prefix_len,where)
 640   | GrafiteAst.NSemicolon _ -> fun x -> x
 641   | GrafiteAst.NShift _ -> NTactics.shift_tac
 642   | GrafiteAst.NSkip _ -> NTactics.skip_tac
 643   | GrafiteAst.NUnfocus _ -> NTactics.unfocus_tac
 644   | GrafiteAst.NWildcard _ -> NTactics.wildcard_tac
 645 ;;
 646
 647 let subst_metasenv_and_fix_names s =
 648   let u,h,metasenv, subst,o = s.NTacStatus.istatus.NTacStatus.pstatus in
 649   let o =
 650     NCicUntrusted.map_obj_kind ~skip_body:true
 651      (NCicUntrusted.apply_subst subst []) o
 652   in
 653   { s with NTacStatus.istatus =
 654      { s.NTacStatus.istatus with NTacStatus.pstatus =
 655         u,h,NCicUntrusted.apply_subst_metasenv subst metasenv,subst,o}}
 656 ;;
 657
 658 let rec eval_command = {ec_go = fun ~disambiguate_command opts status
 659 (text,prefix_len,cmd) ->
 660  let status,cmd = disambiguate_command status (text,prefix_len,cmd) in
 661  let status,uris =
 662   match cmd with
 663   | GrafiteAst.Index (loc,None,uri) ->
 664         assert false (* TODO: for user input *)
 665   | GrafiteAst.Index (loc,Some key,uri) ->
 666       let universe =
 667         status.GrafiteTypes.automation_cache.AutomationCache.univ
 668       in
 669       let universe = Universe.index universe key (CicUtil.term_of_uri uri) in
 670       let cache = {
 671         status.GrafiteTypes.automation_cache with AutomationCache.univ = universe }
 672       in
 673       let status = { status with GrafiteTypes.automation_cache = cache } in
 674 (* debug
 675       let msg =
 676        let candidates = Universe.get_candidates status.GrafiteTypes.universe key in
 677        ("candidates for " ^ (CicPp.ppterm key) ^ " = " ^
 678           (String.concat "\n" (List.map CicPp.ppterm candidates)))
 679      in
 680      prerr_endline msg;
 681 *)
 682       let status = GrafiteTypes.add_moo_content [cmd] status in
 683       status,`Old []
 684   | GrafiteAst.Select (_,uri) as cmd ->
 685       if List.mem cmd status.GrafiteTypes.moo_content_rev then status, `Old []
 686       else
 687        let cache =
 688          AutomationCache.add_term_to_active status.GrafiteTypes.automation_cache
 689            [] [] [] (CicUtil.term_of_uri uri) None
 690        in
 691        let status = { status with GrafiteTypes.automation_cache = cache } in
 692        let status = GrafiteTypes.add_moo_content [cmd] status in
 693        status, `Old []
 694   | GrafiteAst.Pump (_,steps) ->
 695       let cache =
 696         AutomationCache.pump status.GrafiteTypes.automation_cache steps
 697       in
 698       let status = { status with GrafiteTypes.automation_cache = cache } in
 699       status, `Old []
 700   | GrafiteAst.PreferCoercion (loc, coercion) ->
 701      eval_prefer_coercion status coercion
 702   | GrafiteAst.Coercion (loc, uri, add_composites, arity, saturations) ->
 703      let res,uris =
 704       eval_coercion status ~add_composites uri arity saturations
 705      in
 706       res,`Old uris
 707   | GrafiteAst.Inverter (loc, name, indty, params) ->
 708      let buri = GrafiteTypes.get_baseuri status in
 709      let uri = UriManager.uri_of_string (buri ^ "/" ^ name ^ ".con") in
 710      let indty_uri =
 711        try CicUtil.uri_of_term indty
 712        with Invalid_argument _ ->
 713          raise (Invalid_argument "not an inductive type to invert") in
 714      let res,uris =
 715       Inversion_principle.build_inverter ~add_obj status uri indty_uri params
 716      in
 717       res,`Old uris
 718   | GrafiteAst.UnificationHint (loc, t, n) ->
 719      eval_unification_hint status t n
 720   | GrafiteAst.Default (loc, what, uris) as cmd ->
 721      LibraryObjects.set_default what uris;
 722      GrafiteTypes.add_moo_content [cmd] status,`Old []
 723   | GrafiteAst.Drop loc -> raise Drop
 724   | GrafiteAst.Include (loc, _, baseuri) ->
 725      let moopath_rw, moopath_r =
 726        LibraryMisc.obj_file_of_baseuri
 727          ~must_exist:false ~baseuri ~writable:true,
 728        LibraryMisc.obj_file_of_baseuri
 729          ~must_exist:false ~baseuri ~writable:false
 730      in
 731      let moopath =
 732        if Sys.file_exists moopath_r then moopath_r else
 733          if Sys.file_exists moopath_rw then moopath_rw else
 734            raise (IncludedFileNotCompiled (moopath_rw,baseuri))
 735      in
 736      let status = eval_from_moo.efm_go status moopath in
 737      let rstatus = GrafiteTypes.get_rstatus status in
 738      let rstatus =
 739       NCicLibrary.require ~baseuri:(NUri.uri_of_string baseuri) rstatus in
 740      let status = GrafiteTypes.set_rstatus rstatus status in
 741 (* debug
 742      let lt_uri = UriManager.uri_of_string "cic:/matita/nat/orders/lt.con" in
 743      let nat_uri = UriManager.uri_of_string "cic:/matita/nat/nat/nat.ind" in
 744      let nat = Cic.MutInd(nat_uri,0,[]) in
 745      let zero = Cic.MutConstruct(nat_uri,0,1,[]) in
 746      let succ = Cic.MutConstruct(nat_uri,0,2,[]) in
 747      let fake= Cic.Meta(-1,[]) in
 748      let term= Cic.Appl [Cic.Const (lt_uri,[]);zero;Cic.Appl[succ;zero]] in     let msg =
 749        let candidates = Universe.get_candidates status.GrafiteTypes.universe term in
 750        ("candidates for " ^ (CicPp.ppterm term) ^ " = " ^
 751           (String.concat "\n" (List.map CicPp.ppterm candidates)))
 752      in
 753      prerr_endline msg;
 754 *)
 755      status,`Old []
 756   | GrafiteAst.Print (_,"proofterm") ->
 757       let _,_,_,p,_, _ = GrafiteTypes.get_current_proof status in
 758       prerr_endline (Auto.pp_proofterm (Lazy.force p));
 759       status,`Old []
 760   | GrafiteAst.Print (_,_) -> status,`Old []
 761   | GrafiteAst.Qed loc ->
 762       let uri, metasenv, _subst, bo, ty, attrs =
 763         match status.GrafiteTypes.proof_status with
 764         | GrafiteTypes.Proof (Some uri, metasenv, subst, body, ty, attrs) ->
 765             uri, metasenv, subst, body, ty, attrs
 766         | GrafiteTypes.Proof (None, metasenv, subst, body, ty, attrs) ->
 767             raise (GrafiteTypes.Command_error
 768               ("Someone allows to start a theorem without giving the "^
 769                "name/uri. This should be fixed!"))
 770         | _->
 771           raise
 772            (GrafiteTypes.Command_error "You can't Qed an incomplete theorem")
 773       in
 774       if metasenv <> [] then
 775         raise
 776          (GrafiteTypes.Command_error
 777            "Proof not completed! metasenv is not empty!");
 778       let name = UriManager.name_of_uri uri in
 779       let obj = Cic.Constant (name,Some (Lazy.force bo),ty,[],attrs) in
 780       let status, lemmas = add_obj uri obj status in
 781        {status with GrafiteTypes.proof_status = GrafiteTypes.No_proof},
 782         (*CSC: I throw away the arities *)
 783         `Old (uri::lemmas)
 784   | GrafiteAst.NQed loc ->
 785       (match status.GrafiteTypes.ng_status with
 786        | GrafiteTypes.ProofMode
 787           { NTacStatus.istatus =
 788              { NTacStatus.pstatus = pstatus; estatus = estatus } } ->
 789             let uri,height,menv,subst,obj_kind = pstatus in
 790              if menv <> [] then
 791               raise
 792                (GrafiteTypes.Command_error"You can't Qed an incomplete theorem")
 793              else
 794               let obj_kind =
 795                NCicUntrusted.map_obj_kind
 796                 (NCicUntrusted.apply_subst subst []) obj_kind in
 797               let height = NCicTypeChecker.height_of_obj_kind uri obj_kind in
 798               let obj = uri,height,[],[],obj_kind in
 799                NCicTypeChecker.typecheck_obj obj;
 800                let timestamp = NCicLibrary.add_obj uri obj in
 801                let objs = NCicElim.mk_elims obj in
 802                let timestamp,uris_rev =
 803                  List.fold_left
 804                   (fun (timestamp,uris_rev) (uri,_,_,_,_) as obj ->
 805                     NCicTypeChecker.typecheck_obj obj;
 806                     let timestamp = NCicLibrary.add_obj uri obj in
 807                      timestamp,uri::uris_rev
 808                   ) (timestamp,[]) objs in
 809                let uris = uri::List.rev uris_rev in
 810                 GrafiteTypes.set_library_db timestamp
 811                  {status with
 812                   GrafiteTypes.ng_status =
 813                    GrafiteTypes.CommandMode estatus },`New uris
 814        | _ -> raise (GrafiteTypes.Command_error "Not in proof mode"))
 815   | GrafiteAst.Relation (loc, id, a, aeq, refl, sym, trans) ->
 816      Setoids.add_relation id a aeq refl sym trans;
 817      status, `Old [] (*CSC: TO BE FIXED *)
 818   | GrafiteAst.Set (loc, name, value) -> status, `Old []
 819 (*       GrafiteTypes.set_option status name value,[] *)
 820   | GrafiteAst.NUnivConstraint (loc,strict,u1,u2) ->
 821       NCicEnvironment.add_constraint strict [false,u1] [false,u2];
 822       status, `New [u1;u2]
 823   | GrafiteAst.NObj (loc,obj) ->
 824      let estatus =
 825        match status.GrafiteTypes.ng_status with
 826        | GrafiteTypes.ProofMode _ -> assert false
 827        | GrafiteTypes.CommandMode es -> es
 828      in
 829      let estatus,obj =
 830       GrafiteDisambiguate.disambiguate_nobj estatus
 831        ~baseuri:(GrafiteTypes.get_baseuri status) (text,prefix_len,obj) in
 832      let uri,height,nmenv,nsubst,nobj = obj in
 833      let ninitial_stack = Continuationals.Stack.of_nmetasenv nmenv in
 834      let status =
 835       { status with
 836          GrafiteTypes.ng_status =
 837           GrafiteTypes.ProofMode
 838            (subst_metasenv_and_fix_names
 839             { NTacStatus.gstatus = ninitial_stack;
 840              istatus = { NTacStatus.pstatus = obj; estatus = estatus}})
 841              }
 842      in
 843      (match nmenv with
 844          [] ->
 845           eval_command.ec_go ~disambiguate_command opts status
 846            ("",0,GrafiteAst.NQed Stdpp.dummy_loc)
 847        | _ -> status,`New [])
 848   | GrafiteAst.Obj (loc,obj) ->
 849      let ext,name =
 850       match obj with
 851          Cic.Constant (name,_,_,_,_)
 852        | Cic.CurrentProof (name,_,_,_,_,_) -> ".con",name
 853        | Cic.InductiveDefinition (types,_,_,_) ->
 854           ".ind",
 855           (match types with (name,_,_,_)::_ -> name | _ -> assert false)
 856        | _ -> assert false in
 857      let buri = GrafiteTypes.get_baseuri status in
 858      let uri = UriManager.uri_of_string (buri ^ "/" ^ name ^ ext) in
 859      let obj = CicRefine.pack_coercion_obj obj in
 860      let metasenv = GrafiteTypes.get_proof_metasenv status in
 861      match obj with
 862      | Cic.CurrentProof (_,metasenv',bo,ty,_, attrs) ->
 863          let name = UriManager.name_of_uri uri in
 864          if not(CicPp.check name ty) then
 865            HLog.warn ("Bad name: " ^ name);
 866          if opts.do_heavy_checks then
 867            begin
 868              let dbd = LibraryDb.instance () in
 869              let similar = Whelp.match_term ~dbd ty in
 870              let similar_len = List.length similar in
 871              if similar_len> 30 then
 872                (HLog.message
 873                  ("Duplicate check will compare your theorem with " ^
 874                    string_of_int similar_len ^
 875                    " theorems, this may take a while."));
 876              let convertible =
 877                List.filter (
 878                  fun u ->
 879                    let t = CicUtil.term_of_uri u in
 880                    let ty',g =
 881                      CicTypeChecker.type_of_aux'
 882                        metasenv' [] t CicUniv.oblivion_ugraph
 883                    in
 884                    fst(CicReduction.are_convertible [] ty' ty g))
 885                similar
 886              in
 887              (match convertible with
 888              | [] -> ()
 889              | x::_ ->
 890                  HLog.warn
 891                  ("Theorem already proved: " ^ UriManager.string_of_uri x ^
 892                   "\nPlease use a variant."));
 893            end;
 894          let _subst = [] in
 895          let initial_proof = (Some uri, metasenv', _subst, lazy bo, ty, attrs) in
 896          let initial_stack = Continuationals.Stack.of_metasenv metasenv' in
 897          { status with GrafiteTypes.proof_status =
 898             GrafiteTypes.Incomplete_proof
 899             { GrafiteTypes.proof = initial_proof; stack = initial_stack } ;
 900          },
 901           `Old []
 902      | _ ->
 903          if metasenv <> [] then
 904           raise (GrafiteTypes.Command_error (
 905             "metasenv not empty while giving a definition with body: " ^
 906             CicMetaSubst.ppmetasenv [] metasenv));
 907          let status, lemmas = add_obj uri obj status in
 908          let status,new_lemmas = add_coercions_of_lemmas lemmas status in
 909           {status with GrafiteTypes.proof_status = GrafiteTypes.No_proof},
 910            `Old (uri::new_lemmas@lemmas)
 911  in
 912   match status.GrafiteTypes.proof_status with
 913      GrafiteTypes.Intermediate _ ->
 914       {status with GrafiteTypes.proof_status = GrafiteTypes.No_proof},uris
 915    | _ -> status,uris
 916
 917 } and eval_executable = {ee_go = fun ~disambiguate_tactic ~disambiguate_command
 918 ~disambiguate_macro opts status (text,prefix_len,ex) ->
 919   match ex with
 920   | GrafiteAst.Tactic (_(*loc*), Some tac, punct) ->
 921      let tac = apply_tactic ~disambiguate_tactic (text,prefix_len,tac) in
 922      let status = eval_tactical status (tactic_of_ast' tac) in
 923      (* CALL auto on every goal, easy way of testing it
 924      let auto =
 925        GrafiteAst.AutoBatch
 926          (loc, ([],["depth","2";"timeout","1";"type","1"])) in
 927      (try
 928        let auto = apply_tactic ~disambiguate_tactic ("",0,auto) in
 929        let _ = eval_tactical status (tactic_of_ast' auto) in
 930        print_endline "GOOD"; ()
 931      with ProofEngineTypes.Fail _ -> print_endline "BAD" | _ -> ());*)
 932       eval_tactical status
 933        (punctuation_tactical_of_ast (text,prefix_len,punct)),`Old []
 934   | GrafiteAst.Tactic (_, None, punct) ->
 935       eval_tactical status
 936        (punctuation_tactical_of_ast (text,prefix_len,punct)),`Old []
 937   | GrafiteAst.NTactic (_(*loc*), tacl) ->
 938       (match status.GrafiteTypes.ng_status with
 939       | GrafiteTypes.CommandMode _ -> assert false
 940       | GrafiteTypes.ProofMode nstatus ->
 941          let nstatus =
 942           List.fold_left
 943             (fun nstatus tac ->
 944               let nstatus = eval_ng_tac (text,prefix_len,tac) nstatus in
 945               subst_metasenv_and_fix_names nstatus)
 946             nstatus tacl
 947          in
 948          NTacStatus.pp_tac_status nstatus;
 949          { status with GrafiteTypes.ng_status= GrafiteTypes.ProofMode nstatus },
 950          `New [])
 951   | GrafiteAst.NonPunctuationTactical (_, tac, punct) ->
 952      let status =
 953       eval_tactical status
 954        (non_punctuation_tactical_of_ast (text,prefix_len,tac))
 955      in
 956       eval_tactical status
 957        (punctuation_tactical_of_ast (text,prefix_len,punct)),`Old []
 958   | GrafiteAst.Command (_, cmd) ->
 959       eval_command.ec_go ~disambiguate_command opts status (text,prefix_len,cmd)
 960   | GrafiteAst.Macro (loc, macro) ->
 961      raise (Macro (loc,disambiguate_macro status (text,prefix_len,macro)))
 962
 963 } and eval_from_moo = {efm_go = fun status fname ->
 964   let ast_of_cmd cmd =
 965     ("",0,GrafiteAst.Executable (HExtlib.dummy_floc,
 966       GrafiteAst.Command (HExtlib.dummy_floc,
 967         cmd)))
 968   in
 969   let moo = GrafiteMarshal.load_moo fname in
 970   List.fold_left
 971     (fun status ast ->
 972       let ast = ast_of_cmd ast in
 973       let status,lemmas =
 974        eval_ast.ea_go
 975          ~disambiguate_tactic:(fun status _ (_,_,tactic) -> status,tactic)
 976          ~disambiguate_command:(fun status (_,_,cmd) -> status,cmd)
 977          ~disambiguate_macro:(fun _ _ -> assert false)
 978          status ast
 979       in
 980        assert (lemmas=`Old []);
 981        status)
 982     status moo
 983 } and eval_ast = {ea_go = fun ~disambiguate_tactic ~disambiguate_command
 984 ~disambiguate_macro ?(do_heavy_checks=false) status
 985 (text,prefix_len,st)
 986 ->
 987   let opts = { do_heavy_checks = do_heavy_checks ; } in
 988   match st with
 989   | GrafiteAst.Executable (_,ex) ->
 990      eval_executable.ee_go ~disambiguate_tactic ~disambiguate_command
 991       ~disambiguate_macro opts status (text,prefix_len,ex)
 992   | GrafiteAst.Comment (_,c) ->
 993       eval_comment.ecm_go ~disambiguate_command opts status (text,prefix_len,c)
 994 } and eval_comment = { ecm_go = fun ~disambiguate_command opts status (text,prefix_len,c) ->
 995     status, `Old []
 996 }
 997 ;;
 998
 999
1000 let eval_ast = eval_ast.ea_go