helm/software/components/library/librarySync.ml

   1 (* Copyright (C) 2004-2005, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://helm.cs.unibo.it/
  24  *)
  25
  26 (* $Id$ *)
  27
  28 let object_declaration_hook = ref (fun _ _ -> ());;
  29 let set_object_declaration_hook f =
  30  object_declaration_hook := f
  31
  32 exception AlreadyDefined of UriManager.uri
  33
  34 let auxiliary_lemmas_hashtbl = UriManager.UriHashtbl.create 29
  35
  36 (* uri |-->  (derived_coercions_in_the_coercion_DB, derived_coercions_in_lib)
  37  *
  38  * in case of remove_coercion uri, the first component is removed from the
  39  * coercion DB, while the second is passed to remove_obj (and is not [] only if
  40  * add_coercion is called with add_composites
  41  * *)
  42 let coercion_hashtbl = UriManager.UriHashtbl.create 3
  43
  44 let uris_of_obj uri =
  45  let innertypesuri = UriManager.innertypesuri_of_uri uri in
  46  let bodyuri = UriManager.bodyuri_of_uri uri in
  47  let univgraphuri = UriManager.univgraphuri_of_uri uri in
  48   innertypesuri,bodyuri,univgraphuri
  49
  50 let paths_and_uris_of_obj uri =
  51   let resolved = Http_getter.filename' ~local:true ~writable:true uri in
  52   let basepath = Filename.dirname resolved in
  53   let innertypesuri, bodyuri, univgraphuri = uris_of_obj uri in
  54   let innertypesfilename=(UriManager.nameext_of_uri innertypesuri)^".xml.gz"in
  55   let innertypespath = basepath ^ "/" ^ innertypesfilename in
  56   let xmlfilename = (UriManager.nameext_of_uri uri) ^ ".xml.gz" in
  57   let xmlpath = basepath ^ "/" ^ xmlfilename in
  58   let xmlbodyfilename = (UriManager.nameext_of_uri uri) ^ ".body.xml.gz" in
  59   let xmlbodypath = basepath ^ "/" ^  xmlbodyfilename in
  60   let xmlunivgraphfilename=(UriManager.nameext_of_uri univgraphuri)^".xml.gz"in
  61   let xmlunivgraphpath = basepath ^ "/" ^ xmlunivgraphfilename in
  62   xmlpath, xmlbodypath, innertypespath, bodyuri, innertypesuri,
  63   xmlunivgraphpath, univgraphuri
  64
  65 let save_object_to_disk uri obj ugraph univlist =
  66   let write f x =
  67     if not (Helm_registry.get_opt_default
  68               Helm_registry.bool "matita.nodisk" ~default:false)
  69     then
  70       f x
  71   in
  72   let ensure_path_exists path =
  73     let dir = Filename.dirname path in
  74     HExtlib.mkdir dir
  75   in
  76   (* generate annobj, ids_to_inner_sorts and ids_to_inner_types *)
  77   let annobj, innertypes, ids_to_inner_sorts, generate_attributes =
  78    if Helm_registry.get_bool "matita.system" &&
  79       not (Helm_registry.get_bool "matita.noinnertypes")
  80    then
  81     let annobj, _, _, ids_to_inner_sorts, ids_to_inner_types, _, _ =
  82      Cic2acic.acic_object_of_cic_object obj
  83     in
  84     let innertypesxml =
  85      Cic2Xml.print_inner_types
  86       uri ~ids_to_inner_sorts ~ids_to_inner_types ~ask_dtd_to_the_getter:false
  87     in
  88     annobj, Some innertypesxml, Some ids_to_inner_sorts, false
  89    else
  90     let annobj = Cic2acic.plain_acic_object_of_cic_object obj in
  91     annobj, None, None, true
  92   in
  93   (* prepare XML *)
  94   let xml, bodyxml =
  95    Cic2Xml.print_object
  96     uri ?ids_to_inner_sorts ~ask_dtd_to_the_getter:false
  97     ~generate_attributes annobj
  98   in
  99   let xmlpath, xmlbodypath, innertypespath, bodyuri, innertypesuri,
 100       xmlunivgraphpath, univgraphuri =
 101     paths_and_uris_of_obj uri
 102   in
 103   write (List.iter HExtlib.mkdir) (List.map Filename.dirname [xmlpath]);
 104   (* now write to disk *)
 105   write ensure_path_exists xmlpath;
 106   write (Xml.pp ~gzip:true xml) (Some xmlpath);
 107   write (CicUniv.write_xml_of_ugraph xmlunivgraphpath ugraph) univlist;
 108   (* we return a list of uri,path we registered/created *)
 109   (uri,xmlpath) ::
 110   (univgraphuri,xmlunivgraphpath) ::
 111     (* now the optional inner types, both write and register *)
 112     (match innertypes with
 113      | None -> []
 114      | Some innertypesxml ->
 115          write ensure_path_exists innertypespath;
 116          write (Xml.pp ~gzip:true innertypesxml) (Some innertypespath);
 117          [innertypesuri, innertypespath]
 118     ) @
 119     (* now the optional body, both write and register *)
 120     (match bodyxml,bodyuri with
 121        None,_ -> []
 122      | Some bodyxml,Some bodyuri->
 123          write ensure_path_exists xmlbodypath;
 124          write (Xml.pp ~gzip:true bodyxml) (Some xmlbodypath);
 125          [bodyuri, xmlbodypath]
 126      | _-> assert false)
 127
 128
 129 let typecheck_obj =
 130  let profiler = HExtlib.profile "add_obj.typecheck_obj" in
 131   fun uri obj -> profiler.HExtlib.profile (CicTypeChecker.typecheck_obj uri) obj
 132
 133 let index_obj =
 134  let profiler = HExtlib.profile "add_obj.index_obj" in
 135   fun ~dbd ~uri ->
 136    profiler.HExtlib.profile (fun uri -> MetadataDb.index_obj ~dbd ~uri) uri
 137
 138 let add_single_obj uri obj refinement_toolkit =
 139   let module RT = RefinementTool in
 140   let obj =
 141     if (*List.mem `Generated (CicUtil.attributes_of_obj obj) &&*)
 142        not (CoercDb.is_a_coercion' (Cic.Const (uri, [])))
 143     then
 144       refinement_toolkit.RT.pack_coercion_obj obj
 145     else
 146       obj
 147   in
 148   let dbd = LibraryDb.instance () in
 149   if CicEnvironment.in_library uri then
 150     raise (AlreadyDefined uri)
 151   else begin
 152     (*CicUniv.reset_spent_time ();
 153     let before = Unix.gettimeofday () in*)
 154     typecheck_obj uri obj; (* 1 *)
 155     (*let after = Unix.gettimeofday () in
 156     let univ_time = CicUniv.get_spent_time () in
 157     let total_time = after -. before in
 158     prerr_endline
 159       (Printf.sprintf "QED: %%univ = %2.5f, total = %2.5f, univ = %2.5f, %s\n"
 160       (univ_time *. 100. /. total_time) (total_time) (univ_time)
 161       (UriManager.name_of_uri uri));*)
 162     let _, ugraph, univlist =
 163       CicEnvironment.get_cooked_obj_with_univlist CicUniv.empty_ugraph uri in
 164     try
 165       index_obj ~dbd ~uri; (* 2 must be in the env *)
 166       try
 167         (*3*)
 168         let new_stuff = save_object_to_disk uri obj ugraph univlist in
 169         (* EXPERIMENTAL: pretty print the object in natural language *)
 170         (try !object_declaration_hook uri obj
 171          with exc ->
 172           prerr_endline ("Error: object_declaration_hook failed"^
 173           Printexc.to_string exc));
 174         try
 175          HLog.message
 176           (Printf.sprintf "%s defined" (UriManager.string_of_uri uri))
 177         with exc ->
 178           List.iter HExtlib.safe_remove (List.map snd new_stuff); (* -3 *)
 179           raise exc
 180       with exc ->
 181         ignore(LibraryDb.remove_uri uri); (* -2 *)
 182         raise exc
 183     with exc ->
 184       CicEnvironment.remove_obj uri; (* -1 *)
 185       raise exc
 186   end
 187
 188 let remove_single_obj uri =
 189   let derived_uris_of_uri uri =
 190    let innertypesuri, bodyuri, univgraphuri = uris_of_obj uri in
 191     innertypesuri::univgraphuri::(match bodyuri with None -> [] | Some u -> [u])
 192   in
 193   let uris_to_remove =
 194    if UriManager.uri_is_ind uri then LibraryDb.xpointers_of_ind uri else [uri]
 195   in
 196   let files_to_remove = uri :: derived_uris_of_uri uri in
 197   List.iter
 198    (fun uri ->
 199      (try
 200        let file = Http_getter.resolve' ~local:true ~writable:true uri in
 201         HExtlib.safe_remove file;
 202         HExtlib.rmdir_descend (Filename.dirname file)
 203      with Http_getter_types.Key_not_found _ -> ());
 204    ) files_to_remove ;
 205   List.iter
 206    (fun uri ->
 207      ignore (LibraryDb.remove_uri uri);
 208      (*CoercGraph.remove_coercion uri;*)
 209    ) uris_to_remove ;
 210   CicEnvironment.remove_obj uri
 211
 212 (*** GENERATION OF AUXILIARY LEMMAS ***)
 213
 214 let generate_elimination_principles uri refinement_toolkit =
 215   let uris = ref [] in
 216   let elim i =
 217     let elim sort =
 218       try
 219         let uri,obj = CicElim.elim_of ~sort uri i in
 220           add_single_obj uri obj refinement_toolkit;
 221           uris := uri :: !uris
 222       with CicElim.Can_t_eliminate -> ()
 223     in
 224       try
 225         List.iter
 226           elim [ Cic.Prop; Cic.Set; (Cic.Type (CicUniv.fresh ())) ];
 227       with exn ->
 228         List.iter remove_single_obj !uris;
 229         raise exn
 230   in
 231   let (obj, univ) = (CicEnvironment.get_obj CicUniv.empty_ugraph uri) in
 232     match obj with
 233       | Cic.InductiveDefinition (indTypes, _, _, _) ->
 234           let counter = ref 0 in
 235             List.iter (fun _ -> elim !counter; counter := !counter+1) indTypes;
 236             !uris
 237       | _  ->
 238           failwith (Printf.sprintf "not an inductive definition (%s)"
 239                       (UriManager.string_of_uri uri))
 240
 241 (* COERCIONS ***********************************************************)
 242
 243 let remove_all_coercions () =
 244   UriManager.UriHashtbl.clear coercion_hashtbl;
 245   CoercDb.remove_coercion (fun (_,_,_,_) -> true)
 246
 247 let stack = ref [];;
 248
 249 let h2l h =
 250   UriManager.UriHashtbl.fold
 251   (fun k v acc -> (k,v) :: acc) h []
 252 ;;
 253
 254 let push () =
 255   stack := (CoercDb.dump (), h2l coercion_hashtbl) :: !stack;
 256   remove_all_coercions ()
 257 ;;
 258
 259 let pop () =
 260   match !stack with
 261   | [] -> raise (Failure "Unable to POP from librarySync.ml")
 262   | (db,h) :: tl ->
 263       stack := tl;
 264       remove_all_coercions ();
 265       CoercDb.restore db;
 266       List.iter (fun (k,v) -> UriManager.UriHashtbl.add coercion_hashtbl k v)
 267       h
 268 ;;
 269
 270 let add_coercion ~add_composites refinement_toolkit uri arity saturations
 271  baseuri
 272 =
 273   let coer_ty,_ =
 274     let coer = CicUtil.term_of_uri uri in
 275     CicTypeChecker.type_of_aux' [] [] coer CicUniv.empty_ugraph
 276   in
 277   (* we have to get the source and the tgt type uri
 278    * in Coq syntax we have already their names, but
 279    * since we don't support Funclass and similar I think
 280    * all the coercion should be of the form
 281    * (A:?)(B:?)T1->T2
 282    * So we should be able to extract them from the coercion type
 283    *
 284    * Currently only (_:T1)T2 is supported.
 285    * should we saturate it with metas in case we insert it?
 286    *
 287    *)
 288   let spine2list ty =
 289     let rec aux = function
 290       | Cic.Prod( _, src, tgt) -> src::aux tgt
 291       | t -> [t]
 292     in
 293     aux ty
 294   in
 295   let src_carr, tgt_carr =
 296     let get_classes arity saturations l =
 297       (* this is the ackerman's function revisited *)
 298       let rec aux = function
 299          0,0,None,tgt::src::_ -> src,Some (`Class tgt)
 300        | 0,0,target,src::_ -> src,target
 301        | 0,saturations,None,tgt::tl -> aux (0,saturations,Some (`Class tgt),tl)
 302        | 0,saturations,target,_::tl -> aux (0,saturations - 1,target,tl)
 303        | arity,saturations,None,_::tl ->
 304             aux (arity, saturations, Some `Funclass, tl)
 305        | arity,saturations,target,_::tl ->
 306             aux (arity - 1, saturations, target, tl)
 307        | _ -> assert false
 308       in
 309        aux (arity,saturations,None,List.rev l)
 310     in
 311     let types = spine2list coer_ty in
 312     let src,tgt = get_classes arity saturations types in
 313      CoercDb.coerc_carr_of_term (CicReduction.whd ~delta:false [] src),
 314      match tgt with
 315         None -> assert false
 316       | Some `Funclass -> CoercDb.Fun arity
 317       | Some (`Class tgt) ->
 318          CoercDb.coerc_carr_of_term (CicReduction.whd ~delta:false [] tgt)
 319   in
 320   let already_in_obj src_carr tgt_carr uri obj =
 321      List.exists
 322       (fun (s,t,ul) ->
 323         List.exists
 324          (fun u,_ ->
 325            let bo =
 326             match obj with
 327             | Cic.Constant (_, Some bo, _, _, _) -> bo
 328             | _ -> assert false
 329            in
 330            CoercDb.eq_carr s src_carr &&
 331            CoercDb.eq_carr t tgt_carr &&
 332            if fst (CicReduction.are_convertible [] (CicUtil.term_of_uri u) bo
 333            CicUniv.oblivion_ugraph)
 334            then true else
 335             (HLog.warn
 336               ("Coercions " ^
 337                 UriManager.string_of_uri u ^ " and " ^ UriManager.string_of_uri
 338                 uri^" are not convertible, but are between the same nodes.\n"^
 339                 "From now on unification can fail randomly.");
 340              false))
 341          ul)
 342       (CoercDb.to_list ())
 343   in
 344   if not add_composites then
 345     (CoercDb.add_coercion (src_carr, tgt_carr, uri, saturations);
 346     UriManager.UriHashtbl.add coercion_hashtbl uri ([],[]);
 347     [])
 348   else
 349     let new_coercions =
 350       CicCoercion.close_coercion_graph src_carr tgt_carr uri saturations
 351        baseuri
 352     in
 353     let new_coercions =
 354       List.filter (fun (s,t,u,_,obj,_) -> not(already_in_obj s t u obj))
 355       new_coercions
 356     in
 357     let composite_uris = List.map (fun (_,_,uri,_,_,_) -> uri) new_coercions in
 358     (* update the DB *)
 359     List.iter
 360       (fun (src,tgt,uri,saturations,_,_) ->
 361         CoercDb.add_coercion (src,tgt,uri,saturations))
 362       new_coercions;
 363     CoercDb.add_coercion (src_carr, tgt_carr, uri, saturations);
 364     (* add the composites obj and they eventual lemmas *)
 365     let lemmas =
 366         List.fold_left
 367           (fun acc (_,tgt,uri,saturations,obj,arity) ->
 368             add_single_obj uri obj refinement_toolkit;
 369              (uri,arity,saturations)::acc)
 370           [] new_coercions
 371     in
 372     (* store that composite_uris are related to uri. the first component is
 373      * the stuff in the DB while the second is stuff for remove_obj *)
 374     (*
 375        prerr_endline ("adding: " ^
 376          string_of_bool add_composites ^ UriManager.string_of_uri uri);
 377        List.iter (fun u -> prerr_endline (UriManager.string_of_uri u))
 378         composite_uris;
 379     *)
 380     UriManager.UriHashtbl.add
 381       coercion_hashtbl uri (composite_uris,composite_uris);
 382     (*
 383     prerr_endline ("lemmas:");
 384       List.iter (fun u -> prerr_endline (UriManager.string_of_uri u))
 385       lemmas;
 386     prerr_endline ("lemmas END");*)
 387     lemmas
 388 ;;
 389
 390 let remove_coercion uri =
 391   try
 392     let (composites_in_db, composites_in_lib) =
 393       UriManager.UriHashtbl.find coercion_hashtbl uri
 394     in
 395     (*prerr_endline ("removing: " ^UriManager.string_of_uri uri);
 396     List.iter (fun u -> prerr_endline (UriManager.string_of_uri u))
 397       composites_in_db;*)
 398     UriManager.UriHashtbl.remove coercion_hashtbl uri;
 399     CoercDb.remove_coercion
 400       (fun (_,_,u,_) -> UriManager.eq uri u);
 401     (* remove from the DB *)
 402     List.iter
 403       (fun u -> CoercDb.remove_coercion (fun (_,_,u1,_) -> UriManager.eq u u1))
 404       composites_in_db;
 405     (* remove composites from the lib *)
 406     List.iter remove_single_obj composites_in_lib
 407   with
 408     Not_found -> HLog.warn "Coercion removal raise Not_found" (* mhh..... *)
 409
 410
 411 let generate_projections refinement_toolkit uri fields =
 412  let uris = ref [] in
 413  let projections =
 414    CicRecord.projections_of uri
 415      (List.map (fun (x,_,_) -> x) fields)
 416  in
 417   try
 418    List.iter2
 419     (fun (uri, name, bo) (_name, coercion, arity) ->
 420       let saturations = 0 in
 421       try
 422        let ty, ugraph =
 423          CicTypeChecker.type_of_aux' [] [] bo CicUniv.empty_ugraph in
 424        let attrs = [`Class `Projection; `Generated] in
 425        let obj = Cic.Constant (name,Some bo,ty,[],attrs) in
 426         add_single_obj uri obj refinement_toolkit;
 427         let composites =
 428          if coercion then
 429             begin
 430 (*prerr_endline ("composite for " ^ UriManager.string_of_uri uri);*)
 431               (*CSC: I think there is a bug here. The composite coercions
 432                 are not remembered in the .moo file. Thus they are re-generated
 433                 every time. Right? *)
 434               let x =
 435                 add_coercion ~add_composites:true refinement_toolkit uri arity
 436                  saturations (UriManager.buri_of_uri uri)
 437               in
 438 (*prerr_endline ("are: ");
 439   List.iter (fun u -> prerr_endline (UriManager.string_of_uri u)) x;
 440   prerr_endline "---";
 441 *)
 442               (*CSC: I throw the arity away. See comment above *)
 443               List.map (fun u,_,_ -> u) x
 444             end
 445           else
 446             []
 447         in
 448         uris := uri :: composites @ !uris
 449       with
 450          CicTypeChecker.TypeCheckerFailure s ->
 451           HLog.message
 452            ("Unable to create projection " ^ name ^ " cause: " ^ Lazy.force s);
 453        | CicEnvironment.Object_not_found uri ->
 454           let depend = UriManager.name_of_uri uri in
 455            HLog.message
 456             ("Unable to create projection " ^ name ^ " because it requires " ^
 457                depend)
 458     ) projections fields;
 459    !uris
 460   with exn ->
 461    List.iter remove_single_obj !uris;
 462    raise exn
 463
 464 let build_inversion_principle = ref (fun a b -> assert false);;
 465
 466 let generate_inversion refinement_toolkit uri obj =
 467   List.map
 468     (fun (ind_uri,ind_obj) ->
 469        add_single_obj ind_uri ind_obj refinement_toolkit;ind_uri)
 470     (!build_inversion_principle uri obj)
 471
 472 let
 473  generate_sibling_mutual_definitions refinement_toolkit uri attrs name_to_avoid
 474 =
 475  function
 476     Cic.Fix (_,funs) ->
 477      snd (
 478       List.fold_right
 479        (fun (name,idx,ty,bo) (n,uris) ->
 480          if name = name_to_avoid then
 481           (n+1,uris)
 482          else
 483           let uri =
 484            UriManager.uri_of_string
 485             (UriManager.buri_of_uri uri ^ "/" ^ name ^ ".con") in
 486           let bo = Cic.Fix (n,funs) in
 487           let obj = Cic.Constant (name,Some bo,ty,[],attrs) in
 488            add_single_obj uri obj refinement_toolkit;
 489            (n+1,uri::uris)
 490        ) funs (1,[]))
 491   | Cic.CoFix (_,funs) ->
 492      snd (
 493       List.fold_right
 494        (fun (name,ty,bo) (n,uris) ->
 495          if name = name_to_avoid then
 496           (n+1,uris)
 497          else
 498           let uri =
 499            UriManager.uri_of_string
 500             (UriManager.buri_of_uri uri ^ "/" ^ name ^ ".con") in
 501           let bo = Cic.CoFix (n,funs) in
 502           let obj = Cic.Constant (name,Some bo,ty,[],attrs) in
 503            add_single_obj uri obj refinement_toolkit;
 504            (n+1,uri::uris)
 505        ) funs (1,[]))
 506   | _ -> assert false
 507
 508 let add_obj refinement_toolkit uri obj =
 509  add_single_obj uri obj refinement_toolkit;
 510  let uris = ref [] in
 511  let not_debug = not (Helm_registry.get_bool "matita.debug") in
 512  try
 513   begin
 514    match obj with
 515     | Cic.Constant (name,Some bo,_,_,attrs) when
 516        List.mem (`Flavour `MutualDefinition) attrs ->
 517         uris :=
 518          !uris @
 519            generate_sibling_mutual_definitions refinement_toolkit uri attrs
 520             name bo
 521     | Cic.Constant _ -> ()
 522     | Cic.InductiveDefinition (inductivefuns,_,_,attrs) ->
 523        let _,inductive,_,_ = List.hd inductivefuns in
 524        if inductive then
 525         begin
 526          uris := !uris @
 527            generate_elimination_principles uri refinement_toolkit;
 528          uris := !uris @ generate_inversion refinement_toolkit uri obj;
 529         end ;
 530        let rec get_record_attrs =
 531          function
 532          | [] -> None
 533          | (`Class (`Record fields))::_ -> Some fields
 534          | _::tl -> get_record_attrs tl
 535        in
 536         (match get_record_attrs attrs with
 537         | None -> () (* not a record *)
 538         | Some fields ->
 539            uris := !uris @
 540              (generate_projections refinement_toolkit uri fields))
 541     | Cic.CurrentProof _
 542     | Cic.Variable _ -> assert false
 543   end;
 544   UriManager.UriHashtbl.add auxiliary_lemmas_hashtbl uri !uris;
 545   !uris
 546  with
 547  | exn when not_debug ->
 548     List.iter remove_single_obj !uris;
 549     raise exn
 550
 551 let remove_obj uri =
 552  let uris =
 553   try
 554    let res = UriManager.UriHashtbl.find auxiliary_lemmas_hashtbl uri in
 555     UriManager.UriHashtbl.remove auxiliary_lemmas_hashtbl uri;
 556     res
 557   with
 558     Not_found -> [] (*assert false*)
 559  in
 560   List.iter remove_single_obj (uri::uris)
 561