helm/software/components/ng_kernel/nCicLibrary.ml

   1 (*
   2     ||M||  This file is part of HELM, an Hypertextual, Electronic
   3     ||A||  Library of Mathematics, developed at the Computer Science
   4     ||T||  Department, University of Bologna, Italy.
   5     ||I||
   6     ||T||  HELM is free software; you can redistribute it and/or
   7     ||A||  modify it under the terms of the GNU General Public License
   8     \   /  version 2 or (at your option) any later version.
   9      \ /   This software is distributed as is, NO WARRANTY.
  10       V_______________________________________________________________ *)
  11
  12 (* $Id$ *)
  13
  14 exception LibraryOutOfSync of string Lazy.t
  15
  16 let magic = 1;;
  17
  18 let refresh_uri uri = NUri.uri_of_string (NUri.string_of_uri uri);;
  19
  20 let rec refresh_uri_in_term =
  21  function
  22     NCic.Const (NReference.Ref (u,spec)) ->
  23      NCic.Const (NReference.reference_of_spec (refresh_uri u) spec)
  24   | t -> NCicUtils.map (fun _ _ -> ()) () (fun _ -> refresh_uri_in_term) t
  25 ;;
  26
  27 let refresh_uri_in_obj (uri,height,metasenv,subst,obj_kind) =
  28  assert (metasenv = []);
  29  assert (subst = []);
  30  uri,height,metasenv,subst,
  31   NCicUntrusted.map_obj_kind refresh_uri_in_term obj_kind
  32 ;;
  33
  34 let path_of_baseuri ?(no_suffix=false) baseuri =
  35  let uri = NUri.string_of_uri baseuri in
  36  let path = String.sub uri 4 (String.length uri - 4) in
  37  let path = Helm_registry.get "matita.basedir" ^ path in
  38  let dirname = Filename.dirname path in
  39   HExtlib.mkdir dirname;
  40   if no_suffix then
  41    path
  42   else
  43    path ^ ".ng"
  44 ;;
  45
  46 let require_path path =
  47  let ch = open_in path in
  48  let mmagic,dump = Marshal.from_channel ch in
  49   close_in ch;
  50   if mmagic <> magic then
  51    raise (LibraryOutOfSync (lazy "The library is out of sync with the implementation. Please recompile the library."))
  52   else
  53    dump
  54 ;;
  55
  56 let require0 ~baseuri = require_path (path_of_baseuri baseuri);;
  57
  58 let db_path () = Helm_registry.get "matita.basedir" ^ "/ng_db.ng";;
  59
  60 type timestamp =
  61  (NUri.uri * NCic.obj) list *
  62  (NUri.uri * string * NReference.reference) list *
  63  NCic.obj NUri.UriMap.t *
  64  NUri.uri list;;
  65
  66 let time0 = [],[],NUri.UriMap.empty,[];;
  67 let storage = ref [];;
  68 let local_aliases = ref [];;
  69 let cache = ref NUri.UriMap.empty;;
  70 let includes = ref [];;
  71
  72 let load_db,set_global_aliases,get_global_aliases,add_deps,get_deps,remove_deps=
  73  let global_aliases = ref [] in
  74  let rev_includes_map = ref NUri.UriMap.empty in
  75  let store_db () =
  76   let ch = open_out (db_path ()) in
  77   Marshal.to_channel ch (magic,(!global_aliases,!rev_includes_map)) [];
  78   close_out ch in
  79  let load_db () =
  80   HExtlib.mkdir (Helm_registry.get "matita.basedir");
  81   try
  82    let ga,im = require_path (db_path ()) in
  83    let ga =
  84     List.map
  85      (fun (uri,name,NReference.Ref (uri2,spec)) ->
  86        refresh_uri uri,name,NReference.reference_of_spec (refresh_uri uri2) spec
  87      ) ga in
  88    let im =
  89     NUri.UriMap.fold
  90      (fun u l im -> NUri.UriMap.add (refresh_uri u) (List.map refresh_uri l) im
  91      ) im NUri.UriMap.empty
  92    in
  93     global_aliases := ga;
  94     rev_includes_map := im
  95   with
  96    Sys_error _ -> () in
  97  let get_deps u =
  98   let get_deps_one_step u =
  99     try NUri.UriMap.find u !rev_includes_map with Not_found -> [] in
 100   let rec aux res =
 101    function
 102       [] -> res
 103     | he::tl ->
 104        if List.mem he res then
 105         aux res tl
 106        else
 107         aux (he::res) (get_deps_one_step he @ tl)
 108   in
 109    aux [] [u] in
 110  let remove_deps u =
 111   rev_includes_map := NUri.UriMap.remove u !rev_includes_map;
 112   rev_includes_map :=
 113    NUri.UriMap.map
 114     (fun l -> List.filter (fun uri -> not (NUri.eq u uri)) l) !rev_includes_map;
 115   store_db ()
 116  in
 117   load_db,
 118   (fun ga -> global_aliases := ga; store_db ()),
 119   (fun () -> !global_aliases),
 120   (fun u l ->
 121     rev_includes_map := NUri.UriMap.add u (l @ get_deps u) !rev_includes_map;
 122     store_db ()),
 123   get_deps,
 124   remove_deps
 125 ;;
 126
 127 let init = load_db;;
 128
 129 class status =
 130  object
 131   val timestamp = (time0 : timestamp)
 132   method timestamp = timestamp
 133   method set_timestamp v = {< timestamp = v >}
 134   method set_library_status
 135    : 'status. < timestamp : timestamp; .. > as 'status -> 'self
 136    = fun o -> {< timestamp = o#timestamp >}
 137  end
 138
 139 let time_travel status =
 140  let sto,ali,cac,inc = status#timestamp in
 141   let diff_len = List.length !storage - List.length sto in
 142   let to_be_deleted,_ = HExtlib.split_nth diff_len !storage in
 143    if List.length to_be_deleted > 0 then
 144     let u,_ = HExtlib.list_last to_be_deleted in
 145      NCicEnvironment.invalidate_obj u;
 146    storage := sto; local_aliases := ali; cache := cac; includes := inc
 147 ;;
 148
 149 let serialize ~baseuri dump =
 150  let ch = open_out (path_of_baseuri baseuri) in
 151  Marshal.to_channel ch (magic,dump) [];
 152  close_out ch;
 153  List.iter
 154   (fun (uri,obj) ->
 155     let ch = open_out (path_of_baseuri uri) in
 156     Marshal.to_channel ch (magic,obj) [];
 157     close_out ch
 158   ) !storage;
 159  set_global_aliases (!local_aliases @ get_global_aliases ());
 160  List.iter (fun u -> add_deps u [baseuri]) !includes;
 161  time_travel (new status)
 162 ;;
 163
 164 module type Serializer =
 165  sig
 166   type status
 167   type obj
 168   val register:
 169    string ->
 170     ('a -> refresh_uri_in_term:(NCic.term -> NCic.term) -> status -> status) ->
 171     ('a -> obj)
 172   val serialize: baseuri:NUri.uri -> obj list -> unit
 173   val require: baseuri:NUri.uri -> status -> status
 174  end
 175
 176 module Serializer(S: sig type status end) =
 177  struct
 178   type status = S.status
 179   type obj = string * Obj.t
 180
 181   let require1 = ref (fun _ -> assert false (* unknown data*))
 182   let already_registered = ref []
 183
 184   let register tag require =
 185    assert (not (List.mem tag !already_registered));
 186    already_registered := tag :: !already_registered;
 187    require1 :=
 188     (fun (tag',data) as x ->
 189      if tag=tag' then
 190       require (Obj.magic data) ~refresh_uri_in_term
 191      else
 192       !require1 x);
 193    (fun x -> tag,Obj.repr x)
 194
 195   let serialize = serialize
 196
 197   let require ~baseuri status =
 198    includes := baseuri::!includes;
 199    let dump = require0 ~baseuri in
 200     List.fold_right !require1 dump status
 201 end
 202
 203 let decompile ~baseuri =
 204  let baseuris = get_deps baseuri in
 205  List.iter (fun baseuri ->
 206   remove_deps baseuri;
 207   HExtlib.safe_remove (path_of_baseuri baseuri);
 208   let basepath = path_of_baseuri ~no_suffix:true baseuri in
 209   try
 210    let od = Unix.opendir basepath in
 211    let rec aux names =
 212     try
 213      let name = Unix.readdir od in
 214       if name <> "." && name <> ".." then aux (name::names) else aux names
 215     with
 216      End_of_file -> names in
 217    let names = List.map (fun name -> basepath ^ "/" ^ name) (aux []) in
 218     Unix.closedir od;
 219     List.iter Unix.unlink names;
 220     HExtlib.rmdir_descend basepath;
 221     set_global_aliases
 222      (List.filter
 223       (fun (_,_,NReference.Ref (nuri,_)) ->
 224         Filename.dirname (NUri.string_of_uri nuri) <> NUri.string_of_uri baseuri
 225       ) (get_global_aliases ()))
 226   with
 227    Unix.Unix_error _ -> () (* raised by Unix.opendir, we hope :-) *)
 228  ) baseuris
 229 ;;
 230
 231 LibraryClean.set_decompile_cb
 232  (fun ~baseuri -> decompile ~baseuri:(NUri.uri_of_string baseuri));;
 233
 234 let fetch_obj uri =
 235  let obj = require0 ~baseuri:uri in
 236   refresh_uri_in_obj obj
 237 ;;
 238
 239 let resolve name =
 240  try
 241   HExtlib.filter_map
 242    (fun (_,name',nref) -> if name'=name then Some nref else None)
 243    (!local_aliases @ get_global_aliases ())
 244  with
 245   Not_found -> raise (NCicEnvironment.ObjectNotFound (lazy name))
 246 ;;
 247
 248 let aliases_of uri =
 249  try
 250   HExtlib.filter_map
 251    (fun (uri',_,nref) ->
 252      if NUri.eq uri' uri then Some nref else None) !local_aliases
 253  with
 254   Not_found -> raise (NCicEnvironment.ObjectNotFound (lazy (NUri.string_of_uri uri)))
 255 ;;
 256
 257 let add_obj status ((u,_,_,_,_) as obj) =
 258  NCicEnvironment.check_and_add_obj obj;
 259  storage := (u,obj)::!storage;
 260   let _,height,_,_,obj = obj in
 261   let references =
 262    match obj with
 263       NCic.Constant (_,name,None,_,_) ->
 264        [u,name,NReference.reference_of_spec u NReference.Decl]
 265     | NCic.Constant (_,name,Some _,_,_) ->
 266        [u,name,NReference.reference_of_spec u (NReference.Def height)]
 267     | NCic.Fixpoint (is_ind,fl,_) ->
 268        HExtlib.list_mapi
 269         (fun (_,name,recno,_,_) i ->
 270           if is_ind then
 271            u,name,NReference.reference_of_spec u(NReference.Fix(i,recno,height))
 272           else
 273            u,name,NReference.reference_of_spec u (NReference.CoFix i)) fl
 274     | NCic.Inductive (inductive,leftno,il,_) ->
 275        List.flatten
 276         (HExtlib.list_mapi
 277          (fun (_,iname,_,cl) i ->
 278            HExtlib.list_mapi
 279             (fun (_,cname,_) j->
 280               u,cname,
 281                NReference.reference_of_spec u (NReference.Con (i,j+1,leftno))
 282             ) cl @
 283            [u,iname,
 284              NReference.reference_of_spec u
 285               (NReference.Ind (inductive,i,leftno))]
 286          ) il)
 287   in
 288   local_aliases := references @ !local_aliases;
 289   status#set_timestamp (!storage,!local_aliases,!cache,!includes)
 290 ;;
 291
 292 let get_obj u =
 293  try List.assq u !storage
 294  with Not_found ->
 295   try fetch_obj u
 296   with Sys_error _ ->
 297    try NUri.UriMap.find u !cache
 298    with Not_found ->
 299     let ouri = NCic2OCic.ouri_of_nuri u in
 300     try
 301       let o,_ = CicEnvironment.get_obj CicUniv.oblivion_ugraph ouri in
 302       let l = OCic2NCic.convert_obj ouri o in
 303       List.iter (fun (u,_,_,_,_ as o) -> cache:= NUri.UriMap.add u o !cache) l;
 304       HExtlib.list_last l
 305     with CicEnvironment.Object_not_found u ->
 306       raise (NCicEnvironment.ObjectNotFound
 307                (lazy (NUri.string_of_uri (OCic2NCic.nuri_of_ouri u))))
 308 ;;
 309
 310 let clear_cache () = cache := NUri.UriMap.empty;;
 311
 312 NCicEnvironment.set_get_obj get_obj;;
 313 NCicPp.set_get_obj get_obj;;