helm/software/components/lexicon/lexiconEngine.ml

   1 (* Copyright (C) 2004-2005, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://helm.cs.unibo.it/
  24  *)
  25
  26 (* $Id$ *)
  27
  28 module L = LexiconAst
  29
  30 let debug = ref false
  31
  32 (* lexicon file name * ma file name *)
  33 exception IncludedFileNotCompiled of string * string
  34 exception MetadataNotFound of string        (* file name *)
  35
  36 type lexicon_status = {
  37   aliases: L.alias_spec DisambiguateTypes.Environment.t;
  38   multi_aliases: L.alias_spec list DisambiguateTypes.Environment.t;
  39   lexicon_content_rev: LexiconMarshal.lexicon;
  40   notation_ids: CicNotation.notation_id list;      (** in-scope notation ids *)
  41 }
  42
  43 let initial_status = {
  44   aliases = DisambiguateTypes.Environment.empty;
  45   multi_aliases = DisambiguateTypes.Environment.empty;
  46   lexicon_content_rev = [];
  47   notation_ids = [];
  48 }
  49
  50 class type g_status =
  51  object
  52   method lstatus: lexicon_status
  53  end
  54
  55 class status =
  56  object(self)
  57   val lstatus = initial_status
  58   method lstatus = lstatus
  59   method set_lstatus v = {< lstatus = v >}
  60   method set_lexicon_engine_status : 'status. #g_status as 'status -> 'self
  61    = fun o -> self#set_lstatus o#lstatus
  62  end
  63
  64 let dump_aliases out msg status =
  65    out (if msg = "" then "aliases dump:" else msg ^ ": aliases dump:");
  66    DisambiguateTypes.Environment.iter
  67       (fun _ x -> out (LexiconAstPp.pp_alias x))
  68       status#lstatus.aliases
  69
  70 let add_lexicon_content cmds status =
  71   let content = status#lstatus.lexicon_content_rev in
  72   let content' =
  73     List.fold_right
  74      (fun cmd acc ->
  75         match cmd with
  76         | L.Alias _
  77         | L.Include _
  78         | L.Notation _ -> cmd :: (List.filter ((<>) cmd) acc)
  79         | L.Interpretation _ -> if List.exists ((=) cmd) acc then acc else cmd::acc)
  80      cmds content
  81   in
  82 (*
  83   prerr_endline ("new lexicon content: " ^
  84      String.concat "; " (List.map LexiconAstPp.pp_command content')
  85   );
  86 *)
  87   status#set_lstatus
  88    { status#lstatus with lexicon_content_rev = content' }
  89
  90 let set_proof_aliases mode status new_aliases =
  91  if mode = L.WithoutPreferences then
  92    status
  93  else
  94    let commands_of_aliases =
  95      List.map
  96       (fun _,alias -> L.Alias (HExtlib.dummy_floc, alias))
  97    in
  98    let aliases =
  99     List.fold_left (fun acc (d,c) -> DisambiguateTypes.Environment.add d c acc)
 100      status#lstatus.aliases new_aliases in
 101    let multi_aliases =
 102     List.fold_left (fun acc (d,c) ->
 103       DisambiguateTypes.Environment.cons L.description_of_alias
 104          d c acc)
 105      status#lstatus.multi_aliases new_aliases
 106    in
 107    let new_status =
 108      { status#lstatus with
 109         multi_aliases = multi_aliases ; aliases = aliases} in
 110    let new_status = status#set_lstatus new_status in
 111     if new_aliases = [] then
 112       new_status
 113     else
 114       add_lexicon_content (commands_of_aliases new_aliases) new_status
 115
 116 let rec eval_command ?(mode=L.WithPreferences) sstatus cmd =
 117 (*
 118  let bmode = match mode with L.WithPreferences -> true | _ -> false in
 119  Printf.eprintf "Include preferences: %b\n" bmode;
 120 *)
 121  let status = sstatus#lstatus in
 122  let cmd =
 123   match cmd with
 124   | L.Interpretation (loc, dsc, (symbol, args), cic_appl_pattern) ->
 125      let rec disambiguate =
 126       function
 127          CicNotationPt.ApplPattern l ->
 128           CicNotationPt.ApplPattern (List.map disambiguate l)
 129        | CicNotationPt.VarPattern id
 130           when not
 131            (List.exists
 132             (function (CicNotationPt.IdentArg (_,id')) -> id'=id) args)
 133           ->
 134            let item = DisambiguateTypes.Id id in
 135             begin try
 136               match DisambiguateTypes.Environment.find item status.aliases with
 137                  L.Ident_alias (_, uri) ->
 138                   (try
 139                     CicNotationPt.NRefPattern
 140                      (NReference.reference_of_string uri)
 141                    with
 142                     NReference.IllFormedReference _ ->
 143                      CicNotationPt.UriPattern (UriManager.uri_of_string uri))
 144                | _ -> assert false
 145              with Not_found ->
 146               prerr_endline ("LexiconEngine.eval_command: domain item not found: " ^
 147                (DisambiguateTypes.string_of_domain_item item));
 148               dump_aliases prerr_endline "" sstatus;
 149               raise (Failure (
 150                       (DisambiguateTypes.string_of_domain_item item) ^
 151                       " not found"));
 152             end
 153        | p -> p
 154      in
 155       L.Interpretation
 156        (loc, dsc, (symbol, args), disambiguate cic_appl_pattern)
 157   | _-> cmd
 158  in
 159  let notation_ids' = CicNotation.process_notation cmd in
 160  let status =
 161    { status with notation_ids = notation_ids' @ status.notation_ids } in
 162  let sstatus = sstatus#set_lstatus status in
 163   match cmd with
 164   | L.Include (loc, baseuri, mode, fullpath) ->
 165      let lexiconpath_rw, lexiconpath_r =
 166        LibraryMisc.lexicon_file_of_baseuri
 167          ~must_exist:false ~writable:true ~baseuri,
 168        LibraryMisc.lexicon_file_of_baseuri
 169          ~must_exist:false ~writable:false ~baseuri
 170      in
 171      let lexiconpath =
 172        if Sys.file_exists lexiconpath_rw then lexiconpath_rw else
 173          if Sys.file_exists lexiconpath_r then lexiconpath_r else
 174           raise (IncludedFileNotCompiled (lexiconpath_rw,fullpath))
 175      in
 176      let lexicon = LexiconMarshal.load_lexicon lexiconpath in
 177       List.fold_left (eval_command ~mode) sstatus lexicon
 178   | L.Alias (loc, spec) ->
 179      let diff =
 180       (*CSC: Warning: this code should be factorized with the corresponding
 181              code in DisambiguatePp *)
 182       match spec with
 183       | L.Ident_alias (id,uri) ->
 184          [DisambiguateTypes.Id id,spec]
 185       | L.Symbol_alias (symb, instance, desc) ->
 186          [DisambiguateTypes.Symbol (symb,instance),spec]
 187       | L.Number_alias (instance,desc) ->
 188          [DisambiguateTypes.Num instance,spec]
 189      in
 190       set_proof_aliases mode sstatus diff
 191   | L.Interpretation (_, dsc, (symbol, _), _) as stm ->
 192       let sstatus = add_lexicon_content [stm] sstatus in
 193       let diff =
 194        try
 195         [DisambiguateTypes.Symbol (symbol, 0),
 196           L.Symbol_alias (symbol,0,dsc)]
 197        with
 198         DisambiguateChoices.Choice_not_found msg ->
 199           prerr_endline (Lazy.force msg);
 200           assert false
 201       in
 202       let sstatus = set_proof_aliases mode sstatus diff in
 203       sstatus
 204   | L.Notation _ as stm ->
 205       add_lexicon_content [stm] sstatus
 206
 207 let eval_command status cmd =
 208    if !debug then dump_aliases prerr_endline "before eval_command" status;
 209    let status = eval_command ?mode:None status cmd in
 210    if !debug then dump_aliases prerr_endline "after eval_command" status;
 211    status
 212
 213 let set_proof_aliases status aliases =
 214    if !debug then dump_aliases prerr_endline "before set_proof_aliases" status;
 215    let status = set_proof_aliases L.WithPreferences status aliases in
 216    if !debug then dump_aliases prerr_endline "after set_proof_aliases" status;
 217    status