helm/software/components/ng_kernel/nCicLibrary.ml

   1 (*
   2     ||M||  This file is part of HELM, an Hypertextual, Electronic
   3     ||A||  Library of Mathematics, developed at the Computer Science
   4     ||T||  Department, University of Bologna, Italy.
   5     ||I||
   6     ||T||  HELM is free software; you can redistribute it and/or
   7     ||A||  modify it under the terms of the GNU General Public License
   8     \   /  version 2 or (at your option) any later version.
   9      \ /   This software is distributed as is, NO WARRANTY.
  10       V_______________________________________________________________ *)
  11
  12 (* $Id$ *)
  13
  14 exception LibraryOutOfSync of string Lazy.t
  15
  16 type timestamp =
  17  (NUri.uri * NCic.obj) list *
  18  (NUri.uri * string * NReference.reference) list *
  19  NCic.obj NUri.UriMap.t;;
  20
  21 let time0 = [],[],NUri.UriMap.empty;;
  22 let storage = ref [];;
  23 let aliases = ref [];;
  24 let cache = ref NUri.UriMap.empty;;
  25
  26 class status =
  27  object
  28   val timestamp = (time0 : timestamp)
  29   method timestamp = timestamp
  30   method set_timestamp v = {< timestamp = v >}
  31  end
  32
  33 let time_travel status =
  34  let sto,ali,cac = status#timestamp in
  35   storage := sto; aliases := ali; cache := cac
  36 ;;
  37
  38 let path_of_baseuri baseuri =
  39  let uri = NUri.string_of_uri baseuri in
  40  let path = String.sub uri 4 (String.length uri - 4) in
  41  let path = Helm_registry.get "matita.basedir" ^ path in
  42  let dirname = Filename.dirname path in
  43   HExtlib.mkdir dirname;
  44   path ^ ".ng"
  45 ;;
  46
  47 let magic = 0;;
  48
  49 let require0 ~baseuri =
  50  let ch = open_in (path_of_baseuri baseuri) in
  51  let mmagic,dump = Marshal.from_channel ch in
  52   close_in ch;
  53   if mmagic <> magic then
  54    raise (LibraryOutOfSync (lazy "The library is out of sync with the implementation. Please recompile the library."))
  55   else
  56    dump
  57 ;;
  58
  59 let serialize ~baseuri dump =
  60  let ch = open_out (path_of_baseuri baseuri) in
  61  Marshal.to_channel ch (magic,dump) [Marshal.Closures];
  62  close_out ch;
  63  List.iter
  64   (fun (uri,obj) ->
  65     let ch = open_out (path_of_baseuri uri) in
  66     Marshal.to_channel ch (magic,obj) [];
  67     close_out ch
  68   ) !storage;
  69  time_travel (new status)
  70 ;;
  71
  72 let refresh_uri uri = NUri.uri_of_string (NUri.string_of_uri uri);;
  73
  74 let rec refresh_uri_in_term =
  75  function
  76     NCic.Const (NReference.Ref (u,spec)) ->
  77      NCic.Const (NReference.reference_of_spec (refresh_uri u) spec)
  78   | t -> NCicUtils.map (fun _ _ -> ()) () (fun _ -> refresh_uri_in_term) t
  79 ;;
  80
  81 let refresh_uri_in_obj (uri,height,metasenv,subst,obj_kind) =
  82  assert (metasenv = []);
  83  assert (subst = []);
  84  uri,height,metasenv,subst,
  85   NCicUntrusted.map_obj_kind refresh_uri_in_term obj_kind
  86 ;;
  87
  88 module type Serializer =
  89  sig
  90   type status
  91   type obj
  92   val register:
  93    string ->
  94     ('a -> refresh_uri_in_term:(NCic.term -> NCic.term) -> status -> status) ->
  95     ('a -> obj)
  96   val serialize: baseuri:NUri.uri -> obj list -> unit
  97   val require: baseuri:NUri.uri -> status -> status
  98  end
  99
 100 module Serializer(S: sig type status end) =
 101  struct
 102   type status = S.status
 103   type obj = string * Obj.t
 104
 105   let require1 = ref (fun _ -> assert false (* unknown data*))
 106   let already_registered = ref []
 107
 108   let register tag require =
 109    assert (not (List.mem tag !already_registered));
 110    already_registered := tag :: !already_registered;
 111    require1 :=
 112     (fun (tag',data) as x ->
 113      if tag=tag' then
 114       require (Obj.magic data) ~refresh_uri_in_term
 115      else
 116       !require1 x);
 117    (fun x -> tag,Obj.repr x)
 118
 119   let serialize = serialize
 120
 121   let require ~baseuri status =
 122    let dump = require0 ~baseuri in
 123     List.fold_right !require1 dump status
 124 end
 125
 126 let decompile ~baseuri =
 127  Unix.unlink (path_of_baseuri baseuri)
 128  (* WE ARE NOT REMOVING ALL THE OBJECTS YET! *)
 129 ;;
 130
 131 let fetch_obj uri =
 132  let obj = require0 ~baseuri:uri in
 133   refresh_uri_in_obj obj
 134 ;;
 135
 136 let resolve name =
 137  try
 138   HExtlib.filter_map
 139    (fun (_,name',nref) -> if name'=name then Some nref else None) !aliases
 140  with
 141   Not_found -> raise (NCicEnvironment.ObjectNotFound (lazy name))
 142 ;;
 143
 144 let aliases_of uri =
 145  try
 146   HExtlib.filter_map
 147    (fun (uri',_,nref) -> if NUri.eq uri' uri then Some nref else None) !aliases
 148  with
 149   Not_found -> raise (NCicEnvironment.ObjectNotFound (lazy (NUri.string_of_uri uri)))
 150 ;;
 151
 152 let add_obj status u obj =
 153  storage := (u,obj)::!storage;
 154   let _,height,_,_,obj = obj in
 155   let references =
 156    match obj with
 157       NCic.Constant (_,name,None,_,_) ->
 158        [u,name,NReference.reference_of_spec u NReference.Decl]
 159     | NCic.Constant (_,name,Some _,_,_) ->
 160        [u,name,NReference.reference_of_spec u (NReference.Def height)]
 161     | NCic.Fixpoint (is_ind,fl,_) ->
 162        HExtlib.list_mapi
 163         (fun (_,name,recno,_,_) i ->
 164           if is_ind then
 165            u,name,NReference.reference_of_spec u(NReference.Fix(i,recno,height))
 166           else
 167            u,name,NReference.reference_of_spec u (NReference.CoFix i)) fl
 168     | NCic.Inductive (inductive,leftno,il,_) ->
 169        List.flatten
 170         (HExtlib.list_mapi
 171          (fun (_,iname,_,cl) i ->
 172            HExtlib.list_mapi
 173             (fun (_,cname,_) j->
 174               u,cname,
 175                NReference.reference_of_spec u (NReference.Con (i,j+1,leftno))
 176             ) cl @
 177            [u,iname,
 178              NReference.reference_of_spec u
 179               (NReference.Ind (inductive,i,leftno))]
 180          ) il)
 181   in
 182   aliases := references @ !aliases;
 183   status#set_timestamp (!storage,!aliases,!cache)
 184 ;;
 185
 186 let get_obj u =
 187  try List.assq u !storage
 188  with Not_found ->
 189   try fetch_obj u
 190   with Sys_error _ ->
 191    try NUri.UriMap.find u !cache
 192    with Not_found ->
 193     let ouri = NCic2OCic.ouri_of_nuri u in
 194     try
 195       let o,_ = CicEnvironment.get_obj CicUniv.oblivion_ugraph ouri in
 196       let l = OCic2NCic.convert_obj ouri o in
 197       List.iter (fun (u,_,_,_,_ as o) -> cache:= NUri.UriMap.add u o !cache) l;
 198       HExtlib.list_last l
 199     with CicEnvironment.Object_not_found u ->
 200       raise (NCicEnvironment.ObjectNotFound
 201                (lazy (NUri.string_of_uri (OCic2NCic.nuri_of_ouri u))))
 202 ;;
 203
 204 let clear_cache () = cache := NUri.UriMap.empty;;
 205
 206 NCicEnvironment.set_get_obj get_obj;;
 207 NCicPp.set_get_obj get_obj;;