helm/software/components/ng_kernel/nCicLibrary.ml

   1 (*
   2     ||M||  This file is part of HELM, an Hypertextual, Electronic
   3     ||A||  Library of Mathematics, developed at the Computer Science
   4     ||T||  Department, University of Bologna, Italy.
   5     ||I||
   6     ||T||  HELM is free software; you can redistribute it and/or
   7     ||A||  modify it under the terms of the GNU General Public License
   8     \   /  version 2 or (at your option) any later version.
   9      \ /   This software is distributed as is, NO WARRANTY.
  10       V_______________________________________________________________ *)
  11
  12 (* $Id$ *)
  13
  14 exception LibraryOutOfSync of string Lazy.t
  15
  16 let magic = 2;;
  17
  18 let refresh_uri uri = NUri.uri_of_string (NUri.string_of_uri uri);;
  19
  20 let refresh_uri_in_universe =
  21  List.map (fun (x,u) -> x, refresh_uri u)
  22 ;;
  23
  24 let rec refresh_uri_in_term =
  25  function
  26   | NCic.Meta (i,(n,NCic.Ctx l)) ->
  27      NCic.Meta (i,(n,NCic.Ctx (List.map refresh_uri_in_term l)))
  28   | NCic.Meta _ as t -> t
  29   | NCic.Const (NReference.Ref (u,spec)) ->
  30      NCic.Const (NReference.reference_of_spec (refresh_uri u) spec)
  31   | NCic.Sort (NCic.Type l) -> NCic.Sort (NCic.Type (refresh_uri_in_universe l))
  32   | NCic.Match (NReference.Ref (uri,spec),outtype,term,pl) ->
  33      let r = NReference.reference_of_spec (refresh_uri uri) spec in
  34      let outtype = refresh_uri_in_term outtype in
  35      let term = refresh_uri_in_term term in
  36      let pl = List.map refresh_uri_in_term pl in
  37       NCic.Match (r,outtype,term,pl)
  38   | t -> NCicUtils.map (fun _ _ -> ()) () (fun _ -> refresh_uri_in_term) t
  39 ;;
  40
  41 let refresh_uri_in_obj (uri,height,metasenv,subst,obj_kind) =
  42  assert (metasenv = []);
  43  assert (subst = []);
  44  refresh_uri uri,height,metasenv,subst,
  45   NCicUntrusted.map_obj_kind refresh_uri_in_term obj_kind
  46 ;;
  47
  48 let path_of_baseuri ?(no_suffix=false) baseuri =
  49  let uri = NUri.string_of_uri baseuri in
  50  let path = String.sub uri 4 (String.length uri - 4) in
  51  let path = Helm_registry.get "matita.basedir" ^ path in
  52  let dirname = Filename.dirname path in
  53   HExtlib.mkdir dirname;
  54   if no_suffix then
  55    path
  56   else
  57    path ^ ".ng"
  58 ;;
  59
  60 let require_path path =
  61  let ch = open_in path in
  62  let mmagic,dump = Marshal.from_channel ch in
  63   close_in ch;
  64   if mmagic <> magic then
  65    raise (LibraryOutOfSync (lazy "The library is out of sync with the implementation. Please recompile the library."))
  66   else
  67    dump
  68 ;;
  69
  70 let require0 ~baseuri = require_path (path_of_baseuri baseuri);;
  71
  72 let db_path () = Helm_registry.get "matita.basedir" ^ "/ng_db.ng";;
  73
  74
  75 type timestamp =
  76  [ `Obj of NUri.uri * NCic.obj
  77  | `Constr of bool * NCic.universe * NCic.universe] list *
  78  (NUri.uri * string * NReference.reference) list *
  79  NCic.obj NUri.UriMap.t *
  80  NUri.uri list
  81 ;;
  82
  83 let time0 = [],[],NUri.UriMap.empty,[];;
  84 let storage = ref [];;
  85 let local_aliases = ref [];;
  86 let cache = ref NUri.UriMap.empty;;
  87 let includes = ref [];;
  88
  89 let load_db,set_global_aliases,get_global_aliases,add_deps,get_deps,remove_deps=
  90  let global_aliases = ref [] in
  91  let rev_includes_map = ref NUri.UriMap.empty in
  92  let store_db () =
  93   let ch = open_out (db_path ()) in
  94   Marshal.to_channel ch (magic,(!global_aliases,!rev_includes_map)) [];
  95   close_out ch in
  96  let load_db () =
  97   HExtlib.mkdir (Helm_registry.get "matita.basedir");
  98   try
  99    let ga,im = require_path (db_path ()) in
 100    let ga =
 101     List.map
 102      (fun (uri,name,NReference.Ref (uri2,spec)) ->
 103        refresh_uri uri,name,NReference.reference_of_spec (refresh_uri uri2) spec
 104      ) ga in
 105    let im =
 106     NUri.UriMap.fold
 107      (fun u l im -> NUri.UriMap.add (refresh_uri u) (List.map refresh_uri l) im
 108      ) im NUri.UriMap.empty
 109    in
 110     global_aliases := ga;
 111     rev_includes_map := im
 112   with
 113    Sys_error _ -> () in
 114  let get_deps u =
 115   let get_deps_one_step u =
 116     try NUri.UriMap.find u !rev_includes_map with Not_found -> [] in
 117   let rec aux res =
 118    function
 119       [] -> res
 120     | he::tl ->
 121        if List.mem he res then
 122         aux res tl
 123        else
 124         aux (he::res) (get_deps_one_step he @ tl)
 125   in
 126    aux [] [u] in
 127  let remove_deps u =
 128   rev_includes_map := NUri.UriMap.remove u !rev_includes_map;
 129   rev_includes_map :=
 130    NUri.UriMap.map
 131     (fun l -> List.filter (fun uri -> not (NUri.eq u uri)) l) !rev_includes_map;
 132   store_db ()
 133  in
 134   load_db,
 135   (fun ga -> global_aliases := ga; store_db ()),
 136   (fun () -> !global_aliases),
 137   (fun u l ->
 138     rev_includes_map := NUri.UriMap.add u (l @ get_deps u) !rev_includes_map;
 139     store_db ()),
 140   get_deps,
 141   remove_deps
 142 ;;
 143
 144 let init = load_db;;
 145
 146 class type g_status =
 147  object
 148   method timestamp: timestamp
 149  end
 150
 151 class status =
 152  object
 153   val timestamp = (time0 : timestamp)
 154   method timestamp = timestamp
 155   method set_timestamp v = {< timestamp = v >}
 156   method set_library_status
 157    : 'status. #g_status as 'status -> 'self
 158    = fun o -> {< timestamp = o#timestamp >}
 159  end
 160
 161 let time_travel status =
 162  let sto,ali,cac,inc = status#timestamp in
 163   let diff_len = List.length !storage - List.length sto in
 164   let to_be_deleted,_ = HExtlib.split_nth diff_len !storage in
 165    if List.length to_be_deleted > 0 then
 166      NCicEnvironment.invalidate_item (HExtlib.list_last to_be_deleted);
 167    storage := sto; local_aliases := ali; cache := cac; includes := inc
 168 ;;
 169
 170 let serialize ~baseuri dump =
 171  let ch = open_out (path_of_baseuri baseuri) in
 172  Marshal.to_channel ch (magic,dump) [];
 173  close_out ch;
 174  List.iter
 175   (function
 176    | `Obj (uri,obj) ->
 177        let ch = open_out (path_of_baseuri uri) in
 178        Marshal.to_channel ch (magic,obj) [];
 179        close_out ch
 180    | `Constr _ -> ()
 181   ) !storage;
 182  set_global_aliases (!local_aliases @ get_global_aliases ());
 183  List.iter (fun u -> add_deps u [baseuri]) !includes;
 184  time_travel (new status)
 185 ;;
 186
 187 module type Serializer =
 188  sig
 189   type status
 190   type obj
 191   val register:
 192    string ->
 193     ('a -> refresh_uri_in_universe:(NCic.universe -> NCic.universe) -> refresh_uri_in_term:(NCic.term -> NCic.term) -> status -> status) ->
 194     ('a -> obj)
 195   val serialize: baseuri:NUri.uri -> obj list -> unit
 196   val require: baseuri:NUri.uri -> status -> status
 197  end
 198
 199 module Serializer(S: sig type status end) =
 200  struct
 201   type status = S.status
 202   type obj = string * Obj.t
 203
 204   let require1 = ref (fun _ -> assert false (* unknown data*))
 205   let already_registered = ref []
 206
 207   let register tag require =
 208    assert (not (List.mem tag !already_registered));
 209    already_registered := tag :: !already_registered;
 210    let old_require1 = !require1 in
 211    require1 :=
 212      (fun (tag',data) as x ->
 213       if tag=tag' then
 214        require (Obj.magic data) ~refresh_uri_in_universe ~refresh_uri_in_term
 215       else
 216        old_require1 x);
 217    (fun x -> tag,Obj.repr x)
 218
 219   let serialize = serialize
 220
 221   let require ~baseuri status =
 222    includes := baseuri::!includes;
 223    let dump = require0 ~baseuri in
 224     List.fold_right !require1 dump status
 225 end
 226
 227 let decompile ~baseuri =
 228  let baseuris = get_deps baseuri in
 229  List.iter (fun baseuri ->
 230   remove_deps baseuri;
 231   HExtlib.safe_remove (path_of_baseuri baseuri);
 232   let basepath = path_of_baseuri ~no_suffix:true baseuri in
 233   try
 234    let od = Unix.opendir basepath in
 235    let rec aux names =
 236     try
 237      let name = Unix.readdir od in
 238       if name <> "." && name <> ".." then aux (name::names) else aux names
 239     with
 240      End_of_file -> names in
 241    let names = List.map (fun name -> basepath ^ "/" ^ name) (aux []) in
 242     Unix.closedir od;
 243     List.iter Unix.unlink names;
 244     HExtlib.rmdir_descend basepath;
 245     set_global_aliases
 246      (List.filter
 247       (fun (_,_,NReference.Ref (nuri,_)) ->
 248         Filename.dirname (NUri.string_of_uri nuri) <> NUri.string_of_uri baseuri
 249       ) (get_global_aliases ()))
 250   with
 251    Unix.Unix_error _ -> () (* raised by Unix.opendir, we hope :-) *)
 252  ) baseuris
 253 ;;
 254
 255 LibraryClean.set_decompile_cb
 256  (fun ~baseuri -> decompile ~baseuri:(NUri.uri_of_string baseuri));;
 257
 258 let fetch_obj uri =
 259  let obj = require0 ~baseuri:uri in
 260   refresh_uri_in_obj obj
 261 ;;
 262
 263 let resolve name =
 264  try
 265   HExtlib.filter_map
 266    (fun (_,name',nref) -> if name'=name then Some nref else None)
 267    (!local_aliases @ get_global_aliases ())
 268  with
 269   Not_found -> raise (NCicEnvironment.ObjectNotFound (lazy name))
 270 ;;
 271
 272 let aliases_of uri =
 273  try
 274   HExtlib.filter_map
 275    (fun (uri',_,nref) ->
 276      if NUri.eq uri' uri then Some nref else None) !local_aliases
 277  with
 278   Not_found -> raise (NCicEnvironment.ObjectNotFound (lazy (NUri.string_of_uri uri)))
 279 ;;
 280
 281 let add_obj status ((u,_,_,_,_) as obj) =
 282  NCicEnvironment.check_and_add_obj obj;
 283  storage := (`Obj (u,obj))::!storage;
 284   let _,height,_,_,obj = obj in
 285   let references =
 286    match obj with
 287       NCic.Constant (_,name,None,_,_) ->
 288        [u,name,NReference.reference_of_spec u NReference.Decl]
 289     | NCic.Constant (_,name,Some _,_,_) ->
 290        [u,name,NReference.reference_of_spec u (NReference.Def height)]
 291     | NCic.Fixpoint (is_ind,fl,_) ->
 292        HExtlib.list_mapi
 293         (fun (_,name,recno,_,_) i ->
 294           if is_ind then
 295            u,name,NReference.reference_of_spec u(NReference.Fix(i,recno,height))
 296           else
 297            u,name,NReference.reference_of_spec u (NReference.CoFix i)) fl
 298     | NCic.Inductive (inductive,leftno,il,_) ->
 299        List.flatten
 300         (HExtlib.list_mapi
 301          (fun (_,iname,_,cl) i ->
 302            HExtlib.list_mapi
 303             (fun (_,cname,_) j->
 304               u,cname,
 305                NReference.reference_of_spec u (NReference.Con (i,j+1,leftno))
 306             ) cl @
 307            [u,iname,
 308              NReference.reference_of_spec u
 309               (NReference.Ind (inductive,i,leftno))]
 310          ) il)
 311   in
 312   local_aliases := references @ !local_aliases;
 313   status#set_timestamp (!storage,!local_aliases,!cache,!includes)
 314 ;;
 315
 316 let add_constraint status strict u1 u2 =
 317   NCicEnvironment.add_constraint strict u1 u2;
 318   storage := (`Constr (strict,u1,u2)) :: !storage;
 319   status#set_timestamp (!storage,!local_aliases,!cache,!includes)
 320 ;;
 321
 322 let get_obj u =
 323  try
 324   List.assq u
 325    (HExtlib.filter_map
 326     (function `Obj (u,o) -> Some (u,o) | _ -> None )
 327     !storage)
 328  with Not_found ->
 329   try fetch_obj u
 330   with Sys_error _ ->
 331    try NUri.UriMap.find u !cache
 332    with Not_found ->
 333     let ouri = NCic2OCic.ouri_of_nuri u in
 334     try
 335       let o,_ = CicEnvironment.get_obj CicUniv.oblivion_ugraph ouri in
 336       let l = OCic2NCic.convert_obj ouri o in
 337       List.iter (fun (u,_,_,_,_ as o) -> cache:= NUri.UriMap.add u o !cache) l;
 338       HExtlib.list_last l
 339     with CicEnvironment.Object_not_found u ->
 340       raise (NCicEnvironment.ObjectNotFound
 341                (lazy (NUri.string_of_uri (OCic2NCic.nuri_of_ouri u))))
 342 ;;
 343
 344 let clear_cache () = cache := NUri.UriMap.empty;;
 345
 346 NCicEnvironment.set_get_obj get_obj;;
 347 NCicPp.set_get_obj get_obj;;