helm/software/components/ng_kernel/nCicReduction.ml

   1 (*
   2     ||M||  This file is part of HELM, an Hypertextual, Electronic
   3     ||A||  Library of Mathematics, developed at the Computer Science
   4     ||T||  Department, University of Bologna, Italy.
   5     ||I||
   6     ||T||  HELM is free software; you can redistribute it and/or
   7     ||A||  modify it under the terms of the GNU General Public License
   8     \   /  version 2 or (at your option) any later version.
   9      \ /   This software is distributed as is, NO WARRANTY.
  10       V_______________________________________________________________ *)
  11
  12 (* $Id$ *)
  13
  14 module C = NCic
  15 module Ref = NReference
  16 module E = NCicEnvironment
  17
  18 module type Strategy = sig
  19   type stack_term
  20   type env_term
  21   type config = int * env_term list * C.term * stack_term list
  22   val to_env :
  23    reduce: (config -> config * bool) -> unwind: (config -> C.term) ->
  24     config -> env_term
  25   val from_stack : stack_term -> config
  26   val from_stack_list_for_unwind :
  27    unwind: (config -> C.term) -> stack_term list -> C.term list
  28   val from_env : env_term -> config
  29   val from_env_for_unwind :
  30    unwind: (config -> C.term) -> env_term -> C.term
  31   val stack_to_env :
  32    reduce: (config -> config * bool) -> unwind: (config -> C.term) ->
  33     stack_term -> env_term
  34   val compute_to_env :
  35    reduce: (config -> config * bool) -> unwind: (config -> C.term) ->
  36     int -> env_term list -> C.term -> env_term
  37   val compute_to_stack :
  38    reduce: (config -> config * bool) -> unwind: (config -> C.term) ->
  39     config -> stack_term
  40  end
  41 ;;
  42
  43 module CallByValueByNameForUnwind' = struct
  44   type config = int * env_term list * C.term * stack_term list
  45   and stack_term = config lazy_t * C.term lazy_t (* cbv, cbn *)
  46   and env_term = config lazy_t * C.term lazy_t (* cbv, cbn *)
  47   let to_env ~reduce ~unwind c = lazy (fst (reduce c)),lazy (unwind c)
  48   let from_stack (c,_) = Lazy.force c
  49   let from_stack_list_for_unwind ~unwind:_ l =
  50    List.map (function (_,c) -> Lazy.force c) l
  51   let from_env (c,_) = Lazy.force c
  52   let from_env_for_unwind ~unwind:_ (_,c) = Lazy.force c
  53   let stack_to_env ~reduce:_ ~unwind:_ config = config
  54   let compute_to_env ~reduce ~unwind k e t =
  55    lazy (fst (reduce (k,e,t,[]))), lazy (unwind (k,e,t,[]))
  56   let compute_to_stack ~reduce ~unwind config =
  57    lazy (fst (reduce config)), lazy (unwind config)
  58  end
  59 ;;
  60
  61 module Reduction(RS : Strategy) = struct
  62   type env = RS.env_term list
  63   type stack = RS.stack_term list
  64   type config = int * env * C.term * stack
  65
  66   let rec unwind (k,e,t,s) =
  67     let t =
  68       if k = 0 then t
  69       else
  70         NCicSubstitution.psubst ~avoid_beta_redexes:true
  71           (RS.from_env_for_unwind ~unwind) e t
  72     in
  73     if s = [] then t
  74     else C.Appl(t::(RS.from_stack_list_for_unwind ~unwind s))
  75   ;;
  76
  77   let list_nth l n = try List.nth l n with Failure _ -> assert false;;
  78   let rec replace i s t =
  79     match i,s with
  80     |  0,_::tl -> t::tl
  81     | n,he::tl -> he::(replace (n - 1) tl t)
  82     | _,_ -> assert false
  83   ;;
  84
  85   let rec reduce ~delta ?(subst = []) context : config -> config * bool =
  86    let rec aux = function
  87      | k, e, C.Rel n, s when n <= k ->
  88         let k',e',t',s' = RS.from_env (list_nth e (n-1)) in
  89         aux (k',e',t',s'@s)
  90      | k, _, C.Rel n, s as config (* when n > k *) ->
  91         let x= try Some (List.nth context (n - 1 - k)) with Failure _ -> None in
  92          (match x with
  93          | Some(_,C.Def(x,_)) -> aux (0,[],NCicSubstitution.lift (n - k) x,s)
  94          | _ -> config, true)
  95      | (k, e, C.Meta (n,l), s) as config ->
  96         (try
  97            let _,_, term,_ = NCicUtils.lookup_subst n subst in
  98            aux (k, e, NCicSubstitution.subst_meta l term,s)
  99          with  NCicUtils.Subst_not_found _ -> config, true)
 100      | (_, _, C.Implicit _, _) -> assert false
 101      | (_, _, C.Sort _, _)
 102      | (_, _, C.Prod _, _)
 103      | (_, _, C.Lambda _, []) as config -> config, true
 104      | (k, e, C.Lambda (_,_,t), p::s) ->
 105          aux (k+1, (RS.stack_to_env ~reduce:aux ~unwind p)::e, t,s)
 106      | (k, e, C.LetIn (_,_,m,t), s) ->
 107         let m' = RS.compute_to_env ~reduce:aux ~unwind k e m in
 108          aux (k+1, m'::e, t, s)
 109      | (_, _, C.Appl ([]|[_]), _) -> assert false
 110      | (k, e, C.Appl (he::tl), s) ->
 111         let tl' =
 112          List.map (fun t->RS.compute_to_stack ~reduce:aux ~unwind (k,e,t,[])) tl
 113         in
 114          aux (k, e, he, tl' @ s)
 115      | (_, _, C.Const
 116             (Ref.Ref (_,Ref.Def height) as refer), s) as config ->
 117          if delta >= height then config, false else
 118            let _,_,body,_,_,_ = NCicEnvironment.get_checked_def refer in
 119            aux (0, [], body, s)
 120      | (_, _, C.Const (Ref.Ref (_,
 121          (Ref.Decl|Ref.Ind _|Ref.Con _|Ref.CoFix _))), _) as config ->
 122            config, true
 123      | (_, _, (C.Const (Ref.Ref
 124            (_,Ref.Fix (fixno,recindex,height)) as refer) as head),s) as config ->
 125 (*         if delta >= height then config else *)
 126         (match
 127           try Some (RS.from_stack (List.nth s recindex))
 128           with Failure _ -> None
 129         with
 130         | None -> config, true
 131         | Some recparam ->
 132            let fixes,_,_ = NCicEnvironment.get_checked_fixes_or_cofixes refer in
 133            match reduce ~delta:0 ~subst context recparam with
 134            | (_,_,C.Const (Ref.Ref (_,Ref.Con _)), _) as c, _
 135               when delta >= height ->
 136                let new_s =
 137                  replace recindex s (RS.compute_to_stack ~reduce:aux ~unwind c)
 138                in
 139                (0, [], head, new_s), false
 140            | (_,_,C.Const (Ref.Ref (_,Ref.Con _)), _) as c, _ ->
 141                let new_s =
 142                  replace recindex s (RS.compute_to_stack ~reduce:aux ~unwind c)
 143                in
 144                let _,_,_,_,body = List.nth fixes fixno in
 145                aux (0, [], body, new_s)
 146            | _ -> config, true)
 147      | (k, e, C.Match (_,_,term,pl),s) as config ->
 148         let decofix = function
 149           | (_,_,C.Const(Ref.Ref(_,Ref.CoFix c)as refer),s)->
 150              let cofixes,_,_ =
 151                NCicEnvironment.get_checked_fixes_or_cofixes refer in
 152              let _,_,_,_,body = List.nth cofixes c in
 153              let c,_ = reduce ~delta:0 ~subst context (0,[],body,s) in
 154              c
 155           | config -> config
 156         in
 157         (match decofix (fst (reduce ~delta:0 ~subst context (k,e,term,[]))) with
 158         | (_, _, C.Const (Ref.Ref (_,Ref.Con (_,j,_))),[]) ->
 159             aux (k, e, List.nth pl (j-1), s)
 160         | (_, _, C.Const (Ref.Ref (_,Ref.Con (_,j,lno))), s')->
 161           let _,params = HExtlib.split_nth lno s' in
 162           aux (k, e, List.nth pl (j-1), params@s)
 163         | _ -> config,true)
 164    in
 165     aux
 166   ;;
 167
 168   let whd ?(delta=0) ?(subst=[]) context t =
 169    unwind (fst (reduce ~delta ~subst context (0, [], t, [])))
 170   ;;
 171
 172  end
 173 ;;
 174
 175
 176 module RS = CallByValueByNameForUnwind';;
 177 module R = Reduction(RS);;
 178
 179 let whd = R.whd
 180
 181 let (===) x y = Pervasives.compare x y = 0 ;;
 182
 183 let get_relevance = ref (fun ~subst:_ _ _ -> assert false);;
 184
 185 let set_get_relevance f = get_relevance := f;;
 186
 187 (* t1, t2 must be well-typed *)
 188 let are_convertible ?(subst=[]) =
 189  let rec aux test_eq_only context t1 t2 =
 190    let alpha_eq test_eq_only t1 t2 =
 191      if t1 === t2 then
 192        true
 193      else
 194        match (t1,t2) with
 195        | (C.Sort (C.Type a), C.Sort (C.Type b)) when not test_eq_only ->
 196            NCicEnvironment.universe_leq a b
 197        | (C.Sort (C.Type a), C.Sort (C.Type b)) ->
 198            NCicEnvironment.universe_eq a b
 199        | (C.Sort C.Prop,C.Sort (C.Type _)) -> (not test_eq_only)
 200        | (C.Sort C.Prop, C.Sort C.Prop) -> true
 201
 202        | (C.Prod (name1,s1,t1), C.Prod(_,s2,t2)) ->
 203            aux true context s1 s2 &&
 204            aux test_eq_only ((name1, C.Decl s1)::context) t1 t2
 205        | (C.Lambda (name1,s1,t1), C.Lambda(_,_,t2)) ->
 206           (* thanks to inversion of well typedness, the source
 207            * of these lambdas must be already convertible *)
 208           aux test_eq_only ((name1, C.Decl s1)::context) t1 t2
 209        | (C.LetIn (name1,ty1,s1,t1), C.LetIn(_,ty2,s2,t2)) ->
 210           aux test_eq_only context ty1 ty2 &&
 211           aux test_eq_only context s1 s2 &&
 212           aux test_eq_only ((name1, C.Def (s1,ty1))::context) t1 t2
 213
 214        | (C.Meta (n1,(s1, C.Irl _)), C.Meta (n2,(s2, C.Irl _)))
 215           when n1 = n2 && s1 = s2 -> true
 216        | (C.Meta (n1,(s1, l1)), C.Meta (n2,(s2, l2))) when n1 = n2 &&
 217           let l1 = NCicUtils.expand_local_context l1 in
 218           let l2 = NCicUtils.expand_local_context l2 in
 219           (try List.for_all2
 220             (fun t1 t2 -> aux test_eq_only context
 221               (NCicSubstitution.lift s1 t1)
 222               (NCicSubstitution.lift s2 t2))
 223             l1 l2
 224           with Invalid_argument _ -> assert false) -> true
 225
 226        | C.Meta (n1,l1), _ ->
 227           (try
 228              let _,_,term,_ = NCicUtils.lookup_subst n1 subst in
 229              let term = NCicSubstitution.subst_meta l1 term in
 230               aux test_eq_only context term t2
 231            with NCicUtils.Subst_not_found _ -> false)
 232        | _, C.Meta (n2,l2) ->
 233           (try
 234              let _,_,term,_ = NCicUtils.lookup_subst n2 subst in
 235              let term = NCicSubstitution.subst_meta l2 term in
 236               aux test_eq_only context t1 term
 237            with NCicUtils.Subst_not_found _ -> false)
 238
 239        | (C.Appl ((C.Const r1) as hd1::tl1), C.Appl (C.Const r2::tl2))
 240            when (Ref.eq r1 r2 &&
 241              List.length (E.get_relevance r1) >= List.length tl1) ->
 242          let relevance = E.get_relevance r1 in
 243          let relevance = match r1 with
 244              | Ref.Ref (_,Ref.Con (_,_,lno)) ->
 245                  let _,relevance = HExtlib.split_nth lno relevance in
 246                    HExtlib.mk_list false lno @ relevance
 247              | _ -> relevance
 248          in
 249          (try
 250              HExtlib.list_forall_default3_var
 251               (fun t1 t2 b -> not b || aux test_eq_only context t1 t2 )
 252               tl1 tl2 true relevance
 253             with Invalid_argument _ -> false
 254                | HExtlib.FailureAt fail ->
 255                  let relevance = !get_relevance ~subst context hd1 tl1 in
 256                  let _,relevance = HExtlib.split_nth fail relevance in
 257                  let b,relevance = (match relevance with
 258                    | [] -> assert false
 259                    | b::tl -> b,tl) in
 260                  if (not b) then
 261                    let _,tl1 = HExtlib.split_nth (fail+1) tl1 in
 262                    let _,tl2 = HExtlib.split_nth (fail+1) tl2 in
 263                      try
 264                         HExtlib.list_forall_default3
 265                         (fun t1 t2 b -> not b || aux test_eq_only context t1 t2)
 266                         tl1 tl2 true relevance
 267                      with Invalid_argument _ -> false
 268                  else false)
 269
 270        | (C.Appl (hd1::tl1),  C.Appl (hd2::tl2)) ->
 271            aux test_eq_only context hd1 hd2 &&
 272            let relevance = !get_relevance ~subst context hd1 tl1 in
 273             (try
 274              HExtlib.list_forall_default3
 275               (fun t1 t2 b -> not b || aux test_eq_only context t1 t2)
 276               tl1 tl2 true relevance
 277             with Invalid_argument _ -> false)
 278
 279        | (C.Match (Ref.Ref (_,Ref.Ind (_,tyno,_)) as ref1,outtype1,term1,pl1),
 280           C.Match (ref2,outtype2,term2,pl2)) ->
 281            let _,_,itl,_,_ = E.get_checked_indtys ref1 in
 282            let _,_,ty,_ = List.nth itl tyno in
 283            let rec remove_prods ~subst context ty =
 284              let ty = whd ~subst context ty in
 285              match ty with
 286              | C.Sort _ -> ty
 287              | C.Prod (name,so,ta) -> remove_prods ~subst ((name,(C.Decl so))::context) ta
 288              | _ -> assert false
 289            in
 290            let is_prop =
 291              match remove_prods ~subst [] ty with
 292              | C.Sort C.Prop -> true
 293              | _ -> false
 294            in
 295            Ref.eq ref1 ref2 &&
 296            aux test_eq_only context outtype1 outtype2 &&
 297            (is_prop || aux test_eq_only context term1 term2) &&
 298            (try List.for_all2 (aux test_eq_only context) pl1 pl2
 299             with Invalid_argument _ -> false)
 300        | (C.Implicit _, _) | (_, C.Implicit _) -> assert false
 301        | (_,_) -> false
 302   in
 303    if alpha_eq test_eq_only t1 t2 then
 304      true
 305    else
 306      let height_of = function
 307       | C.Const (Ref.Ref (_,Ref.Def h))
 308       | C.Const (Ref.Ref (_,Ref.Fix (_,_,h)))
 309       | C.Appl(C.Const(Ref.Ref(_,Ref.Def h))::_)
 310       | C.Appl(C.Const(Ref.Ref(_,Ref.Fix (_,_,h)))::_) -> h
 311       | _ -> 0
 312      in
 313      let put_in_whd m1 m2 =
 314        R.reduce ~delta:max_int ~subst context m1,
 315        R.reduce ~delta:max_int ~subst context m2
 316      in
 317      let small_delta_step
 318        ((_,_,t1,_ as m1), norm1 as x1) ((_,_,t2,_ as m2), norm2 as x2)
 319      =
 320        assert(not (norm1 && norm2));
 321        if norm1 then
 322          x1, R.reduce ~delta:(height_of t2 -1) ~subst context m2
 323        else if norm2 then
 324          R.reduce ~delta:(height_of t1 -1) ~subst context m1, x2
 325        else
 326         let h1 = height_of t1 in
 327         let h2 = height_of t2 in
 328         let delta = if h1 = h2 then max 0 (h1 -1) else min h1 h2 in
 329         R.reduce ~delta ~subst context m1,
 330         R.reduce ~delta ~subst context m2
 331      in
 332      let rec convert_machines
 333        ((k1,e1,t1,s1),norm1 as m1),((k2,e2,t2,s2), norm2 as m2)
 334      =
 335        (alpha_eq test_eq_only
 336          (R.unwind (k1,e1,t1,[])) (R.unwind (k2,e2,t2,[])) &&
 337         let relevance =
 338           match t1 with
 339               C.Const r -> NCicEnvironment.get_relevance r
 340             | _ -> [] in
 341         try
 342          HExtlib.list_forall_default3
 343            (fun t1 t2 b  ->
 344              not b ||
 345              let t1 = RS.from_stack t1 in
 346              let t2 = RS.from_stack t2 in
 347              convert_machines (put_in_whd t1 t2)) s1 s2 true relevance
 348         with Invalid_argument _ -> false) ||
 349        (not (norm1 && norm2) && convert_machines (small_delta_step m1 m2))
 350      in
 351      convert_machines (put_in_whd (0,[],t1,[]) (0,[],t2,[]))
 352  in
 353   aux false
 354 ;;
 355
 356 let rec head_beta_reduce ?(delta=max_int) ?(upto=(-1)) t l =
 357  match upto, t, l with
 358   | 0, C.Appl l1, _ -> C.Appl (l1 @ l)
 359   | 0, t, [] -> t
 360   | 0, t, _ -> C.Appl (t::l)
 361   | _, C.Appl (hd::tl), _ -> head_beta_reduce ~delta ~upto hd (tl @ l)
 362   | _, C.Lambda(_,_,bo), arg::tl ->
 363      let bo = NCicSubstitution.subst arg bo in
 364      head_beta_reduce ~delta ~upto:(upto - 1) bo tl
 365   | _, C.Const (Ref.Ref (_, Ref.Def height) as re), _
 366     when delta <= height ->
 367       let _, _, bo, _, _, _ = NCicEnvironment.get_checked_def re in
 368       head_beta_reduce ~upto ~delta bo l
 369   | _, t, [] -> t
 370   | _, t, _ -> C.Appl (t::l)
 371 ;;
 372
 373 let head_beta_reduce ?delta ?upto t = head_beta_reduce ?delta ?upto t [];;
 374
 375 type stack_item = RS.stack_term
 376 type environment_item = RS.env_term
 377
 378 type machine = int * environment_item list * NCic.term * stack_item list
 379
 380 let reduce_machine = R.reduce
 381 let from_stack = RS.from_stack
 382 let unwind = R.unwind
 383
 384 (* vim:set foldmethod=marker: *)