helm/software/components/ng_kernel/nCicPp.ml

   1 (*
   2     ||M||  This file is part of HELM, an Hypertextual, Electronic
   3     ||A||  Library of Mathematics, developed at the Computer Science
   4     ||T||  Department, University of Bologna, Italy.
   5     ||I||
   6     ||T||  HELM is free software; you can redistribute it and/or
   7     ||A||  modify it under the terms of the GNU General Public License
   8     \   /  version 2 or (at your option) any later version.
   9      \ /   This software is distributed as is, NO WARRANTY.
  10       V_______________________________________________________________ *)
  11
  12 (* $Id$ *)
  13
  14 module C = NCic
  15 module R = NReference
  16 module F = Format
  17
  18 let head_beta_reduce = ref (fun ~upto:_ _ -> assert false);;
  19 let set_head_beta_reduce = (:=) head_beta_reduce;;
  20
  21 let r2s pp_fix_name r =
  22   try
  23     match r with
  24     | R.Ref (u,R.Ind (_,i,_)) ->
  25         (match NCicLibrary.get_obj u with
  26         | _,_,_,_, C.Inductive (_,_,itl,_) ->
  27             let _,name,_,_ = List.nth itl i in name
  28         | _ -> assert false)
  29     | R.Ref (u,R.Con (i,j,_)) ->
  30         (match NCicLibrary.get_obj u with
  31         | _,_,_,_, C.Inductive (_,_,itl,_) ->
  32             let _,_,_,cl = List.nth itl i in
  33             let _,name,_ = List.nth cl (j-1) in name
  34         | _ -> assert false)
  35     | R.Ref (u,(R.Decl | R.Def _)) ->
  36         (match NCicLibrary.get_obj u with
  37         | _,_,_,_, C.Constant (_,name,_,_,_) -> name
  38         | _ -> assert false)
  39     | R.Ref (u,(R.Fix (i,_,_)|R.CoFix i)) ->
  40         (match NCicLibrary.get_obj u with
  41         | _,_,_,_, C.Fixpoint (_,fl,_) ->
  42             if pp_fix_name then
  43               let _,name,_,_,_ = List.nth fl i in name
  44             else
  45               NUri.name_of_uri u ^"("^ string_of_int i ^ ")"
  46         | _ -> assert false)
  47   with
  48   | NCicLibrary.ObjectNotFound _
  49   | Failure "nth"
  50   | Invalid_argument "List.nth" -> R.string_of_reference r
  51
  52 ;;
  53
  54 let string_of_implicit_annotation = function
  55   | `Closed -> "▪"
  56   | `Type -> ""
  57   | `Hole -> "□"
  58   | `Term -> "Term"
  59   | `Typeof x -> "Ty("^string_of_int x^")"
  60 ;;
  61
  62 let ppterm ~formatter:f ~context ~subst ~metasenv:_ ?(inside_fix=false) t =
  63  let rec aux ?(toplevel=false) ctx = function
  64   | C.Rel m ->
  65         (try
  66            let name = List.nth ctx (m-1) in
  67            F.fprintf f "%s" (if name = "_" then "__"^string_of_int m else name)
  68         with Failure "nth" | Invalid_argument "List.nth" ->
  69             F.fprintf f " -%d" (m - List.length ctx))
  70   | C.Const r -> F.fprintf f "%s" (r2s inside_fix r)
  71   | C.Prod ("_",s,t) ->
  72       if not toplevel then F.fprintf f "(";
  73       F.fprintf f "@[<hov 1>";
  74       (match s with
  75       | C.Prod ("_",_,_) -> aux ~toplevel:false ctx s
  76       | _ -> aux ~toplevel:true ctx s);
  77       F.fprintf f "@;→ ";
  78       aux ~toplevel:true ("_"::ctx) t;
  79       F.fprintf f "@]";
  80       if not toplevel then F.fprintf f ")";
  81   | C.Prod (name,s,t) ->
  82       if not toplevel then F.fprintf f "(";
  83       F.fprintf f "@[<hov 1>";
  84       F.fprintf f "@[<hov 2>∀%s:@;" name;
  85       aux ~toplevel:true ctx s;
  86       F.fprintf f "@].@;";
  87       aux ~toplevel:true (name::ctx) t;
  88       F.fprintf f "@]";
  89       if not toplevel then F.fprintf f ")";
  90   | C.Lambda (name,s,t) ->
  91       if not toplevel then F.fprintf f "(";
  92       F.fprintf f "@[<hov 1>";
  93       F.fprintf f "λ%s:" name;
  94       aux ~toplevel:true ctx s;
  95       F.fprintf f ".@;";
  96       aux ~toplevel:true (name::ctx) t;
  97       F.fprintf f "@]";
  98       if not toplevel then F.fprintf f ")";
  99   | C.LetIn (name,ty,t,b) ->
 100       if not toplevel then F.fprintf f "(";
 101       F.fprintf f "@[<hov 1>";
 102       F.fprintf f "let %s:@;" name;
 103       aux ~toplevel:true ctx ty;
 104       F.fprintf f "@;≝ ";
 105       aux ~toplevel:true ctx t;
 106       F.fprintf f "@;in@;";
 107       (aux ~toplevel:true (name::ctx) b);
 108       F.fprintf f "@]";
 109       if not toplevel then F.fprintf f ")";
 110   | C.Match (r,oty,t,pl) ->
 111       F.fprintf f "@[<hov>match ";
 112       aux ~toplevel:true ctx t;
 113       F.fprintf f "@;return ";
 114       aux ~toplevel:true ctx oty;
 115       F.fprintf f "@; @[<v>[ ";
 116       if pl <> [] then
 117         begin
 118           F.fprintf f "@[<hov 2>%s ⇒@;"
 119             (try r2s inside_fix (R.mk_constructor 1 r)
 120              with R.IllFormedReference _ -> "#ERROR#");
 121           aux ~toplevel:true ctx (List.hd pl);
 122           F.fprintf f "@]";
 123           ignore(List.fold_left
 124             (fun i t ->
 125              F.fprintf f "@;| @[<hov 2>%s ⇒@;"
 126                (try r2s inside_fix (R.mk_constructor i r)
 127                 with R.IllFormedReference _ -> "#ERROR#");
 128              aux ~toplevel:true ctx t;
 129              F.fprintf f "@]";
 130              i+1)
 131             2 (List.tl pl));
 132         end;
 133      F.fprintf f "]@] @]";
 134   | C.Appl [] | C.Appl [_] | C.Appl (C.Appl _::_) ->
 135       F.fprintf f "BAD APPLICATION"
 136   | C.Appl (C.Meta (n,lc) :: args) when List.mem_assoc n subst ->
 137       let _,_,t,_ = List.assoc n subst in
 138       let hd = NCicSubstitution.subst_meta lc t in
 139       aux ctx
 140         (!head_beta_reduce ~upto:(List.length args)
 141           (match hd with
 142           | NCic.Appl l -> NCic.Appl (l@args)
 143           | _ -> NCic.Appl (hd :: args)))
 144   | C.Appl l ->
 145       F.fprintf f "@[<hov 2>";
 146       if not toplevel then F.fprintf f "(";
 147       aux ctx (List.hd l);
 148       List.iter (fun x -> F.fprintf f "@;";aux ctx x) (List.tl l);
 149       if not toplevel then F.fprintf f ")";
 150       F.fprintf f "@]"
 151   | C.Implicit annot ->
 152       F.fprintf f "?%s" (string_of_implicit_annotation annot)
 153   | C.Meta (n,lc) when List.mem_assoc n subst ->
 154        let _,_,t,_ = List.assoc n subst in
 155        aux ctx (NCicSubstitution.subst_meta lc t)
 156   | C.Meta (n,(shift,C.Irl len)) ->
 157        F.fprintf f "?%d(%d,%d)" n shift len
 158   | C.Meta (n,(shift,C.Ctx l)) ->
 159        F.fprintf f "?%d(%d,[" n shift;
 160        if List.length l > 0 then
 161          begin
 162            aux ctx (NCicSubstitution.lift shift (List.hd l));
 163            List.iter (fun x -> F.fprintf f ",";aux ctx x)
 164             (List.map (NCicSubstitution.lift shift) (List.tl l));
 165          end;
 166        F.fprintf f "])"
 167   | C.Sort C.Prop -> F.fprintf f "Prop"
 168   | C.Sort (C.Type []) -> F.fprintf f "Type0"
 169   | C.Sort (C.Type [false, u]) -> F.fprintf f "%s" (NUri.name_of_uri u)
 170   | C.Sort (C.Type [true, u]) -> F.fprintf f "S(%s)" (NUri.name_of_uri u)
 171   | C.Sort (C.Type l) ->
 172       F.fprintf f "Max(";
 173       aux ctx (C.Sort (C.Type [List.hd l]));
 174       List.iter (fun x -> F.fprintf f ",";aux ctx (C.Sort (C.Type [x])))
 175        (List.tl l);
 176       F.fprintf f ")"
 177  in
 178   aux ~toplevel:true (List.map fst context) t
 179 ;;
 180
 181 let on_buffer f t =
 182   let buff = Buffer.create 100 in
 183   let formatter = F.formatter_of_buffer buff in
 184   f ~formatter:formatter t;
 185   F.fprintf formatter "@?";
 186   Buffer.contents buff
 187 ;;
 188
 189 let ppterm ~formatter ~context ~subst ~metasenv ?(margin=80) ?inside_fix t =
 190   F.set_margin margin;
 191   ppterm ~formatter ~context ~subst ~metasenv ?inside_fix t
 192 ;;
 193
 194 let rec ppcontext ~formatter ?(sep="\n") ~subst ~metasenv = function
 195   | [] -> ()
 196   | (name, NCic.Decl t) :: tl ->
 197       ppcontext ~formatter ~sep ~subst ~metasenv tl;
 198       F.fprintf formatter "%s: " name;
 199       ppterm ~formatter ~subst ~metasenv ~context:tl t;
 200       F.fprintf formatter "%s" sep
 201   | (name, NCic.Def (bo,ty)) :: tl->
 202       ppcontext ~formatter ~sep ~subst ~metasenv tl;
 203       F.fprintf formatter "%s: " name;
 204       ppterm ~formatter ~subst ~metasenv ~context:tl ty;
 205       F.fprintf formatter " := ";
 206       ppterm ~formatter ~subst ~metasenv ~context:tl bo;
 207       F.fprintf formatter "%s" sep
 208 ;;
 209
 210 let rec ppmetasenv ~formatter ~subst metasenv = function
 211   | [] -> ()
 212   | (i,(name, ctx, ty)) :: tl ->
 213       let name = match name with Some n -> "("^n^")" | _ -> "" in
 214       ppcontext ~formatter ~sep:"; " ~subst ~metasenv ctx;
 215       F.fprintf formatter " ⊢ ?%d%s : " i name;
 216       ppterm ~formatter ~metasenv ~subst ~context:ctx ty;
 217       F.fprintf formatter "\n";
 218       ppmetasenv ~formatter ~subst metasenv tl
 219 ;;
 220
 221 let ppmetasenv ~formatter ~subst metasenv =
 222  ppmetasenv ~formatter ~subst metasenv metasenv
 223 ;;
 224
 225 let rec ppsubst ~formatter ~subst ~metasenv = function
 226   | [] -> ()
 227   | (i,(name, ctx, t, ty)) :: tl ->
 228       let name = match name with Some n -> "("^n^")" | _ -> "" in
 229       ppcontext ~formatter ~sep:"; " ~subst ~metasenv ctx;
 230       F.fprintf formatter " ⊢ ?%d%s := " i name;
 231       ppterm ~formatter ~metasenv ~subst ~context:ctx t;
 232       F.fprintf formatter " : ";
 233       ppterm ~formatter ~metasenv ~subst ~context:ctx ty;
 234       F.fprintf formatter "\n";
 235       ppsubst ~formatter ~subst ~metasenv tl
 236 ;;
 237
 238 let ppsubst ~formatter ~metasenv subst =
 239  ppsubst ~formatter ~metasenv ~subst subst
 240 ;;
 241
 242 let ppobj ~formatter (u,_,metasenv, subst, o) =
 243   F.fprintf formatter "metasenv:\n";
 244   ppmetasenv ~formatter ~subst metasenv;
 245   F.fprintf formatter "\n";
 246   F.fprintf formatter "subst:\n";
 247   (*ppsubst subst ~formatter ~metasenv;*)
 248   F.fprintf formatter "\n";
 249   match o with
 250   | NCic.Fixpoint (b, fl, _) ->
 251       F.fprintf formatter "{%s}\n" (NUri.string_of_uri u);
 252       F.fprintf formatter "%s" (if b then "let rec " else "let corec ");
 253       HExtlib.list_iter_sep ~sep:(fun ()->F.fprintf formatter "\nand ")
 254        (fun (_,name,n,ty,bo) ->
 255         F.fprintf formatter "%s on %d : " name n;
 256         ppterm ~formatter ~metasenv ~subst ~context:[] ty;
 257         F.fprintf formatter " :=\n";
 258         ppterm ~formatter ~metasenv ~subst ~context:[] ~inside_fix:true bo) fl
 259   | NCic.Inductive (b, leftno,tyl, _) ->
 260       F.fprintf formatter "{%s} with %d fixed params\n%s"
 261        (NUri.string_of_uri u) leftno
 262        (if b then "inductive " else "coinductive ");
 263       HExtlib.list_iter_sep ~sep:(fun ()->F.fprintf formatter "\nand ")
 264        (fun (_,name,ty,cl) ->
 265           F.fprintf formatter "%s: " name;
 266           ppterm ~formatter ~metasenv ~subst ~context:[] ty;
 267           F.fprintf formatter " :=\n";
 268           HExtlib.list_iter_sep ~sep:(fun () -> F.fprintf formatter "\n")
 269            (fun (_,name,ty) ->
 270              F.fprintf formatter "  | %s: " name;
 271              ppterm ~formatter ~metasenv ~subst ~context:[] ty)
 272            cl
 273         ) tyl
 274   | NCic.Constant (_,name,None,ty, _) ->
 275      F.fprintf formatter "{%s}\naxiom %s : " (NUri.string_of_uri u) name;
 276      ppterm ~formatter ~metasenv ~subst ~context:[] ty;
 277      F.fprintf formatter "\n"
 278   | NCic.Constant (_,name,Some bo,ty, _) ->
 279      F.fprintf formatter "{%s}\ndefinition %s : " (NUri.string_of_uri u) name;
 280      ppterm ~formatter ~metasenv ~subst ~context:[] ty;
 281      F.fprintf formatter " := \n";
 282      ppterm ~formatter ~metasenv ~subst ~context:[] bo;
 283      F.fprintf formatter "\n"
 284 ;;
 285
 286 let ppterm ~context ~subst ~metasenv ?margin ?inside_fix t =
 287  on_buffer (ppterm ~context ~subst ~metasenv ?margin ?inside_fix) t
 288 ;;
 289
 290 let ppcontext ?sep ~subst ~metasenv ctx =
 291  on_buffer (ppcontext ?sep ~subst ~metasenv) ctx
 292 ;;
 293
 294 let ppmetasenv ~subst metasenv = on_buffer (ppmetasenv ~subst) metasenv;;
 295
 296 let ppsubst ~metasenv subst = on_buffer (ppsubst ~metasenv) subst;;
 297
 298 let ppobj obj = on_buffer ppobj obj;;
 299
 300 let _ = NCicSubstitution.set_ppterm (ppterm ~margin:80);;