helm/software/components/ng_kernel/nCicLibrary.ml

   1 (*
   2     ||M||  This file is part of HELM, an Hypertextual, Electronic
   3     ||A||  Library of Mathematics, developed at the Computer Science
   4     ||T||  Department, University of Bologna, Italy.
   5     ||I||
   6     ||T||  HELM is free software; you can redistribute it and/or
   7     ||A||  modify it under the terms of the GNU General Public License
   8     \   /  version 2 or (at your option) any later version.
   9      \ /   This software is distributed as is, NO WARRANTY.
  10       V_______________________________________________________________ *)
  11
  12 (* $Id$ *)
  13
  14 exception LibraryOutOfSync of string Lazy.t
  15
  16 type timestamp =
  17  (NUri.uri * NCic.obj) list *
  18  (NUri.uri * string * NReference.reference) list *
  19  NCic.obj NUri.UriMap.t;;
  20
  21 let time0 = [],[],NUri.UriMap.empty;;
  22 let storage = ref [];;
  23 let aliases = ref [];;
  24 let cache = ref NUri.UriMap.empty;;
  25
  26 class status =
  27  object
  28   val timestamp = (time0 : timestamp)
  29   method timestamp = timestamp
  30   method set_timestamp v = {< timestamp = v >}
  31   method set_library_status
  32    : 'status. < timestamp : timestamp; .. > as 'status -> 'self
  33    = fun o -> {< timestamp = o#timestamp >}
  34  end
  35
  36 let time_travel status =
  37  let sto,ali,cac = status#timestamp in
  38   storage := sto; aliases := ali; cache := cac
  39 ;;
  40
  41 let path_of_baseuri baseuri =
  42  let uri = NUri.string_of_uri baseuri in
  43  let path = String.sub uri 4 (String.length uri - 4) in
  44  let path = Helm_registry.get "matita.basedir" ^ path in
  45  let dirname = Filename.dirname path in
  46   HExtlib.mkdir dirname;
  47   path ^ ".ng"
  48 ;;
  49
  50 let magic = 0;;
  51
  52 let require0 ~baseuri =
  53  let ch = open_in (path_of_baseuri baseuri) in
  54  let mmagic,dump = Marshal.from_channel ch in
  55   close_in ch;
  56   if mmagic <> magic then
  57    raise (LibraryOutOfSync (lazy "The library is out of sync with the implementation. Please recompile the library."))
  58   else
  59    dump
  60 ;;
  61
  62 let serialize ~baseuri dump =
  63  let ch = open_out (path_of_baseuri baseuri) in
  64  Marshal.to_channel ch (magic,dump) [Marshal.Closures];
  65  close_out ch;
  66  List.iter
  67   (fun (uri,obj) ->
  68     let ch = open_out (path_of_baseuri uri) in
  69     Marshal.to_channel ch (magic,obj) [];
  70     close_out ch
  71   ) !storage;
  72  time_travel (new status)
  73 ;;
  74
  75 let refresh_uri uri = NUri.uri_of_string (NUri.string_of_uri uri);;
  76
  77 let rec refresh_uri_in_term =
  78  function
  79     NCic.Const (NReference.Ref (u,spec)) ->
  80      NCic.Const (NReference.reference_of_spec (refresh_uri u) spec)
  81   | t -> NCicUtils.map (fun _ _ -> ()) () (fun _ -> refresh_uri_in_term) t
  82 ;;
  83
  84 let refresh_uri_in_obj (uri,height,metasenv,subst,obj_kind) =
  85  assert (metasenv = []);
  86  assert (subst = []);
  87  uri,height,metasenv,subst,
  88   NCicUntrusted.map_obj_kind refresh_uri_in_term obj_kind
  89 ;;
  90
  91 module type Serializer =
  92  sig
  93   type status
  94   type obj
  95   val register:
  96    string ->
  97     ('a -> refresh_uri_in_term:(NCic.term -> NCic.term) -> status -> status) ->
  98     ('a -> obj)
  99   val serialize: baseuri:NUri.uri -> obj list -> unit
 100   val require: baseuri:NUri.uri -> status -> status
 101  end
 102
 103 module Serializer(S: sig type status end) =
 104  struct
 105   type status = S.status
 106   type obj = string * Obj.t
 107
 108   let require1 = ref (fun _ -> assert false (* unknown data*))
 109   let already_registered = ref []
 110
 111   let register tag require =
 112    assert (not (List.mem tag !already_registered));
 113    already_registered := tag :: !already_registered;
 114    require1 :=
 115     (fun (tag',data) as x ->
 116      if tag=tag' then
 117       require (Obj.magic data) ~refresh_uri_in_term
 118      else
 119       !require1 x);
 120    (fun x -> tag,Obj.repr x)
 121
 122   let serialize = serialize
 123
 124   let require ~baseuri status =
 125    let dump = require0 ~baseuri in
 126     List.fold_right !require1 dump status
 127 end
 128
 129 let decompile ~baseuri =
 130  Unix.unlink (path_of_baseuri baseuri)
 131  (* WE ARE NOT REMOVING ALL THE OBJECTS YET! *)
 132 ;;
 133
 134 let fetch_obj uri =
 135  let obj = require0 ~baseuri:uri in
 136   refresh_uri_in_obj obj
 137 ;;
 138
 139 let resolve name =
 140  try
 141   HExtlib.filter_map
 142    (fun (_,name',nref) -> if name'=name then Some nref else None) !aliases
 143  with
 144   Not_found -> raise (NCicEnvironment.ObjectNotFound (lazy name))
 145 ;;
 146
 147 let aliases_of uri =
 148  try
 149   HExtlib.filter_map
 150    (fun (uri',_,nref) -> if NUri.eq uri' uri then Some nref else None) !aliases
 151  with
 152   Not_found -> raise (NCicEnvironment.ObjectNotFound (lazy (NUri.string_of_uri uri)))
 153 ;;
 154
 155 let add_obj status u obj =
 156  storage := (u,obj)::!storage;
 157   let _,height,_,_,obj = obj in
 158   let references =
 159    match obj with
 160       NCic.Constant (_,name,None,_,_) ->
 161        [u,name,NReference.reference_of_spec u NReference.Decl]
 162     | NCic.Constant (_,name,Some _,_,_) ->
 163        [u,name,NReference.reference_of_spec u (NReference.Def height)]
 164     | NCic.Fixpoint (is_ind,fl,_) ->
 165        HExtlib.list_mapi
 166         (fun (_,name,recno,_,_) i ->
 167           if is_ind then
 168            u,name,NReference.reference_of_spec u(NReference.Fix(i,recno,height))
 169           else
 170            u,name,NReference.reference_of_spec u (NReference.CoFix i)) fl
 171     | NCic.Inductive (inductive,leftno,il,_) ->
 172        List.flatten
 173         (HExtlib.list_mapi
 174          (fun (_,iname,_,cl) i ->
 175            HExtlib.list_mapi
 176             (fun (_,cname,_) j->
 177               u,cname,
 178                NReference.reference_of_spec u (NReference.Con (i,j+1,leftno))
 179             ) cl @
 180            [u,iname,
 181              NReference.reference_of_spec u
 182               (NReference.Ind (inductive,i,leftno))]
 183          ) il)
 184   in
 185   aliases := references @ !aliases;
 186   status#set_timestamp (!storage,!aliases,!cache)
 187 ;;
 188
 189 let get_obj u =
 190  try List.assq u !storage
 191  with Not_found ->
 192   try fetch_obj u
 193   with Sys_error _ ->
 194    try NUri.UriMap.find u !cache
 195    with Not_found ->
 196     let ouri = NCic2OCic.ouri_of_nuri u in
 197     try
 198       let o,_ = CicEnvironment.get_obj CicUniv.oblivion_ugraph ouri in
 199       let l = OCic2NCic.convert_obj ouri o in
 200       List.iter (fun (u,_,_,_,_ as o) -> cache:= NUri.UriMap.add u o !cache) l;
 201       HExtlib.list_last l
 202     with CicEnvironment.Object_not_found u ->
 203       raise (NCicEnvironment.ObjectNotFound
 204                (lazy (NUri.string_of_uri (OCic2NCic.nuri_of_ouri u))))
 205 ;;
 206
 207 let clear_cache () = cache := NUri.UriMap.empty;;
 208
 209 NCicEnvironment.set_get_obj get_obj;;
 210 NCicPp.set_get_obj get_obj;;