helm/software/components/ng_kernel/nCicLibrary.ml

   1 (*
   2     ||M||  This file is part of HELM, an Hypertextual, Electronic
   3     ||A||  Library of Mathematics, developed at the Computer Science
   4     ||T||  Department, University of Bologna, Italy.
   5     ||I||
   6     ||T||  HELM is free software; you can redistribute it and/or
   7     ||A||  modify it under the terms of the GNU General Public License
   8     \   /  version 2 or (at your option) any later version.
   9      \ /   This software is distributed as is, NO WARRANTY.
  10       V_______________________________________________________________ *)
  11
  12 (* $Id$ *)
  13
  14 exception LibraryOutOfSync of string Lazy.t
  15
  16 type timestamp =
  17  (NUri.uri * NCic.obj) list *
  18  (NUri.uri * string * NReference.reference) list *
  19  NCic.obj NUri.UriMap.t;;
  20
  21 let time0 = [],[],NUri.UriMap.empty;;
  22 let storage = ref [];;
  23 let aliases = ref [];;
  24 let cache = ref NUri.UriMap.empty;;
  25
  26 let time_travel (sto,ali,cac) = storage := sto; aliases := ali; cache := cac;;
  27
  28 let path_of_baseuri baseuri =
  29  let uri = NUri.string_of_uri baseuri in
  30  let path = String.sub uri 4 (String.length uri - 4) in
  31  let path = Helm_registry.get "matita.basedir" ^ path in
  32  let dirname = Filename.dirname path in
  33   HExtlib.mkdir dirname;
  34   path ^ ".ng"
  35 ;;
  36
  37 let magic = 0;;
  38
  39 let require0 ~baseuri =
  40  let ch = open_in (path_of_baseuri baseuri) in
  41  let mmagic,dump = Marshal.from_channel ch in
  42   close_in ch;
  43   if mmagic <> magic then
  44    raise (LibraryOutOfSync (lazy "The library is out of sync with the implementation. Please recompile the library."))
  45   else
  46    dump
  47 ;;
  48
  49 let serialize ~baseuri dump =
  50  let ch = open_out (path_of_baseuri baseuri) in
  51  Marshal.to_channel ch (magic,dump) [Marshal.Closures];
  52  close_out ch;
  53  List.iter
  54   (fun (uri,obj) ->
  55     let ch = open_out (path_of_baseuri uri) in
  56     Marshal.to_channel ch (magic,obj) [];
  57     close_out ch
  58   ) !storage;
  59  time_travel time0
  60 ;;
  61
  62 let refresh_uri uri = NUri.uri_of_string (NUri.string_of_uri uri);;
  63
  64 let rec refresh_uri_in_term =
  65  function
  66     NCic.Const (NReference.Ref (u,spec)) ->
  67      NCic.Const (NReference.reference_of_spec (refresh_uri u) spec)
  68   | t -> NCicUtils.map (fun _ _ -> ()) () (fun _ -> refresh_uri_in_term) t
  69 ;;
  70
  71 let refresh_uri_in_obj (uri,height,metasenv,subst,obj_kind) =
  72  assert (metasenv = []);
  73  assert (subst = []);
  74  uri,height,metasenv,subst,
  75   NCicUntrusted.map_obj_kind refresh_uri_in_term obj_kind
  76 ;;
  77
  78 module type Serializer =
  79  sig
  80   type status
  81   type obj
  82   val register: string -> ('a -> status -> status) -> ('a -> obj)
  83   val serialize: baseuri:NUri.uri -> obj list -> unit
  84   val require: baseuri:NUri.uri -> status -> status
  85  end
  86
  87 module Serializer(S: sig type status end) =
  88  struct
  89   type status = S.status
  90   type obj = string * Obj.t
  91
  92   let require1 = ref (fun _ -> assert false (* unknown data*))
  93   let already_registered = ref []
  94
  95   let register tag require =
  96    assert (not (List.mem tag !already_registered));
  97    already_registered := tag :: !already_registered;
  98    require1 :=
  99     (fun (tag',data) as x ->
 100      if tag=tag' then require (Obj.magic data) else !require1 x);
 101    (fun x -> tag,Obj.repr x)
 102
 103   let serialize = serialize
 104
 105   let require ~baseuri status =
 106    let dump = require0 ~baseuri in
 107     List.fold_right !require1 dump status
 108 end
 109
 110 let decompile ~baseuri =
 111  Unix.unlink (path_of_baseuri baseuri)
 112  (* WE ARE NOT REMOVING ALL THE OBJECTS YET! *)
 113 ;;
 114
 115 let fetch_obj uri =
 116  let obj = require0 ~baseuri:uri in
 117   refresh_uri_in_obj obj
 118 ;;
 119
 120 let resolve name =
 121  try
 122   HExtlib.filter_map
 123    (fun (_,name',nref) -> if name'=name then Some nref else None) !aliases
 124  with
 125   Not_found -> raise (NCicEnvironment.ObjectNotFound (lazy name))
 126 ;;
 127
 128 let aliases_of uri =
 129  try
 130   HExtlib.filter_map
 131    (fun (uri',_,nref) -> if NUri.eq uri' uri then Some nref else None) !aliases
 132  with
 133   Not_found -> raise (NCicEnvironment.ObjectNotFound (lazy (NUri.string_of_uri uri)))
 134 ;;
 135
 136 let add_obj u obj =
 137  storage := (u,obj)::!storage;
 138   let _,height,_,_,obj = obj in
 139   let references =
 140    match obj with
 141       NCic.Constant (_,name,None,_,_) ->
 142        [u,name,NReference.reference_of_spec u NReference.Decl]
 143     | NCic.Constant (_,name,Some _,_,_) ->
 144        [u,name,NReference.reference_of_spec u (NReference.Def height)]
 145     | NCic.Fixpoint (is_ind,fl,_) ->
 146        HExtlib.list_mapi
 147         (fun (_,name,recno,_,_) i ->
 148           if is_ind then
 149            u,name,NReference.reference_of_spec u(NReference.Fix(i,recno,height))
 150           else
 151            u,name,NReference.reference_of_spec u (NReference.CoFix i)) fl
 152     | NCic.Inductive (inductive,leftno,il,_) ->
 153        List.flatten
 154         (HExtlib.list_mapi
 155          (fun (_,iname,_,cl) i ->
 156            HExtlib.list_mapi
 157             (fun (_,cname,_) j->
 158               u,cname,
 159                NReference.reference_of_spec u (NReference.Con (i,j+1,leftno))
 160             ) cl @
 161            [u,iname,
 162              NReference.reference_of_spec u
 163               (NReference.Ind (inductive,i,leftno))]
 164          ) il)
 165   in
 166   aliases := references @ !aliases;
 167   !storage,!aliases,!cache
 168 ;;
 169
 170 let get_obj u =
 171  try List.assq u !storage
 172  with Not_found ->
 173   try fetch_obj u
 174   with Sys_error _ ->
 175    try NUri.UriMap.find u !cache
 176    with Not_found ->
 177     let ouri = NCic2OCic.ouri_of_nuri u in
 178     try
 179       let o,_ = CicEnvironment.get_obj CicUniv.oblivion_ugraph ouri in
 180       let l = OCic2NCic.convert_obj ouri o in
 181       List.iter (fun (u,_,_,_,_ as o) -> cache:= NUri.UriMap.add u o !cache) l;
 182       HExtlib.list_last l
 183     with CicEnvironment.Object_not_found u ->
 184       raise (NCicEnvironment.ObjectNotFound
 185                (lazy (NUri.string_of_uri (OCic2NCic.nuri_of_ouri u))))
 186 ;;
 187
 188 let clear_cache () = cache := NUri.UriMap.empty;;
 189
 190 NCicEnvironment.set_get_obj get_obj;;
 191 NCicPp.set_get_obj get_obj;;