helm/software/components/ng_kernel/nCicReduction.ml

   1 (*
   2     ||M||  This file is part of HELM, an Hypertextual, Electronic
   3     ||A||  Library of Mathematics, developed at the Computer Science
   4     ||T||  Department, University of Bologna, Italy.
   5     ||I||
   6     ||T||  HELM is free software; you can redistribute it and/or
   7     ||A||  modify it under the terms of the GNU General Public License
   8     \   /  version 2 or (at your option) any later version.
   9      \ /   This software is distributed as is, NO WARRANTY.
  10       V_______________________________________________________________ *)
  11
  12 (* $Id$ *)
  13
  14 module C = NCic
  15 module Ref = NReference
  16 module E = NCicEnvironment
  17
  18 exception AssertFailure of string Lazy.t;;
  19
  20 module type Strategy = sig
  21   type stack_term
  22   type env_term
  23   type config = int * env_term list * C.term * stack_term list
  24   val to_env :
  25    reduce: (delta:int -> config -> config * bool) ->
  26    unwind: (config -> C.term) ->
  27     config -> env_term
  28   val from_stack : delta:int -> stack_term -> config
  29   val from_stack_list_for_unwind :
  30     unwind: (config -> C.term) -> stack_term list -> C.term list
  31   val from_env : delta:int -> env_term -> config
  32   val from_env_for_unwind :
  33     unwind: (config -> C.term) -> env_term -> C.term
  34   val stack_to_env :
  35    reduce: (delta:int -> config -> config * bool) ->
  36    unwind: (config -> C.term) ->
  37     stack_term -> env_term
  38   val compute_to_env :
  39    reduce: (delta:int -> config -> config * bool) ->
  40    unwind: (config -> C.term) ->
  41     int -> env_term list -> C.term -> env_term
  42   val compute_to_stack :
  43    reduce: (delta:int -> config -> config * bool) ->
  44    unwind: (config -> C.term) ->
  45     config -> stack_term
  46  end
  47 ;;
  48
  49 module CallByValueByNameForUnwind' : Strategy = struct
  50   type config = int * env_term list * C.term * stack_term list
  51   and stack_term =
  52        config Lazy.t * (int -> config) * C.term Lazy.t
  53   and env_term =
  54         config Lazy.t    (* cbneed   ~delta:0       *)
  55       * (int -> config)  (* cbvalue  ~delta         *)
  56       * C.term Lazy.t    (* cbname   ~delta:max_int *)
  57   let to_env ~reduce ~unwind c =
  58    lazy (fst (reduce ~delta:0 c)),
  59    (fun delta -> fst (reduce ~delta c)),
  60    lazy (unwind c)
  61   let from_stack ~delta (c0,c,_) = if delta = 0 then Lazy.force c0 else c delta
  62   let from_stack_list_for_unwind ~unwind:_ l =
  63    List.map (fun (_,_,c) -> Lazy.force c) l
  64   let from_env ~delta (c0,c,_) = if delta = 0 then Lazy.force c0 else c delta
  65   let from_env_for_unwind ~unwind:_ (_,_,c) = Lazy.force c
  66   let stack_to_env ~reduce:_ ~unwind:_ config = config
  67   let compute_to_env ~reduce ~unwind k e t =
  68    lazy (fst (reduce ~delta:0 (k,e,t,[]))),
  69    (fun delta -> fst (reduce ~delta (k,e,t,[]))),
  70    lazy (unwind (k,e,t,[]))
  71   let compute_to_stack ~reduce ~unwind config =
  72    lazy (fst (reduce ~delta:0 config)),
  73    (fun delta -> fst (reduce ~delta config)),
  74    lazy (unwind config)
  75  end
  76 ;;
  77
  78 module Reduction(RS : Strategy) = struct
  79   type env = RS.env_term list
  80   type stack = RS.stack_term list
  81   type config = int * env * C.term * stack
  82
  83   let rec unwind (k,e,t,s) =
  84     let t =
  85       if k = 0 then t
  86       else
  87         NCicSubstitution.psubst ~avoid_beta_redexes:true
  88           (RS.from_env_for_unwind ~unwind) e t
  89     in
  90     if s = [] then t
  91     else C.Appl(t::(RS.from_stack_list_for_unwind ~unwind s))
  92   ;;
  93
  94   let list_nth l n = try List.nth l n with Failure _ -> assert false;;
  95   let rec replace i s t =
  96     match i,s with
  97     |  0,_::tl -> t::tl
  98     | n,he::tl -> he::(replace (n - 1) tl t)
  99     | _,_ -> assert false
 100   ;;
 101
 102   let rec reduce ~delta ?(subst = []) context : config -> config * bool =
 103    let rec aux = function
 104      | k, e, C.Rel n, s when n <= k ->
 105         let k',e',t',s' = RS.from_env ~delta (list_nth e (n-1)) in
 106         aux (k',e',t',s'@s)
 107      | k, _, C.Rel n, s as config (* when n > k *) ->
 108         let x= try Some (List.nth context (n - 1 - k)) with Failure _ -> None in
 109          (match x with
 110          | Some(_,C.Def(x,_)) -> aux (0,[],NCicSubstitution.lift (n - k) x,s)
 111          | _ -> config, true)
 112      | (k, e, C.Meta (n,l), s) as config ->
 113         (try
 114            let _,_, term,_ = NCicUtils.lookup_subst n subst in
 115            aux (k, e, NCicSubstitution.subst_meta l term,s)
 116          with  NCicUtils.Subst_not_found _ -> config, true)
 117      | (_, _, C.Implicit _, _) -> assert false
 118      | (_, _, C.Sort _, _)
 119      | (_, _, C.Prod _, _)
 120      | (_, _, C.Lambda _, []) as config -> config, true
 121      | (k, e, C.Lambda (_,_,t), p::s) ->
 122          aux (k+1, (RS.stack_to_env ~reduce:(reduce ~subst context) ~unwind p)::e, t,s)
 123      | (k, e, C.LetIn (_,_,m,t), s) ->
 124         let m' = RS.compute_to_env ~reduce:(reduce ~subst context) ~unwind k e m in
 125          aux (k+1, m'::e, t, s)
 126      | (_, _, C.Appl ([]|[_]), _) -> assert false
 127      | (k, e, C.Appl (he::tl), s) ->
 128         let tl' =
 129          List.map (fun t->RS.compute_to_stack
 130            ~reduce:(reduce ~subst context) ~unwind (k,e,t,[])) tl
 131         in
 132          aux (k, e, he, tl' @ s)
 133      | (_, _, C.Const
 134             (Ref.Ref (_,Ref.Def height) as refer), s) as config ->
 135          if delta >= height then
 136            config, false
 137          else
 138            let _,_,body,_,_,_ = NCicEnvironment.get_checked_def refer in
 139            aux (0, [], body, s)
 140      | (_, _, C.Const (Ref.Ref (_,
 141          (Ref.Decl|Ref.Ind _|Ref.Con _|Ref.CoFix _))), _) as config ->
 142            config, true
 143      | (_, _, (C.Const (Ref.Ref
 144           (_,Ref.Fix (fixno,recindex,height)) as refer)),s) as config ->
 145         (let arg = try Some (List.nth s recindex) with Failure _ -> None in
 146          match arg with
 147             None -> config, true
 148           | Some arg ->
 149              let fixes,(_,_,pragma),_ =
 150               NCicEnvironment.get_checked_fixes_or_cofixes refer in
 151              if delta >= height then
 152               match pragma with
 153                | `Projection ->
 154                    (match RS.from_stack ~delta:max_int arg with
 155                      | _,_,C.Const(Ref.Ref(_,Ref.Con _)),_::_ ->
 156                        let _,_,_,_,body = List.nth fixes fixno in
 157                         aux (0, [], body, s)
 158                      | _ -> config,false)
 159                | _ -> config,false
 160              else
 161               match RS.from_stack ~delta:0 arg with
 162                | (_,_,C.Const (Ref.Ref (_,Ref.Con _)), _) as c ->
 163                  let new_s =
 164                   replace recindex s
 165                    (RS.compute_to_stack ~reduce:(reduce ~subst context)
 166                    ~unwind c) in
 167                  let _,_,_,_,body = List.nth fixes fixno in
 168                   aux (0, [], body, new_s)
 169                | _ -> config, true)
 170      | (k, e, C.Match (_,_,term,pl),s) as config ->
 171         let decofix = function
 172           | (_,_,C.Const(Ref.Ref(_,Ref.CoFix c)as refer),s)->
 173              let cofixes,_,_ =
 174                NCicEnvironment.get_checked_fixes_or_cofixes refer in
 175              let _,_,_,_,body = List.nth cofixes c in
 176              let c,_ = reduce ~delta:0 ~subst context (0,[],body,s) in
 177              c
 178           | config -> config
 179         in
 180         let match_head = k,e,term,[] in
 181         let reduced,_ = reduce ~delta:0 ~subst context match_head in
 182         (match decofix reduced with
 183         | (_, _, C.Const (Ref.Ref (_,Ref.Con (_,j,_))),[]) ->
 184             aux (k, e, List.nth pl (j-1), s)
 185         | (_, _, C.Const (Ref.Ref (_,Ref.Con (_,j,lno))), s')->
 186           let _,params = HExtlib.split_nth lno s' in
 187           aux (k, e, List.nth pl (j-1), params@s)
 188         | _ -> config, true)
 189    in
 190     aux
 191   ;;
 192
 193   let whd ?(delta=0) ~subst context t =
 194    unwind (fst (reduce ~delta ~subst context (0, [], t, [])))
 195   ;;
 196
 197  end
 198 ;;
 199
 200
 201 module RS = CallByValueByNameForUnwind';;
 202 module R = Reduction(RS);;
 203
 204 let whd = R.whd
 205
 206 let (===) x y = Pervasives.compare x y = 0 ;;
 207
 208 let get_relevance = ref (fun ~metasenv:_ ~subst:_ _ _ -> assert false);;
 209
 210 let set_get_relevance f = get_relevance := f;;
 211
 212 let alpha_eq ~test_lambda_source aux test_eq_only metasenv subst context t1 t2 =
 213  if t1 === t2 then
 214    true
 215  else
 216    match (t1,t2) with
 217    | C.Sort s1, C.Sort s2 ->
 218        NCicEnvironment.are_sorts_convertible ~test_eq_only s1 s2
 219
 220    | (C.Prod (name1,s1,t1), C.Prod(_,s2,t2)) ->
 221        aux true context s1 s2 &&
 222        aux test_eq_only ((name1, C.Decl s1)::context) t1 t2
 223    | (C.Lambda (name1,s1,t1), C.Lambda(_,_,t2)) ->
 224       if test_lambda_source then
 225        aux test_eq_only context t1 t2
 226       else
 227        (* thanks to inversion of well typedness, the source
 228         * of these lambdas must be already convertible *)
 229        aux test_eq_only ((name1, C.Decl s1)::context) t1 t2
 230    | (C.LetIn (name1,ty1,s1,t1), C.LetIn(_,ty2,s2,t2)) ->
 231       aux test_eq_only context ty1 ty2 &&
 232       aux test_eq_only context s1 s2 &&
 233       aux test_eq_only ((name1, C.Def (s1,ty1))::context) t1 t2
 234
 235    | (C.Meta (n1,(s1, C.Irl _)), C.Meta (n2,(s2, C.Irl _)))
 236       when n1 = n2 && s1 = s2 -> true
 237    | (C.Meta (n1,(s1, l1)), C.Meta (n2,(s2, l2))) when n1 = n2 &&
 238       let l1 = NCicUtils.expand_local_context l1 in
 239       let l2 = NCicUtils.expand_local_context l2 in
 240       (try List.for_all2
 241         (fun t1 t2 -> aux test_eq_only context
 242           (NCicSubstitution.lift s1 t1)
 243           (NCicSubstitution.lift s2 t2))
 244         l1 l2
 245       with Invalid_argument "List.for_all2" ->
 246         prerr_endline ("Meta " ^ string_of_int n1 ^
 247           " occurrs with local contexts of different lenght\n"^
 248           NCicPp.ppterm ~metasenv ~subst ~context t1 ^ " === " ^
 249           NCicPp.ppterm ~metasenv ~subst ~context t2);
 250         assert false) -> true
 251
 252    | C.Meta (n1,l1), _ ->
 253       (try
 254          let _,_,term,_ = NCicUtils.lookup_subst n1 subst in
 255          let term = NCicSubstitution.subst_meta l1 term in
 256           aux test_eq_only context term t2
 257        with NCicUtils.Subst_not_found _ -> false)
 258    | _, C.Meta (n2,l2) ->
 259       (try
 260          let _,_,term,_ = NCicUtils.lookup_subst n2 subst in
 261          let term = NCicSubstitution.subst_meta l2 term in
 262           aux test_eq_only context t1 term
 263        with NCicUtils.Subst_not_found _ -> false)
 264
 265    | (C.Appl ((C.Const r1) as hd1::tl1), C.Appl (C.Const r2::tl2))
 266        when (Ref.eq r1 r2 &&
 267          List.length (E.get_relevance r1) >= List.length tl1) ->
 268      let relevance = E.get_relevance r1 in
 269      let relevance = match r1 with
 270          | Ref.Ref (_,Ref.Con (_,_,lno)) ->
 271              let _,relevance = HExtlib.split_nth lno relevance in
 272                HExtlib.mk_list false lno @ relevance
 273          | _ -> relevance
 274      in
 275      (try
 276          HExtlib.list_forall_default3_var
 277           (fun t1 t2 b -> not b || aux true context t1 t2 )
 278           tl1 tl2 true relevance
 279         with Invalid_argument _ -> false
 280            | HExtlib.FailureAt fail ->
 281              let relevance =
 282                !get_relevance ~metasenv ~subst context hd1 tl1 in
 283              let _,relevance = HExtlib.split_nth fail relevance in
 284              let b,relevance = (match relevance with
 285                | [] -> assert false
 286                | b::tl -> b,tl) in
 287              if (not b) then
 288                let _,tl1 = HExtlib.split_nth (fail+1) tl1 in
 289                let _,tl2 = HExtlib.split_nth (fail+1) tl2 in
 290                  try
 291                     HExtlib.list_forall_default3
 292                     (fun t1 t2 b -> not b || aux true context t1 t2)
 293                     tl1 tl2 true relevance
 294                  with Invalid_argument _ -> false
 295              else false)
 296
 297    | (C.Appl (hd1::tl1),  C.Appl (hd2::tl2)) ->
 298        aux test_eq_only context hd1 hd2 &&
 299         let relevance = !get_relevance ~metasenv ~subst context hd1 tl1 in
 300         (try
 301          HExtlib.list_forall_default3
 302           (fun t1 t2 b -> not b || aux true context t1 t2)
 303           tl1 tl2 true relevance
 304         with Invalid_argument _ -> false)
 305
 306    | (C.Match (Ref.Ref (_,Ref.Ind (_,tyno,_)) as ref1,outtype1,term1,pl1),
 307       C.Match (ref2,outtype2,term2,pl2)) ->
 308        let _,_,itl,_,_ = E.get_checked_indtys ref1 in
 309        let _,_,ty,_ = List.nth itl tyno in
 310        let rec remove_prods ~subst context ty =
 311          let ty = whd ~subst context ty in
 312          match ty with
 313          | C.Sort _ -> ty
 314          | C.Prod (name,so,ta) -> remove_prods ~subst ((name,(C.Decl so))::context) ta
 315          | _ -> assert false
 316        in
 317        let is_prop =
 318          match remove_prods ~subst [] ty with
 319          | C.Sort C.Prop -> true
 320          | _ -> false
 321        in
 322        Ref.eq ref1 ref2 &&
 323        aux test_eq_only context outtype1 outtype2 &&
 324        (is_prop || aux test_eq_only context term1 term2) &&
 325        (try List.for_all2 (aux test_eq_only context) pl1 pl2
 326         with Invalid_argument _ -> false)
 327    | (C.Implicit _, _) | (_, C.Implicit _) -> assert false
 328    | (_,_) -> false
 329 ;;
 330
 331 (* t1, t2 must be well-typed *)
 332 let are_convertible ~metasenv ~subst =
 333  let rec aux test_eq_only context t1 t2 =
 334   let alpha_eq test_eq_only =
 335    alpha_eq ~test_lambda_source:false aux test_eq_only metasenv subst context
 336   in
 337    if alpha_eq test_eq_only t1 t2 then
 338      true
 339    else
 340      let height_of = function
 341       | C.Const (Ref.Ref (_,Ref.Def h))
 342       | C.Const (Ref.Ref (_,Ref.Fix (_,_,h)))
 343       | C.Appl(C.Const(Ref.Ref(_,Ref.Def h))::_)
 344       | C.Appl(C.Const(Ref.Ref(_,Ref.Fix (_,_,h)))::_) -> h
 345       | _ -> 0
 346      in
 347      let put_in_whd m1 m2 =
 348        R.reduce ~delta:max_int ~subst context m1,
 349        R.reduce ~delta:max_int ~subst context m2
 350      in
 351      let small_delta_step
 352        ((_,_,t1,_ as m1), norm1 as x1) ((_,_,t2,_ as m2), norm2 as x2)
 353      =
 354        assert(not (norm1 && norm2));
 355        if norm1 then
 356          x1, R.reduce ~delta:(height_of t2 -1) ~subst context m2
 357        else if norm2 then
 358          R.reduce ~delta:(height_of t1 -1) ~subst context m1, x2
 359        else
 360         let h1 = height_of t1 in
 361         let h2 = height_of t2 in
 362         let delta = if h1 = h2 then max 0 (h1 -1) else min h1 h2 in
 363         R.reduce ~delta ~subst context m1,
 364         R.reduce ~delta ~subst context m2
 365      in
 366      let rec convert_machines test_eq_only
 367        ((k1,e1,t1,s1),norm1 as m1),((k2,e2,t2,s2), norm2 as m2)
 368      =
 369        (alpha_eq test_eq_only
 370          (R.unwind (k1,e1,t1,[])) (R.unwind (k2,e2,t2,[])) &&
 371         let relevance =
 372           match t1 with
 373               C.Const r -> NCicEnvironment.get_relevance r
 374             | _ -> [] in
 375         try
 376          HExtlib.list_forall_default3
 377            (fun t1 t2 b  ->
 378              not b ||
 379              let t1 = RS.from_stack ~delta:max_int t1 in
 380              let t2 = RS.from_stack ~delta:max_int t2 in
 381              convert_machines true (put_in_whd t1 t2)) s1 s2 true relevance
 382         with Invalid_argument _ -> false) ||
 383        (not (norm1 && norm2) && convert_machines test_eq_only (small_delta_step m1 m2))
 384      in
 385      convert_machines test_eq_only (put_in_whd (0,[],t1,[]) (0,[],t2,[]))
 386  in
 387   aux false
 388 ;;
 389
 390 let alpha_eq metasenv subst =
 391  let rec aux test_lambda_source context t1 t2 =
 392   alpha_eq ~test_lambda_source aux true metasenv subst context t1 t2
 393  in
 394   aux true
 395 ;;
 396
 397 let rec head_beta_reduce ~delta ~upto ~subst t l =
 398  match upto, t, l with
 399   | 0, C.Appl l1, _ -> C.Appl (l1 @ l)
 400   | 0, t, [] -> t
 401   | 0, t, _ -> C.Appl (t::l)
 402   | _, C.Meta (n,ctx), _ ->
 403      (try
 404        let _,_, term,_ = NCicUtils.lookup_subst n subst in
 405        head_beta_reduce ~delta ~upto ~subst
 406          (NCicSubstitution.subst_meta ctx term) l
 407      with NCicUtils.Subst_not_found _ -> if l = [] then t else C.Appl (t::l))
 408   | _, C.Appl (hd::tl), _ -> head_beta_reduce ~delta ~upto ~subst hd (tl @ l)
 409   | _, C.Lambda(_,_,bo), arg::tl ->
 410      let bo = NCicSubstitution.subst arg bo in
 411      head_beta_reduce ~delta ~upto:(upto - 1) ~subst bo tl
 412   | _, C.Const (Ref.Ref (_, Ref.Def height) as re), _
 413     when delta <= height ->
 414       let _, _, bo, _, _, _ = NCicEnvironment.get_checked_def re in
 415       head_beta_reduce ~upto ~delta ~subst bo l
 416   | _, t, [] -> t
 417   | _, t, _ -> C.Appl (t::l)
 418 ;;
 419
 420 let head_beta_reduce ?(delta=max_int) ?(upto= -1) ?(subst=[]) t =
 421   head_beta_reduce ~delta ~upto ~subst t []
 422 ;;
 423
 424 type stack_item = RS.stack_term
 425 type environment_item = RS.env_term
 426
 427 type machine = int * environment_item list * NCic.term * stack_item list
 428
 429 let reduce_machine = R.reduce
 430 let from_stack = RS.from_stack
 431 let unwind = R.unwind
 432
 433 let _ =
 434   NCicUtils.set_head_beta_reduce (fun ~upto t -> head_beta_reduce ~upto t);
 435   NCicPp.set_head_beta_reduce (fun ~upto t -> head_beta_reduce ~upto t);
 436 ;;
 437
 438 (* if n < 0, then splits all prods from an arity, returning a sort *)
 439 let rec split_prods ~subst context n te =
 440   match (n, R.whd ~subst context te) with
 441    | (0, _) -> context,te
 442    | (n, C.Sort _) when n <= 0 -> context,te
 443    | (n, C.Prod (name,so,ta)) ->
 444        split_prods ~subst ((name,(C.Decl so))::context) (n - 1) ta
 445    | (_, _) -> raise (AssertFailure (lazy "split_prods"))
 446 ;;
 447
 448 (* vim:set foldmethod=marker: *)