helm/software/components/ng_kernel/nCicTypeChecker.ml

   1 (*
   2     ||M||  This file is part of HELM, an Hypertextual, Electronic
   3     ||A||  Library of Mathematics, developed at the Computer Science
   4     ||T||  Department, University of Bologna, Italy.
   5     ||I||
   6     ||T||  HELM is free software; you can redistribute it and/or
   7     ||A||  modify it under the terms of the GNU General Public License
   8     \   /  version 2 or (at your option) any later version.
   9      \ /   This software is distributed as is, NO WARRANTY.
  10       V_______________________________________________________________ *)
  11
  12 (* $Id$ *)
  13
  14 module C = NCic
  15 module Ref = NReference
  16 module R = NCicReduction
  17 module S = NCicSubstitution
  18 module U = NCicUtils
  19 module E = NCicEnvironment
  20 module PP = NCicPp
  21
  22 exception TypeCheckerFailure of string Lazy.t
  23 exception AssertFailure of string Lazy.t
  24
  25 (*
  26 let raise = function
  27   | TypeCheckerFailure s as e -> prerr_endline (Lazy.force s); raise e
  28   | e -> raise e
  29 ;;
  30 *)
  31
  32 type recf_entry =
  33   | Evil of int (* rno *)
  34   | UnfFix of bool list (* fixed arguments *)
  35   | Safe
  36 ;;
  37
  38 let is_dangerous i l =
  39   List.exists (function (j,Evil _) when j=i -> true | _ -> false) l
  40 ;;
  41
  42 let is_unfolded i l =
  43   List.exists (function (j,UnfFix _) when j=i -> true | _ -> false) l
  44 ;;
  45
  46 let is_safe i l =
  47   List.exists (function (j,Safe) when j=i -> true | _ -> false) l
  48 ;;
  49
  50 let get_recno i l =
  51   try match List.assoc i l with Evil rno -> rno | _ -> assert false
  52   with Not_found -> assert false
  53 ;;
  54
  55 let get_fixed_args i l =
  56   try match List.assoc i l with UnfFix fa -> fa | _ -> assert false
  57   with Not_found -> assert false
  58 ;;
  59
  60 let shift_k e (c,rf,x) = e::c,List.map (fun (k,v) -> k+1,v) rf,x+1;;
  61
  62 (* for debugging only
  63 let string_of_recfuns ~subst ~metasenv ~context l =
  64   let pp = PP.ppterm ~subst ~metasenv ~context in
  65   let safe, rest = List.partition (function (_,Safe) -> true | _ -> false) l in
  66   let dang,unf = List.partition (function (_,UnfFix _)-> false | _->true)rest in
  67   "\n\tsafes: "^String.concat "," (List.map (fun (i,_)->pp (C.Rel i)) safe) ^
  68   "\n\tfix  : "^String.concat ","
  69    (List.map
  70      (function (i,UnfFix l)-> pp(C.Rel i)^"/"^String.concat "," (List.map
  71        string_of_bool l)
  72      | _ ->assert false) unf) ^
  73   "\n\trec  : "^String.concat ","
  74    (List.map
  75      (function (i,Evil rno)->pp(C.Rel i)^"/"^string_of_int rno
  76      | _ -> assert false) dang)
  77 ;;
  78 *)
  79
  80 let fixed_args bos j n nn =
  81  let rec aux k acc = function
  82   | C.Appl (C.Rel i::args) when i-k > n && i-k <= nn ->
  83      let rec combine l1 l2 =
  84       match l1,l2 with
  85          [],[] -> []
  86        | he1::tl1, he2::tl2 -> (he1,he2)::combine tl1 tl2
  87        | _::tl, [] -> (false,C.Rel ~-1)::combine tl [] (* dummy term *)
  88        | [],_::_ -> assert false
  89      in
  90      let lefts, _ = HExtlib.split_nth (min j (List.length args)) args in
  91       List.map (fun ((b,x),i) -> b && x = C.Rel (k-i))
  92        (HExtlib.list_mapi (fun x i -> x,i) (combine acc lefts))
  93   | t -> U.fold (fun _ k -> k+1) k aux acc t
  94  in
  95   List.fold_left (aux 0)
  96    (let rec f = function 0 -> [] | n -> true :: f (n-1) in f j) bos
  97 ;;
  98
  99 (* if n < 0, then splits all prods from an arity, returning a sort *)
 100 let rec split_prods ~subst context n te =
 101   match (n, R.whd ~subst context te) with
 102    | (0, _) -> context,te
 103    | (n, C.Sort _) when n <= 0 -> context,te
 104    | (n, C.Prod (name,so,ta)) ->
 105        split_prods ~subst ((name,(C.Decl so))::context) (n - 1) ta
 106    | (_, _) -> raise (AssertFailure (lazy "split_prods"))
 107 ;;
 108
 109 let debruijn uri number_of_types context =
 110  let rec aux k t =
 111   match t with
 112    | C.Meta (i,(s,C.Ctx l)) ->
 113       let l1 = HExtlib.sharing_map (aux (k-s)) l in
 114       if l1 == l then t else C.Meta (i,(s,C.Ctx l1))
 115    | C.Meta _ -> t
 116    | C.Const (Ref.Ref (uri1,(Ref.Fix (no,_,_) | Ref.CoFix no)))
 117    | C.Const (Ref.Ref (uri1,Ref.Ind (_,no,_))) when NUri.eq uri uri1 ->
 118       C.Rel (k + number_of_types - no)
 119    | t -> U.map (fun _ k -> k+1) k aux t
 120  in
 121   aux (List.length context)
 122 ;;
 123
 124 let sort_of_prod ~metasenv ~subst context (name,s) t (t1, t2) =
 125    let t1 = R.whd ~subst context t1 in
 126    let t2 = R.whd ~subst ((name,C.Decl s)::context) t2 in
 127    match t1, t2 with
 128    | C.Sort _, C.Sort C.Prop -> t2
 129    | C.Sort (C.Type u1), C.Sort (C.Type u2) ->
 130       C.Sort (C.Type (NCicEnvironment.max u1 u2))
 131    | C.Sort C.Prop,C.Sort (C.Type _) -> t2
 132    | C.Meta (_,(_,(C.Irl 0 | C.Ctx []))), C.Sort _ -> t2
 133    | C.Meta (_,(_,(C.Irl 0 | C.Ctx []))), C.Meta (i,(_,(C.Irl 0 | C.Ctx [])))
 134    | C.Sort _, C.Meta  (i,(_,(C.Irl 0 | C.Ctx []))) ->
 135         NCic.Meta (i,(0, C.Irl 0))
 136    | x, (C.Sort _ | C.Meta (_,(_,(C.Irl 0 | C.Ctx []))))
 137    | _, x ->
 138       let y, context =
 139         if x == t1 then s, context else t, ((name,C.Decl s)::context)
 140       in
 141       raise (TypeCheckerFailure (lazy (Printf.sprintf
 142         "%s is expected to be a type, but its type is %s that is not a sort"
 143          (PP.ppterm ~subst ~metasenv ~context y)
 144          (PP.ppterm ~subst ~metasenv ~context x))))
 145 ;;
 146
 147 (* instantiate_parameters ps (x1:T1)...(xn:Tn)C                             *)
 148 (* returns ((x_|ps|:T_|ps|)...(xn:Tn)C){ps_1 / x1 ; ... ; ps_|ps| / x_|ps|} *)
 149 let rec instantiate_parameters params c =
 150   match c, params with
 151   | c,[] -> c
 152   | C.Prod (_,_,ta), he::tl -> instantiate_parameters tl (S.subst he ta)
 153   | _,_ -> raise (AssertFailure (lazy "1"))
 154 ;;
 155
 156 let specialize_inductive_type_constrs ~subst context ty_term =
 157   match R.whd ~subst context ty_term with
 158   | C.Const (Ref.Ref (_,Ref.Ind _) as ref)
 159   | C.Appl (C.Const (Ref.Ref (_,Ref.Ind _) as ref) :: _ ) as ty ->
 160       let args = match ty with C.Appl (_::tl) -> tl | _ -> [] in
 161       let _, leftno, itl, _, i = E.get_checked_indtys ref in
 162       let left_args,_ = HExtlib.split_nth leftno args in
 163       let _,_,_,cl = List.nth itl i in
 164       List.map
 165         (fun (rel,name,ty) -> rel, name, instantiate_parameters left_args ty) cl
 166   | _ -> assert false
 167 ;;
 168
 169 let specialize_and_abstract_constrs ~subst r_uri r_len context ty_term =
 170   let cl = specialize_inductive_type_constrs ~subst context ty_term in
 171   let len = List.length context in
 172   let context_dcl =
 173     match E.get_checked_obj r_uri with
 174     | _,_,_,_, C.Inductive (_,_,tys,_) ->
 175         context @ List.map (fun (_,name,arity,_) -> name,C.Decl arity) tys
 176     | _ -> assert false
 177   in
 178   context_dcl,
 179   List.map (fun (_,id,ty) -> id, debruijn r_uri r_len context ty) cl,
 180   len, len + r_len
 181 ;;
 182
 183 exception DoesOccur;;
 184
 185 let does_not_occur ~subst context n nn t =
 186   let rec aux k _ = function
 187     | C.Rel m when m > n+k && m <= nn+k -> raise DoesOccur
 188     | C.Rel m when m <= k || m > nn+k -> ()
 189     | C.Rel m ->
 190         (try match List.nth context (m-1-k) with
 191           | _,C.Def (bo,_) -> aux (n-m) () bo
 192           | _ -> ()
 193          with Failure _ -> assert false)
 194     | C.Meta (_,(_,(C.Irl 0 | C.Ctx []))) -> (* closed meta *) ()
 195     | C.Meta (mno,(s,l)) ->
 196          (try
 197             (* possible optimization here: try does_not_occur on l and
 198                perform substitution only if DoesOccur is raised *)
 199             let _,_,term,_ = U.lookup_subst mno subst in
 200             aux (k-s) () (S.subst_meta (0,l) term)
 201           with U.Subst_not_found _ -> match l with
 202           | C.Irl len -> if not (n+k >= s+len || s > nn+k) then raise DoesOccur
 203           | C.Ctx lc -> List.iter (aux (k-s) ()) lc)
 204     | t -> U.fold (fun _ k -> k + 1) k aux () t
 205   in
 206    try aux 0 () t; true
 207    with DoesOccur -> false
 208 ;;
 209
 210 let rec eat_lambdas ~subst ~metasenv context n te =
 211   match (n, R.whd ~subst context te) with
 212   | (0, _) -> (te, context)
 213   | (n, C.Lambda (name,so,ta)) when n > 0 ->
 214       eat_lambdas ~subst ~metasenv ((name,(C.Decl so))::context) (n - 1) ta
 215    | (n, te) ->
 216       raise (AssertFailure (lazy (Printf.sprintf "eat_lambdas (%d, %s)" n
 217         (PP.ppterm ~subst ~metasenv ~context te))))
 218 ;;
 219
 220 let rec eat_or_subst_lambdas
 221   ~subst ~metasenv n te to_be_subst args (context,_,_ as k)
 222 =
 223   match n, R.whd ~subst context te, to_be_subst, args with
 224   | (n, C.Lambda (_,_,ta),true::to_be_subst,arg::args) when n > 0 ->
 225       eat_or_subst_lambdas ~subst ~metasenv (n - 1) (S.subst arg ta)
 226        to_be_subst args k
 227   | (n, C.Lambda (name,so,ta),false::to_be_subst,_::args) when n > 0 ->
 228       eat_or_subst_lambdas ~subst ~metasenv (n - 1) ta to_be_subst args
 229        (shift_k (name,(C.Decl so)) k)
 230   | (_, te, _, _) -> te, k
 231 ;;
 232
 233 let check_homogeneous_call ~subst context indparamsno n uri reduct tl =
 234  let last =
 235   List.fold_left
 236    (fun k x ->
 237      if k = 0 then 0
 238      else
 239       match R.whd ~subst context x with
 240       | C.Rel m when m = n - (indparamsno - k) -> k - 1
 241       | _ -> raise (TypeCheckerFailure (lazy
 242          ("Argument "^string_of_int (indparamsno - k + 1) ^ " (of " ^
 243          string_of_int indparamsno ^ " fixed) is not homogeneous in "^
 244          "appl:\n"^ PP.ppterm ~context ~subst ~metasenv:[] reduct))))
 245    indparamsno tl
 246  in
 247   if last <> 0 then
 248    raise (TypeCheckerFailure
 249     (lazy ("Non-positive occurence in mutual inductive definition(s) [2]"^
 250      NUri.string_of_uri uri)))
 251 ;;
 252
 253 (* Inductive types being checked for positivity have *)
 254 (* indexes x s.t. n < x <= nn.                       *)
 255 let rec weakly_positive ~subst context n nn uri indparamsno posuri te =
 256   (*CSC: Not very nice. *)
 257   let dummy = C.Sort C.Prop in
 258   (*CSC: to be moved in cicSubstitution? *)
 259   let rec subst_inductive_type_with_dummy _ = function
 260     | C.Const (Ref.Ref (uri',Ref.Ind (true,0,_))) when NUri.eq uri' uri -> dummy
 261     | C.Appl ((C.Const (Ref.Ref (uri',Ref.Ind (true,0,lno))))::tl)
 262         when NUri.eq uri' uri ->
 263           let _, rargs = HExtlib.split_nth lno tl in
 264           if rargs = [] then dummy else C.Appl (dummy :: rargs)
 265     | t -> U.map (fun _ x->x) () subst_inductive_type_with_dummy t
 266   in
 267   (* this function has the same semantics of are_all_occurrences_positive
 268      but the i-th context entry role is played by dummy and some checks
 269      are skipped because we already know that are_all_occurrences_positive
 270      of uri in te. *)
 271   let rec aux context n nn te =
 272     match R.whd ~subst context te with
 273      | t when t = dummy -> true
 274      | C.Appl (te::rargs) when te = dummy ->
 275         List.for_all (does_not_occur ~subst context n nn) rargs
 276      | C.Prod (name,source,dest) when
 277         does_not_occur ~subst ((name,C.Decl source)::context) 0 1 dest ->
 278          (* dummy abstraction, so we behave as in the anonimous case *)
 279          strictly_positive ~subst context n nn indparamsno posuri source &&
 280          aux ((name,C.Decl source)::context) (n + 1) (nn + 1) dest
 281      | C.Prod (name,source,dest) ->
 282          does_not_occur ~subst context n nn source &&
 283          aux ((name,C.Decl source)::context) (n + 1) (nn + 1) dest
 284      | _ ->
 285        raise (TypeCheckerFailure (lazy "Malformed inductive constructor type"))
 286    in
 287      aux context n nn (subst_inductive_type_with_dummy () te)
 288
 289 and strictly_positive ~subst context n nn indparamsno posuri te =
 290   match R.whd ~subst context te with
 291    | t when does_not_occur ~subst context n nn t -> true
 292    | C.Rel _ when indparamsno = 0 -> true
 293    | C.Appl ((C.Rel m)::tl) as reduct when m > n && m <= nn ->
 294       check_homogeneous_call ~subst context indparamsno n posuri reduct tl;
 295       List.for_all (does_not_occur ~subst context n nn) tl
 296    | C.Prod (name,so,ta) ->
 297       does_not_occur ~subst context n nn so &&
 298        strictly_positive ~subst ((name,C.Decl so)::context) (n+1) (nn+1)
 299         indparamsno posuri ta
 300    | C.Appl (C.Const (Ref.Ref (uri,Ref.Ind _) as r)::tl) ->
 301       let _,paramsno,tyl,_,i = E.get_checked_indtys r in
 302       let _,name,ity,cl = List.nth tyl i in
 303       let ok = List.length tyl = 1 in
 304       let params, arguments = HExtlib.split_nth paramsno tl in
 305       let lifted_params = List.map (S.lift 1) params in
 306       let cl =
 307         List.map (fun (_,_,te) -> instantiate_parameters lifted_params te) cl
 308       in
 309       ok &&
 310       List.for_all (does_not_occur ~subst context n nn) arguments &&
 311       List.for_all
 312        (weakly_positive ~subst ((name,C.Decl ity)::context) (n+1) (nn+1)
 313          uri indparamsno posuri) cl
 314    | _ -> false
 315
 316 (* the inductive type indexes are s.t. n < x <= nn *)
 317 and are_all_occurrences_positive ~subst context uri indparamsno i n nn te =
 318   match R.whd ~subst context te with
 319   |  C.Appl ((C.Rel m)::tl) as reduct when m = i ->
 320       check_homogeneous_call ~subst context indparamsno n uri reduct tl;
 321       List.for_all (does_not_occur ~subst context n nn) tl
 322   | C.Rel m when m = i ->
 323       if indparamsno = 0 then
 324        true
 325       else
 326         raise (TypeCheckerFailure
 327          (lazy ("Non-positive occurence in mutual inductive definition(s) [3]"^
 328           NUri.string_of_uri uri)))
 329    | C.Prod (name,source,dest) when
 330       does_not_occur ~subst ((name,C.Decl source)::context) 0 1 dest ->
 331       strictly_positive ~subst context n nn indparamsno uri source &&
 332        are_all_occurrences_positive ~subst
 333         ((name,C.Decl source)::context) uri indparamsno
 334         (i+1) (n + 1) (nn + 1) dest
 335    | C.Prod (name,source,dest) ->
 336        if not (does_not_occur ~subst context n nn source) then
 337          raise (TypeCheckerFailure (lazy ("Non-positive occurrence in "^
 338          PP.ppterm ~context ~metasenv:[] ~subst te)));
 339        are_all_occurrences_positive ~subst ((name,C.Decl source)::context)
 340         uri indparamsno (i+1) (n + 1) (nn + 1) dest
 341    | _ ->
 342      raise
 343       (TypeCheckerFailure (lazy ("Malformed inductive constructor type " ^
 344         (NUri.string_of_uri uri))))
 345 ;;
 346
 347 exception NotGuarded of string Lazy.t;;
 348
 349 let type_of_branch ~subst context leftno outty cons tycons =
 350  let rec aux liftno context cons tycons =
 351    match R.whd ~subst context tycons with
 352    | C.Const (Ref.Ref (_,Ref.Ind _)) -> C.Appl [S.lift liftno outty ; cons]
 353    | C.Appl (C.Const (Ref.Ref (_,Ref.Ind _))::tl) ->
 354        let _,arguments = HExtlib.split_nth leftno tl in
 355        C.Appl (S.lift liftno outty::arguments@[cons])
 356    | C.Prod (name,so,de) ->
 357        let cons =
 358         match S.lift 1 cons with
 359         | C.Appl l -> C.Appl (l@[C.Rel 1])
 360         | t -> C.Appl [t ; C.Rel 1]
 361        in
 362         C.Prod (name,so, aux (liftno+1) ((name,(C.Decl so))::context) cons de)
 363    | _ -> raise (AssertFailure (lazy "type_of_branch"))
 364  in
 365   aux 0 context cons tycons
 366 ;;
 367
 368
 369 let rec typeof ~subst ~metasenv context term =
 370   let rec typeof_aux context =
 371     fun t -> (*prerr_endline (PP.ppterm ~metasenv ~subst ~context t);*)
 372     match t with
 373     | C.Rel n ->
 374        (try
 375          match List.nth context (n - 1) with
 376          | (_,C.Decl ty) -> S.lift n ty
 377          | (_,C.Def (_,ty)) -> S.lift n ty
 378         with Failure _ -> raise (TypeCheckerFailure (lazy "unbound variable")))
 379     | C.Sort (C.Type [false,u]) -> C.Sort (C.Type [true, u])
 380     | C.Sort (C.Type _) ->
 381         raise (AssertFailure (lazy ("Cannot type an inferred type: "^
 382           NCicPp.ppterm ~subst ~metasenv ~context t)))
 383     | C.Sort _ -> C.Sort (C.Type NCicEnvironment.type0)
 384     | C.Implicit _ -> raise (AssertFailure (lazy "Implicit found"))
 385     | C.Meta (n,l) as t ->
 386        let canonical_ctx,ty =
 387         try
 388          let _,c,_,ty = U.lookup_subst n subst in c,ty
 389         with U.Subst_not_found _ -> try
 390          let _,c,ty = U.lookup_meta n metasenv in c, ty
 391 (*          match ty with C.Implicit _ -> assert false | _ -> c,ty *)
 392         with U.Meta_not_found _ ->
 393          raise (AssertFailure (lazy (Printf.sprintf
 394           "%s not found in:\n%s" (PP.ppterm ~subst ~metasenv ~context t)
 395            (PP.ppmetasenv ~subst metasenv)
 396           )))
 397        in
 398         check_metasenv_consistency t ~subst ~metasenv context canonical_ctx l;
 399         S.subst_meta l ty
 400     | C.Const ref -> type_of_constant ref
 401     | C.Prod (name,s,t) ->
 402        let sort1 = typeof_aux context s in
 403        let sort2 = typeof_aux ((name,(C.Decl s))::context) t in
 404        sort_of_prod ~metasenv ~subst context (name,s) t (sort1,sort2)
 405     | C.Lambda (n,s,t) ->
 406        let sort = typeof_aux context s in
 407        (match R.whd ~subst context sort with
 408        | C.Meta _ | C.Sort _ -> ()
 409        | _ ->
 410          raise
 411            (TypeCheckerFailure (lazy (Printf.sprintf
 412              ("Not well-typed lambda-abstraction: " ^^
 413              "the source %s should be a type; instead it is a term " ^^
 414              "of type %s") (PP.ppterm ~subst ~metasenv ~context s)
 415              (PP.ppterm ~subst ~metasenv ~context sort)))));
 416        let ty = typeof_aux ((n,(C.Decl s))::context) t in
 417          C.Prod (n,s,ty)
 418     | C.LetIn (n,ty,t,bo) ->
 419        let ty_t = typeof_aux context t in
 420        let _ = typeof_aux context ty in
 421        if not (R.are_convertible ~metasenv ~subst context ty_t ty) then
 422          raise
 423           (TypeCheckerFailure
 424             (lazy (Printf.sprintf
 425               "The type of %s is %s but it is expected to be %s"
 426                 (PP.ppterm ~subst ~metasenv ~context t)
 427                 (PP.ppterm ~subst ~metasenv ~context ty_t)
 428                 (PP.ppterm ~subst ~metasenv ~context ty))))
 429        else
 430          let ty_bo = typeof_aux  ((n,C.Def (t,ty))::context) bo in
 431          S.subst ~avoid_beta_redexes:true t ty_bo
 432     | C.Appl (he::(_::_ as args)) ->
 433        let ty_he = typeof_aux context he in
 434        let args_with_ty = List.map (fun t -> t, typeof_aux context t) args in
 435        eat_prods ~subst ~metasenv context he ty_he args_with_ty
 436    | C.Appl _ -> raise (AssertFailure (lazy "Appl of length < 2"))
 437    | C.Match (Ref.Ref (_,Ref.Ind (_,tyno,_)) as r,outtype,term,pl) ->
 438       let outsort = typeof_aux context outtype in
 439       let _,leftno,itl,_,_ = E.get_checked_indtys r in
 440       let constructorsno =
 441         let _,_,_,cl = List.nth itl tyno in List.length cl
 442       in
 443       let parameters, arguments =
 444         let ty = R.whd ~subst context (typeof_aux context term) in
 445         let r',tl =
 446          match ty with
 447             C.Const (Ref.Ref (_,Ref.Ind _) as r') -> r',[]
 448           | C.Appl (C.Const (Ref.Ref (_,Ref.Ind _) as r') :: tl) -> r',tl
 449           | _ ->
 450              raise
 451                (TypeCheckerFailure (lazy (Printf.sprintf
 452                  "Case analysis: analysed term %s is not an inductive one"
 453                  (PP.ppterm ~subst ~metasenv ~context term)))) in
 454         if not (Ref.eq r r') then
 455          raise
 456           (TypeCheckerFailure (lazy (Printf.sprintf
 457             ("Case analysys: analysed term type is %s, but is expected " ^^
 458              "to be (an application of) %s")
 459             (PP.ppterm ~subst ~metasenv ~context ty)
 460             (PP.ppterm ~subst ~metasenv ~context (C.Const r')))))
 461         else
 462          try HExtlib.split_nth leftno tl
 463          with
 464           Failure _ ->
 465            raise (TypeCheckerFailure (lazy (Printf.sprintf
 466            "%s is partially applied"
 467            (PP.ppterm  ~subst ~metasenv ~context ty)))) in
 468       (* let's control if the sort elimination is allowed: [(I q1 ... qr)|B] *)
 469       let sort_of_ind_type =
 470         if parameters = [] then C.Const r
 471         else C.Appl ((C.Const r)::parameters) in
 472       let type_of_sort_of_ind_ty = typeof_aux context sort_of_ind_type in
 473       check_allowed_sort_elimination ~subst ~metasenv r context
 474        sort_of_ind_type type_of_sort_of_ind_ty outsort;
 475       (* let's check if the type of branches are right *)
 476       if List.length pl <> constructorsno then
 477        raise (TypeCheckerFailure (lazy ("Wrong number of cases in a match")));
 478       let j,branches_ok,p_ty, exp_p_ty =
 479         List.fold_left
 480           (fun (j,b,old_p_ty,old_exp_p_ty) p ->
 481             if b then
 482               let cons =
 483                 let cons = Ref.mk_constructor j r in
 484                 if parameters = [] then C.Const cons
 485                 else C.Appl (C.Const cons::parameters)
 486               in
 487               let ty_p = typeof_aux context p in
 488               let ty_cons = typeof_aux context cons in
 489               let ty_branch =
 490                 type_of_branch ~subst context leftno outtype cons ty_cons
 491               in
 492               j+1, R.are_convertible ~metasenv ~subst context ty_p ty_branch,
 493               ty_p, ty_branch
 494             else
 495               j,false,old_p_ty,old_exp_p_ty
 496           ) (1,true,C.Sort C.Prop,C.Sort C.Prop) pl
 497       in
 498       if not branches_ok then
 499         raise
 500          (TypeCheckerFailure
 501           (lazy (Printf.sprintf ("Branch for constructor %s :=\n%s\n"^^
 502           "has type %s\nnot convertible with %s")
 503           (PP.ppterm  ~subst ~metasenv ~context
 504             (C.Const (Ref.mk_constructor (j-1) r)))
 505           (PP.ppterm ~metasenv ~subst ~context (List.nth pl (j-2)))
 506           (PP.ppterm ~metasenv ~subst ~context p_ty)
 507           (PP.ppterm ~metasenv ~subst ~context exp_p_ty))));
 508       let res = outtype::arguments@[term] in
 509       R.head_beta_reduce (C.Appl res)
 510     | C.Match _ -> assert false
 511
 512   (* check_metasenv_consistency checks that the "canonical" context of a
 513      metavariable is consitent - up to relocation via the relocation list l -
 514      with the actual context *)
 515   and check_metasenv_consistency
 516     ~subst ~metasenv term context canonical_context l
 517   =
 518    match l with
 519     | shift, C.Irl n ->
 520        let context = snd (HExtlib.split_nth shift context) in
 521         let rec compare = function
 522          | 0,_,[] -> ()
 523          | 0,_,_::_
 524          | _,_,[] ->
 525             raise (AssertFailure (lazy (Printf.sprintf
 526              "(2) Local and canonical context %s have different lengths"
 527              (PP.ppterm ~subst ~context ~metasenv term))))
 528          | m,[],_::_ ->
 529             raise (TypeCheckerFailure (lazy (Printf.sprintf
 530              "Unbound variable -%d in %s" m
 531              (PP.ppterm ~subst ~metasenv ~context term))))
 532          | m,t::tl,ct::ctl ->
 533             (match t,ct with
 534                 (_,C.Decl t1), (_,C.Decl t2)
 535               | (_,C.Def (t1,_)), (_,C.Def (t2,_))
 536               | (_,C.Def (_,t1)), (_,C.Decl t2) ->
 537                  if not (R.are_convertible ~metasenv ~subst tl t1 t2) then
 538                   raise
 539                       (TypeCheckerFailure
 540                         (lazy (Printf.sprintf
 541                       ("Not well typed metavariable local context for %s: " ^^
 542                        "%s expected, which is not convertible with %s")
 543                       (PP.ppterm ~subst ~metasenv ~context term)
 544                       (PP.ppterm ~subst ~metasenv ~context t2)
 545                       (PP.ppterm ~subst ~metasenv ~context t1))))
 546               | _,_ ->
 547                raise
 548                    (TypeCheckerFailure (lazy (Printf.sprintf
 549                     ("Not well typed metavariable local context for %s: " ^^
 550                      "a definition expected, but a declaration found")
 551                     (PP.ppterm ~subst ~metasenv ~context term)))));
 552             compare (m - 1,tl,ctl)
 553         in
 554          compare (n,context,canonical_context)
 555     | shift, lc_kind ->
 556        (* we avoid useless lifting by shortening the context*)
 557        let l,context = (0,lc_kind), snd (HExtlib.split_nth shift context) in
 558        let lifted_canonical_context =
 559          let rec lift_metas i = function
 560            | [] -> []
 561            | (n,C.Decl t)::tl ->
 562                (n,C.Decl (S.subst_meta l (S.lift i t)))::(lift_metas (i+1) tl)
 563            | (n,C.Def (t,ty))::tl ->
 564                (n,C.Def ((S.subst_meta l (S.lift i t)),
 565                           S.subst_meta l (S.lift i ty)))::(lift_metas (i+1) tl)
 566          in
 567           lift_metas 1 canonical_context in
 568        let l = U.expand_local_context lc_kind in
 569        try
 570         List.iter2
 571         (fun t ct ->
 572           match (t,ct) with
 573           | t, (_,C.Def (ct,_)) ->
 574              (*CSC: the following optimization is to avoid a possibly expensive
 575                     reduction that can be easily avoided and that is quite
 576                     frequent. However, this is better handled using levels to
 577                     control reduction *)
 578              let optimized_t =
 579               match t with
 580               | C.Rel n ->
 581                   (try
 582                     match List.nth context (n - 1) with
 583                     | (_,C.Def (te,_)) -> S.lift n te
 584                     | _ -> t
 585                     with Failure _ -> t)
 586               | _ -> t
 587              in
 588              if not (R.are_convertible ~metasenv ~subst context optimized_t ct)
 589              then
 590                raise
 591                  (TypeCheckerFailure
 592                    (lazy (Printf.sprintf
 593                      ("Not well typed metavariable local context: " ^^
 594                       "expected a term convertible with %s, found %s")
 595                      (PP.ppterm ~subst ~metasenv ~context ct)
 596                      (PP.ppterm ~subst ~metasenv ~context t))))
 597           | t, (_,C.Decl ct) ->
 598               let type_t = typeof_aux context t in
 599               if not (R.are_convertible ~metasenv ~subst context type_t ct) then
 600                 raise (TypeCheckerFailure
 601                  (lazy (Printf.sprintf
 602                   ("Not well typed metavariable local context: "^^
 603                   "expected a term of type %s, found %s of type %s")
 604                   (PP.ppterm ~subst ~metasenv ~context ct)
 605                   (PP.ppterm ~subst ~metasenv ~context t)
 606                   (PP.ppterm ~subst ~metasenv ~context type_t))))
 607         ) l lifted_canonical_context
 608        with
 609        | Invalid_argument "List.iter2" ->
 610           raise (AssertFailure (lazy (Printf.sprintf
 611            "(1) Local and canonical context %s have different lengths"
 612            (PP.ppterm ~subst ~metasenv ~context term))))
 613
 614  in
 615    typeof_aux context term
 616
 617 and check_allowed_sort_elimination ~subst ~metasenv r =
 618   let mkapp he arg =
 619     match he with
 620     | C.Appl l -> C.Appl (l @ [arg])
 621     | t -> C.Appl [t;arg] in
 622   let rec aux context ind arity1 arity2 =
 623    let arity1 = R.whd ~subst context arity1 in
 624    let arity2 = R.whd ~subst context arity2 in
 625      match arity1,arity2 with
 626       | C.Prod (name,so1,de1), C.Prod (_,so2,de2) ->
 627          if not (R.are_convertible ~metasenv ~subst context so1 so2) then
 628           raise (TypeCheckerFailure (lazy (Printf.sprintf
 629            "In outtype: expected %s, found %s"
 630            (PP.ppterm ~subst ~metasenv ~context so1)
 631            (PP.ppterm ~subst ~metasenv ~context so2)
 632            )));
 633          aux ((name, C.Decl so1)::context)
 634           (mkapp (S.lift 1 ind) (C.Rel 1)) de1 de2
 635       | C.Sort _, C.Prod (name,so,ta) ->
 636          if not (R.are_convertible ~metasenv ~subst context so ind) then
 637           raise (TypeCheckerFailure (lazy (Printf.sprintf
 638            "In outtype: expected %s, found %s"
 639            (PP.ppterm ~subst ~metasenv ~context ind)
 640            (PP.ppterm ~subst ~metasenv ~context so)
 641            )));
 642          (match arity1, R.whd ~subst ((name,C.Decl so)::context) ta with
 643            | (C.Sort C.Type _, C.Sort _)
 644            | (C.Sort C.Prop, C.Sort C.Prop) -> ()
 645            | (C.Sort C.Prop, C.Sort C.Type _) ->
 646        (* TODO: we should pass all these parameters since we
 647         * have them already *)
 648                let _,leftno,itl,_,i = E.get_checked_indtys r in
 649                let itl_len = List.length itl in
 650                let _,itname,ittype,cl = List.nth itl i in
 651                let cl_len = List.length cl in
 652                 (* is it a singleton, non recursive and non informative
 653                    definition or an empty one? *)
 654                 if not
 655                  (cl_len = 0 ||
 656                   (itl_len = 1 && cl_len = 1 &&
 657                    let _,_,constrty = List.hd cl in
 658                      is_non_recursive_singleton
 659                        ~subst r itname ittype constrty &&
 660                      is_non_informative ~metasenv ~subst leftno constrty))
 661                 then
 662                  raise (TypeCheckerFailure (lazy
 663                   ("Sort elimination not allowed")));
 664          | _,_ -> ())
 665       | _,_ -> ()
 666   in
 667    aux
 668
 669 and eat_prods ~subst ~metasenv context he ty_he args_with_ty =
 670   let rec aux ty_he = function
 671   | [] -> ty_he
 672   | (arg, ty_arg)::tl ->
 673       match R.whd ~subst context ty_he with
 674       | C.Prod (_,s,t) ->
 675           if R.are_convertible ~metasenv ~subst context ty_arg s then
 676             aux (S.subst ~avoid_beta_redexes:true arg t) tl
 677           else
 678             raise
 679               (TypeCheckerFailure
 680                 (lazy (Printf.sprintf
 681                   ("Appl: wrong application of %s: the argument %s has type"^^
 682                    "\n%s\nbut it should have type \n%s\nContext:\n%s\n")
 683                   (PP.ppterm ~subst ~metasenv ~context he)
 684                   (PP.ppterm ~subst ~metasenv ~context arg)
 685                   (PP.ppterm ~subst ~metasenv ~context ty_arg)
 686                   (PP.ppterm ~subst ~metasenv ~context s)
 687                   (PP.ppcontext ~subst ~metasenv context))))
 688        | _ ->
 689           raise
 690             (TypeCheckerFailure
 691               (lazy (Printf.sprintf
 692                 "Appl: %s is not a function, it cannot be applied"
 693                 (PP.ppterm ~subst ~metasenv ~context
 694                  (let res = List.length tl in
 695                   let eaten = List.length args_with_ty - res in
 696                    (C.Appl
 697                     (he::List.map fst
 698                      (fst (HExtlib.split_nth eaten args_with_ty)))))))))
 699   in
 700     aux ty_he args_with_ty
 701
 702 and is_non_recursive_singleton ~subst (Ref.Ref (uri,_)) iname ity cty =
 703      let ctx = [iname, C.Decl ity] in
 704      let cty = debruijn uri 1 [] cty in
 705      let len = List.length ctx in
 706      let rec aux ctx n nn t =
 707        match R.whd ~subst ctx t with
 708        | C.Prod (name, src, tgt) ->
 709             does_not_occur ~subst ctx n nn src &&
 710              aux ((name, C.Decl src) :: ctx) (n+1) (nn+1) tgt
 711        | C.Rel k | C.Appl (C.Rel k :: _) when k = nn -> true
 712        | _ -> assert false
 713      in
 714      aux ctx (len-1) len cty
 715
 716 and is_non_informative ~metasenv ~subst paramsno c =
 717  let rec aux context c =
 718    match R.whd ~subst context c with
 719     | C.Prod (n,so,de) ->
 720        let s = typeof ~metasenv ~subst context so in
 721        s = C.Sort C.Prop && aux ((n,(C.Decl so))::context) de
 722     | _ -> true in
 723  let context',dx = split_prods ~subst [] paramsno c in
 724   aux context' dx
 725
 726 and check_mutual_inductive_defs uri ~metasenv ~subst leftno tyl =
 727   (* let's check if the arity of the inductive types are well formed *)
 728   List.iter (fun (_,_,x,_) -> ignore (typeof ~subst ~metasenv [] x)) tyl;
 729   (* let's check if the types of the inductive constructors are well formed. *)
 730   let len = List.length tyl in
 731   let tys = List.rev_map (fun (_,n,ty,_) -> (n,(C.Decl ty))) tyl in
 732   ignore
 733    (List.fold_right
 734     (fun (it_relev,_,ty,cl) i ->
 735        let context,ty_sort = split_prods ~subst [] ~-1 ty in
 736        let sx_context_ty_rev,_ = HExtlib.split_nth leftno (List.rev context) in
 737        List.iter
 738          (fun (k_relev,_,te) ->
 739            let _,k_relev = HExtlib.split_nth leftno k_relev in
 740            let te = debruijn uri len [] te in
 741            let context,te = split_prods ~subst tys leftno te in
 742            let _,chopped_context_rev =
 743             HExtlib.split_nth (List.length tys) (List.rev context) in
 744            let sx_context_te_rev,_ =
 745             HExtlib.split_nth leftno chopped_context_rev in
 746            (try
 747              ignore (List.fold_left2
 748               (fun context item1 item2 ->
 749                 let convertible =
 750                  match item1,item2 with
 751                    (n1,C.Decl ty1),(n2,C.Decl ty2) ->
 752                      n1 = n2 &&
 753                      R.are_convertible ~metasenv ~subst context ty1 ty2
 754                  | (n1,C.Def (bo1,ty1)),(n2,C.Def (bo2,ty2)) ->
 755                      n1 = n2
 756                      && R.are_convertible ~metasenv ~subst context ty1 ty2
 757                      && R.are_convertible ~metasenv ~subst context bo1 bo2
 758                  | _,_ -> false
 759                 in
 760                  if not convertible then
 761                   raise (TypeCheckerFailure (lazy
 762                    ("Mismatch between the left parameters of the constructor " ^
 763                     "and those of its inductive type")))
 764                  else
 765                   item1::context
 766               ) [] sx_context_ty_rev sx_context_te_rev)
 767             with Invalid_argument "List.fold_left2" -> assert false);
 768            let con_sort = typeof ~subst ~metasenv context te in
 769            (match R.whd ~subst context con_sort, R.whd ~subst [] ty_sort with
 770                (C.Sort (C.Type u1) as s1), (C.Sort (C.Type u2) as s2) ->
 771                 if not (E.universe_leq u1 u2) then
 772                  raise
 773                   (TypeCheckerFailure
 774                     (lazy ("The type " ^ PP.ppterm ~metasenv ~subst ~context s1^
 775                       " of the constructor is not included in the inductive" ^
 776                       " type sort " ^ PP.ppterm ~metasenv ~subst ~context s2)))
 777              | C.Sort _, C.Sort C.Prop
 778              | C.Sort _, C.Sort C.Type _ -> ()
 779              | _, _ ->
 780                 raise
 781                  (TypeCheckerFailure
 782                    (lazy ("Wrong constructor or inductive arity shape"))));
 783            (* let's check also the positivity conditions *)
 784            if
 785              not
 786                (are_all_occurrences_positive ~subst context uri leftno
 787                  (i+leftno) leftno (len+leftno) te)
 788            then
 789              raise
 790                (TypeCheckerFailure
 791                  (lazy ("Non positive occurence in "^NUri.string_of_uri
 792                  uri)))
 793            else check_relevance ~subst ~metasenv context k_relev te)
 794          cl;
 795         check_relevance ~subst ~metasenv [] it_relev ty;
 796         i+1)
 797     tyl 1)
 798
 799 and check_relevance ~subst ~metasenv context relevance ty =
 800   let error context ty =
 801     raise (TypeCheckerFailure
 802      (lazy ("Wrong relevance declaration: " ^
 803      String.concat "," (List.map string_of_bool relevance)^
 804      "\nfor type: "^PP.ppterm ~metasenv ~subst ~context ty)))
 805   in
 806   let rec aux context relevance ty =
 807     match R.whd ~subst context ty with
 808     | C.Prod (name,so,de) ->
 809         let sort = typeof ~subst ~metasenv context so in
 810         (match (relevance,R.whd ~subst context sort) with
 811           | [],_ -> ()
 812           | false::tl,C.Sort C.Prop -> aux ((name,(C.Decl so))::context) tl de
 813           | true::_,C.Sort C.Prop
 814           | false::_,C.Sort _
 815           | false::_,C.Meta _ -> error context ty
 816           | true::tl,C.Sort _
 817           | true::tl,C.Meta _ -> aux ((name,(C.Decl so))::context) tl de
 818           | _ -> raise (AssertFailure (lazy (Printf.sprintf
 819                  "Prod: the type %s of the source of %s is not a sort"
 820                   (PP.ppterm ~subst ~metasenv ~context sort)
 821                   (PP.ppterm ~subst ~metasenv ~context so)))))
 822     | _ -> (match relevance with
 823       | [] -> ()
 824       | _::_ -> error context ty)
 825   in aux context relevance ty
 826
 827 and guarded_by_destructors r_uri r_len ~subst ~metasenv context recfuns t =
 828  let recursor f k t = U.fold shift_k k (fun k () -> f k) () t in
 829  let rec aux (context, recfuns, x as k) t =
 830 (*
 831    prerr_endline ("GB:\n" ^
 832      PP.ppcontext ~subst ~metasenv context^
 833      PP.ppterm ~metasenv ~subst ~context t^
 834        string_of_recfuns ~subst ~metasenv ~context recfuns);
 835 *)
 836   try
 837   match t with
 838   | C.Rel m as t when is_dangerous m recfuns ->
 839       raise (NotGuarded (lazy
 840         (PP.ppterm ~subst ~metasenv ~context t ^
 841          " is a partial application of a fix")))
 842   | C.Appl ((C.Rel m)::tl) as t when is_dangerous m recfuns ->
 843      let rec_no = get_recno m recfuns in
 844      if not (List.length tl > rec_no) then
 845        raise (NotGuarded (lazy
 846          (PP.ppterm ~context ~subst ~metasenv t ^
 847          " is a partial application of a fix")))
 848      else
 849        let rec_arg = List.nth tl rec_no in
 850        if not (is_really_smaller r_uri r_len ~subst ~metasenv k rec_arg) then
 851          raise (NotGuarded (lazy (Printf.sprintf ("Recursive call %s, %s is not"
 852           ^^ " smaller.\ncontext:\n%s") (PP.ppterm ~context ~subst ~metasenv
 853           t) (PP.ppterm ~context ~subst ~metasenv rec_arg)
 854           (PP.ppcontext ~subst ~metasenv context))));
 855        List.iter (aux k) tl
 856   | C.Appl ((C.Rel m)::tl) when is_unfolded m recfuns ->
 857        let fixed_args = get_fixed_args m recfuns in
 858        HExtlib.list_iter_default2
 859         (fun x b -> if not b then aux k x) tl false fixed_args
 860   | C.Rel m ->
 861      (match List.nth context (m-1) with
 862      | _,C.Decl _ -> ()
 863      | _,C.Def (bo,_) -> aux k (S.lift m bo))
 864   | C.Meta _ -> ()
 865   | C.Appl (C.Const ((Ref.Ref (uri,Ref.Fix (i,recno,_))) as r)::args) ->
 866       if List.exists (fun t -> try aux k t;false with NotGuarded _ -> true) args
 867       then
 868       let fl,_,_ = E.get_checked_fixes_or_cofixes r in
 869       let ctx_tys, bos =
 870         List.split (List.map (fun (_,name,_,ty,bo) -> (name, C.Decl ty), bo) fl)
 871       in
 872       let fl_len = List.length fl in
 873       let bos = List.map (debruijn uri fl_len context) bos in
 874       let j = List.fold_left min max_int (List.map (fun (_,_,i,_,_)->i) fl) in
 875       let ctx_len = List.length context in
 876         (* we may look for fixed params not only up to j ... *)
 877       let fa = fixed_args bos j ctx_len (ctx_len + fl_len) in
 878       HExtlib.list_iter_default2
 879        (fun x b -> if not b then aux k x) args false fa;
 880       let context = context@ctx_tys in
 881       let ctx_len = List.length context in
 882       let extra_recfuns =
 883         HExtlib.list_mapi (fun _ i -> ctx_len - i, UnfFix fa) ctx_tys
 884       in
 885       let new_k = context, extra_recfuns@recfuns, x in
 886       let bos_and_ks =
 887         HExtlib.list_mapi
 888          (fun bo fno ->
 889           let bo_and_k =
 890             eat_or_subst_lambdas ~subst ~metasenv j bo fa args new_k
 891           in
 892            if
 893             fno = i &&
 894             List.length args > recno &&
 895             (*case where the recursive argument is already really_smaller *)
 896             is_really_smaller r_uri r_len ~subst ~metasenv k
 897              (List.nth args recno)
 898            then
 899             let bo,(context, _, _ as new_k) = bo_and_k in
 900             let bo, context' =
 901              eat_lambdas ~subst ~metasenv context (recno + 1 - j) bo in
 902             let new_context_part,_ =
 903              HExtlib.split_nth (List.length context' - List.length context)
 904               context' in
 905             let k = List.fold_right shift_k new_context_part new_k in
 906             let context, recfuns, x = k in
 907             let k = context, (1,Safe)::recfuns, x in
 908               bo,k
 909            else
 910             bo_and_k
 911          ) bos
 912       in
 913        List.iter (fun (bo,k) -> aux k bo) bos_and_ks
 914   | C.Match (Ref.Ref (_,Ref.Ind (true,_,_)),outtype,term,pl) as t ->
 915      (match R.whd ~subst context term with
 916      | C.Rel m | C.Appl (C.Rel m :: _ ) as t when is_safe m recfuns || m = x ->
 917          let ty = typeof ~subst ~metasenv context term in
 918          let dc_ctx, dcl, start, stop =
 919            specialize_and_abstract_constrs ~subst r_uri r_len context ty in
 920          let args = match t with C.Appl (_::tl) -> tl | _ -> [] in
 921          aux k outtype;
 922          List.iter (aux k) args;
 923          List.iter2
 924            (fun p (_,dc) ->
 925              let rl = recursive_args ~subst ~metasenv dc_ctx start stop dc in
 926              let p, k = get_new_safes ~subst k p rl in
 927              aux k p)
 928            pl dcl
 929      | _ -> recursor aux k t)
 930   | t -> recursor aux k t
 931   with
 932    NotGuarded _ as exc ->
 933     let t' = R.whd ~delta:0 ~subst context t in
 934     if t = t' then raise exc
 935     else aux k t'
 936  in
 937   try aux (context, recfuns, 1) t
 938   with NotGuarded s -> raise (TypeCheckerFailure s)
 939
 940 and guarded_by_constructors ~subst ~metasenv context t indURI indlen nn =
 941  let rec aux context n nn h te =
 942   match R.whd ~subst context te with
 943    | C.Rel m when m > n && m <= nn -> h
 944    | C.Rel _ | C.Meta _ -> true
 945    | C.Sort _
 946    | C.Implicit _
 947    | C.Prod _
 948    | C.Const (Ref.Ref (_,Ref.Ind _))
 949    | C.LetIn _ -> raise (AssertFailure (lazy "17"))
 950    | C.Lambda (name,so,de) ->
 951       does_not_occur ~subst context n nn so &&
 952       aux ((name,C.Decl so)::context) (n + 1) (nn + 1) h de
 953    | C.Appl ((C.Rel m)::tl) when m > n && m <= nn ->
 954       h && List.for_all (does_not_occur ~subst context n nn) tl
 955    | C.Const (Ref.Ref (_,Ref.Con _)) -> true
 956    | C.Appl (C.Const (Ref.Ref (_, Ref.Con (_,j,paramsno))) :: tl) as t ->
 957       let ty_t = typeof ~subst ~metasenv context t in
 958       let dc_ctx, dcl, start, stop =
 959         specialize_and_abstract_constrs ~subst indURI indlen context ty_t in
 960       let _, dc = List.nth dcl (j-1) in
 961 (*
 962         prerr_endline (PP.ppterm ~subst ~metasenv ~context:dc_ctx dc);
 963         prerr_endline (PP.ppcontext ~subst ~metasenv dc_ctx);
 964  *)
 965       let rec_params = recursive_args ~subst ~metasenv dc_ctx start stop dc in
 966       let rec analyse_instantiated_type rec_spec args =
 967        match rec_spec, args with
 968        | h::rec_spec, he::args ->
 969            aux context n nn h he && analyse_instantiated_type rec_spec args
 970        | _,[] -> true
 971        | _ -> raise (AssertFailure (lazy
 972          ("Too many args for constructor: " ^ String.concat " "
 973          (List.map (fun x-> PP.ppterm ~subst ~metasenv ~context x) args))))
 974       in
 975       let _, args = HExtlib.split_nth paramsno tl in
 976       analyse_instantiated_type rec_params args
 977    | C.Appl ((C.Match (_,out,te,pl))::_)
 978    | C.Match (_,out,te,pl) as t ->
 979        let tl = match t with C.Appl (_::tl) -> tl | _ -> [] in
 980        List.for_all (does_not_occur ~subst context n nn) tl &&
 981        does_not_occur ~subst context n nn out &&
 982        does_not_occur ~subst context n nn te &&
 983        List.for_all (aux context n nn h) pl
 984 (* IMPOSSIBLE unsless we allow to pass cofix to other fix/cofix as we do for
 985    higher order fix in g_b_destructors.
 986
 987    | C.Const (Ref.Ref (u,(Ref.Fix _| Ref.CoFix _)) as ref)
 988    | C.Appl(C.Const (Ref.Ref(u,(Ref.Fix _| Ref.CoFix _)) as ref) :: _) as t ->
 989       let tl = match t with C.Appl (_::tl) -> tl | _ -> [] in
 990       let fl,_,_ = E.get_checked_fixes_or_cofixes ref in
 991       let len = List.length fl in
 992       let tys = List.map (fun (_,n,_,ty,_) -> n, C.Decl ty) fl in
 993       List.for_all (does_not_occur ~subst context n nn) tl &&
 994       List.for_all
 995        (fun (_,_,_,_,bo) ->
 996           aux (context@tys) n nn h (debruijn u len context bo))
 997        fl
 998 *)
 999    | C.Const _
1000    | C.Appl _ as t -> does_not_occur ~subst context n nn t
1001  in
1002    aux context 0 nn false t
1003
1004 and recursive_args ~subst ~metasenv context n nn te =
1005   match R.whd ~subst context te with
1006   | C.Rel _ | C.Appl _ | C.Const _ -> []
1007   | C.Prod (name,so,de) ->
1008      (not (does_not_occur ~subst context n nn so)) ::
1009       (recursive_args ~subst ~metasenv
1010         ((name,(C.Decl so))::context) (n+1) (nn + 1) de)
1011   | t ->
1012      raise (AssertFailure (lazy ("recursive_args:" ^ PP.ppterm ~subst
1013      ~metasenv ~context:[] t)))
1014
1015 and get_new_safes ~subst (context, recfuns, x as k) p rl =
1016   match R.whd ~subst context p, rl with
1017   | C.Lambda (name,so,ta), b::tl ->
1018       let recfuns = (if b then [0,Safe] else []) @ recfuns in
1019       get_new_safes ~subst
1020         (shift_k (name,(C.Decl so)) (context, recfuns, x)) ta tl
1021   | C.Meta _ as e, _ | e, [] -> e, k
1022   | _ -> raise (AssertFailure (lazy "Ill formed pattern"))
1023
1024 and is_really_smaller
1025   r_uri r_len ~subst ~metasenv (context, recfuns, x as k) te
1026 =
1027  match R.whd ~subst context te with
1028  | C.Rel m when is_safe m recfuns -> true
1029  | C.Lambda (name, s, t) ->
1030     is_really_smaller r_uri r_len ~subst ~metasenv (shift_k (name,C.Decl s) k) t
1031  | C.Appl (he::_) ->
1032     is_really_smaller r_uri r_len ~subst ~metasenv k he
1033  | C.Rel _
1034  | C.Const (Ref.Ref (_,Ref.Con _)) -> false
1035  | C.Appl []
1036  | C.Const (Ref.Ref (_,Ref.Fix _)) -> assert false
1037  | C.Meta _ -> true
1038  | C.Match (Ref.Ref (_,Ref.Ind (isinductive,_,_)),_,term,pl) ->
1039     (match term with
1040     | C.Rel m | C.Appl (C.Rel m :: _ ) when is_safe m recfuns || m = x ->
1041         if not isinductive then
1042           List.for_all (is_really_smaller r_uri r_len ~subst ~metasenv k) pl
1043         else
1044           let ty = typeof ~subst ~metasenv context term in
1045           let dc_ctx, dcl, start, stop =
1046             specialize_and_abstract_constrs ~subst r_uri r_len context ty in
1047           List.for_all2
1048            (fun p (_,dc) ->
1049              let rl = recursive_args ~subst ~metasenv dc_ctx start stop dc in
1050              let e, k = get_new_safes ~subst k p rl in
1051              is_really_smaller r_uri r_len ~subst ~metasenv k e)
1052            pl dcl
1053     | _ -> List.for_all (is_really_smaller r_uri r_len ~subst ~metasenv k) pl)
1054  | _ -> assert false
1055
1056 and returns_a_coinductive ~subst context ty =
1057   match R.whd ~subst context ty with
1058   | C.Const (Ref.Ref (uri,Ref.Ind (false,_,_)) as ref)
1059   | C.Appl (C.Const (Ref.Ref (uri,Ref.Ind (false,_,_)) as ref)::_) ->
1060      let _, _, itl, _, _ = E.get_checked_indtys ref in
1061      Some (uri,List.length itl)
1062   | C.Prod (n,so,de) ->
1063      returns_a_coinductive ~subst ((n,C.Decl so)::context) de
1064   | _ -> None
1065
1066 and type_of_constant ((Ref.Ref (uri,_)) as ref) =
1067  let error () =
1068   raise (TypeCheckerFailure (lazy "Inconsistent cached infos in reference"))
1069  in
1070   match E.get_checked_obj uri, ref with
1071   | (_,_,_,_,C.Inductive(isind1,lno1,tl,_)),Ref.Ref(_,Ref.Ind (isind2,i,lno2))->
1072       if isind1 <> isind2 || lno1 <> lno2 then error ();
1073       let _,_,arity,_ = List.nth tl i in arity
1074   | (_,_,_,_,C.Inductive (_,lno1,tl,_)), Ref.Ref (_,Ref.Con (i,j,lno2))  ->
1075       if lno1 <> lno2 then error ();
1076       let _,_,_,cl = List.nth tl i in
1077       let _,_,arity = List.nth cl (j-1) in
1078       arity
1079   | (_,_,_,_,C.Fixpoint (false,fl,_)), Ref.Ref (_,Ref.CoFix i) ->
1080       let _,_,_,arity,_ = List.nth fl i in
1081       arity
1082   | (_,h1,_,_,C.Fixpoint (true,fl,_)), Ref.Ref (_,Ref.Fix (i,recno2,h2)) ->
1083       let _,_,recno1,arity,_ = List.nth fl i in
1084       if h1 <> h2 || recno1 <> recno2 then error ();
1085       arity
1086   | (_,_,_,_,C.Constant (_,_,_,ty,_)), Ref.Ref (_,Ref.Decl) -> ty
1087   | (_,h1,_,_,C.Constant (_,_,_,ty,_)), Ref.Ref (_,Ref.Def h2) ->
1088      if h1 <> h2 then error ();
1089      ty
1090   | _ -> raise (AssertFailure (lazy "type_of_constant: environment/reference"))
1091
1092 and get_relevance ~metasenv ~subst context t args =
1093    let ty = typeof ~subst ~metasenv context t in
1094    let rec aux context ty = function
1095      | [] -> []
1096      | arg::tl -> match R.whd ~subst context ty with
1097        | C.Prod (_,so,de) ->
1098            let sort = typeof ~subst ~metasenv context so in
1099            let new_ty = S.subst ~avoid_beta_redexes:true arg de in
1100            (*prerr_endline ("so: " ^ PP.ppterm ~subst ~metasenv:[]
1101              ~context so);
1102            prerr_endline ("sort: " ^ PP.ppterm ~subst ~metasenv:[]
1103              ~context sort);*)
1104            (match R.whd ~subst context sort with
1105               | C.Sort C.Prop ->
1106                   false::(aux context new_ty tl)
1107               | C.Sort _
1108               | C.Meta _ -> true::(aux context new_ty tl)
1109               | _ -> raise (TypeCheckerFailure (lazy (Printf.sprintf
1110                 "Prod: the type %s of the source of %s is not a sort"
1111                  (PP.ppterm ~subst ~metasenv ~context sort)
1112                  (PP.ppterm ~subst ~metasenv ~context so)))))
1113        | _ ->
1114           raise
1115             (TypeCheckerFailure
1116               (lazy (Printf.sprintf
1117                 "Appl: %s is not a function, it cannot be applied"
1118                 (PP.ppterm ~subst ~metasenv ~context
1119                  (let res = List.length tl in
1120                   let eaten = List.length args - res in
1121                    (C.Appl
1122                     (t::fst
1123                      (HExtlib.split_nth eaten args))))))))
1124    in aux context ty args
1125 ;;
1126
1127 let typecheck_context ~metasenv ~subst context =
1128  ignore
1129   (List.fold_right
1130    (fun d context  ->
1131      begin
1132       match d with
1133          _,C.Decl t -> ignore (typeof ~metasenv ~subst:[] context t)
1134        | name,C.Def (te,ty) ->
1135          ignore (typeof ~metasenv ~subst:[] context ty);
1136          let ty' = typeof ~metasenv ~subst:[] context te in
1137           if not (R.are_convertible ~metasenv ~subst context ty' ty) then
1138            raise (AssertFailure (lazy (Printf.sprintf (
1139             "the type of the definiens for %s in the context is not "^^
1140             "convertible with the declared one.\n"^^
1141             "inferred type:\n%s\nexpected type:\n%s")
1142             name (PP.ppterm ~subst ~metasenv ~context ty')
1143             (PP.ppterm ~subst ~metasenv ~context ty))))
1144      end;
1145      d::context
1146    ) context [])
1147 ;;
1148
1149 let typecheck_metasenv metasenv =
1150  ignore
1151   (List.fold_left
1152     (fun metasenv (i,(_,context,ty) as conj) ->
1153       if List.mem_assoc i metasenv then
1154        raise (TypeCheckerFailure (lazy ("duplicate meta " ^ string_of_int i ^
1155         " in metasenv")));
1156       typecheck_context ~metasenv ~subst:[] context;
1157       ignore (typeof ~metasenv ~subst:[] context ty);
1158       metasenv @ [conj]
1159     ) [] metasenv)
1160 ;;
1161
1162 let typecheck_subst ~metasenv subst =
1163  ignore
1164   (List.fold_left
1165     (fun subst (i,(_,context,ty,bo) as conj) ->
1166       if List.mem_assoc i subst then
1167        raise (AssertFailure (lazy ("duplicate meta " ^ string_of_int i ^
1168         " in substitution")));
1169       if List.mem_assoc i metasenv then
1170        raise (AssertFailure (lazy ("meta " ^ string_of_int i ^
1171         " is both in the metasenv and in the substitution")));
1172       typecheck_context ~metasenv ~subst context;
1173       ignore (typeof ~metasenv ~subst context ty);
1174       let ty' = typeof ~metasenv ~subst context bo in
1175        if not (R.are_convertible ~metasenv ~subst context ty' ty) then
1176         raise (AssertFailure (lazy (Printf.sprintf (
1177          "the type of the definiens for %d in the substitution is not "^^
1178          "convertible with the declared one.\n"^^
1179          "inferred type:\n%s\nexpected type:\n%s")
1180          i
1181          (PP.ppterm ~subst ~metasenv ~context ty')
1182          (PP.ppterm ~subst ~metasenv ~context ty))));
1183       subst @ [conj]
1184     ) [] subst)
1185 ;;
1186
1187
1188 let typecheck_obj (uri,_height,metasenv,subst,kind) =
1189  (* height is not checked since it is only used to implement an optimization *)
1190  typecheck_metasenv metasenv;
1191  typecheck_subst ~metasenv subst;
1192  match kind with
1193    | C.Constant (relevance,_,Some te,ty,_) ->
1194       let _ = typeof ~subst ~metasenv [] ty in
1195       let ty_te = typeof ~subst ~metasenv [] te in
1196       if not (R.are_convertible ~metasenv ~subst [] ty_te ty) then
1197        raise (TypeCheckerFailure (lazy (Printf.sprintf (
1198         "the type of the body is not convertible with the declared one.\n"^^
1199         "inferred type:\n%s\nexpected type:\n%s")
1200         (PP.ppterm ~subst ~metasenv ~context:[] ty_te)
1201         (PP.ppterm ~subst ~metasenv ~context:[] ty))));
1202       check_relevance ~subst ~metasenv [] relevance ty
1203       (*check_relevance ~in_type:false ~subst ~metasenv relevance te*)
1204    | C.Constant (relevance,_,None,ty,_) ->
1205       ignore (typeof ~subst ~metasenv [] ty);
1206       check_relevance ~subst ~metasenv [] relevance ty
1207    | C.Inductive (_, leftno, tyl, _) ->
1208        check_mutual_inductive_defs uri ~metasenv ~subst leftno tyl
1209    | C.Fixpoint (inductive,fl,_) ->
1210       let types, kl =
1211         List.fold_left
1212          (fun (types,kl) (relevance,name,k,ty,_) ->
1213            let _ = typeof ~subst ~metasenv [] ty in
1214             check_relevance ~subst ~metasenv [] relevance ty;
1215             ((name,C.Decl ty)::types, k::kl)
1216          ) ([],[]) fl
1217       in
1218       let len = List.length types in
1219       let dfl, kl =
1220         List.split (List.map2
1221           (fun (_,_,_,_,bo) rno ->
1222              let dbo = debruijn uri len [] bo in
1223              dbo, Evil rno)
1224           fl kl)
1225       in
1226       List.iter2 (fun (_,_,x,ty,_) bo ->
1227        let ty_bo = typeof ~subst ~metasenv types bo in
1228        if not (R.are_convertible ~metasenv ~subst types ty_bo ty)
1229        then raise (TypeCheckerFailure (lazy ("(Co)Fix: ill-typed bodies")))
1230        else
1231         if inductive then begin
1232           let m, context = eat_lambdas ~subst ~metasenv types (x + 1) bo in
1233           let r_uri, r_len =
1234             let he =
1235              match List.hd context with _,C.Decl t -> t | _ -> assert false
1236             in
1237             match R.whd ~subst (List.tl context) he with
1238             | C.Const (Ref.Ref (uri,Ref.Ind _) as ref)
1239             | C.Appl (C.Const (Ref.Ref (uri,Ref.Ind _) as ref) :: _) ->
1240                 let _,_,itl,_,_ = E.get_checked_indtys ref in
1241                   uri, List.length itl
1242             | _ -> assert false
1243           in
1244           (* guarded by destructors conditions D{f,k,x,M} *)
1245           let rec enum_from k =
1246             function [] -> [] | v::tl -> (k,v)::enum_from (k+1) tl
1247           in
1248           guarded_by_destructors r_uri r_len
1249            ~subst ~metasenv context (enum_from (x+2) kl) m
1250         end else
1251          match returns_a_coinductive ~subst [] ty with
1252           | None ->
1253              raise (TypeCheckerFailure
1254                (lazy "CoFix: does not return a coinductive type"))
1255           | Some (r_uri, r_len) ->
1256              (* guarded by constructors conditions C{f,M} *)
1257              if not
1258              (guarded_by_constructors ~subst ~metasenv types bo r_uri r_len len)
1259              then
1260                raise (TypeCheckerFailure
1261                 (lazy "CoFix: not guarded by constructors"))
1262         ) fl dfl
1263 ;;
1264
1265 (* trust *)
1266
1267 let trust = ref  (fun _ -> false);;
1268 let set_trust f = trust := f
1269 let trust_obj obj = !trust obj
1270
1271
1272 (* web interface stuff *)
1273
1274 let logger =
1275  ref (function (`Start_type_checking _|`Type_checking_completed _|`Type_checking_interrupted _|`Type_checking_failed _|`Trust_obj _) -> ())
1276 ;;
1277
1278 let set_logger f = logger := f;;
1279
1280 let typecheck_obj obj =
1281  let u,_,_,_,_ = obj in
1282  try
1283   !logger (`Start_type_checking u);
1284   typecheck_obj obj;
1285   !logger (`Type_checking_completed u)
1286  with
1287     Sys.Break as e ->
1288      !logger (`Type_checking_interrupted u);
1289      raise e
1290   | e ->
1291      !logger (`Type_checking_failed u);
1292      raise e
1293 ;;
1294
1295 E.set_typecheck_obj
1296  (fun obj ->
1297    if trust_obj obj then
1298     let u,_,_,_,_ = obj in
1299      !logger (`Trust_obj u)
1300    else
1301     typecheck_obj obj)
1302 ;;
1303
1304 let _ = NCicReduction.set_get_relevance get_relevance;;
1305
1306
1307 let indent = ref 0;;
1308 let debug = true;;
1309 let logger =
1310     let do_indent () = String.make !indent ' ' in
1311     (function
1312       | `Start_type_checking s ->
1313           if debug then
1314            prerr_endline (do_indent () ^ "Start: " ^ NUri.string_of_uri s);
1315           incr indent
1316       | `Type_checking_completed s ->
1317           decr indent;
1318           if debug then
1319            prerr_endline (do_indent () ^ "End: " ^ NUri.string_of_uri s)
1320       | `Type_checking_interrupted s ->
1321           decr indent;
1322           if debug then
1323            prerr_endline (do_indent () ^ "Break: " ^ NUri.string_of_uri s)
1324       | `Type_checking_failed s ->
1325           decr indent;
1326           if debug then
1327            prerr_endline (do_indent () ^ "Fail: " ^ NUri.string_of_uri s)
1328       | `Trust_obj s ->
1329           if debug then
1330            prerr_endline (do_indent () ^ "Trust: " ^ NUri.string_of_uri s))
1331 ;;
1332 (* let _ = set_logger logger ;; *)
1333 (* EOF *)