helm/software/components/ng_kernel/nCicReduction.ml

   1 (*
   2     ||M||  This file is part of HELM, an Hypertextual, Electronic
   3     ||A||  Library of Mathematics, developed at the Computer Science
   4     ||T||  Department, University of Bologna, Italy.
   5     ||I||
   6     ||T||  HELM is free software; you can redistribute it and/or
   7     ||A||  modify it under the terms of the GNU General Public License
   8     \   /  version 2 or (at your option) any later version.
   9      \ /   This software is distributed as is, NO WARRANTY.
  10       V_______________________________________________________________ *)
  11
  12 (* $Id$ *)
  13
  14 module C = NCic
  15 module Ref = NReference
  16 module E = NCicEnvironment
  17
  18 module type Strategy = sig
  19   type stack_term
  20   type env_term
  21   type config = int * env_term list * C.term * stack_term list
  22   val to_env :
  23    reduce: (config -> config) -> unwind: (config -> C.term) ->
  24     config -> env_term
  25   val from_stack : stack_term -> config
  26   val from_stack_list_for_unwind :
  27    unwind: (config -> C.term) -> stack_term list -> C.term list
  28   val from_env : env_term -> config
  29   val from_env_for_unwind :
  30    unwind: (config -> C.term) -> env_term -> C.term
  31   val stack_to_env :
  32    reduce: (config -> config) -> unwind: (config -> C.term) ->
  33     stack_term -> env_term
  34   val compute_to_env :
  35    reduce: (config -> config) -> unwind: (config -> C.term) ->
  36     int -> env_term list -> C.term -> env_term
  37   val compute_to_stack :
  38    reduce: (config -> config) -> unwind: (config -> C.term) ->
  39     config -> stack_term
  40  end
  41 ;;
  42
  43 module CallByValueByNameForUnwind' = struct
  44   type config = int * env_term list * C.term * stack_term list
  45   and stack_term = config lazy_t * C.term lazy_t (* cbv, cbn *)
  46   and env_term = config lazy_t * C.term lazy_t (* cbv, cbn *)
  47   let to_env ~reduce ~unwind c = lazy (reduce c),lazy (unwind c)
  48   let from_stack (c,_) = Lazy.force c
  49   let from_stack_list_for_unwind ~unwind:_ l =
  50    List.map (function (_,c) -> Lazy.force c) l
  51   let from_env (c,_) = Lazy.force c
  52   let from_env_for_unwind ~unwind:_ (_,c) = Lazy.force c
  53   let stack_to_env ~reduce:_ ~unwind:_ config = config
  54   let compute_to_env ~reduce ~unwind k e t =
  55    lazy (reduce (k,e,t,[])), lazy (unwind (k,e,t,[]))
  56   let compute_to_stack ~reduce ~unwind config =
  57    lazy (reduce config), lazy (unwind config)
  58  end
  59 ;;
  60
  61 module Reduction(RS : Strategy) = struct
  62   type env = RS.env_term list
  63   type stack = RS.stack_term list
  64   type config = int * env * C.term * stack
  65
  66   let rec unwind (k,e,t,s) =
  67     let t =
  68       if k = 0 then t
  69       else
  70         NCicSubstitution.psubst ~avoid_beta_redexes:true
  71           (RS.from_env_for_unwind ~unwind) e t
  72     in
  73     if s = [] then t
  74     else C.Appl(t::(RS.from_stack_list_for_unwind ~unwind s))
  75   ;;
  76
  77   let list_nth l n = try List.nth l n with Failure _ -> assert false;;
  78   let rec replace i s t =
  79     match i,s with
  80     |  0,_::tl -> t::tl
  81     | n,he::tl -> he::(replace (n - 1) tl t)
  82     | _,_ -> assert false
  83   ;;
  84
  85   let rec reduce ~delta ?(subst = []) context : config -> config =
  86    let rec aux = function
  87      | k, e, C.Rel n, s when n <= k ->
  88         let k',e',t',s' = RS.from_env (list_nth e (n-1)) in
  89         aux (k',e',t',s'@s)
  90      | k, _, C.Rel n, s as config (* when n > k *) ->
  91         let x= try Some (List.nth context (n - 1 - k)) with Failure _ -> None in
  92          (match x with
  93          | Some(_,C.Def(x,_)) -> aux (0,[],NCicSubstitution.lift (n - k) x,s)
  94          | _ -> config)
  95      | (k, e, C.Meta (n,l), s) as config ->
  96         (try
  97            let _,_, term,_ = NCicUtils.lookup_subst n subst in
  98            aux (k, e, NCicSubstitution.subst_meta l term,s)
  99          with  NCicUtils.Subst_not_found _ -> config)
 100      | (_, _, C.Implicit _, _) -> assert false
 101      | (_, _, C.Sort _, _)
 102      | (_, _, C.Prod _, _)
 103      | (_, _, C.Lambda _, []) as config -> config
 104      | (k, e, C.Lambda (_,_,t), p::s) ->
 105          aux (k+1, (RS.stack_to_env ~reduce:aux ~unwind p)::e, t,s)
 106      | (k, e, C.LetIn (_,_,m,t), s) ->
 107         let m' = RS.compute_to_env ~reduce:aux ~unwind k e m in
 108          aux (k+1, m'::e, t, s)
 109      | (_, _, C.Appl ([]|[_]), _) -> assert false
 110      | (k, e, C.Appl (he::tl), s) ->
 111         let tl' =
 112          List.map (fun t->RS.compute_to_stack ~reduce:aux ~unwind (k,e,t,[])) tl
 113         in
 114          aux (k, e, he, tl' @ s)
 115      | (_, _, C.Const
 116             (Ref.Ref (_,Ref.Def height) as refer), s) as config ->
 117          if delta >= height then config else
 118            let _,_,body,_,_,_ = NCicEnvironment.get_checked_def refer in
 119            aux (0, [], body, s)
 120      | (_, _, C.Const (Ref.Ref (_,
 121             (Ref.Decl|Ref.Ind _|Ref.Con _|Ref.CoFix _))), _) as config -> config
 122      | (_, _, C.Const (Ref.Ref
 123            (_,Ref.Fix (fixno,recindex,height)) as refer),s) as config ->
 124         if delta >= height then config else
 125         (match
 126           try Some (RS.from_stack (List.nth s recindex))
 127           with Failure _ -> None
 128         with
 129         | None -> config
 130         | Some recparam ->
 131            let fixes,_,_ = NCicEnvironment.get_checked_fixes_or_cofixes refer in
 132            match reduce ~delta:0 ~subst context recparam with
 133            | (_,_,C.Const (Ref.Ref (_,Ref.Con _)), _) as c ->
 134                let new_s =
 135                  replace recindex s (RS.compute_to_stack ~reduce:aux ~unwind c)
 136                in
 137                let _,_,_,_,body = List.nth fixes fixno in
 138                aux (0, [], body, new_s)
 139            | _ -> config)
 140      | (k, e, C.Match (_,_,term,pl),s) as config ->
 141         let decofix = function
 142           | (_,_,C.Const(Ref.Ref(_,Ref.CoFix c)as refer),s)->
 143              let cofixes,_,_ = NCicEnvironment.get_checked_fixes_or_cofixes refer in
 144              let _,_,_,_,body = List.nth cofixes c in
 145              reduce ~delta:0 ~subst context (0,[],body,s)
 146           | config -> config
 147         in
 148         (match decofix (reduce ~delta:0 ~subst context (k,e,term,[])) with
 149         | (_, _, C.Const (Ref.Ref (_,Ref.Con (_,j,_))),[]) ->
 150             aux (k, e, List.nth pl (j-1), s)
 151         | (_, _, C.Const (Ref.Ref (_,Ref.Con (_,j,lno))), s')->
 152           let _,params = HExtlib.split_nth lno s' in
 153           aux (k, e, List.nth pl (j-1), params@s)
 154         | _ -> config)
 155    in
 156     aux
 157   ;;
 158
 159   let whd ?(delta=0) ?(subst=[]) context t =
 160    unwind (reduce ~delta ~subst context (0, [], t, []))
 161   ;;
 162
 163  end
 164 ;;
 165
 166
 167 module RS = CallByValueByNameForUnwind';;
 168 module R = Reduction(RS);;
 169
 170 let whd = R.whd
 171
 172 let (===) x y = Pervasives.compare x y = 0 ;;
 173
 174 (* t1, t2 must be well-typed *)
 175 let are_convertible ?(subst=[]) get_relevance =
 176  let rec aux test_eq_only context t1 t2 =
 177    let rec alpha_eq test_eq_only t1 t2 =
 178      if t1 === t2 then
 179        true
 180      else
 181        match (t1,t2) with
 182        | (C.Sort (C.Type a), C.Sort (C.Type b)) when not test_eq_only ->
 183            NCicEnvironment.universe_leq a b
 184        | (C.Sort (C.Type a), C.Sort (C.Type b)) ->
 185            NCicEnvironment.universe_eq a b
 186        | (C.Sort C.Prop,C.Sort (C.Type _)) -> (not test_eq_only)
 187        | (C.Sort C.Prop, C.Sort C.Prop) -> true
 188
 189        | (C.Prod (name1,s1,t1), C.Prod(_,s2,t2)) ->
 190            aux true context s1 s2 &&
 191            aux test_eq_only ((name1, C.Decl s1)::context) t1 t2
 192        | (C.Lambda (name1,s1,t1), C.Lambda(_,_,t2)) ->
 193           (* thanks to inversion of well typedness, the source
 194            * of these lambdas must be already convertible *)
 195           aux test_eq_only ((name1, C.Decl s1)::context) t1 t2
 196        | (C.LetIn (name1,ty1,s1,t1), C.LetIn(_,ty2,s2,t2)) ->
 197           aux test_eq_only context ty1 ty2 &&
 198           aux test_eq_only context s1 s2 &&
 199           aux test_eq_only ((name1, C.Def (s1,ty1))::context) t1 t2
 200
 201        | (C.Meta (n1,(s1, C.Irl _)), C.Meta (n2,(s2, C.Irl _)))
 202           when n1 = n2 && s1 = s2 -> true
 203        | (C.Meta (n1,(s1, l1)), C.Meta (n2,(s2, l2))) when n1 = n2 &&
 204           let l1 = NCicUtils.expand_local_context l1 in
 205           let l2 = NCicUtils.expand_local_context l2 in
 206           (try List.for_all2
 207             (fun t1 t2 -> aux test_eq_only context
 208               (NCicSubstitution.lift s1 t1)
 209               (NCicSubstitution.lift s2 t2))
 210             l1 l2
 211           with Invalid_argument _ -> assert false) -> true
 212
 213        | C.Meta (n1,l1), _ ->
 214           (try
 215              let _,_,term,_ = NCicUtils.lookup_subst n1 subst in
 216              let term = NCicSubstitution.subst_meta l1 term in
 217               aux test_eq_only context term t2
 218            with NCicUtils.Subst_not_found _ -> false)
 219        | _, C.Meta (n2,l2) ->
 220           (try
 221              let _,_,term,_ = NCicUtils.lookup_subst n2 subst in
 222              let term = NCicSubstitution.subst_meta l2 term in
 223               aux test_eq_only context t1 term
 224            with NCicUtils.Subst_not_found _ -> false)
 225
 226        | (C.Appl (hd1::tl1), C.Appl (hd2::tl2)) ->
 227            aux test_eq_only context hd1 hd2 &&
 228            let relevance = get_relevance ~subst context hd1 tl1 in
 229            (try
 230              HExtlib.list_forall_default3
 231               (fun t1 t2 b -> not b || aux test_eq_only context t1 t2)
 232               tl1 tl2 true relevance
 233             with Invalid_argument _ -> false)
 234
 235        | (C.Match (Ref.Ref (_,Ref.Ind (_,tyno,_)) as ref1,outtype1,term1,pl1),
 236           C.Match (ref2,outtype2,term2,pl2)) ->
 237            let _,_,itl,_,_ = E.get_checked_indtys ref1 in
 238            let _,_,ty,_ = List.nth itl tyno in
 239            let rec remove_prods ~subst context ty =
 240              let ty = whd ~subst context ty in
 241              match ty with
 242              | C.Sort _ -> ty
 243              | C.Prod (name,so,ta) -> remove_prods ~subst ((name,(C.Decl so))::context) ta
 244              | _ -> assert false
 245            in
 246            let is_prop =
 247              match remove_prods ~subst [] ty with
 248              | C.Sort C.Prop -> true
 249              | _ -> false
 250            in
 251            Ref.eq ref1 ref2 &&
 252            aux test_eq_only context outtype1 outtype2 &&
 253            (is_prop || aux test_eq_only context term1 term2) &&
 254            (try List.for_all2 (aux test_eq_only context) pl1 pl2
 255             with Invalid_argument _ -> false)
 256        | (C.Implicit _, _) | (_, C.Implicit _) -> assert false
 257        | (_,_) -> false
 258   in
 259    if alpha_eq test_eq_only t1 t2 then
 260      true
 261    else
 262      let height_of = function
 263       | C.Const (Ref.Ref (_,Ref.Def h))
 264       | C.Const (Ref.Ref (_,Ref.Fix (_,_,h)))
 265       | C.Appl(C.Const(Ref.Ref(_,Ref.Def h))::_)
 266       | C.Appl(C.Const(Ref.Ref(_,Ref.Fix (_,_,h)))::_) -> h
 267       | _ -> 0
 268      in
 269      let small_delta_step (_,_,t1,_ as m1) (_,_,t2,_ as m2) =
 270        let h1 = height_of t1 in
 271        let h2 = height_of t2 in
 272        let delta = if h1 = h2 then max 0 (h1 -1) else min h1 h2 in
 273        R.reduce ~delta ~subst context m1,
 274        R.reduce ~delta ~subst context m2,
 275        delta
 276      in
 277      let rec convert_machines ((k1,e1,t1,s1 as m1),(k2,e2,t2,s2 as m2),delta) =
 278        (alpha_eq test_eq_only
 279          (R.unwind (k1,e1,t1,[])) (R.unwind (k2,e2,t2,[])) &&
 280         let relevance =
 281           match t1 with
 282               C.Const r -> NCicEnvironment.get_relevance r
 283             | _ -> [] in
 284         try
 285          HExtlib.list_forall_default3
 286            (fun t1 t2 b  ->
 287              not b ||
 288              let t1 = RS.from_stack t1 in
 289              let t2 = RS.from_stack t2 in
 290              convert_machines (small_delta_step t1 t2)) s1 s2 true relevance
 291         with Invalid_argument _ -> false) ||
 292        (delta > 0 &&
 293           let delta = delta - 1 in
 294           let red = R.reduce ~delta ~subst context in
 295           convert_machines (red m1,red m2,delta))
 296      in
 297      convert_machines (small_delta_step (0,[],t1,[]) (0,[],t2,[]))
 298  in
 299   aux false
 300 ;;
 301
 302 let rec head_beta_reduce ?(delta=max_int) ?(upto=(-1)) t l =
 303  match upto, t, l with
 304   | 0, C.Appl l1, _ -> C.Appl (l1 @ l)
 305   | 0, t, [] -> t
 306   | 0, t, _ -> C.Appl (t::l)
 307   | _, C.Appl (hd::tl), _ -> head_beta_reduce ~delta ~upto hd (tl @ l)
 308   | _, C.Lambda(_,_,bo), arg::tl ->
 309      let bo = NCicSubstitution.subst arg bo in
 310      head_beta_reduce ~delta ~upto:(upto - 1) bo tl
 311   | _, C.Const (Ref.Ref (_, Ref.Def height) as re), _
 312     when delta <= height ->
 313       let _, _, bo, _, _, _ = NCicEnvironment.get_checked_def re in
 314       head_beta_reduce ~upto ~delta bo l
 315   | _, t, [] -> t
 316   | _, t, _ -> C.Appl (t::l)
 317 ;;
 318
 319 let head_beta_reduce ?delta ?upto t = head_beta_reduce ?delta ?upto t [];;
 320
 321 (* vim:set foldmethod=marker: *)