helm/software/components/ng_kernel/nCicReduction.ml

   1 (*
   2     ||M||  This file is part of HELM, an Hypertextual, Electronic
   3     ||A||  Library of Mathematics, developed at the Computer Science
   4     ||T||  Department, University of Bologna, Italy.
   5     ||I||
   6     ||T||  HELM is free software; you can redistribute it and/or
   7     ||A||  modify it under the terms of the GNU General Public License
   8     \   /  version 2 or (at your option) any later version.
   9      \ /   This software is distributed as is, NO WARRANTY.
  10       V_______________________________________________________________ *)
  11
  12 (* $Id$ *)
  13
  14 module C = NCic
  15 module Ref = NReference
  16 module E = NCicEnvironment
  17
  18 exception AssertFailure of string Lazy.t;;
  19
  20 module type Strategy = sig
  21   type stack_term
  22   type env_term
  23   type config = int * env_term list * C.term * stack_term list
  24   val to_env :
  25    reduce: (delta:int -> config -> config * bool) ->
  26    unwind: (config -> C.term) ->
  27     config -> env_term
  28   val from_stack : delta:int -> stack_term -> config
  29   val from_stack_list_for_unwind :
  30     unwind: (config -> C.term) -> stack_term list -> C.term list
  31   val from_env : delta:int -> env_term -> config
  32   val from_env_for_unwind :
  33     unwind: (config -> C.term) -> env_term -> C.term
  34   val stack_to_env :
  35    reduce: (delta:int -> config -> config * bool) ->
  36    unwind: (config -> C.term) ->
  37     stack_term -> env_term
  38   val compute_to_env :
  39    reduce: (delta:int -> config -> config * bool) ->
  40    unwind: (config -> C.term) ->
  41     int -> env_term list -> C.term -> env_term
  42   val compute_to_stack :
  43    reduce: (delta:int -> config -> config * bool) ->
  44    unwind: (config -> C.term) ->
  45     config -> stack_term
  46  end
  47 ;;
  48
  49 module CallByValueByNameForUnwind' : Strategy = struct
  50   type config = int * env_term list * C.term * stack_term list
  51   and stack_term =
  52        config Lazy.t * (int -> config) * C.term Lazy.t
  53   and env_term =
  54         config Lazy.t    (* cbneed   ~delta:0       *)
  55       * (int -> config)  (* cbvalue  ~delta         *)
  56       * C.term Lazy.t    (* cbname   ~delta:max_int *)
  57   let to_env ~reduce ~unwind c =
  58    lazy (fst (reduce ~delta:0 c)),
  59    (fun delta -> fst (reduce ~delta c)),
  60    lazy (unwind c)
  61   let from_stack ~delta (c0,c,_) = if delta = 0 then Lazy.force c0 else c delta
  62   let from_stack_list_for_unwind ~unwind:_ l =
  63    List.map (fun (_,_,c) -> Lazy.force c) l
  64   let from_env ~delta (c0,c,_) = if delta = 0 then Lazy.force c0 else c delta
  65   let from_env_for_unwind ~unwind:_ (_,_,c) = Lazy.force c
  66   let stack_to_env ~reduce:_ ~unwind:_ config = config
  67   let compute_to_env ~reduce ~unwind k e t =
  68    lazy (fst (reduce ~delta:0 (k,e,t,[]))),
  69    (fun delta -> fst (reduce ~delta (k,e,t,[]))),
  70    lazy (unwind (k,e,t,[]))
  71   let compute_to_stack ~reduce ~unwind config =
  72    lazy (fst (reduce ~delta:0 config)),
  73    (fun delta -> fst (reduce ~delta config)),
  74    lazy (unwind config)
  75  end
  76 ;;
  77
  78 module Reduction(RS : Strategy) = struct
  79   type env = RS.env_term list
  80   type stack = RS.stack_term list
  81   type config = int * env * C.term * stack
  82
  83   let rec unwind (k,e,t,s) =
  84     let t =
  85       if k = 0 then t
  86       else
  87         NCicSubstitution.psubst ~avoid_beta_redexes:true
  88           (RS.from_env_for_unwind ~unwind) e t
  89     in
  90     if s = [] then t
  91     else C.Appl(t::(RS.from_stack_list_for_unwind ~unwind s))
  92   ;;
  93
  94   let list_nth l n = try List.nth l n with Failure _ -> assert false;;
  95   let rec replace i s t =
  96     match i,s with
  97     |  0,_::tl -> t::tl
  98     | n,he::tl -> he::(replace (n - 1) tl t)
  99     | _,_ -> assert false
 100   ;;
 101
 102   let rec reduce ~delta ?(subst = []) context : config -> config * bool =
 103    let rec aux = function
 104      | k, e, C.Rel n, s when n <= k ->
 105         let k',e',t',s' = RS.from_env ~delta (list_nth e (n-1)) in
 106         aux (k',e',t',s'@s)
 107      | k, _, C.Rel n, s as config (* when n > k *) ->
 108         let x= try Some (List.nth context (n - 1 - k)) with Failure _ -> None in
 109          (match x with
 110          | Some(_,C.Def(x,_)) -> aux (0,[],NCicSubstitution.lift (n - k) x,s)
 111          | _ -> config, true)
 112      | (k, e, C.Meta (n,l), s) as config ->
 113         (try
 114            let _,_, term,_ = NCicUtils.lookup_subst n subst in
 115            aux (k, e, NCicSubstitution.subst_meta l term,s)
 116          with  NCicUtils.Subst_not_found _ -> config, true)
 117      | (_, _, C.Implicit _, _) -> assert false
 118      | (_, _, C.Sort _, _)
 119      | (_, _, C.Prod _, _)
 120      | (_, _, C.Lambda _, []) as config -> config, true
 121      | (k, e, C.Lambda (_,_,t), p::s) ->
 122          aux (k+1, (RS.stack_to_env ~reduce:(reduce ~subst context) ~unwind p)::e, t,s)
 123      | (k, e, C.LetIn (_,_,m,t), s) ->
 124         let m' = RS.compute_to_env ~reduce:(reduce ~subst context) ~unwind k e m in
 125          aux (k+1, m'::e, t, s)
 126      | (_, _, C.Appl ([]|[_]), _) -> assert false
 127      | (k, e, C.Appl (he::tl), s) ->
 128         let tl' =
 129          List.map (fun t->RS.compute_to_stack
 130            ~reduce:(reduce ~subst context) ~unwind (k,e,t,[])) tl
 131         in
 132          aux (k, e, he, tl' @ s)
 133      | (_, _, C.Const
 134             (Ref.Ref (_,Ref.Def height) as refer), s) as config ->
 135          if delta >= height then
 136            config, false
 137          else
 138            let _,_,body,_,_,_ = NCicEnvironment.get_checked_def refer in
 139            aux (0, [], body, s)
 140      | (_, _, C.Const (Ref.Ref (_,
 141          (Ref.Decl|Ref.Ind _|Ref.Con _|Ref.CoFix _))), _) as config ->
 142            config, true
 143      | (_, _, (C.Const (Ref.Ref
 144            (_,Ref.Fix (fixno,recindex,height)) as refer) as head),s) as config ->
 145 (*         if delta >= height then config else *)
 146         (match
 147           try Some (RS.from_stack ~delta (List.nth s recindex))
 148           with Failure _ -> None
 149         with
 150         | None -> config, true
 151         | Some recparam ->
 152            let fixes,_,_ = NCicEnvironment.get_checked_fixes_or_cofixes refer in
 153            match reduce ~delta:0 ~subst context recparam with
 154            | (_,_,C.Const (Ref.Ref (_,Ref.Con _)), _) as c, _
 155               when delta >= height ->
 156                let new_s =
 157                  replace recindex s (RS.compute_to_stack ~reduce:(reduce ~subst
 158                  context) ~unwind c)
 159                in
 160                (0, [], head, new_s), false
 161            | (_,_,C.Const (Ref.Ref (_,Ref.Con _)), _) as c, _ ->
 162                let new_s =
 163                  replace recindex s (RS.compute_to_stack ~reduce:(reduce ~subst
 164                  context) ~unwind c)
 165                in
 166                let _,_,_,_,body = List.nth fixes fixno in
 167                aux (0, [], body, new_s)
 168            | _ -> config, true)
 169      | (k, e, C.Match (_,_,term,pl),s) as config ->
 170         let decofix = function
 171           | (_,_,C.Const(Ref.Ref(_,Ref.CoFix c)as refer),s)->
 172              let cofixes,_,_ =
 173                NCicEnvironment.get_checked_fixes_or_cofixes refer in
 174              let _,_,_,_,body = List.nth cofixes c in
 175              let c,_ = reduce ~delta:0 ~subst context (0,[],body,s) in
 176              c
 177           | config -> config
 178         in
 179         let match_head = k,e,term,[] in
 180         let reduced,_ = reduce ~delta:0 ~subst context match_head in
 181         (match decofix reduced with
 182         | (_, _, C.Const (Ref.Ref (_,Ref.Con (_,j,_))),[]) ->
 183             aux (k, e, List.nth pl (j-1), s)
 184         | (_, _, C.Const (Ref.Ref (_,Ref.Con (_,j,lno))), s')->
 185           let _,params = HExtlib.split_nth lno s' in
 186           aux (k, e, List.nth pl (j-1), params@s)
 187         | _ -> config, true)
 188    in
 189     aux
 190   ;;
 191
 192   let whd ?(delta=0) ~subst context t =
 193    unwind (fst (reduce ~delta ~subst context (0, [], t, [])))
 194   ;;
 195
 196  end
 197 ;;
 198
 199
 200 module RS = CallByValueByNameForUnwind';;
 201 module R = Reduction(RS);;
 202
 203 let whd = R.whd
 204
 205 let (===) x y = Pervasives.compare x y = 0 ;;
 206
 207 let get_relevance = ref (fun ~metasenv:_ ~subst:_ _ _ -> assert false);;
 208
 209 let set_get_relevance f = get_relevance := f;;
 210
 211 let alpha_eq ~test_lambda_source aux test_eq_only metasenv subst context t1 t2 =
 212  if t1 === t2 then
 213    true
 214  else
 215    match (t1,t2) with
 216    | C.Sort s1, C.Sort s2 ->
 217        NCicEnvironment.are_sorts_convertible ~test_eq_only s1 s2
 218
 219    | (C.Prod (name1,s1,t1), C.Prod(_,s2,t2)) ->
 220        aux true context s1 s2 &&
 221        aux test_eq_only ((name1, C.Decl s1)::context) t1 t2
 222    | (C.Lambda (name1,s1,t1), C.Lambda(_,_,t2)) ->
 223       if test_lambda_source then
 224        aux test_eq_only context t1 t2
 225       else
 226        (* thanks to inversion of well typedness, the source
 227         * of these lambdas must be already convertible *)
 228        aux test_eq_only ((name1, C.Decl s1)::context) t1 t2
 229    | (C.LetIn (name1,ty1,s1,t1), C.LetIn(_,ty2,s2,t2)) ->
 230       aux test_eq_only context ty1 ty2 &&
 231       aux test_eq_only context s1 s2 &&
 232       aux test_eq_only ((name1, C.Def (s1,ty1))::context) t1 t2
 233
 234    | (C.Meta (n1,(s1, C.Irl _)), C.Meta (n2,(s2, C.Irl _)))
 235       when n1 = n2 && s1 = s2 -> true
 236    | (C.Meta (n1,(s1, l1)), C.Meta (n2,(s2, l2))) when n1 = n2 &&
 237       let l1 = NCicUtils.expand_local_context l1 in
 238       let l2 = NCicUtils.expand_local_context l2 in
 239       (try List.for_all2
 240         (fun t1 t2 -> aux test_eq_only context
 241           (NCicSubstitution.lift s1 t1)
 242           (NCicSubstitution.lift s2 t2))
 243         l1 l2
 244       with Invalid_argument "List.for_all2" ->
 245         prerr_endline ("Meta " ^ string_of_int n1 ^
 246           " occurrs with local contexts of different lenght\n"^
 247           NCicPp.ppterm ~metasenv ~subst ~context t1 ^ " === " ^
 248           NCicPp.ppterm ~metasenv ~subst ~context t2);
 249         assert false) -> true
 250
 251    | C.Meta (n1,l1), _ ->
 252       (try
 253          let _,_,term,_ = NCicUtils.lookup_subst n1 subst in
 254          let term = NCicSubstitution.subst_meta l1 term in
 255           aux test_eq_only context term t2
 256        with NCicUtils.Subst_not_found _ -> false)
 257    | _, C.Meta (n2,l2) ->
 258       (try
 259          let _,_,term,_ = NCicUtils.lookup_subst n2 subst in
 260          let term = NCicSubstitution.subst_meta l2 term in
 261           aux test_eq_only context t1 term
 262        with NCicUtils.Subst_not_found _ -> false)
 263
 264    | (C.Appl ((C.Const r1) as hd1::tl1), C.Appl (C.Const r2::tl2))
 265        when (Ref.eq r1 r2 &&
 266          List.length (E.get_relevance r1) >= List.length tl1) ->
 267      let relevance = E.get_relevance r1 in
 268      let relevance = match r1 with
 269          | Ref.Ref (_,Ref.Con (_,_,lno)) ->
 270              let _,relevance = HExtlib.split_nth lno relevance in
 271                HExtlib.mk_list false lno @ relevance
 272          | _ -> relevance
 273      in
 274      (try
 275          HExtlib.list_forall_default3_var
 276           (fun t1 t2 b -> not b || aux true context t1 t2 )
 277           tl1 tl2 true relevance
 278         with Invalid_argument _ -> false
 279            | HExtlib.FailureAt fail ->
 280              let relevance =
 281                !get_relevance ~metasenv ~subst context hd1 tl1 in
 282              let _,relevance = HExtlib.split_nth fail relevance in
 283              let b,relevance = (match relevance with
 284                | [] -> assert false
 285                | b::tl -> b,tl) in
 286              if (not b) then
 287                let _,tl1 = HExtlib.split_nth (fail+1) tl1 in
 288                let _,tl2 = HExtlib.split_nth (fail+1) tl2 in
 289                  try
 290                     HExtlib.list_forall_default3
 291                     (fun t1 t2 b -> not b || aux true context t1 t2)
 292                     tl1 tl2 true relevance
 293                  with Invalid_argument _ -> false
 294              else false)
 295
 296    | (C.Appl (hd1::tl1),  C.Appl (hd2::tl2)) ->
 297        aux test_eq_only context hd1 hd2 &&
 298         let relevance = !get_relevance ~metasenv ~subst context hd1 tl1 in
 299         (try
 300          HExtlib.list_forall_default3
 301           (fun t1 t2 b -> not b || aux true context t1 t2)
 302           tl1 tl2 true relevance
 303         with Invalid_argument _ -> false)
 304
 305    | (C.Match (Ref.Ref (_,Ref.Ind (_,tyno,_)) as ref1,outtype1,term1,pl1),
 306       C.Match (ref2,outtype2,term2,pl2)) ->
 307        let _,_,itl,_,_ = E.get_checked_indtys ref1 in
 308        let _,_,ty,_ = List.nth itl tyno in
 309        let rec remove_prods ~subst context ty =
 310          let ty = whd ~subst context ty in
 311          match ty with
 312          | C.Sort _ -> ty
 313          | C.Prod (name,so,ta) -> remove_prods ~subst ((name,(C.Decl so))::context) ta
 314          | _ -> assert false
 315        in
 316        let is_prop =
 317          match remove_prods ~subst [] ty with
 318          | C.Sort C.Prop -> true
 319          | _ -> false
 320        in
 321        Ref.eq ref1 ref2 &&
 322        aux test_eq_only context outtype1 outtype2 &&
 323        (is_prop || aux test_eq_only context term1 term2) &&
 324        (try List.for_all2 (aux test_eq_only context) pl1 pl2
 325         with Invalid_argument _ -> false)
 326    | (C.Implicit _, _) | (_, C.Implicit _) -> assert false
 327    | (_,_) -> false
 328 ;;
 329
 330 (* t1, t2 must be well-typed *)
 331 let are_convertible ~metasenv ~subst =
 332  let rec aux test_eq_only context t1 t2 =
 333   let alpha_eq test_eq_only =
 334    alpha_eq ~test_lambda_source:false aux test_eq_only metasenv subst context
 335   in
 336    if alpha_eq test_eq_only t1 t2 then
 337      true
 338    else
 339      let height_of = function
 340       | C.Const (Ref.Ref (_,Ref.Def h))
 341       | C.Const (Ref.Ref (_,Ref.Fix (_,_,h)))
 342       | C.Appl(C.Const(Ref.Ref(_,Ref.Def h))::_)
 343       | C.Appl(C.Const(Ref.Ref(_,Ref.Fix (_,_,h)))::_) -> h
 344       | _ -> 0
 345      in
 346      let put_in_whd m1 m2 =
 347        R.reduce ~delta:max_int ~subst context m1,
 348        R.reduce ~delta:max_int ~subst context m2
 349      in
 350      let small_delta_step
 351        ((_,_,t1,_ as m1), norm1 as x1) ((_,_,t2,_ as m2), norm2 as x2)
 352      =
 353        assert(not (norm1 && norm2));
 354        if norm1 then
 355          x1, R.reduce ~delta:(height_of t2 -1) ~subst context m2
 356        else if norm2 then
 357          R.reduce ~delta:(height_of t1 -1) ~subst context m1, x2
 358        else
 359         let h1 = height_of t1 in
 360         let h2 = height_of t2 in
 361         let delta = if h1 = h2 then max 0 (h1 -1) else min h1 h2 in
 362         R.reduce ~delta ~subst context m1,
 363         R.reduce ~delta ~subst context m2
 364      in
 365      let rec convert_machines test_eq_only
 366        ((k1,e1,t1,s1),norm1 as m1),((k2,e2,t2,s2), norm2 as m2)
 367      =
 368        (alpha_eq test_eq_only
 369          (R.unwind (k1,e1,t1,[])) (R.unwind (k2,e2,t2,[])) &&
 370         let relevance =
 371           match t1 with
 372               C.Const r -> NCicEnvironment.get_relevance r
 373             | _ -> [] in
 374         try
 375          HExtlib.list_forall_default3
 376            (fun t1 t2 b  ->
 377              not b ||
 378              let t1 = RS.from_stack ~delta:max_int t1 in
 379              let t2 = RS.from_stack ~delta:max_int t2 in
 380              convert_machines true (put_in_whd t1 t2)) s1 s2 true relevance
 381         with Invalid_argument _ -> false) ||
 382        (not (norm1 && norm2) && convert_machines test_eq_only (small_delta_step m1 m2))
 383      in
 384      convert_machines test_eq_only (put_in_whd (0,[],t1,[]) (0,[],t2,[]))
 385  in
 386   aux false
 387 ;;
 388
 389 let alpha_eq metasenv subst =
 390  let rec aux test_lambda_source context t1 t2 =
 391   alpha_eq ~test_lambda_source aux true metasenv subst context t1 t2
 392  in
 393   aux true
 394 ;;
 395
 396 let rec head_beta_reduce ~delta ~upto ~subst t l =
 397  match upto, t, l with
 398   | 0, C.Appl l1, _ -> C.Appl (l1 @ l)
 399   | 0, t, [] -> t
 400   | 0, t, _ -> C.Appl (t::l)
 401   | _, C.Meta (n,ctx), _ ->
 402      (try
 403        let _,_, term,_ = NCicUtils.lookup_subst n subst in
 404        head_beta_reduce ~delta ~upto ~subst
 405          (NCicSubstitution.subst_meta ctx term) l
 406      with NCicUtils.Subst_not_found _ -> if l = [] then t else C.Appl (t::l))
 407   | _, C.Appl (hd::tl), _ -> head_beta_reduce ~delta ~upto ~subst hd (tl @ l)
 408   | _, C.Lambda(_,_,bo), arg::tl ->
 409      let bo = NCicSubstitution.subst arg bo in
 410      head_beta_reduce ~delta ~upto:(upto - 1) ~subst bo tl
 411   | _, C.Const (Ref.Ref (_, Ref.Def height) as re), _
 412     when delta <= height ->
 413       let _, _, bo, _, _, _ = NCicEnvironment.get_checked_def re in
 414       head_beta_reduce ~upto ~delta ~subst bo l
 415   | _, t, [] -> t
 416   | _, t, _ -> C.Appl (t::l)
 417 ;;
 418
 419 let head_beta_reduce ?(delta=max_int) ?(upto= -1) ?(subst=[]) t =
 420   head_beta_reduce ~delta ~upto ~subst t []
 421 ;;
 422
 423 type stack_item = RS.stack_term
 424 type environment_item = RS.env_term
 425
 426 type machine = int * environment_item list * NCic.term * stack_item list
 427
 428 let reduce_machine = R.reduce
 429 let from_stack = RS.from_stack
 430 let unwind = R.unwind
 431
 432 let _ =
 433   NCicUtils.set_head_beta_reduce (fun ~upto t -> head_beta_reduce ~upto t);
 434   NCicPp.set_head_beta_reduce (fun ~upto t -> head_beta_reduce ~upto t);
 435 ;;
 436
 437 (* if n < 0, then splits all prods from an arity, returning a sort *)
 438 let rec split_prods ~subst context n te =
 439   match (n, R.whd ~subst context te) with
 440    | (0, _) -> context,te
 441    | (n, C.Sort _) when n <= 0 -> context,te
 442    | (n, C.Prod (name,so,ta)) ->
 443        split_prods ~subst ((name,(C.Decl so))::context) (n - 1) ta
 444    | (_, _) -> raise (AssertFailure (lazy "split_prods"))
 445 ;;
 446
 447 (* vim:set foldmethod=marker: *)