helm/software/components/ng_kernel/nCicPp.ml

   1 (*
   2     ||M||  This file is part of HELM, an Hypertextual, Electronic
   3     ||A||  Library of Mathematics, developed at the Computer Science
   4     ||T||  Department, University of Bologna, Italy.
   5     ||I||
   6     ||T||  HELM is free software; you can redistribute it and/or
   7     ||A||  modify it under the terms of the GNU General Public License
   8     \   /  version 2 or (at your option) any later version.
   9      \ /   This software is distributed as is, NO WARRANTY.
  10       V_______________________________________________________________ *)
  11
  12 (* $Id$ *)
  13
  14 module C = NCic
  15 module R = NReference
  16
  17 let r2s pp_fix_name r =
  18   try
  19     match r with
  20     | R.Ref (u,R.Ind (_,i,_)) ->
  21         (match NCicLibrary.get_obj u with
  22         | _,_,_,_, C.Inductive (_,_,itl,_) ->
  23             let _,name,_,_ = List.nth itl i in name
  24         | _ -> assert false)
  25     | R.Ref (u,R.Con (i,j,_)) ->
  26         (match NCicLibrary.get_obj u with
  27         | _,_,_,_, C.Inductive (_,_,itl,_) ->
  28             let _,_,_,cl = List.nth itl i in
  29             let _,name,_ = List.nth cl (j-1) in name
  30         | _ -> assert false)
  31     | R.Ref (u,(R.Decl | R.Def _)) ->
  32         (match NCicLibrary.get_obj u with
  33         | _,_,_,_, C.Constant (_,name,_,_,_) -> name
  34         | _ -> assert false)
  35     | R.Ref (u,(R.Fix (i,_,_)|R.CoFix i)) ->
  36         (match NCicLibrary.get_obj u with
  37         | _,_,_,_, C.Fixpoint (_,fl,_) ->
  38             if pp_fix_name then
  39               let _,name,_,_,_ = List.nth fl i in name
  40             else
  41               NUri.name_of_uri u ^"("^ string_of_int i ^ ")"
  42         | _ -> assert false)
  43   with NCicLibrary.ObjectNotFound _ -> R.string_of_reference r
  44 ;;
  45
  46 let ppterm ~context ~subst ~metasenv:_ ?(inside_fix=false) t =
  47   let buff = Buffer.create 100 in
  48   let f = Format.formatter_of_buffer buff in
  49   let module F = Format in
  50   let rec aux ?(toplevel=false) ctx = function
  51    | C.Rel m ->
  52          (try
  53             let name = List.nth ctx (m-1) in
  54             F.fprintf f "%s" (if name = "_" then "__"^string_of_int m else name)
  55          with Failure _ -> F.fprintf f " -%d" (m - List.length ctx))
  56    | C.Const r -> F.fprintf f "%s" (r2s inside_fix r)
  57    | C.Prod ("_",s,t) ->
  58        if not toplevel then F.fprintf f "(";
  59        F.fprintf f "@[<hov 1>";
  60        (match s with
  61        | C.Prod ("_",_,_) -> aux ~toplevel:false ctx s
  62        | _ -> aux ~toplevel:true ctx s);
  63        F.fprintf f "@;→ ";
  64        aux ~toplevel:true ("_"::ctx) t;
  65        F.fprintf f "@]";
  66        if not toplevel then F.fprintf f ")";
  67    | C.Prod (name,s,t) ->
  68        if not toplevel then F.fprintf f "(";
  69        F.fprintf f "@[<hov 1>";
  70        F.fprintf f "@[<hov 2>∀%s:@;" name;
  71        aux ~toplevel:true ctx s;
  72        F.fprintf f "@].@;";
  73        aux ~toplevel:true (name::ctx) t;
  74        F.fprintf f "@]";
  75        if not toplevel then F.fprintf f ")";
  76    | C.Lambda (name,s,t) ->
  77        if not toplevel then F.fprintf f "(";
  78        F.fprintf f "@[<hov 1>";
  79        F.fprintf f "λ%s:" name;
  80        aux ~toplevel:true ctx s;
  81        F.fprintf f ".@;";
  82        aux ~toplevel:true (name::ctx) t;
  83        F.fprintf f "@]";
  84        if not toplevel then F.fprintf f ")";
  85    | C.LetIn (name,ty,t,b) ->
  86        if not toplevel then F.fprintf f "(";
  87        F.fprintf f "@[<hov 1>";
  88        F.fprintf f "let %s:@;" name;
  89        aux ~toplevel:true ctx ty;
  90        F.fprintf f "@;≝ ";
  91        aux ~toplevel:true ctx t;
  92        F.fprintf f "@;in@;";
  93        (aux ~toplevel:true (name::ctx) b);
  94        F.fprintf f "@]";
  95        if not toplevel then F.fprintf f ")";
  96    | C.Match (r,oty,t,pl) ->
  97        F.fprintf f "@[<hov>match ";
  98        aux ~toplevel:true ctx t;
  99        F.fprintf f "@;return ";
 100        aux ~toplevel:true ctx oty;
 101        F.fprintf f "@; @[<v>[ ";
 102        if pl <> [] then
 103          begin
 104            F.fprintf f "@[<hov 2>%s ⇒@;" (r2s inside_fix (R.mk_constructor 1 r));
 105            aux ~toplevel:true ctx (List.hd pl);
 106            F.fprintf f "@]";
 107            ignore(List.fold_left
 108              (fun i t ->
 109               F.fprintf f "@;| @[<hov 2>%s ⇒@;" (r2s inside_fix (R.mk_constructor i r));
 110               aux ~toplevel:true ctx t;
 111               F.fprintf f "@]";
 112               i+1)
 113              2 (List.tl pl));
 114          end;
 115       F.fprintf f "]@] @]";
 116    | C.Appl l ->
 117        F.fprintf f "@[<hov 2>";
 118        if not toplevel then F.fprintf f "(";
 119        aux ctx (List.hd l);
 120        List.iter (fun x -> F.fprintf f "@;";aux ctx x) (List.tl l);
 121        if not toplevel then F.fprintf f ")";
 122        F.fprintf f "@]"
 123    | C.Implicit _ -> F.fprintf f "?"
 124    | C.Meta (n,lc) when List.mem_assoc n subst ->
 125         let _,_,t,_ = List.assoc n subst in
 126         aux ctx (NCicSubstitution.subst_meta lc t)
 127    | C.Meta (n,(shift,C.Irl len)) ->
 128         F.fprintf f "?%d(%d,%d)" n shift len
 129    | C.Meta (n,(shift,C.Ctx l)) ->
 130         F.fprintf f "?%d(%d,[" n shift;
 131         if List.length l > 0 then
 132           begin
 133             aux ctx (List.hd l);
 134             List.iter (fun x -> F.fprintf f ",";aux ctx x) (List.tl l);
 135           end;
 136         F.fprintf f "])"
 137    | C.Sort C.Prop -> F.fprintf f "Prop"
 138    | C.Sort (C.Type []) -> F.fprintf f "IllFormedUniverse"
 139    | C.Sort (C.Type [false, u]) -> F.fprintf f "%s" (NUri.name_of_uri u)
 140    | C.Sort (C.Type [true, u]) -> F.fprintf f "S(%s)" (NUri.name_of_uri u)
 141    | C.Sort (C.Type l) ->
 142        F.fprintf f "Max(";
 143        aux ctx (C.Sort (C.Type [List.hd l]));
 144        List.iter (fun x -> F.fprintf f ",";aux ctx (C.Sort (C.Type [x])))
 145         (List.tl l);
 146        F.fprintf f ")"
 147   in
 148   aux ~toplevel:true (List.map fst context) t;
 149   F.fprintf f "@?";
 150   Buffer.contents buff
 151 ;;
 152
 153 let ppobj = function
 154   | (u,_,metasenv,subst,NCic.Fixpoint (b, fl, _)) ->
 155       "{"^NUri.string_of_uri u^"}\n"^
 156       (if b then "let rec " else "let corec ") ^
 157        String.concat "\nand "
 158         (List.map (fun (_,name,n,ty,bo) ->
 159           name^ " on " ^ string_of_int n ^ " : " ^
 160           ppterm ~metasenv ~subst ~context:[] ty ^ " :=\n"^
 161           ppterm ~metasenv ~subst ~context:[] ~inside_fix:true bo) fl)
 162   | (u,_,metasenv,subst,NCic.Inductive (b, leftno,tyl, _)) ->
 163       "{"^NUri.string_of_uri u^"} with "^string_of_int leftno^" fixed params\n"^
 164       (if b then "inductive " else "coinductive ")^
 165       String.concat "\nand "
 166         (List.map (fun (_,name,ty,cl) ->
 167           name^": "^ppterm ~metasenv ~subst ~context:[] ty^ " :=\n"^
 168           String.concat "\n"
 169           (List.map (fun (_,name,ty) ->
 170            "  | "^name^": "^ppterm ~metasenv ~subst ~context:[] ty)
 171            cl)) tyl) ^ "."
 172   | (u,_,metasenv,subst,NCic.Constant (_,name,None,ty, _)) ->
 173       "{"^NUri.string_of_uri u^"}\n"^
 174         "axiom " ^ name ^ " : " ^
 175           ppterm ~metasenv ~subst ~context:[] ty ^ "\n"
 176   | (u,_,metasenv,subst,NCic.Constant (_,name,Some bo,ty, _)) ->
 177       "{"^NUri.string_of_uri u^"}\n"^
 178         "definition " ^ name ^ " : " ^
 179           ppterm ~metasenv ~subst ~context:[] ty ^ " := \n"^
 180           ppterm ~metasenv ~subst ~context:[] bo ^ "\n"
 181 ;;
 182
 183 let rec ppcontext ~subst ~metasenv = function
 184   | [] -> ""
 185   | (name, NCic.Decl t) :: tl ->
 186       ppcontext ~subst ~metasenv tl ^
 187       name ^ ": " ^ ppterm ~subst ~metasenv ~context:tl t ^ "\n"
 188   | (name, NCic.Def (bo,ty)) :: tl->
 189       ppcontext ~subst ~metasenv tl ^
 190       name ^ ": " ^ ppterm ~subst ~metasenv ~context:tl ty ^
 191       " := " ^ ppterm ~subst ~metasenv ~context:tl bo ^ "\n"
 192 ;;