helm/software/components/library/librarian.ml

   1 (* Copyright (C) 2005, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://helm.cs.unibo.it/
  24  *)
  25
  26 let debug = ref false
  27
  28 let time_stamp =
  29    let old = ref 0.0 in
  30    fun msg ->
  31       if !debug then begin
  32          let times = Unix.times () in
  33          let stamp = times.Unix.tms_utime +. times.Unix.tms_stime in
  34          let lap = stamp -. !old in
  35          Printf.eprintf "TIME STAMP (%s): %f\n" msg lap; flush stderr;
  36          old := stamp
  37       end
  38
  39 exception NoRootFor of string
  40
  41 let absolutize path =
  42  let path =
  43    if String.length path > 0 && path.[0] <> '/' then
  44      Sys.getcwd () ^ "/" ^ path
  45    else
  46      path
  47  in
  48    HExtlib.normalize_path path
  49 ;;
  50
  51
  52 let find_root path =
  53   let path = absolutize path in
  54   let paths = List.rev (Str.split (Str.regexp "/") path) in
  55   let rec build = function
  56     | he::tl as l -> ("/" ^ String.concat "/" (List.rev l) ^ "/") :: build tl
  57     | [] -> ["/"]
  58   in
  59   let paths = List.map HExtlib.normalize_path (build paths) in
  60   try HExtlib.find_in paths "root"
  61   with Failure "find_in" ->
  62     raise (NoRootFor (path ^ " (" ^ String.concat ", " paths ^ ")"))
  63 ;;
  64
  65 let ensure_trailing_slash s =
  66   if s = "" then "/" else
  67   if s.[String.length s-1] <> '/' then s^"/" else s
  68 ;;
  69
  70 let remove_trailing_slash s =
  71   if s = "" then "" else
  72   let len = String.length s in
  73   if s.[len-1] = '/' then String.sub s 0 (len-1) else s
  74 ;;
  75
  76 let load_root_file rootpath =
  77   let data = HExtlib.input_file rootpath in
  78   let lines = Str.split (Str.regexp "\n") data in
  79   let clean s =
  80     Pcre.replace ~pat:"[ \t]+" ~templ:" "
  81       (Pcre.replace ~pat:"^ *" (Pcre.replace ~pat:" *$" s))
  82   in
  83   List.map
  84     (fun l ->
  85       match Str.split (Str.regexp "=") l with
  86       | [k;v] -> clean k, Http_getter_misc.strip_trailing_slash (clean v)
  87       | _ -> raise (Failure ("Malformed root file: " ^ rootpath)))
  88     lines
  89 ;;
  90
  91 let rec find_root_for ~include_paths file =
  92  let include_paths = "" :: Sys.getcwd () :: include_paths in
  93  try
  94    let path = HExtlib.find_in include_paths file in
  95    let path = absolutize path in
  96 (*     HLog.debug ("file "^file^" resolved as "^path);  *)
  97    let rootpath, root, buri =
  98      try
  99        let mburi = Helm_registry.get "matita.baseuri" in
 100        match Str.split (Str.regexp " ") mburi with
 101        | [root; buri] when HExtlib.is_prefix_of root path ->
 102            ":registry:", root, buri
 103        | _ -> raise (Helm_registry.Key_not_found "matita.baseuri")
 104      with Helm_registry.Key_not_found "matita.baseuri" ->
 105        let rootpath = find_root path in
 106        let buri = List.assoc "baseuri" (load_root_file rootpath) in
 107        rootpath, Filename.dirname rootpath, buri
 108    in
 109 (*     HLog.debug ("file "^file^" rooted by "^rootpath^"");  *)
 110    let uri = Http_getter_misc.strip_trailing_slash buri in
 111    if String.length uri < 5 || String.sub uri 0 5 <> "cic:/" then
 112      HLog.error (rootpath ^ " sets an incorrect baseuri: " ^ buri);
 113    ensure_trailing_slash root, remove_trailing_slash uri, path
 114  with Failure "find_in" ->
 115    if Filename.check_suffix file ".ma" then begin
 116       let mma = Filename.chop_suffix file ".ma" ^ ".mma" in
 117       HLog.warn ("We look for: " ^ mma);
 118       find_root_for ~include_paths mma
 119    end else begin
 120       HLog.error ("We are in: " ^ Sys.getcwd ());
 121       HLog.error ("Unable to find: "^file^"\nPaths explored:");
 122       List.iter (fun x -> HLog.error (" - "^x)) include_paths;
 123       raise (NoRootFor file)
 124    end
 125 ;;
 126
 127 let mk_baseuri root extra =
 128   let chop name =
 129     assert(Filename.check_suffix name ".ma" ||
 130       Filename.check_suffix name ".mma");
 131     try Filename.chop_extension name
 132     with Invalid_argument "Filename.chop_extension" -> name
 133   in
 134    remove_trailing_slash (HExtlib.normalize_path (root ^ "/" ^ chop extra))
 135 ;;
 136
 137 let baseuri_of_script ~include_paths file =
 138   let root, buri, path = find_root_for ~include_paths file in
 139   let path = HExtlib.normalize_path path in
 140   let root = HExtlib.normalize_path root in
 141   let lpath = Str.split (Str.regexp "/") path in
 142   let lroot = Str.split (Str.regexp "/") root in
 143   let rec substract l1 l2 =
 144     match l1, l2 with
 145     | h1::tl1,h2::tl2 when h1 = h2 -> substract tl1 tl2
 146     | l,[] -> l
 147     | _ -> raise (NoRootFor (file ^" "^path^" "^root))
 148   in
 149   let extra_buri = substract lpath lroot in
 150   let extra = String.concat "/" extra_buri in
 151    root,
 152    mk_baseuri buri extra,
 153    path,
 154    extra
 155 ;;
 156
 157 let find_roots_in_dir dir =
 158   HExtlib.find ~test:(fun f ->
 159     Filename.basename f = "root" &&
 160     try (Unix.stat f).Unix.st_kind = Unix.S_REG
 161     with Unix.Unix_error _ -> false)
 162     dir
 163 ;;
 164
 165 (* make *)
 166 let load_deps_file f =
 167   let deps = ref [] in
 168   let ic = open_in f in
 169   try
 170     while true do
 171       begin
 172         let l = input_line ic in
 173         match Str.split (Str.regexp " ") l with
 174         | [] ->
 175             HLog.error ("Malformed deps file: " ^ f);
 176             raise (Failure ("Malformed deps file: " ^ f))
 177         | he::tl -> deps := (he,tl) :: !deps
 178       end
 179     done; !deps
 180     with End_of_file -> !deps
 181 ;;
 182
 183 type options = (string * string) list
 184
 185 module type Format =
 186   sig
 187     type source_object
 188     type target_object
 189     val load_deps_file: string -> (source_object * source_object list) list
 190     val string_of_source_object: source_object -> string
 191     val string_of_target_object: target_object -> string
 192     val build: options -> source_object -> bool
 193     val root_and_target_of:
 194           options -> source_object -> string option * target_object
 195     val mtime_of_source_object: source_object -> float option
 196     val mtime_of_target_object: target_object -> float option
 197     val is_readonly_buri_of: options -> source_object -> bool
 198   end
 199
 200 module Make = functor (F:Format) -> struct
 201
 202   type status = Done of bool
 203               | Ready of bool
 204
 205   let say s = if !debug then prerr_endline ("make: "^s);;
 206
 207   let unopt_or_call x f y = match x with Some _ -> x | None -> f y;;
 208
 209   let fst4 = function (x,_,_,_) -> x;;
 210
 211   let modified_before_s_t (_,cs, ct, _, _) a b =
 212     let a = try Hashtbl.find cs a with Not_found -> assert false in
 213     let b =
 214       try
 215         match Hashtbl.find ct b with
 216         | Some _ as x -> x
 217         | None ->
 218            match F.mtime_of_target_object b with
 219            | Some t as x ->
 220                Hashtbl.remove ct b;
 221                Hashtbl.add ct b x; x
 222            | x -> x
 223       with Not_found -> assert false
 224     in
 225     match a, b with
 226        | Some a, Some b -> a <= b
 227        | _ -> false
 228   ;;
 229
 230   let modified_before_t_t (_,_,ct, _, _) a b =
 231     let a =
 232       try
 233         match Hashtbl.find ct a with
 234         | Some _ as x -> x
 235         | None ->
 236            match F.mtime_of_target_object a with
 237            | Some t as x ->
 238                Hashtbl.remove ct a;
 239                Hashtbl.add ct a x; x
 240            | x -> x
 241       with Not_found -> assert false
 242     in
 243     let b =
 244       try
 245         match Hashtbl.find ct b with
 246         | Some _ as x -> x
 247         | None ->
 248            match F.mtime_of_target_object b with
 249            | Some t as x ->
 250                Hashtbl.remove ct b;
 251                Hashtbl.add ct b x; x
 252            | x -> x
 253       with Not_found -> assert false
 254     in
 255     match a, b with
 256     | Some a, Some b ->
 257        a <= b
 258     | _ -> false
 259   ;;
 260
 261   let rec purge_unwanted_roots wanted deps =
 262     let roots, rest =
 263        List.partition
 264          (fun (t,d,_,_) ->
 265            not (List.exists (fun (_,d1,_,_) -> List.mem t d1) deps))
 266          deps
 267     in
 268     let newroots = List.filter (fun (t,_,_,_) -> List.mem t wanted) roots in
 269     if newroots = roots then
 270       deps
 271     else
 272       purge_unwanted_roots wanted (newroots @ rest)
 273   ;;
 274
 275   let is_not_ro (opts,_,_,_,_) (f,_,r,_) =
 276     match r with
 277     | Some root -> not (F.is_readonly_buri_of opts f)
 278     | None -> assert false
 279   ;;
 280 (* FG: Old sorting algorithm ************************************************)
 281 (*
 282   let rec get_status opts what =
 283      let _, _, _, cc, cd = opts in
 284      let t, dependencies, root, tgt = what in
 285      try Done (Hashtbl.find cc t)
 286 (* say "already built" *)
 287      with Not_found ->
 288         let map st d = match st with
 289            | Done false  -> st
 290            | Ready false -> st
 291            | _           ->
 292               let whatd = Hashtbl.find cd d in
 293               let _, _, _, tgtd = whatd in
 294               begin match st, get_status opts whatd with
 295                  | _, Done false         -> Hashtbl.add cc t false; Done false
 296                  | Done true, Done true  ->
 297                     if modified_before_t_t opts tgt tgtd then Ready true else Done true
 298 (* say (F.string_of_source_object t^" depends on "^F.string_of_target_object unsat^" and "^F.string_of_source_object t^".o is younger than "^ F.string_of_target_object unsat^", thus needs to be built") *)
 299                  | Done true, Ready _    -> Ready false
 300                  | Ready true, Ready _   -> Ready false
 301 (* say (F.string_of_source_object t^" depends on "^ F.string_of_source_object (fst4 unsat)^ " that is not built, thus is not ready") *)
 302                  | Ready true, Done true -> Ready true
 303                  | _                     -> st
 304               end
 305         in
 306         let st = if modified_before_s_t opts t tgt then Done true else Ready true in
 307         match List.fold_left map st dependencies with
 308            | Done true -> Hashtbl.add cc t true; Done true
 309 (* say(F.string_of_source_object t^" is built" *)
 310            | st     -> st
 311
 312   let list_partition_filter_rev filter l =
 313      let rec aux l1 l2 = function
 314         | []       -> l1, l2
 315         | hd :: tl ->
 316            begin match filter hd with
 317               | None       -> aux l1 l2 tl
 318               | Some true  -> aux (hd :: l1) l2 tl
 319               | Some false -> aux l1 (hd :: l2) tl
 320            end
 321      in
 322      aux [] [] l
 323
 324   let rec make_aux root (lo,_,ct, cc, _ as opts) ok deps =
 325     time_stamp "filter get_status: begin";
 326     let map what = match get_status opts what with
 327        | Done _  -> None
 328        | Ready b -> Some b
 329     in
 330     let todo, deps = list_partition_filter_rev map deps in
 331     time_stamp "filter get_status: end";
 332     let todo =
 333       let local, remote =
 334         List.partition (fun (_,_,froot,_) -> froot = Some root) todo
 335       in
 336       let local, skipped = List.partition (is_not_ro opts) local in
 337       List.iter
 338        (fun x ->
 339         HLog.warn("Read only baseuri for: "^F.string_of_source_object(fst4 x)))
 340        skipped;
 341       remote @ local
 342     in
 343     if todo <> [] then begin
 344        let ok = List.fold_left
 345           (fun ok (file,_,froot,tgt) ->
 346             let rc =
 347               match froot with
 348               | Some froot when froot = root ->
 349                   Hashtbl.remove ct tgt;
 350                   Hashtbl.add ct tgt None;
 351                   time_stamp "building";
 352                   let r = F.build lo file in
 353                   time_stamp "done"; r
 354               | Some froot -> make froot [file]
 355               | None ->
 356                   HLog.error ("No root for: "^F.string_of_source_object file);
 357                   false
 358             in
 359             Hashtbl.add cc file rc;
 360             ok && rc
 361           )
 362           ok (List.rev todo)
 363        in
 364       make_aux root opts ok (List.rev deps)
 365     end
 366     else
 367       ok
 368 *)
 369 (* FG: new sorting algorithm ************************************************)
 370
 371   let rec make_aux root opts ok deps =
 372     List.fold_left (make_one root opts) ok deps
 373
 374   and make_one root opts ok what =
 375     let lo, _, ct, cc, cd = opts in
 376     let t, deps, froot, tgt = what in
 377     let str = F.string_of_source_object t in
 378     let map (okd, okt) d =
 379        let (_, _, _, tgtd) as whatd = (Hashtbl.find cd d) in
 380        let r = make_one root opts okd whatd in
 381        r, okt && modified_before_t_t opts tgtd tgt
 382     in
 383     try
 384        let r = Hashtbl.find cc t in
 385        ok && r
 386 (* say "already built" *)
 387     with Not_found ->
 388        let okd, okt = List.fold_left map (true, modified_before_s_t opts t tgt) deps in
 389        let res =
 390           if okd then
 391           if okt then true else
 392           match froot with
 393              | Some froot when froot = root ->
 394                 if is_not_ro opts what then begin
 395                    Hashtbl.remove ct tgt;
 396                    Hashtbl.add ct tgt None;
 397                    time_stamp ("L : BUILDING " ^ str);
 398                    let res = F.build lo t in
 399                    time_stamp ("L : DONE     " ^ str); res
 400                 end else begin
 401                    HLog.warn("Read only baseuri for: "^ str); false
 402                 end
 403              | Some froot -> make froot [t]
 404              | None ->
 405                 HLog.error ("No root for: " ^ str); false
 406           else false
 407        in
 408        Hashtbl.add cc t res; ok && res
 409
 410 (****************************************************************************)
 411
 412   and make root targets =
 413     time_stamp "L : ENTERING";
 414     HLog.debug ("Entering directory '"^root^"'");
 415     let old_root = Sys.getcwd () in
 416     Sys.chdir root;
 417     let deps = F.load_deps_file (root^"/depends") in
 418     let local_options = load_root_file (root^"/root") in
 419     let caches,cachet,cachec,cached =
 420        Hashtbl.create 73, Hashtbl.create 73, Hashtbl.create 73, Hashtbl.create 73
 421     in
 422     (* deps are enriched with these informations to sped up things later *)
 423     let deps =
 424       List.map
 425         (fun (file,d) ->
 426           let r,tgt = F.root_and_target_of local_options file in
 427           Hashtbl.add caches file (F.mtime_of_source_object file);
 428           Hashtbl.add cachet tgt (F.mtime_of_target_object tgt);
 429           Hashtbl.add cached file (file, d, r, tgt);
 430           (file, d, r, tgt)
 431         )
 432         deps
 433     in
 434     let opts = local_options, caches, cachet, cachec, cached in
 435     let ok =
 436       if targets = [] then
 437         make_aux root opts true deps
 438       else
 439         make_aux root opts true
 440           (purge_unwanted_roots targets deps)
 441     in
 442     HLog.debug ("Leaving directory '"^root^"'");
 443     Sys.chdir old_root;
 444     time_stamp "L : LEAVING";
 445     ok
 446   ;;
 447
 448 end
 449
 450 let write_deps_file where deps = match where with
 451    | Some root ->
 452       let oc = open_out (root ^ "/depends") in
 453       let map (t, d) = output_string oc (t^" "^String.concat " " d^"\n") in
 454       List.iter map deps; close_out oc;
 455       HLog.message ("Generated: " ^ root ^ "/depends")
 456    | None ->
 457       print_endline (String.concat " " (List.flatten (List.map snd deps)))
 458
 459 (* FG ***********************************************************************)
 460
 461 (* scheme uri part as defined in URI Generic Syntax (RFC 3986) *)
 462 let uri_scheme_rex = Pcre.regexp "^[[:alpha:]][[:alnum:]\-+.]*:"
 463
 464 let is_uri str =
 465    Pcre.pmatch ~rex:uri_scheme_rex str