helm/software/components/ng_kernel/nCicReduction.ml

   1 (*
   2     ||M||  This file is part of HELM, an Hypertextual, Electronic
   3     ||A||  Library of Mathematics, developed at the Computer Science
   4     ||T||  Department, University of Bologna, Italy.
   5     ||I||
   6     ||T||  HELM is free software; you can redistribute it and/or
   7     ||A||  modify it under the terms of the GNU General Public License
   8     \   /  version 2 or (at your option) any later version.
   9      \ /   This software is distributed as is, NO WARRANTY.
  10       V_______________________________________________________________ *)
  11
  12 (* $Id$ *)
  13
  14 module C = NCic
  15 module Ref = NReference
  16 module E = NCicEnvironment
  17
  18 exception AssertFailure of string Lazy.t;;
  19
  20 module type Strategy = sig
  21   type stack_term
  22   type env_term
  23   type config = int * env_term list * C.term * stack_term list
  24   val to_env :
  25    reduce: (delta:int -> config -> config * bool) ->
  26    unwind: (config -> C.term) ->
  27     config -> env_term
  28   val from_stack : delta:int -> stack_term -> config
  29   val from_stack_list_for_unwind :
  30     unwind: (config -> C.term) -> stack_term list -> C.term list
  31   val from_env : delta:int -> env_term -> config
  32   val from_env_for_unwind :
  33     unwind: (config -> C.term) -> env_term -> C.term
  34   val stack_to_env :
  35    reduce: (delta:int -> config -> config * bool) ->
  36    unwind: (config -> C.term) ->
  37     stack_term -> env_term
  38   val compute_to_env :
  39    reduce: (delta:int -> config -> config * bool) ->
  40    unwind: (config -> C.term) ->
  41     int -> env_term list -> C.term -> env_term
  42   val compute_to_stack :
  43    reduce: (delta:int -> config -> config * bool) ->
  44    unwind: (config -> C.term) ->
  45     config -> stack_term
  46  end
  47 ;;
  48
  49 module CallByValueByNameForUnwind' : Strategy = struct
  50   type config = int * env_term list * C.term * stack_term list
  51   and stack_term =
  52        config Lazy.t * (int -> config) * C.term Lazy.t
  53   and env_term =
  54         config Lazy.t    (* cbneed   ~delta:0       *)
  55       * (int -> config)  (* cbvalue  ~delta         *)
  56       * C.term Lazy.t    (* cbname   ~delta:max_int *)
  57   let to_env ~reduce ~unwind c =
  58    lazy (fst (reduce ~delta:0 c)),
  59    (fun delta -> fst (reduce ~delta c)),
  60    lazy (unwind c)
  61   let from_stack ~delta (c0,c,_) = if delta = 0 then Lazy.force c0 else c delta
  62   let from_stack_list_for_unwind ~unwind:_ l =
  63    List.map (fun (_,_,c) -> Lazy.force c) l
  64   let from_env ~delta (c0,c,_) = if delta = 0 then Lazy.force c0 else c delta
  65   let from_env_for_unwind ~unwind:_ (_,_,c) = Lazy.force c
  66   let stack_to_env ~reduce:_ ~unwind:_ config = config
  67   let compute_to_env ~reduce ~unwind k e t =
  68    lazy (fst (reduce ~delta:0 (k,e,t,[]))),
  69    (fun delta -> fst (reduce ~delta (k,e,t,[]))),
  70    lazy (unwind (k,e,t,[]))
  71   let compute_to_stack ~reduce ~unwind config =
  72    lazy (fst (reduce ~delta:0 config)),
  73    (fun delta -> fst (reduce ~delta config)),
  74    lazy (unwind config)
  75  end
  76 ;;
  77
  78 module Reduction(RS : Strategy) = struct
  79   type env = RS.env_term list
  80   type stack = RS.stack_term list
  81   type config = int * env * C.term * stack
  82
  83   let rec unwind (k,e,t,s) =
  84     let t =
  85       if k = 0 then t
  86       else
  87         NCicSubstitution.psubst ~avoid_beta_redexes:true
  88           (RS.from_env_for_unwind ~unwind) e t
  89     in
  90     if s = [] then t
  91     else C.Appl(t::(RS.from_stack_list_for_unwind ~unwind s))
  92   ;;
  93
  94   let list_nth l n = try List.nth l n with Failure _ -> assert false;;
  95   let rec replace i s t =
  96     match i,s with
  97     |  0,_::tl -> t::tl
  98     | n,he::tl -> he::(replace (n - 1) tl t)
  99     | _,_ -> assert false
 100   ;;
 101
 102   let rec reduce ~delta ?(subst = []) context : config -> config * bool =
 103    let rec aux = function
 104      | k, e, C.Rel n, s when n <= k ->
 105         let k',e',t',s' = RS.from_env ~delta (list_nth e (n-1)) in
 106         aux (k',e',t',s'@s)
 107      | k, _, C.Rel n, s as config (* when n > k *) ->
 108         let x= try Some (List.nth context (n - 1 - k)) with Failure _ -> None in
 109          (match x with
 110          | Some(_,C.Def(x,_)) -> aux (0,[],NCicSubstitution.lift (n - k) x,s)
 111          | _ -> config, true)
 112      | (k, e, C.Meta (n,l), s) as config ->
 113         (try
 114            let _,_, term,_ = NCicUtils.lookup_subst n subst in
 115            aux (k, e, NCicSubstitution.subst_meta l term,s)
 116          with  NCicUtils.Subst_not_found _ -> config, true)
 117      | (_, _, C.Implicit _, _) -> assert false
 118      | (_, _, C.Sort _, _)
 119      | (_, _, C.Prod _, _)
 120      | (_, _, C.Lambda _, []) as config -> config, true
 121      | (k, e, C.Lambda (_,_,t), p::s) ->
 122          aux (k+1, (RS.stack_to_env ~reduce:(reduce ~subst context) ~unwind p)::e, t,s)
 123      | (k, e, C.LetIn (_,_,m,t), s) ->
 124         let m' = RS.compute_to_env ~reduce:(reduce ~subst context) ~unwind k e m in
 125          aux (k+1, m'::e, t, s)
 126      | (_, _, C.Appl ([]|[_]), _) -> assert false
 127      | (k, e, C.Appl (he::tl), s) ->
 128         let tl' =
 129          List.map (fun t->RS.compute_to_stack
 130            ~reduce:(reduce ~subst context) ~unwind (k,e,t,[])) tl
 131         in
 132          aux (k, e, he, tl' @ s)
 133      | (_, _, C.Const
 134             (Ref.Ref (_,Ref.Def height) as refer), s) as config ->
 135          if delta >= height then
 136            config, false
 137          else
 138            let _,_,body,_,_,_ = NCicEnvironment.get_checked_def refer in
 139            aux (0, [], body, s)
 140      | (_, _, C.Const (Ref.Ref (_,
 141          (Ref.Decl|Ref.Ind _|Ref.Con _|Ref.CoFix _))), _) as config ->
 142            config, true
 143      | (_, _, (C.Const (Ref.Ref
 144            (_,Ref.Fix (fixno,recindex,height)) as refer) as head),s) as config ->
 145 (*         if delta >= height then config else *)
 146         (match
 147           try Some (RS.from_stack ~delta (List.nth s recindex))
 148           with Failure _ -> None
 149         with
 150         | None -> config, true
 151         | Some recparam ->
 152            let fixes,_,_ = NCicEnvironment.get_checked_fixes_or_cofixes refer in
 153            match reduce ~delta:0 ~subst context recparam with
 154            | (_,_,C.Const (Ref.Ref (_,Ref.Con _)), _) as c, _
 155               when delta >= height ->
 156                let new_s =
 157                  replace recindex s (RS.compute_to_stack ~reduce:(reduce ~subst
 158                  context) ~unwind c)
 159                in
 160                (0, [], head, new_s), false
 161            | (_,_,C.Const (Ref.Ref (_,Ref.Con _)), _) as c, _ ->
 162                let new_s =
 163                  replace recindex s (RS.compute_to_stack ~reduce:(reduce ~subst
 164                  context) ~unwind c)
 165                in
 166                let _,_,_,_,body = List.nth fixes fixno in
 167                aux (0, [], body, new_s)
 168            | _ -> config, true)
 169      | (k, e, C.Match (_,_,term,pl),s) as config ->
 170         let decofix = function
 171           | (_,_,C.Const(Ref.Ref(_,Ref.CoFix c)as refer),s)->
 172              let cofixes,_,_ =
 173                NCicEnvironment.get_checked_fixes_or_cofixes refer in
 174              let _,_,_,_,body = List.nth cofixes c in
 175              let c,_ = reduce ~delta:0 ~subst context (0,[],body,s) in
 176              c
 177           | config -> config
 178         in
 179         let match_head = k,e,term,[] in
 180         let reduced,_ = reduce ~delta:0 ~subst context match_head in
 181         (match decofix reduced with
 182         | (_, _, C.Const (Ref.Ref (_,Ref.Con (_,j,_))),[]) ->
 183             aux (k, e, List.nth pl (j-1), s)
 184         | (_, _, C.Const (Ref.Ref (_,Ref.Con (_,j,lno))), s')->
 185           let _,params = HExtlib.split_nth lno s' in
 186           aux (k, e, List.nth pl (j-1), params@s)
 187         | _ -> config, true)
 188    in
 189     aux
 190   ;;
 191
 192   let whd ?(delta=0) ~subst context t =
 193    unwind (fst (reduce ~delta ~subst context (0, [], t, [])))
 194   ;;
 195
 196  end
 197 ;;
 198
 199
 200 module RS = CallByValueByNameForUnwind';;
 201 module R = Reduction(RS);;
 202
 203 let whd = R.whd
 204
 205 let (===) x y = Pervasives.compare x y = 0 ;;
 206
 207 let get_relevance = ref (fun ~metasenv:_ ~subst:_ _ _ -> assert false);;
 208
 209 let set_get_relevance f = get_relevance := f;;
 210
 211 let alpha_eq ~test_lambda_source aux test_eq_only metasenv subst context t1 t2 =
 212  if t1 === t2 then
 213    true
 214  else
 215    match (t1,t2) with
 216    | (C.Sort (C.Type a), C.Sort (C.Type b)) when not test_eq_only ->
 217        NCicEnvironment.universe_leq a b
 218    | (C.Sort (C.Type a), C.Sort (C.Type b)) ->
 219        NCicEnvironment.universe_eq a b
 220    | (C.Sort C.Prop,C.Sort (C.Type _)) -> (not test_eq_only)
 221    | (C.Sort C.Prop, C.Sort C.Prop) -> true
 222
 223    | (C.Prod (name1,s1,t1), C.Prod(_,s2,t2)) ->
 224        aux true context s1 s2 &&
 225        aux test_eq_only ((name1, C.Decl s1)::context) t1 t2
 226    | (C.Lambda (name1,s1,t1), C.Lambda(_,_,t2)) ->
 227       if test_lambda_source then
 228        aux test_eq_only context t1 t2
 229       else
 230        (* thanks to inversion of well typedness, the source
 231         * of these lambdas must be already convertible *)
 232        aux test_eq_only ((name1, C.Decl s1)::context) t1 t2
 233    | (C.LetIn (name1,ty1,s1,t1), C.LetIn(_,ty2,s2,t2)) ->
 234       aux test_eq_only context ty1 ty2 &&
 235       aux test_eq_only context s1 s2 &&
 236       aux test_eq_only ((name1, C.Def (s1,ty1))::context) t1 t2
 237
 238    | (C.Meta (n1,(s1, C.Irl _)), C.Meta (n2,(s2, C.Irl _)))
 239       when n1 = n2 && s1 = s2 -> true
 240    | (C.Meta (n1,(s1, l1)), C.Meta (n2,(s2, l2))) when n1 = n2 &&
 241       let l1 = NCicUtils.expand_local_context l1 in
 242       let l2 = NCicUtils.expand_local_context l2 in
 243       (try List.for_all2
 244         (fun t1 t2 -> aux test_eq_only context
 245           (NCicSubstitution.lift s1 t1)
 246           (NCicSubstitution.lift s2 t2))
 247         l1 l2
 248       with Invalid_argument "List.for_all2" ->
 249         prerr_endline ("Meta " ^ string_of_int n1 ^
 250           " occurrs with local contexts of different lenght\n"^
 251           NCicPp.ppterm ~metasenv ~subst ~context t1 ^ " === " ^
 252           NCicPp.ppterm ~metasenv ~subst ~context t2);
 253         assert false) -> true
 254
 255    | C.Meta (n1,l1), _ ->
 256       (try
 257          let _,_,term,_ = NCicUtils.lookup_subst n1 subst in
 258          let term = NCicSubstitution.subst_meta l1 term in
 259           aux test_eq_only context term t2
 260        with NCicUtils.Subst_not_found _ -> false)
 261    | _, C.Meta (n2,l2) ->
 262       (try
 263          let _,_,term,_ = NCicUtils.lookup_subst n2 subst in
 264          let term = NCicSubstitution.subst_meta l2 term in
 265           aux test_eq_only context t1 term
 266        with NCicUtils.Subst_not_found _ -> false)
 267
 268    | (C.Appl ((C.Const r1) as hd1::tl1), C.Appl (C.Const r2::tl2))
 269        when (Ref.eq r1 r2 &&
 270          List.length (E.get_relevance r1) >= List.length tl1) ->
 271      let relevance = E.get_relevance r1 in
 272      let relevance = match r1 with
 273          | Ref.Ref (_,Ref.Con (_,_,lno)) ->
 274              let _,relevance = HExtlib.split_nth lno relevance in
 275                HExtlib.mk_list false lno @ relevance
 276          | _ -> relevance
 277      in
 278      (try
 279          HExtlib.list_forall_default3_var
 280           (fun t1 t2 b -> not b || aux true context t1 t2 )
 281           tl1 tl2 true relevance
 282         with Invalid_argument _ -> false
 283            | HExtlib.FailureAt fail ->
 284              let relevance =
 285                !get_relevance ~metasenv ~subst context hd1 tl1 in
 286              let _,relevance = HExtlib.split_nth fail relevance in
 287              let b,relevance = (match relevance with
 288                | [] -> assert false
 289                | b::tl -> b,tl) in
 290              if (not b) then
 291                let _,tl1 = HExtlib.split_nth (fail+1) tl1 in
 292                let _,tl2 = HExtlib.split_nth (fail+1) tl2 in
 293                  try
 294                     HExtlib.list_forall_default3
 295                     (fun t1 t2 b -> not b || aux true context t1 t2)
 296                     tl1 tl2 true relevance
 297                  with Invalid_argument _ -> false
 298              else false)
 299
 300    | (C.Appl (hd1::tl1),  C.Appl (hd2::tl2)) ->
 301        aux test_eq_only context hd1 hd2 &&
 302         let relevance = !get_relevance ~metasenv ~subst context hd1 tl1 in
 303         (try
 304          HExtlib.list_forall_default3
 305           (fun t1 t2 b -> not b || aux true context t1 t2)
 306           tl1 tl2 true relevance
 307         with Invalid_argument _ -> false)
 308
 309    | (C.Match (Ref.Ref (_,Ref.Ind (_,tyno,_)) as ref1,outtype1,term1,pl1),
 310       C.Match (ref2,outtype2,term2,pl2)) ->
 311        let _,_,itl,_,_ = E.get_checked_indtys ref1 in
 312        let _,_,ty,_ = List.nth itl tyno in
 313        let rec remove_prods ~subst context ty =
 314          let ty = whd ~subst context ty in
 315          match ty with
 316          | C.Sort _ -> ty
 317          | C.Prod (name,so,ta) -> remove_prods ~subst ((name,(C.Decl so))::context) ta
 318          | _ -> assert false
 319        in
 320        let is_prop =
 321          match remove_prods ~subst [] ty with
 322          | C.Sort C.Prop -> true
 323          | _ -> false
 324        in
 325        Ref.eq ref1 ref2 &&
 326        aux test_eq_only context outtype1 outtype2 &&
 327        (is_prop || aux test_eq_only context term1 term2) &&
 328        (try List.for_all2 (aux test_eq_only context) pl1 pl2
 329         with Invalid_argument _ -> false)
 330    | (C.Implicit _, _) | (_, C.Implicit _) -> assert false
 331    | (_,_) -> false
 332 ;;
 333
 334 (* t1, t2 must be well-typed *)
 335 let are_convertible ~metasenv ~subst =
 336  let rec aux test_eq_only context t1 t2 =
 337   let alpha_eq test_eq_only =
 338    alpha_eq ~test_lambda_source:false aux test_eq_only metasenv subst context
 339   in
 340    if alpha_eq test_eq_only t1 t2 then
 341      true
 342    else
 343      let height_of = function
 344       | C.Const (Ref.Ref (_,Ref.Def h))
 345       | C.Const (Ref.Ref (_,Ref.Fix (_,_,h)))
 346       | C.Appl(C.Const(Ref.Ref(_,Ref.Def h))::_)
 347       | C.Appl(C.Const(Ref.Ref(_,Ref.Fix (_,_,h)))::_) -> h
 348       | _ -> 0
 349      in
 350      let put_in_whd m1 m2 =
 351        R.reduce ~delta:max_int ~subst context m1,
 352        R.reduce ~delta:max_int ~subst context m2
 353      in
 354      let small_delta_step
 355        ((_,_,t1,_ as m1), norm1 as x1) ((_,_,t2,_ as m2), norm2 as x2)
 356      =
 357        assert(not (norm1 && norm2));
 358        if norm1 then
 359          x1, R.reduce ~delta:(height_of t2 -1) ~subst context m2
 360        else if norm2 then
 361          R.reduce ~delta:(height_of t1 -1) ~subst context m1, x2
 362        else
 363         let h1 = height_of t1 in
 364         let h2 = height_of t2 in
 365         let delta = if h1 = h2 then max 0 (h1 -1) else min h1 h2 in
 366         R.reduce ~delta ~subst context m1,
 367         R.reduce ~delta ~subst context m2
 368      in
 369      let rec convert_machines test_eq_only
 370        ((k1,e1,t1,s1),norm1 as m1),((k2,e2,t2,s2), norm2 as m2)
 371      =
 372        (alpha_eq test_eq_only
 373          (R.unwind (k1,e1,t1,[])) (R.unwind (k2,e2,t2,[])) &&
 374         let relevance =
 375           match t1 with
 376               C.Const r -> NCicEnvironment.get_relevance r
 377             | _ -> [] in
 378         try
 379          HExtlib.list_forall_default3
 380            (fun t1 t2 b  ->
 381              not b ||
 382              let t1 = RS.from_stack ~delta:max_int t1 in
 383              let t2 = RS.from_stack ~delta:max_int t2 in
 384              convert_machines true (put_in_whd t1 t2)) s1 s2 true relevance
 385         with Invalid_argument _ -> false) ||
 386        (not (norm1 && norm2) && convert_machines test_eq_only (small_delta_step m1 m2))
 387      in
 388      convert_machines test_eq_only (put_in_whd (0,[],t1,[]) (0,[],t2,[]))
 389  in
 390   aux false
 391 ;;
 392
 393 let alpha_eq metasenv subst =
 394  let rec aux test_lambda_source context t1 t2 =
 395   alpha_eq ~test_lambda_source aux true metasenv subst context t1 t2
 396  in
 397   aux true
 398 ;;
 399
 400 let rec head_beta_reduce ~delta ~upto ~subst t l =
 401  match upto, t, l with
 402   | 0, C.Appl l1, _ -> C.Appl (l1 @ l)
 403   | 0, t, [] -> t
 404   | 0, t, _ -> C.Appl (t::l)
 405   | _, C.Meta (n,ctx), _ ->
 406      (try
 407        let _,_, term,_ = NCicUtils.lookup_subst n subst in
 408        head_beta_reduce ~delta ~upto ~subst
 409          (NCicSubstitution.subst_meta ctx term) l
 410      with NCicUtils.Subst_not_found _ -> if l = [] then t else C.Appl (t::l))
 411   | _, C.Appl (hd::tl), _ -> head_beta_reduce ~delta ~upto ~subst hd (tl @ l)
 412   | _, C.Lambda(_,_,bo), arg::tl ->
 413      let bo = NCicSubstitution.subst arg bo in
 414      head_beta_reduce ~delta ~upto:(upto - 1) ~subst bo tl
 415   | _, C.Const (Ref.Ref (_, Ref.Def height) as re), _
 416     when delta <= height ->
 417       let _, _, bo, _, _, _ = NCicEnvironment.get_checked_def re in
 418       head_beta_reduce ~upto ~delta ~subst bo l
 419   | _, t, [] -> t
 420   | _, t, _ -> C.Appl (t::l)
 421 ;;
 422
 423 let head_beta_reduce ?(delta=max_int) ?(upto= -1) ?(subst=[]) t =
 424   head_beta_reduce ~delta ~upto ~subst t []
 425 ;;
 426
 427 type stack_item = RS.stack_term
 428 type environment_item = RS.env_term
 429
 430 type machine = int * environment_item list * NCic.term * stack_item list
 431
 432 let reduce_machine = R.reduce
 433 let from_stack = RS.from_stack
 434 let unwind = R.unwind
 435
 436 let _ =
 437   NCicUtils.set_head_beta_reduce (fun ~upto t -> head_beta_reduce ~upto t);
 438   NCicPp.set_head_beta_reduce (fun ~upto t -> head_beta_reduce ~upto t);
 439 ;;
 440
 441 (* if n < 0, then splits all prods from an arity, returning a sort *)
 442 let rec split_prods ~subst context n te =
 443   match (n, R.whd ~subst context te) with
 444    | (0, _) -> context,te
 445    | (n, C.Sort _) when n <= 0 -> context,te
 446    | (n, C.Prod (name,so,ta)) ->
 447        split_prods ~subst ((name,(C.Decl so))::context) (n - 1) ta
 448    | (_, _) -> raise (AssertFailure (lazy "split_prods"))
 449 ;;
 450
 451 (* vim:set foldmethod=marker: *)