helm/software/components/ng_kernel/nCicLibrary.ml

   1 (*
   2     ||M||  This file is part of HELM, an Hypertextual, Electronic
   3     ||A||  Library of Mathematics, developed at the Computer Science
   4     ||T||  Department, University of Bologna, Italy.
   5     ||I||
   6     ||T||  HELM is free software; you can redistribute it and/or
   7     ||A||  modify it under the terms of the GNU General Public License
   8     \   /  version 2 or (at your option) any later version.
   9      \ /   This software is distributed as is, NO WARRANTY.
  10       V_______________________________________________________________ *)
  11
  12 (* $Id$ *)
  13
  14 exception LibraryOutOfSync of string Lazy.t
  15
  16 let magic = 2;;
  17
  18 let refresh_uri uri = NUri.uri_of_string (NUri.string_of_uri uri);;
  19
  20 let refresh_uri_in_universe =
  21  List.map (fun (x,u) -> x, refresh_uri u)
  22 ;;
  23
  24 let rec refresh_uri_in_term =
  25  function
  26   | NCic.Meta (i,(n,NCic.Ctx l)) ->
  27      NCic.Meta (i,(n,NCic.Ctx (List.map refresh_uri_in_term l)))
  28   | NCic.Meta _ as t -> t
  29   | NCic.Const (NReference.Ref (u,spec)) ->
  30      NCic.Const (NReference.reference_of_spec (refresh_uri u) spec)
  31   | NCic.Sort (NCic.Type l) -> NCic.Sort (NCic.Type (refresh_uri_in_universe l))
  32   | NCic.Match (NReference.Ref (uri,spec),outtype,term,pl) ->
  33      let r = NReference.reference_of_spec (refresh_uri uri) spec in
  34      let outtype = refresh_uri_in_term outtype in
  35      let term = refresh_uri_in_term term in
  36      let pl = List.map refresh_uri_in_term pl in
  37       NCic.Match (r,outtype,term,pl)
  38   | t -> NCicUtils.map (fun _ _ -> ()) () (fun _ -> refresh_uri_in_term) t
  39 ;;
  40
  41 let refresh_uri_in_obj (uri,height,metasenv,subst,obj_kind) =
  42  assert (metasenv = []);
  43  assert (subst = []);
  44  refresh_uri uri,height,metasenv,subst,
  45   NCicUntrusted.map_obj_kind refresh_uri_in_term obj_kind
  46 ;;
  47
  48 let path_of_baseuri ?(no_suffix=false) baseuri =
  49  let uri = NUri.string_of_uri baseuri in
  50  let path = String.sub uri 4 (String.length uri - 4) in
  51  let path = Helm_registry.get "matita.basedir" ^ path in
  52  let dirname = Filename.dirname path in
  53   HExtlib.mkdir dirname;
  54   if no_suffix then
  55    path
  56   else
  57    path ^ ".ng"
  58 ;;
  59
  60 let require_path path =
  61  let ch = open_in path in
  62  let mmagic,dump = Marshal.from_channel ch in
  63   close_in ch;
  64   if mmagic <> magic then
  65    raise (LibraryOutOfSync (lazy "The library is out of sync with the implementation. Please recompile the library."))
  66   else
  67    dump
  68 ;;
  69
  70 let require0 ~baseuri = require_path (path_of_baseuri baseuri);;
  71
  72 let db_path () = Helm_registry.get "matita.basedir" ^ "/ng_db.ng";;
  73
  74
  75 type timestamp =
  76  [ `Obj of NUri.uri * NCic.obj
  77  | `Constr of bool * NCic.universe * NCic.universe] list *
  78  (NUri.uri * string * NReference.reference) list *
  79  NCic.obj NUri.UriMap.t *
  80  NUri.uri list
  81 ;;
  82
  83 let time0 = [],[],NUri.UriMap.empty,[];;
  84 let storage = ref [];;
  85 let local_aliases = ref [];;
  86 let cache = ref NUri.UriMap.empty;;
  87 let includes = ref [];;
  88
  89 let load_db,set_global_aliases,get_global_aliases,add_deps,get_deps,remove_deps=
  90  let global_aliases = ref [] in
  91  let rev_includes_map = ref NUri.UriMap.empty in
  92  let store_db () =
  93   let ch = open_out (db_path ()) in
  94   Marshal.to_channel ch (magic,(!global_aliases,!rev_includes_map)) [];
  95   close_out ch in
  96  let load_db () =
  97   HExtlib.mkdir (Helm_registry.get "matita.basedir");
  98   try
  99    let ga,im = require_path (db_path ()) in
 100    let ga =
 101     List.map
 102      (fun (uri,name,NReference.Ref (uri2,spec)) ->
 103        refresh_uri uri,name,NReference.reference_of_spec (refresh_uri uri2) spec
 104      ) ga in
 105    let im =
 106     NUri.UriMap.fold
 107      (fun u l im -> NUri.UriMap.add (refresh_uri u) (List.map refresh_uri l) im
 108      ) im NUri.UriMap.empty
 109    in
 110     global_aliases := ga;
 111     rev_includes_map := im
 112   with
 113    Sys_error _ -> () in
 114  let get_deps u =
 115   let get_deps_one_step u =
 116     try NUri.UriMap.find u !rev_includes_map with Not_found -> [] in
 117   let rec aux res =
 118    function
 119       [] -> res
 120     | he::tl ->
 121        if List.mem he res then
 122         aux res tl
 123        else
 124         aux (he::res) (get_deps_one_step he @ tl)
 125   in
 126    aux [] [u] in
 127  let remove_deps u =
 128   rev_includes_map := NUri.UriMap.remove u !rev_includes_map;
 129   rev_includes_map :=
 130    NUri.UriMap.map
 131     (fun l -> List.filter (fun uri -> not (NUri.eq u uri)) l) !rev_includes_map;
 132   store_db ()
 133  in
 134   load_db,
 135   (fun ga -> global_aliases := ga; store_db ()),
 136   (fun () -> !global_aliases),
 137   (fun u l ->
 138     rev_includes_map := NUri.UriMap.add u (l @ get_deps u) !rev_includes_map;
 139     store_db ()),
 140   get_deps,
 141   remove_deps
 142 ;;
 143
 144 let init = load_db;;
 145
 146
 147 class status =
 148  object
 149   val timestamp = (time0 : timestamp)
 150   method timestamp = timestamp
 151   method set_timestamp v = {< timestamp = v >}
 152   method set_library_status
 153    : 'status. < timestamp : timestamp; .. > as 'status -> 'self
 154    = fun o -> {< timestamp = o#timestamp >}
 155  end
 156
 157 let time_travel status =
 158  let sto,ali,cac,inc = status#timestamp in
 159   let diff_len = List.length !storage - List.length sto in
 160   let to_be_deleted,_ = HExtlib.split_nth diff_len !storage in
 161    if List.length to_be_deleted > 0 then
 162      NCicEnvironment.invalidate_item (HExtlib.list_last to_be_deleted);
 163    storage := sto; local_aliases := ali; cache := cac; includes := inc
 164 ;;
 165
 166 let serialize ~baseuri dump =
 167  let ch = open_out (path_of_baseuri baseuri) in
 168  Marshal.to_channel ch (magic,dump) [];
 169  close_out ch;
 170  List.iter
 171   (function
 172    | `Obj (uri,obj) ->
 173        let ch = open_out (path_of_baseuri uri) in
 174        Marshal.to_channel ch (magic,obj) [];
 175        close_out ch
 176    | `Constr _ -> ()
 177   ) !storage;
 178  set_global_aliases (!local_aliases @ get_global_aliases ());
 179  List.iter (fun u -> add_deps u [baseuri]) !includes;
 180  time_travel (new status)
 181 ;;
 182
 183 module type Serializer =
 184  sig
 185   type status
 186   type obj
 187   val register:
 188    string ->
 189     ('a -> refresh_uri_in_universe:(NCic.universe -> NCic.universe) -> refresh_uri_in_term:(NCic.term -> NCic.term) -> status -> status) ->
 190     ('a -> obj)
 191   val serialize: baseuri:NUri.uri -> obj list -> unit
 192   val require: baseuri:NUri.uri -> status -> status
 193  end
 194
 195 module Serializer(S: sig type status end) =
 196  struct
 197   type status = S.status
 198   type obj = string * Obj.t
 199
 200   let require1 = ref (fun _ -> assert false (* unknown data*))
 201   let already_registered = ref []
 202
 203   let register tag require =
 204    assert (not (List.mem tag !already_registered));
 205    already_registered := tag :: !already_registered;
 206    let old_require1 = !require1 in
 207    require1 :=
 208      (fun (tag',data) as x ->
 209       if tag=tag' then
 210        require (Obj.magic data) ~refresh_uri_in_universe ~refresh_uri_in_term
 211       else
 212        old_require1 x);
 213    (fun x -> tag,Obj.repr x)
 214
 215   let serialize = serialize
 216
 217   let require ~baseuri status =
 218    includes := baseuri::!includes;
 219    let dump = require0 ~baseuri in
 220     List.fold_right !require1 dump status
 221 end
 222
 223 let decompile ~baseuri =
 224  let baseuris = get_deps baseuri in
 225  List.iter (fun baseuri ->
 226   remove_deps baseuri;
 227   HExtlib.safe_remove (path_of_baseuri baseuri);
 228   let basepath = path_of_baseuri ~no_suffix:true baseuri in
 229   try
 230    let od = Unix.opendir basepath in
 231    let rec aux names =
 232     try
 233      let name = Unix.readdir od in
 234       if name <> "." && name <> ".." then aux (name::names) else aux names
 235     with
 236      End_of_file -> names in
 237    let names = List.map (fun name -> basepath ^ "/" ^ name) (aux []) in
 238     Unix.closedir od;
 239     List.iter Unix.unlink names;
 240     HExtlib.rmdir_descend basepath;
 241     set_global_aliases
 242      (List.filter
 243       (fun (_,_,NReference.Ref (nuri,_)) ->
 244         Filename.dirname (NUri.string_of_uri nuri) <> NUri.string_of_uri baseuri
 245       ) (get_global_aliases ()))
 246   with
 247    Unix.Unix_error _ -> () (* raised by Unix.opendir, we hope :-) *)
 248  ) baseuris
 249 ;;
 250
 251 LibraryClean.set_decompile_cb
 252  (fun ~baseuri -> decompile ~baseuri:(NUri.uri_of_string baseuri));;
 253
 254 let fetch_obj uri =
 255  let obj = require0 ~baseuri:uri in
 256   refresh_uri_in_obj obj
 257 ;;
 258
 259 let resolve name =
 260  try
 261   HExtlib.filter_map
 262    (fun (_,name',nref) -> if name'=name then Some nref else None)
 263    (!local_aliases @ get_global_aliases ())
 264  with
 265   Not_found -> raise (NCicEnvironment.ObjectNotFound (lazy name))
 266 ;;
 267
 268 let aliases_of uri =
 269  try
 270   HExtlib.filter_map
 271    (fun (uri',_,nref) ->
 272      if NUri.eq uri' uri then Some nref else None) !local_aliases
 273  with
 274   Not_found -> raise (NCicEnvironment.ObjectNotFound (lazy (NUri.string_of_uri uri)))
 275 ;;
 276
 277 let add_obj status ((u,_,_,_,_) as obj) =
 278  NCicEnvironment.check_and_add_obj obj;
 279  storage := (`Obj (u,obj))::!storage;
 280   let _,height,_,_,obj = obj in
 281   let references =
 282    match obj with
 283       NCic.Constant (_,name,None,_,_) ->
 284        [u,name,NReference.reference_of_spec u NReference.Decl]
 285     | NCic.Constant (_,name,Some _,_,_) ->
 286        [u,name,NReference.reference_of_spec u (NReference.Def height)]
 287     | NCic.Fixpoint (is_ind,fl,_) ->
 288        HExtlib.list_mapi
 289         (fun (_,name,recno,_,_) i ->
 290           if is_ind then
 291            u,name,NReference.reference_of_spec u(NReference.Fix(i,recno,height))
 292           else
 293            u,name,NReference.reference_of_spec u (NReference.CoFix i)) fl
 294     | NCic.Inductive (inductive,leftno,il,_) ->
 295        List.flatten
 296         (HExtlib.list_mapi
 297          (fun (_,iname,_,cl) i ->
 298            HExtlib.list_mapi
 299             (fun (_,cname,_) j->
 300               u,cname,
 301                NReference.reference_of_spec u (NReference.Con (i,j+1,leftno))
 302             ) cl @
 303            [u,iname,
 304              NReference.reference_of_spec u
 305               (NReference.Ind (inductive,i,leftno))]
 306          ) il)
 307   in
 308   local_aliases := references @ !local_aliases;
 309   status#set_timestamp (!storage,!local_aliases,!cache,!includes)
 310 ;;
 311
 312 let add_constraint status strict u1 u2 =
 313   NCicEnvironment.add_constraint strict u1 u2;
 314   storage := (`Constr (strict,u1,u2)) :: !storage;
 315   status#set_timestamp (!storage,!local_aliases,!cache,!includes)
 316 ;;
 317
 318 let get_obj u =
 319  try
 320   List.assq u
 321    (HExtlib.filter_map
 322     (function `Obj (u,o) -> Some (u,o) | _ -> None )
 323     !storage)
 324  with Not_found ->
 325   try fetch_obj u
 326   with Sys_error _ ->
 327    try NUri.UriMap.find u !cache
 328    with Not_found ->
 329     let ouri = NCic2OCic.ouri_of_nuri u in
 330     try
 331       let o,_ = CicEnvironment.get_obj CicUniv.oblivion_ugraph ouri in
 332       let l = OCic2NCic.convert_obj ouri o in
 333       List.iter (fun (u,_,_,_,_ as o) -> cache:= NUri.UriMap.add u o !cache) l;
 334       HExtlib.list_last l
 335     with CicEnvironment.Object_not_found u ->
 336       raise (NCicEnvironment.ObjectNotFound
 337                (lazy (NUri.string_of_uri (OCic2NCic.nuri_of_ouri u))))
 338 ;;
 339
 340 let clear_cache () = cache := NUri.UriMap.empty;;
 341
 342 NCicEnvironment.set_get_obj get_obj;;
 343 NCicPp.set_get_obj get_obj;;