helm/software/components/grafite_parser/grafiteDisambiguate.ml

   1 (*
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://helm.cs.unibo.it/
  24  *)
  25
  26 (* $Id$ *)
  27
  28 exception BaseUriNotSetYet
  29
  30 type tactic =
  31  (CicNotationPt.term, CicNotationPt.term,
  32   CicNotationPt.term GrafiteAst.reduction, string)
  33    GrafiteAst.tactic
  34
  35 type lazy_tactic =
  36   (Cic.term, Cic.lazy_term, Cic.lazy_term GrafiteAst.reduction, string)
  37     GrafiteAst.tactic
  38
  39 let singleton msg = function
  40   | [x], _ -> x
  41   | l, _   ->
  42       let debug =
  43          Printf.sprintf "GrafiteDisambiguate.singleton (%s): %u interpretations"
  44          msg (List.length l)
  45       in
  46       HLog.debug debug; assert false
  47
  48 let __Implicit = "__Implicit__"
  49 let __Closed_Implicit = "__Closed_Implicit__"
  50
  51 let cic_mk_choice = function
  52   | LexiconAst.Symbol_alias (name, _, dsc) ->
  53      if name = __Implicit then
  54        dsc, `Sym_interp (fun _ -> Cic.Implicit None)
  55      else if name = __Closed_Implicit then
  56        dsc, `Sym_interp (fun _ -> Cic.Implicit (Some `Closed))
  57      else
  58        DisambiguateChoices.cic_lookup_symbol_by_dsc name dsc
  59   | LexiconAst.Number_alias (_, dsc) ->
  60      DisambiguateChoices.lookup_num_by_dsc dsc
  61   | LexiconAst.Ident_alias (name, uri) ->
  62      uri, `Sym_interp
  63       (fun l->assert(l = []);CicUtil.term_of_uri (UriManager.uri_of_string uri))
  64 ;;
  65
  66 let ncic_mk_choice = function
  67   | LexiconAst.Symbol_alias (name, _, dsc) ->
  68      if name = __Implicit then
  69        dsc, `Sym_interp (fun _ -> NCic.Implicit `Term)
  70      else if name = __Closed_Implicit then
  71        dsc, `Sym_interp (fun _ -> NCic.Implicit `Closed)
  72      else
  73        DisambiguateChoices.lookup_symbol_by_dsc
  74         ~mk_implicit:(function
  75            | true -> NCic.Implicit `Closed
  76            | false -> NCic.Implicit `Term)
  77         ~mk_appl:(function
  78            (NCic.Appl l)::tl -> NCic.Appl (l@tl) | l -> NCic.Appl l)
  79         ~term_of_uri:(fun uri ->
  80            fst (OCic2NCic.convert_term uri (CicUtil.term_of_uri uri)))
  81        name dsc
  82   | LexiconAst.Number_alias (_, dsc) ->
  83        let desc,f = DisambiguateChoices.lookup_num_by_dsc dsc in
  84        desc, `Num_interp
  85          (fun num ->
  86             fst (OCic2NCic.convert_term
  87               (UriManager.uri_of_string "cic:/xxx/x.con")
  88               (match f with `Num_interp f -> f num | _ -> assert false)))
  89   | LexiconAst.Ident_alias (name, uri) ->
  90      uri, `Sym_interp
  91       (fun l->assert(l = []);
  92       let uri = UriManager.uri_of_string uri in
  93        fst (OCic2NCic.convert_term uri (CicUtil.term_of_uri uri)))
  94 ;;
  95
  96
  97 let mk_implicit b =
  98   match b with
  99   | false ->
 100       LexiconAst.Symbol_alias (__Implicit,-1,"Fake Implicit")
 101   | true ->
 102       LexiconAst.Symbol_alias (__Closed_Implicit,-1,"Fake Closed Implicit")
 103 ;;
 104
 105 let lookup_in_library
 106   interactive_user_uri_choice input_or_locate_uri item
 107 =
 108   let mk_ident_alias id u =
 109     LexiconAst.Ident_alias (id,UriManager.string_of_uri u)
 110   in
 111   let mk_num_alias instance =
 112     List.map
 113      (fun dsc,_ -> LexiconAst.Number_alias (instance,dsc))
 114      (DisambiguateChoices.lookup_num_choices())
 115   in
 116   let mk_symbol_alias symb ino (dsc, _,_) =
 117      LexiconAst.Symbol_alias (symb,ino,dsc)
 118   in
 119   let dbd = LibraryDb.instance () in
 120   let choices_of_id id =
 121     let uris = Whelp.locate ~dbd id in
 122      match uris with
 123       | [] ->
 124          (match
 125            (input_or_locate_uri
 126              ~title:("URI matching \"" ^ id ^ "\" unknown.")
 127              ?id:(Some id) ())
 128          with
 129          | None -> []
 130          | Some uri -> [uri])
 131       | [uri] -> [uri]
 132       | _ ->
 133           interactive_user_uri_choice ~selection_mode:`MULTIPLE
 134            ?ok:(Some "Try selected.")
 135            ?enable_button_for_non_vars:(Some true)
 136            ~title:"Ambiguous input."
 137            ~msg: ("Ambiguous input \"" ^ id ^
 138               "\". Please, choose one or more interpretations:")
 139            ~id
 140            uris
 141   in
 142   match item with
 143   | DisambiguateTypes.Id id ->
 144       let uris = choices_of_id id in
 145       List.map (mk_ident_alias id) uris
 146   | DisambiguateTypes.Symbol (symb, ino) ->
 147    (try
 148      List.map (mk_symbol_alias symb ino)
 149       (TermAcicContent.lookup_interpretations symb)
 150     with
 151      TermAcicContent.Interpretation_not_found -> [])
 152   | DisambiguateTypes.Num instance -> mk_num_alias instance
 153 ;;
 154
 155   (** @param term not meaningful when context is given *)
 156 let disambiguate_term goal text prefix_len lexicon_status_ref context metasenv
 157 term =
 158   let lexicon_status = !lexicon_status_ref in
 159   let (diff, metasenv, subst, cic, _) =
 160     singleton "first"
 161       (CicDisambiguate.disambiguate_term
 162         ~aliases:lexicon_status.LexiconEngine.aliases
 163         ?goal ~universe:(Some lexicon_status.LexiconEngine.multi_aliases)
 164         ~lookup_in_library
 165         ~mk_choice:cic_mk_choice
 166         ~mk_implicit
 167         ~description_of_alias:LexiconAst.description_of_alias
 168         ~context ~metasenv ~subst:[] (text,prefix_len,term))
 169   in
 170   let lexicon_status = LexiconEngine.set_proof_aliases lexicon_status diff in
 171   lexicon_status_ref := lexicon_status;
 172   metasenv,(*subst,*) cic
 173 ;;
 174
 175   (** disambiguate_lazy_term (circa): term -> (unit -> status) * lazy_term
 176    * rationale: lazy_term will be invoked in different context to obtain a term,
 177    * each invocation will disambiguate the term and can add aliases. Once all
 178    * disambiguations have been performed, the first returned function can be
 179    * used to obtain the resulting aliases *)
 180 let disambiguate_lazy_term goal text prefix_len lexicon_status_ref term =
 181   (fun context metasenv ugraph ->
 182     let lexicon_status = !lexicon_status_ref in
 183     let (diff, metasenv, _, cic, ugraph) =
 184       singleton "second"
 185         (CicDisambiguate.disambiguate_term
 186           ~lookup_in_library
 187           ~mk_choice:cic_mk_choice
 188           ~mk_implicit
 189           ~description_of_alias:LexiconAst.description_of_alias
 190           ~initial_ugraph:ugraph ~aliases:lexicon_status.LexiconEngine.aliases
 191           ~universe:(Some lexicon_status.LexiconEngine.multi_aliases)
 192           ~context ~metasenv ~subst:[] ?goal
 193           (text,prefix_len,term)) in
 194     let lexicon_status = LexiconEngine.set_proof_aliases lexicon_status diff in
 195     lexicon_status_ref := lexicon_status;
 196     cic, metasenv, ugraph)
 197 ;;
 198
 199 let disambiguate_pattern
 200   text prefix_len lexicon_status_ref (wanted, hyp_paths, goal_path)
 201 =
 202   let interp path =CicDisambiguate.interpretate_path [] path in
 203   let goal_path = HExtlib.map_option interp goal_path in
 204   let hyp_paths = List.map (fun (name, path) -> name, interp path) hyp_paths in
 205   let wanted =
 206    match wanted with
 207       None -> None
 208     | Some wanted ->
 209        let wanted =
 210          disambiguate_lazy_term None text prefix_len lexicon_status_ref wanted
 211        in
 212        Some wanted
 213   in
 214   (wanted, hyp_paths, goal_path)
 215 ;;
 216
 217 let disambiguate_reduction_kind text prefix_len lexicon_status_ref = function
 218   | `Unfold (Some t) ->
 219       let t =
 220          disambiguate_lazy_term None text prefix_len lexicon_status_ref t in
 221       `Unfold (Some t)
 222   | `Normalize
 223   | `Simpl
 224   | `Unfold None
 225   | `Whd as kind -> kind
 226 ;;
 227
 228 let disambiguate_auto_params
 229   disambiguate_term metasenv context (terms, params)
 230 =
 231     let metasenv, terms =
 232       List.fold_right
 233        (fun t (metasenv, terms) ->
 234          let metasenv,t = disambiguate_term context metasenv t in
 235          metasenv,t::terms) terms (metasenv, [])
 236     in
 237     metasenv, (terms, params)
 238 ;;
 239
 240 let disambiguate_just disambiguate_term context metasenv =
 241  function
 242     `Term t ->
 243       let metasenv,t = disambiguate_term context metasenv t in
 244        metasenv, `Term t
 245   | `Auto params ->
 246       let metasenv,params = disambiguate_auto_params disambiguate_term metasenv
 247        context params
 248       in
 249        metasenv, `Auto params
 250 ;;
 251
 252 let rec disambiguate_tactic
 253   lexicon_status_ref context metasenv goal (text,prefix_len,tactic)
 254 =
 255   let disambiguate_term_hint =
 256     disambiguate_term goal text prefix_len lexicon_status_ref in
 257   let disambiguate_term =
 258     disambiguate_term None text prefix_len lexicon_status_ref in
 259   let disambiguate_pattern =
 260     disambiguate_pattern text prefix_len lexicon_status_ref in
 261   let disambiguate_reduction_kind =
 262     disambiguate_reduction_kind text prefix_len lexicon_status_ref in
 263   let disambiguate_lazy_term =
 264     disambiguate_lazy_term None text prefix_len lexicon_status_ref in
 265   let disambiguate_tactic metasenv tac =
 266    disambiguate_tactic lexicon_status_ref context metasenv goal (text,prefix_len,tac)
 267   in
 268   let disambiguate_auto_params m p =
 269     disambiguate_auto_params disambiguate_term m context p
 270   in
 271    match tactic with
 272     (* Higher  order tactics *)
 273     | GrafiteAst.Progress (loc,tac) ->
 274         let metasenv,tac = disambiguate_tactic metasenv tac in
 275         metasenv,GrafiteAst.Progress (loc,tac)
 276     | GrafiteAst.Solve (loc,tacl) ->
 277         let metasenv,tacl =
 278          List.fold_right
 279           (fun tac (metasenv,tacl) ->
 280             let metasenv,tac = disambiguate_tactic metasenv tac in
 281              metasenv,tac::tacl
 282           ) tacl (metasenv,[])
 283         in
 284          metasenv,GrafiteAst.Solve (loc,tacl)
 285     | GrafiteAst.Try (loc,tac) ->
 286         let metasenv,tac = disambiguate_tactic metasenv tac in
 287         metasenv,GrafiteAst.Try (loc,tac)
 288     | GrafiteAst.First (loc,tacl) ->
 289         let metasenv,tacl =
 290          List.fold_right
 291           (fun tac (metasenv,tacl) ->
 292             let metasenv,tac = disambiguate_tactic metasenv tac in
 293              metasenv,tac::tacl
 294           ) tacl (metasenv,[])
 295         in
 296          metasenv,GrafiteAst.First (loc,tacl)
 297     | GrafiteAst.Seq (loc,tacl) ->
 298         let metasenv,tacl =
 299          List.fold_right
 300           (fun tac (metasenv,tacl) ->
 301             let metasenv,tac = disambiguate_tactic metasenv tac in
 302              metasenv,tac::tacl
 303           ) tacl (metasenv,[])
 304         in
 305          metasenv,GrafiteAst.Seq (loc,tacl)
 306     | GrafiteAst.Repeat (loc,tac) ->
 307         let metasenv,tac = disambiguate_tactic metasenv tac in
 308         metasenv,GrafiteAst.Repeat (loc,tac)
 309     | GrafiteAst.Do (loc,n,tac) ->
 310         let metasenv,tac = disambiguate_tactic metasenv tac in
 311         metasenv,GrafiteAst.Do (loc,n,tac)
 312     | GrafiteAst.Then (loc,tac,tacl) ->
 313         let metasenv,tac = disambiguate_tactic metasenv tac in
 314         let metasenv,tacl =
 315          List.fold_right
 316           (fun tac (metasenv,tacl) ->
 317             let metasenv,tac = disambiguate_tactic metasenv tac in
 318              metasenv,tac::tacl
 319           ) tacl (metasenv,[])
 320         in
 321          metasenv,GrafiteAst.Then (loc,tac,tacl)
 322     (* First order tactics *)
 323     | GrafiteAst.Absurd (loc, term) ->
 324         let metasenv,cic = disambiguate_term context metasenv term in
 325         metasenv,GrafiteAst.Absurd (loc, cic)
 326     | GrafiteAst.Apply (loc, term) ->
 327         let metasenv,cic = disambiguate_term context metasenv term in
 328         metasenv,GrafiteAst.Apply (loc, cic)
 329     | GrafiteAst.ApplyRule (loc, term) ->
 330         let metasenv,cic = disambiguate_term_hint context metasenv term in
 331         metasenv,GrafiteAst.ApplyRule (loc, cic)
 332     | GrafiteAst.ApplyP (loc, term) ->
 333         let metasenv,cic = disambiguate_term context metasenv term in
 334         metasenv,GrafiteAst.ApplyP (loc, cic)
 335     | GrafiteAst.ApplyS (loc, term, params) ->
 336         let metasenv, params = disambiguate_auto_params metasenv params in
 337         let metasenv,cic = disambiguate_term context metasenv term in
 338         metasenv,GrafiteAst.ApplyS (loc, cic, params)
 339     | GrafiteAst.Assumption loc ->
 340         metasenv,GrafiteAst.Assumption loc
 341     | GrafiteAst.AutoBatch (loc,params) ->
 342         let metasenv, params = disambiguate_auto_params metasenv params in
 343         metasenv,GrafiteAst.AutoBatch (loc,params)
 344     | GrafiteAst.Cases (loc, what, pattern, idents) ->
 345         let metasenv,what = disambiguate_term context metasenv what in
 346         let pattern = disambiguate_pattern pattern in
 347         metasenv,GrafiteAst.Cases (loc, what, pattern, idents)
 348     | GrafiteAst.Change (loc, pattern, with_what) ->
 349         let with_what = disambiguate_lazy_term with_what in
 350         let pattern = disambiguate_pattern pattern in
 351         metasenv,GrafiteAst.Change (loc, pattern, with_what)
 352     | GrafiteAst.Clear (loc,id) ->
 353         metasenv,GrafiteAst.Clear (loc,id)
 354     | GrafiteAst.ClearBody (loc,id) ->
 355        metasenv,GrafiteAst.ClearBody (loc,id)
 356     | GrafiteAst.Compose (loc, t1, t2, times, spec) ->
 357         let metasenv,t1 = disambiguate_term context metasenv t1 in
 358         let metasenv,t2 =
 359           match t2 with
 360           | None -> metasenv, None
 361           | Some t2 ->
 362               let m, t2 = disambiguate_term context metasenv t2 in
 363               m, Some t2
 364         in
 365         metasenv,   GrafiteAst.Compose (loc, t1, t2, times, spec)
 366     | GrafiteAst.Constructor (loc,n) ->
 367         metasenv,GrafiteAst.Constructor (loc,n)
 368     | GrafiteAst.Contradiction loc ->
 369         metasenv,GrafiteAst.Contradiction loc
 370     | GrafiteAst.Cut (loc, ident, term) ->
 371         let metasenv,cic = disambiguate_term context metasenv term in
 372         metasenv,GrafiteAst.Cut (loc, ident, cic)
 373     | GrafiteAst.Decompose (loc, names) ->
 374          metasenv,GrafiteAst.Decompose (loc, names)
 375     | GrafiteAst.Demodulate (loc, params) ->
 376         let metasenv, params = disambiguate_auto_params metasenv params in
 377         metasenv,GrafiteAst.Demodulate (loc, params)
 378     | GrafiteAst.Destruct (loc, Some terms) ->
 379         let map term (metasenv, terms) =
 380            let metasenv, term = disambiguate_term context metasenv term in
 381            metasenv, term :: terms
 382         in
 383         let metasenv, terms = List.fold_right map terms (metasenv, []) in
 384         metasenv, GrafiteAst.Destruct(loc, Some terms)
 385     | GrafiteAst.Destruct (loc, None) ->
 386         metasenv,GrafiteAst.Destruct(loc,None)
 387     | GrafiteAst.Exact (loc, term) ->
 388         let metasenv,cic = disambiguate_term context metasenv term in
 389         metasenv,GrafiteAst.Exact (loc, cic)
 390     | GrafiteAst.Elim (loc, what, Some using, pattern, specs) ->
 391         let metasenv,what = disambiguate_term context metasenv what in
 392         let metasenv,using = disambiguate_term context metasenv using in
 393         let pattern = disambiguate_pattern pattern in
 394         metasenv,GrafiteAst.Elim (loc, what, Some using, pattern, specs)
 395     | GrafiteAst.Elim (loc, what, None, pattern, specs) ->
 396         let metasenv,what = disambiguate_term context metasenv what in
 397         let pattern = disambiguate_pattern pattern in
 398         metasenv,GrafiteAst.Elim (loc, what, None, pattern, specs)
 399     | GrafiteAst.ElimType (loc, what, Some using, specs) ->
 400         let metasenv,what = disambiguate_term context metasenv what in
 401         let metasenv,using = disambiguate_term context metasenv using in
 402         metasenv,GrafiteAst.ElimType (loc, what, Some using, specs)
 403     | GrafiteAst.ElimType (loc, what, None, specs) ->
 404         let metasenv,what = disambiguate_term context metasenv what in
 405         metasenv,GrafiteAst.ElimType (loc, what, None, specs)
 406     | GrafiteAst.Exists loc ->
 407         metasenv,GrafiteAst.Exists loc
 408     | GrafiteAst.Fail loc ->
 409         metasenv,GrafiteAst.Fail loc
 410     | GrafiteAst.Fold (loc,red_kind, term, pattern) ->
 411         let pattern = disambiguate_pattern pattern in
 412         let term = disambiguate_lazy_term term in
 413         let red_kind = disambiguate_reduction_kind red_kind in
 414         metasenv,GrafiteAst.Fold (loc, red_kind, term, pattern)
 415     | GrafiteAst.FwdSimpl (loc, hyp, names) ->
 416        metasenv,GrafiteAst.FwdSimpl (loc, hyp, names)
 417     | GrafiteAst.Fourier loc ->
 418        metasenv,GrafiteAst.Fourier loc
 419     | GrafiteAst.Generalize (loc,pattern,ident) ->
 420         let pattern = disambiguate_pattern pattern in
 421         metasenv,GrafiteAst.Generalize (loc,pattern,ident)
 422     | GrafiteAst.IdTac loc ->
 423         metasenv,GrafiteAst.IdTac loc
 424     | GrafiteAst.Intros (loc, specs) ->
 425         metasenv,GrafiteAst.Intros (loc, specs)
 426     | GrafiteAst.Inversion (loc, term) ->
 427        let metasenv,term = disambiguate_term context metasenv term in
 428         metasenv,GrafiteAst.Inversion (loc, term)
 429     | GrafiteAst.LApply (loc, linear, depth, to_what, what, ident) ->
 430        let f term (metasenv, to_what) =
 431           let metasenv, term = disambiguate_term context metasenv term in
 432           metasenv, term :: to_what
 433        in
 434        let metasenv, to_what = List.fold_right f to_what (metasenv, []) in
 435        let metasenv, what = disambiguate_term context metasenv what in
 436        metasenv,GrafiteAst.LApply (loc, linear, depth, to_what, what, ident)
 437     | GrafiteAst.Left loc ->
 438        metasenv,GrafiteAst.Left loc
 439     | GrafiteAst.LetIn (loc, term, name) ->
 440         let metasenv,term = disambiguate_term context metasenv term in
 441         metasenv,GrafiteAst.LetIn (loc,term,name)
 442     | GrafiteAst.Reduce (loc, red_kind, pattern) ->
 443         let pattern = disambiguate_pattern pattern in
 444         let red_kind = disambiguate_reduction_kind red_kind in
 445         metasenv,GrafiteAst.Reduce(loc, red_kind, pattern)
 446     | GrafiteAst.Reflexivity loc ->
 447         metasenv,GrafiteAst.Reflexivity loc
 448     | GrafiteAst.Replace (loc, pattern, with_what) ->
 449         let pattern = disambiguate_pattern pattern in
 450         let with_what = disambiguate_lazy_term with_what in
 451         metasenv,GrafiteAst.Replace (loc, pattern, with_what)
 452     | GrafiteAst.Rewrite (loc, dir, t, pattern, names) ->
 453         let metasenv,term = disambiguate_term context metasenv t in
 454         let pattern = disambiguate_pattern pattern in
 455         metasenv,GrafiteAst.Rewrite (loc, dir, term, pattern, names)
 456     | GrafiteAst.Right loc ->
 457         metasenv,GrafiteAst.Right loc
 458     | GrafiteAst.Ring loc ->
 459         metasenv,GrafiteAst.Ring loc
 460     | GrafiteAst.Split loc ->
 461         metasenv,GrafiteAst.Split loc
 462     | GrafiteAst.Symmetry loc ->
 463         metasenv,GrafiteAst.Symmetry loc
 464     | GrafiteAst.Transitivity (loc, term) ->
 465         let metasenv,cic = disambiguate_term context metasenv term in
 466         metasenv,GrafiteAst.Transitivity (loc, cic)
 467       (* Nuovi casi *)
 468     | GrafiteAst.Assume (loc, id, term) ->
 469         let metasenv,cic = disambiguate_term context metasenv term in
 470         metasenv,GrafiteAst.Assume (loc, id, cic)
 471     | GrafiteAst.Suppose (loc, term, id, term') ->
 472         let metasenv,cic = disambiguate_term context metasenv term in
 473         let metasenv,cic' =
 474            match term' with
 475               None -> metasenv,None
 476             | Some t ->
 477                   let metasenv,t = disambiguate_term context metasenv t in
 478                   metasenv,Some t in
 479         metasenv,GrafiteAst.Suppose (loc, cic, id, cic')
 480     | GrafiteAst.Bydone (loc,just) ->
 481         let metasenv,just =
 482          disambiguate_just disambiguate_term context metasenv just
 483         in
 484          metasenv,GrafiteAst.Bydone (loc, just)
 485     | GrafiteAst.We_need_to_prove (loc,term,id,term') ->
 486         let metasenv,cic = disambiguate_term context metasenv term in
 487         let metasenv,cic' =
 488             match term' with
 489               None -> metasenv,None
 490             | Some t ->
 491                   let metasenv,t = disambiguate_term context metasenv t in
 492                   metasenv,Some t in
 493         metasenv,GrafiteAst.We_need_to_prove (loc,cic,id,cic')
 494     | GrafiteAst.By_just_we_proved (loc,just,term',id,term'') ->
 495         let metasenv,just =
 496          disambiguate_just disambiguate_term context metasenv just in
 497         let metasenv,cic' = disambiguate_term context metasenv term' in
 498         let metasenv,cic'' =
 499             match term'' with
 500               None -> metasenv,None
 501            |  Some t ->
 502                     let metasenv,t = disambiguate_term context metasenv t in
 503                      metasenv,Some t in
 504         metasenv,GrafiteAst.By_just_we_proved (loc,just,cic',id,cic'')
 505     | GrafiteAst.We_proceed_by_cases_on (loc, term, term') ->
 506         let metasenv,cic = disambiguate_term context metasenv term in
 507         let metasenv,cic' = disambiguate_term context metasenv term' in
 508         metasenv,GrafiteAst.We_proceed_by_cases_on (loc, cic, cic')
 509     | GrafiteAst.We_proceed_by_induction_on (loc, term, term') ->
 510         let metasenv,cic = disambiguate_term context metasenv term in
 511         let metasenv,cic' = disambiguate_term context metasenv term' in
 512         metasenv,GrafiteAst.We_proceed_by_induction_on (loc, cic, cic')
 513    | GrafiteAst.Byinduction (loc, term, id) ->
 514         let metasenv,cic = disambiguate_term context metasenv term in
 515         metasenv,GrafiteAst.Byinduction(loc, cic, id)
 516    | GrafiteAst.Thesisbecomes (loc, term) ->
 517         let metasenv,cic = disambiguate_term context metasenv term in
 518         metasenv,GrafiteAst.Thesisbecomes (loc, cic)
 519    | GrafiteAst.ExistsElim (loc, just, id1, term1, id2, term2) ->
 520         let metasenv,just =
 521          disambiguate_just disambiguate_term context metasenv just in
 522         let metasenv,cic' = disambiguate_term context metasenv term1 in
 523         let cic''= disambiguate_lazy_term term2 in
 524         metasenv,GrafiteAst.ExistsElim(loc, just, id1, cic', id2, cic'')
 525    | GrafiteAst.AndElim (loc, just, id, term1, id1, term2) ->
 526         let metasenv,just =
 527          disambiguate_just disambiguate_term context metasenv just in
 528         let metasenv,cic'= disambiguate_term context metasenv term1 in
 529         let metasenv,cic''= disambiguate_term context metasenv term2 in
 530         metasenv,GrafiteAst.AndElim(loc, just, id, cic', id1, cic'')
 531    | GrafiteAst.Case (loc, id, params) ->
 532         let metasenv,params' =
 533          List.fold_right
 534           (fun (id,term) (metasenv,params) ->
 535             let metasenv,cic = disambiguate_term context metasenv term in
 536              metasenv,(id,cic)::params
 537           ) params (metasenv,[])
 538         in
 539         metasenv,GrafiteAst.Case(loc, id, params')
 540    | GrafiteAst.RewritingStep (loc, term1, term2, term3, cont) ->
 541         let metasenv,cic =
 542          match term1 with
 543             None -> metasenv,None
 544           | Some (start,t) ->
 545              let metasenv,t = disambiguate_term context metasenv t in
 546               metasenv,Some (start,t) in
 547         let metasenv,cic'= disambiguate_term context metasenv term2 in
 548         let metasenv,cic'' =
 549          match term3 with
 550           | `SolveWith term ->
 551              let metasenv,term = disambiguate_term context metasenv term in
 552              metasenv, `SolveWith term
 553           | `Auto params ->
 554               let metasenv, params = disambiguate_auto_params metasenv params in
 555               metasenv,`Auto params
 556           | `Term t ->
 557              let metasenv,t = disambiguate_term context metasenv t in
 558               metasenv,`Term t
 559           | `Proof as t -> metasenv,t in
 560         metasenv,GrafiteAst.RewritingStep (loc, cic, cic', cic'', cont)
 561
 562 let disambiguate_obj lexicon_status ?baseuri metasenv (text,prefix_len,obj) =
 563   let uri =
 564    match obj with
 565     | CicNotationPt.Inductive (_,(name,_,_,_)::_)
 566     | CicNotationPt.Record (_,name,_,_) ->
 567        (match baseuri with
 568          | Some baseuri ->
 569             Some (UriManager.uri_of_string (baseuri ^ "/" ^ name ^ ".ind"))
 570          | None -> raise BaseUriNotSetYet)
 571     | CicNotationPt.Inductive _ -> assert false
 572     | CicNotationPt.Theorem _ -> None in
 573   let time = Unix.gettimeofday () in
 574   let (diff, metasenv, _, cic, _) =
 575     singleton "third"
 576       (CicDisambiguate.disambiguate_obj
 577         ~lookup_in_library
 578         ~mk_choice:cic_mk_choice
 579         ~mk_implicit
 580         ~description_of_alias:LexiconAst.description_of_alias
 581         ~aliases:lexicon_status.LexiconEngine.aliases
 582         ~universe:(Some lexicon_status.LexiconEngine.multi_aliases) ~uri
 583         (text,prefix_len,obj)) in
 584
 585   let time = Unix.gettimeofday () -. time in
 586   prerr_endline ("VECCHIA DISAMBIGUAZIONE: " ^ string_of_float time);
 587   (NCicLibrary.clear_cache ();
 588    NCicEnvironment.invalidate ();
 589    OCic2NCic.clear ();
 590    prerr_endline "INIZIO NUOVA DISAMBIGUAZIONE";
 591    (match obj with
 592       CicNotationPt.Theorem (_,_,ty,_) ->
 593    let graph =
 594      match cic with
 595      | Cic.CurrentProof (_,metasenv, _, ty,_,_) ->
 596          let _, ugraph =
 597            CicTypeChecker.type_of_aux' metasenv [] ty CicUniv.empty_ugraph
 598          in
 599            ugraph
 600      | Cic.Constant (_,_, ty,_,_) ->
 601          let _, ugraph =
 602                  CicTypeChecker.type_of_aux' [] [] ty CicUniv.empty_ugraph
 603          in
 604            ugraph
 605      | _ -> CicUniv.empty_ugraph
 606    in
 607 (*
 608    let _,l = CicUniv.do_rank graph in
 609    List.iter (fun k ->
 610      prerr_endline (CicUniv.string_of_universe k ^ " = " ^ string_of_int
 611      (CicUniv.get_rank k))) l;
 612 *)
 613    let graph =
 614        List.fold_left
 615          (fun graph (_,_,l) ->
 616            List.fold_left
 617              (fun graph (uri,_,_) ->
 618                 let _,g = CicTypeChecker.typecheck uri in
 619                 CicUniv.merge_ugraphs ~base_ugraph:graph ~increment:(g,uri))
 620              graph l)
 621        graph (CoercDb.to_list ())
 622    in
 623    ignore(CicUniv.do_rank graph);
 624    let time = Unix.gettimeofday () in
 625        (try
 626          (match
 627           NCicDisambiguate.disambiguate_term
 628            ~lookup_in_library:lookup_in_library
 629            ~description_of_alias:LexiconAst.description_of_alias
 630            ~mk_choice:ncic_mk_choice
 631            ~mk_implicit
 632            ~coercion_db:(NCicCoercion.db ())
 633            ~context:[] ~metasenv:[] ~subst:[]
 634            ~aliases:lexicon_status.LexiconEngine.aliases
 635            ~universe:(Some lexicon_status.LexiconEngine.multi_aliases)
 636            (text,prefix_len,ty)
 637          with
 638          | [_,metasenv,subst,ty],_ ->
 639           let time = Unix.gettimeofday () -. time in
 640           prerr_endline ("NUOVA DISAMBIGUAZIONE OK: "^ string_of_float time);
 641           prerr_endline (NCicPp.ppterm ~metasenv ~subst ~context:[] ty)
 642          | _ ->
 643           prerr_endline ("NUOVA DISAMBIGUAZIONE AMBIGUO!!!!!!!!!  "))
 644        with
 645        | MultiPassDisambiguator.DisambiguationError (_,s) ->
 646         prerr_endline ("ERRORE NUOVA DISAMBIGUAZIONE:\n" ^
 647          String.concat "\n"
 648           (List.map (fun _,_,x,_ -> snd (Lazy.force x)) (List.flatten s)))
 649 (*        | exn -> prerr_endline (Printexc.to_string exn) *)
 650        )
 651     | _ -> ())
 652   );
 653
 654   let lexicon_status = LexiconEngine.set_proof_aliases lexicon_status diff in
 655   lexicon_status, metasenv, cic
 656
 657 let disambiguate_command lexicon_status ?baseuri metasenv (text,prefix_len,cmd)=
 658   match cmd with
 659    | GrafiteAst.Index(loc,key,uri) ->
 660        let lexicon_status_ref = ref lexicon_status in
 661        let disambiguate_term =
 662          disambiguate_term None text prefix_len lexicon_status_ref [] in
 663        let disambiguate_term_option metasenv =
 664          function
 665              None -> metasenv,None
 666            | Some t ->
 667                let metasenv,t = disambiguate_term metasenv t in
 668                  metasenv, Some t
 669        in
 670        let metasenv,key = disambiguate_term_option metasenv key in
 671        !lexicon_status_ref, metasenv,GrafiteAst.Index(loc,key,uri)
 672    | GrafiteAst.Coercion (loc,t,b,a,s) ->
 673        let lexicon_status_ref = ref lexicon_status in
 674        let disambiguate_term =
 675          disambiguate_term None text prefix_len lexicon_status_ref [] in
 676       let metasenv,t = disambiguate_term metasenv t in
 677       !lexicon_status_ref, metasenv, GrafiteAst.Coercion (loc,t,b,a,s)
 678    | GrafiteAst.Default _
 679    | GrafiteAst.Drop _
 680    | GrafiteAst.Include _
 681    | GrafiteAst.Print _
 682    | GrafiteAst.Qed _
 683    | GrafiteAst.Set _ as cmd ->
 684        lexicon_status,metasenv,cmd
 685    | GrafiteAst.Obj (loc,obj) ->
 686        let lexicon_status,metasenv,obj =
 687         disambiguate_obj lexicon_status ?baseuri metasenv (text,prefix_len,obj)in
 688        lexicon_status, metasenv, GrafiteAst.Obj (loc,obj)
 689    | GrafiteAst.Relation (loc,id,a,aeq,refl,sym,trans) ->
 690       let lexicon_status_ref = ref lexicon_status in
 691       let disambiguate_term =
 692        disambiguate_term None text prefix_len lexicon_status_ref [] in
 693       let disambiguate_term_option metasenv =
 694        function
 695           None -> metasenv,None
 696        | Some t ->
 697           let metasenv,t = disambiguate_term metasenv t in
 698            metasenv, Some t
 699       in
 700       let metasenv,a = disambiguate_term metasenv a in
 701       let metasenv,aeq = disambiguate_term metasenv aeq in
 702       let metasenv,refl = disambiguate_term_option metasenv refl in
 703       let metasenv,sym = disambiguate_term_option metasenv sym in
 704       let metasenv,trans = disambiguate_term_option metasenv trans in
 705        !lexicon_status_ref, metasenv,
 706         GrafiteAst.Relation (loc,id,a,aeq,refl,sym,trans)
 707
 708 let disambiguate_macro
 709   lexicon_status_ref metasenv context (text,prefix_len, macro)
 710 =
 711  let disambiguate_term = disambiguate_term None text prefix_len lexicon_status_ref in
 712   let disambiguate_reduction_kind =
 713     disambiguate_reduction_kind text prefix_len lexicon_status_ref in
 714   match macro with
 715    | GrafiteAst.WMatch (loc,term) ->
 716       let metasenv,term = disambiguate_term context metasenv term in
 717        metasenv,GrafiteAst.WMatch (loc,term)
 718    | GrafiteAst.WInstance (loc,term) ->
 719       let metasenv,term = disambiguate_term context metasenv term in
 720        metasenv,GrafiteAst.WInstance (loc,term)
 721    | GrafiteAst.WElim (loc,term) ->
 722       let metasenv,term = disambiguate_term context metasenv term in
 723        metasenv,GrafiteAst.WElim (loc,term)
 724    | GrafiteAst.WHint (loc,term) ->
 725       let metasenv,term = disambiguate_term context metasenv term in
 726        metasenv,GrafiteAst.WHint (loc,term)
 727    | GrafiteAst.Check (loc,term) ->
 728       let metasenv,term = disambiguate_term context metasenv term in
 729        metasenv,GrafiteAst.Check (loc,term)
 730    | GrafiteAst.Eval (loc,kind,term) ->
 731       let metasenv, term = disambiguate_term context metasenv term in
 732       let kind = disambiguate_reduction_kind kind in
 733        metasenv,GrafiteAst.Eval (loc,kind,term)
 734    | GrafiteAst.AutoInteractive (loc, params) ->
 735       let metasenv, params =
 736         disambiguate_auto_params disambiguate_term metasenv context params in
 737       metasenv, GrafiteAst.AutoInteractive (loc, params)
 738    | GrafiteAst.Hint _
 739    | GrafiteAst.WLocate _
 740    | GrafiteAst.Inline _ as macro ->
 741       metasenv,macro