helm/software/components/ng_kernel/nCicPp.ml

   1 (*
   2     ||M||  This file is part of HELM, an Hypertextual, Electronic
   3     ||A||  Library of Mathematics, developed at the Computer Science
   4     ||T||  Department, University of Bologna, Italy.
   5     ||I||
   6     ||T||  HELM is free software; you can redistribute it and/or
   7     ||A||  modify it under the terms of the GNU General Public License
   8     \   /  version 2 or (at your option) any later version.
   9      \ /   This software is distributed as is, NO WARRANTY.
  10       V_______________________________________________________________ *)
  11
  12 (* $Id$ *)
  13
  14 module C = NCic
  15 module R = NReference
  16 module F = Format
  17
  18 let head_beta_reduce = ref (fun ~upto:_ _ -> assert false);;
  19 let set_head_beta_reduce = (:=) head_beta_reduce;;
  20
  21 let get_obj = ref (fun _ -> assert false);;
  22 let set_get_obj f = get_obj := f;;
  23
  24 let r2s pp_fix_name r =
  25   try
  26     match r with
  27     | R.Ref (u,R.Ind (_,i,_)) ->
  28         (match !get_obj u with
  29         | _,_,_,_, C.Inductive (_,_,itl,_) ->
  30             let _,name,_,_ = List.nth itl i in name
  31         | _ -> assert false)
  32     | R.Ref (u,R.Con (i,j,_)) ->
  33         (match !get_obj u with
  34         | _,_,_,_, C.Inductive (_,_,itl,_) ->
  35             let _,_,_,cl = List.nth itl i in
  36             let _,name,_ = List.nth cl (j-1) in name
  37         | _ -> assert false)
  38     | R.Ref (u,(R.Decl | R.Def _)) ->
  39         (match !get_obj u with
  40         | _,_,_,_, C.Constant (_,name,_,_,_) -> name
  41         | _ -> assert false)
  42     | R.Ref (u,(R.Fix (i,_,_)|R.CoFix i)) ->
  43         (match !get_obj u with
  44         | _,_,_,_, C.Fixpoint (_,fl,_) ->
  45             if pp_fix_name then
  46               let _,name,_,_,_ = List.nth fl i in name
  47             else
  48               NUri.name_of_uri u ^"("^ string_of_int i ^ ")"
  49         | _ -> assert false)
  50   with
  51   | NCicEnvironment.ObjectNotFound _
  52   | Failure "nth"
  53   | Invalid_argument "List.nth" -> R.string_of_reference r
  54
  55 ;;
  56
  57 let string_of_implicit_annotation = function
  58   | `Closed -> "▪"
  59   | `Type -> ""
  60   | `Hole -> "□"
  61   | `Term -> "Term"
  62   | `Typeof x -> "Ty("^string_of_int x^")"
  63 ;;
  64
  65 let ppterm ~formatter:f ~context ~subst ~metasenv:_ ?(inside_fix=false) t =
  66  let rec aux ?(toplevel=false) ctx = function
  67   | C.Rel m ->
  68         (try
  69            let name = List.nth ctx (m-1) in
  70            F.fprintf f "%s" (if name = "_" then "__"^string_of_int m else name)
  71         with Failure "nth" | Invalid_argument "List.nth" ->
  72             F.fprintf f " -%d" (m - List.length ctx))
  73   | C.Const r -> F.fprintf f "%s" (r2s inside_fix r)
  74   | C.Prod ("_",s,t) ->
  75       if not toplevel then F.fprintf f "(";
  76       F.fprintf f "@[<hov 1>";
  77       (match s with
  78       | C.Prod ("_",_,_) -> aux ~toplevel:false ctx s
  79       | _ -> aux ~toplevel:true ctx s);
  80       F.fprintf f "@;→ ";
  81       aux ~toplevel:true ("_"::ctx) t;
  82       F.fprintf f "@]";
  83       if not toplevel then F.fprintf f ")";
  84   | C.Prod (name,s,t) ->
  85       if not toplevel then F.fprintf f "(";
  86       F.fprintf f "@[<hov 1>";
  87       F.fprintf f "@[<hov 2>∀%s:@;" name;
  88       aux ~toplevel:true ctx s;
  89       F.fprintf f "@].@;";
  90       aux ~toplevel:true (name::ctx) t;
  91       F.fprintf f "@]";
  92       if not toplevel then F.fprintf f ")";
  93   | C.Lambda (name,s,t) ->
  94       if not toplevel then F.fprintf f "(";
  95       F.fprintf f "@[<hov 1>";
  96       F.fprintf f "λ%s:" name;
  97       aux ~toplevel:true ctx s;
  98       F.fprintf f ".@;";
  99       aux ~toplevel:true (name::ctx) t;
 100       F.fprintf f "@]";
 101       if not toplevel then F.fprintf f ")";
 102   | C.LetIn (name,ty,t,b) ->
 103       if not toplevel then F.fprintf f "(";
 104       F.fprintf f "@[<hov 1>";
 105       F.fprintf f "let %s:@;" name;
 106       aux ~toplevel:true ctx ty;
 107       F.fprintf f "@;≝ ";
 108       aux ~toplevel:true ctx t;
 109       F.fprintf f "@;in@;";
 110       (aux ~toplevel:true (name::ctx) b);
 111       F.fprintf f "@]";
 112       if not toplevel then F.fprintf f ")";
 113   | C.Match (r,oty,t,pl) ->
 114       F.fprintf f "@[<hov>match ";
 115       aux ~toplevel:true ctx t;
 116       F.fprintf f "@;return ";
 117       aux ~toplevel:true ctx oty;
 118       F.fprintf f "@; @[<v>[ ";
 119       if pl <> [] then
 120         begin
 121           F.fprintf f "@[<hov 2>%s ⇒@;"
 122             (try r2s inside_fix (R.mk_constructor 1 r)
 123              with R.IllFormedReference _ -> "#ERROR#");
 124           aux ~toplevel:true ctx (List.hd pl);
 125           F.fprintf f "@]";
 126           ignore(List.fold_left
 127             (fun i t ->
 128              F.fprintf f "@;| @[<hov 2>%s ⇒@;"
 129                (try r2s inside_fix (R.mk_constructor i r)
 130                 with R.IllFormedReference _ -> "#ERROR#");
 131              aux ~toplevel:true ctx t;
 132              F.fprintf f "@]";
 133              i+1)
 134             2 (List.tl pl));
 135         end;
 136      F.fprintf f "]@] @]";
 137   | C.Appl [] | C.Appl [_] | C.Appl (C.Appl _::_) ->
 138       F.fprintf f "BAD APPLICATION"
 139   | C.Appl (C.Meta (n,lc) :: args) when List.mem_assoc n subst ->
 140       let _,_,t,_ = List.assoc n subst in
 141       let hd = NCicSubstitution.subst_meta lc t in
 142       aux ctx
 143         (!head_beta_reduce ~upto:(List.length args)
 144           (match hd with
 145           | NCic.Appl l -> NCic.Appl (l@args)
 146           | _ -> NCic.Appl (hd :: args)))
 147   | C.Appl l ->
 148       F.fprintf f "@[<hov 2>";
 149       if not toplevel then F.fprintf f "(";
 150       aux ctx (List.hd l);
 151       List.iter (fun x -> F.fprintf f "@;";aux ctx x) (List.tl l);
 152       if not toplevel then F.fprintf f ")";
 153       F.fprintf f "@]"
 154   | C.Implicit annot ->
 155       F.fprintf f "?%s" (string_of_implicit_annotation annot)
 156   | C.Meta (n,lc) when List.mem_assoc n subst ->
 157        let _,_,t,_ = List.assoc n subst in
 158        aux ctx (NCicSubstitution.subst_meta lc t)
 159   | C.Meta (n,(shift,C.Irl len)) ->
 160        F.fprintf f "?%d(%d,%d)" n shift len
 161   | C.Meta (n,(shift,C.Ctx l)) ->
 162        F.fprintf f "?%d(%d,[" n shift;
 163        if List.length l > 0 then
 164          begin
 165            aux ctx (NCicSubstitution.lift shift (List.hd l));
 166            List.iter (fun x -> F.fprintf f ",";aux ctx x)
 167             (List.map (NCicSubstitution.lift shift) (List.tl l));
 168          end;
 169        F.fprintf f "])"
 170   | C.Sort C.Prop -> F.fprintf f "Prop"
 171   | C.Sort (C.Type []) -> F.fprintf f "Type0"
 172   | C.Sort (C.Type [false, u]) -> F.fprintf f "%s" (NUri.name_of_uri u)
 173   | C.Sort (C.Type [true, u]) -> F.fprintf f "S(%s)" (NUri.name_of_uri u)
 174   | C.Sort (C.Type l) ->
 175       F.fprintf f "Max(";
 176       aux ctx (C.Sort (C.Type [List.hd l]));
 177       List.iter (fun x -> F.fprintf f ",";aux ctx (C.Sort (C.Type [x])))
 178        (List.tl l);
 179       F.fprintf f ")"
 180  in
 181   aux ~toplevel:true (List.map fst context) t
 182 ;;
 183
 184 let on_buffer f t =
 185   let buff = Buffer.create 100 in
 186   let formatter = F.formatter_of_buffer buff in
 187   f ~formatter:formatter t;
 188   F.fprintf formatter "@?";
 189   Buffer.contents buff
 190 ;;
 191
 192 let ppterm ~formatter ~context ~subst ~metasenv ?(margin=80) ?inside_fix t =
 193   F.set_margin margin;
 194   ppterm ~formatter ~context ~subst ~metasenv ?inside_fix t
 195 ;;
 196
 197 let rec ppcontext ~formatter ?(sep="\n") ~subst ~metasenv = function
 198   | [] -> ()
 199   | (name, NCic.Decl t) :: tl ->
 200       ppcontext ~formatter ~sep ~subst ~metasenv tl;
 201       F.fprintf formatter "%s: " name;
 202       ppterm ~formatter ~subst ~metasenv ~context:tl t;
 203       F.fprintf formatter "%s" sep
 204   | (name, NCic.Def (bo,ty)) :: tl->
 205       ppcontext ~formatter ~sep ~subst ~metasenv tl;
 206       F.fprintf formatter "%s: " name;
 207       ppterm ~formatter ~subst ~metasenv ~context:tl ty;
 208       F.fprintf formatter " := ";
 209       ppterm ~formatter ~subst ~metasenv ~context:tl bo;
 210       F.fprintf formatter "%s" sep
 211 ;;
 212
 213 let rec ppmetasenv ~formatter ~subst metasenv = function
 214   | [] -> ()
 215   | (i,(name, ctx, ty)) :: tl ->
 216       F.fprintf formatter "@[<hov 2>";
 217       let name = match name with Some n -> "("^n^")" | _ -> "" in
 218       ppcontext ~formatter ~sep:"; " ~subst ~metasenv ctx;
 219       F.fprintf formatter "@;⊢@;?%d%s :@;" i name;
 220       ppterm ~formatter ~metasenv ~subst ~context:ctx ty;
 221       F.fprintf formatter "@]@\n";
 222       ppmetasenv ~formatter ~subst metasenv tl
 223 ;;
 224
 225 let ppmetasenv ~formatter ~subst metasenv =
 226  ppmetasenv ~formatter ~subst metasenv metasenv
 227 ;;
 228
 229 let rec ppsubst ~formatter ~subst ~metasenv = function
 230   | [] -> ()
 231   | (i,(name, ctx, t, ty)) :: tl ->
 232       let name = match name with Some n -> "("^n^")" | _ -> "" in
 233       ppcontext ~formatter ~sep:"; " ~subst ~metasenv ctx;
 234       F.fprintf formatter " ⊢ ?%d%s := " i name;
 235       ppterm ~formatter ~metasenv ~subst ~context:ctx t;
 236       F.fprintf formatter " : ";
 237       ppterm ~formatter ~metasenv ~subst ~context:ctx ty;
 238       F.fprintf formatter "\n";
 239       ppsubst ~formatter ~subst ~metasenv tl
 240 ;;
 241
 242 let ppsubst ~formatter ~metasenv subst =
 243  ppsubst ~formatter ~metasenv ~subst subst
 244 ;;
 245
 246 let ppobj ~formatter (u,_,metasenv, subst, o) =
 247   F.fprintf formatter "metasenv:\n";
 248   ppmetasenv ~formatter ~subst metasenv;
 249   F.fprintf formatter "\n";
 250   F.fprintf formatter "subst:\n";
 251   (*ppsubst subst ~formatter ~metasenv;*) F.fprintf formatter "...";
 252   F.fprintf formatter "\n";
 253   match o with
 254   | NCic.Fixpoint (b, fl, _) ->
 255       F.fprintf formatter "{%s}@\n@[<hov 0>" (NUri.string_of_uri u);
 256       F.fprintf formatter "@[<hov 2>%s"(if b then "let rec " else "let corec ");
 257       HExtlib.list_iter_sep
 258        ~sep:(fun () -> F.fprintf formatter "@\n@[<hov 2>and ")
 259        (fun (_,name,n,ty,bo) ->
 260         F.fprintf formatter "%s on %d :@;" name n;
 261         ppterm ~formatter ~metasenv ~subst ~context:[] ty;
 262         F.fprintf formatter "@]@;@[<hov 2>:=@;";
 263         ppterm ~formatter ~metasenv ~subst ~context:[] ~inside_fix:true bo;
 264         F.fprintf formatter "@]") fl;
 265         F.fprintf formatter "@]"
 266   | NCic.Inductive (b, leftno,tyl, _) ->
 267       F.fprintf formatter "{%s} with %d fixed params@\n@[<hov 0>@[<hov 2>%s"
 268        (NUri.string_of_uri u) leftno
 269        (if b then "inductive " else "coinductive ");
 270       HExtlib.list_iter_sep
 271         ~sep:(fun () -> F.fprintf formatter "@\n@[<hov 2>and ")
 272        (fun (_,name,ty,cl) ->
 273           F.fprintf formatter "%s:@;" name;
 274           ppterm ~formatter ~metasenv ~subst ~context:[] ty;
 275           F.fprintf formatter "@]@;@[<hov 3>:=@;";
 276           HExtlib.list_iter_sep ~sep:(fun () -> F.fprintf formatter "@;")
 277            (fun (_,name,ty) ->
 278              F.fprintf formatter "| %s: " name;
 279              ppterm ~formatter ~metasenv ~subst ~context:[] ty;)
 280            cl;
 281           F.fprintf formatter "@]"
 282         ) tyl ;
 283         F.fprintf formatter "@]"
 284   | NCic.Constant (_,name,None,ty, _) ->
 285      F.fprintf formatter "{%s}@\n@[<hov 2>axiom %s :@;" (NUri.string_of_uri u) name;
 286      ppterm ~formatter ~metasenv ~subst ~context:[] ty;
 287      F.fprintf formatter "@]@\n"
 288   | NCic.Constant (_,name,Some bo,ty, _) ->
 289      F.fprintf formatter "{%s}@\n@[<hov 0>@[<hov 2>definition %s :@;" (NUri.string_of_uri u) name;
 290      ppterm ~formatter ~metasenv ~subst ~context:[] ty;
 291      F.fprintf formatter "@]@;@[<hov 2>:=@;";
 292      ppterm ~formatter ~metasenv ~subst ~context:[] bo;
 293      F.fprintf formatter "@]@\n@]"
 294 ;;
 295
 296 let ppterm ~context ~subst ~metasenv ?margin ?inside_fix t =
 297  on_buffer (ppterm ~context ~subst ~metasenv ?margin ?inside_fix) t
 298 ;;
 299
 300 let ppcontext ?sep ~subst ~metasenv ctx =
 301  on_buffer (ppcontext ?sep ~subst ~metasenv) ctx
 302 ;;
 303
 304 let ppmetasenv ~subst metasenv = on_buffer (ppmetasenv ~subst) metasenv;;
 305
 306 let ppsubst ~metasenv subst = on_buffer (ppsubst ~metasenv) subst;;
 307
 308 let ppobj obj = on_buffer ppobj obj;;
 309
 310 let _ = NCicSubstitution.set_ppterm (ppterm ~margin:80);;