helm/software/components/ng_kernel/nCicTypeChecker.ml

   1 (*
   2     ||M||  This file is part of HELM, an Hypertextual, Electronic
   3     ||A||  Library of Mathematics, developed at the Computer Science
   4     ||T||  Department, University of Bologna, Italy.
   5     ||I||
   6     ||T||  HELM is free software; you can redistribute it and/or
   7     ||A||  modify it under the terms of the GNU General Public License
   8     \   /  version 2 or (at your option) any later version.
   9      \ /   This software is distributed as is, NO WARRANTY.
  10       V_______________________________________________________________ *)
  11
  12 (* $Id$ *)
  13
  14 module C = NCic
  15 module R = NCicReduction
  16 module Ref = NReference
  17 module S = NCicSubstitution
  18 module U = NCicUtils
  19 module E = NCicEnvironment
  20 module PP = NCicPp
  21
  22 exception TypeCheckerFailure of string Lazy.t
  23 exception AssertFailure of string Lazy.t
  24
  25 type recf_entry =
  26   | Evil of int (* rno *)
  27   | UnfFix of bool list (* fixed arguments *)
  28   | Safe
  29 ;;
  30
  31 let is_dangerous i l =
  32   List.exists (function (j,Evil _) when j=i -> true | _ -> false) l
  33 ;;
  34
  35 let is_unfolded i l =
  36   List.exists (function (j,UnfFix _) when j=i -> true | _ -> false) l
  37 ;;
  38
  39 let is_safe i l =
  40   List.exists (function (j,Safe) when j=i -> true | _ -> false) l
  41 ;;
  42
  43 let get_recno i l =
  44   try match List.assoc i l with Evil rno -> rno | _ -> assert false
  45   with Not_found -> assert false
  46 ;;
  47
  48 let get_fixed_args i l =
  49   try match List.assoc i l with UnfFix fa -> fa | _ -> assert false
  50   with Not_found -> assert false
  51 ;;
  52
  53 let shift_k e (c,rf,x) = e::c,List.map (fun (k,v) -> k+1,v) rf,x+1;;
  54
  55 let string_of_recfuns ~subst ~metasenv ~context l =
  56   let pp = PP.ppterm ~subst ~metasenv ~context in
  57   let safe, rest = List.partition (function (_,Safe) -> true | _ -> false) l in
  58   let dang,unf = List.partition (function (_,UnfFix _)-> false | _->true)rest in
  59   "\n\tsafes: "^String.concat "," (List.map (fun (i,_)->pp (C.Rel i)) safe) ^
  60   "\n\tfix  : "^String.concat ","
  61    (List.map
  62      (function (i,UnfFix l)-> pp(C.Rel i)^"/"^String.concat "," (List.map
  63        string_of_bool l)
  64      | _ ->assert false) unf) ^
  65   "\n\trec  : "^String.concat ","
  66    (List.map
  67      (function (i,Evil rno)->pp(C.Rel i)^"/"^string_of_int rno
  68      | _ -> assert false) dang)
  69 ;;
  70
  71 let fixed_args bos j n nn =
  72  let rec aux k acc = function
  73   | C.Appl (C.Rel i::args) when i-k > n && i-k <= nn ->
  74      let rec combine l1 l2 =
  75       match l1,l2 with
  76          [],[] -> []
  77        | he1::tl1, he2::tl2 -> (he1,he2)::combine tl1 tl2
  78        | he::tl, [] -> (false,C.Rel ~-1)::combine tl [] (* dummy term *)
  79        | [],_::_ -> assert false
  80      in
  81      let lefts, _ = HExtlib.split_nth (min j (List.length args)) args in
  82       List.map (fun ((b,x),i) -> b && x = C.Rel (k-i))
  83        (HExtlib.list_mapi (fun x i -> x,i) (combine acc lefts))
  84   | t -> U.fold (fun _ k -> k+1) k aux acc t
  85  in
  86   List.fold_left (aux 0)
  87    (let rec f = function 0 -> [] | n -> true :: f (n-1) in f j) bos
  88 ;;
  89
  90 let rec list_iter_default2 f l1 def l2 =
  91   match l1,l2 with
  92     | [], _ -> ()
  93     | a::ta, b::tb -> f a b; list_iter_default2 f ta def tb
  94     | a::ta, [] -> f a def; list_iter_default2 f ta def []
  95 ;;
  96
  97 let rec split_prods ~subst context n te =
  98   match (n, R.whd ~subst context te) with
  99    | (0, _) -> context,te
 100    | (n, C.Prod (name,so,ta)) when n > 0 ->
 101        split_prods ~subst ((name,(C.Decl so))::context) (n - 1) ta
 102    | (_, _) -> raise (AssertFailure (lazy "split_prods"))
 103 ;;
 104
 105 let debruijn uri number_of_types context =
 106  let rec aux k t =
 107   match t with
 108    | C.Meta (i,(s,C.Ctx l)) ->
 109       let l1 = HExtlib.sharing_map (aux (k-s)) l in
 110       if l1 == l then t else C.Meta (i,(s,C.Ctx l1))
 111    | C.Meta _ -> t
 112    | C.Const (Ref.Ref (_,uri1,(Ref.Fix (no,_) | Ref.CoFix no)))
 113    | C.Const (Ref.Ref (_,uri1,Ref.Ind (_,no))) when NUri.eq uri uri1 ->
 114       C.Rel (k + number_of_types - no)
 115    | t -> U.map (fun _ k -> k+1) k aux t
 116  in
 117   aux (List.length context)
 118 ;;
 119
 120 let sort_of_prod ~metasenv ~subst context (name,s) (t1, t2) =
 121    let t1 = R.whd ~subst context t1 in
 122    let t2 = R.whd ~subst ((name,C.Decl s)::context) t2 in
 123    match t1, t2 with
 124    | C.Sort s1, C.Sort C.Prop -> t2
 125    | C.Sort (C.Type u1), C.Sort (C.Type u2) -> C.Sort (C.Type (max u1 u2))
 126    | C.Sort _,C.Sort (C.Type _) -> t2
 127    | C.Sort (C.Type _) , C.Sort C.CProp -> t1
 128    | C.Sort _, C.Sort C.CProp
 129    | C.Meta (_,(_,(C.Irl 0 | C.Ctx []))), C.Sort _
 130    | C.Meta (_,(_,(C.Irl 0 | C.Ctx []))), C.Meta (_,(_,(C.Irl 0 | C.Ctx [])))
 131    | C.Sort _, C.Meta  (_,(_,(C.Irl 0 | C.Ctx []))) -> t2
 132    | _ ->
 133       raise (TypeCheckerFailure (lazy (Printf.sprintf
 134         "Prod: expected two sorts, found = %s, %s"
 135          (PP.ppterm ~subst ~metasenv ~context t1)
 136          (PP.ppterm ~subst ~metasenv ~context t2))))
 137 ;;
 138
 139 let eat_prods ~subst ~metasenv context he ty_he args_with_ty =
 140   let rec aux ty_he = function
 141   | [] -> ty_he
 142   | (arg, ty_arg)::tl ->
 143       match R.whd ~subst context ty_he with
 144       | C.Prod (n,s,t) ->
 145 (*
 146           prerr_endline (PP.ppterm ~subst ~metasenv ~context s ^ " - Vs - "
 147             ^ PP.ppterm ~subst ~metasenv ~context ty_arg);
 148           prerr_endline (PP.ppterm ~subst ~metasenv ~context
 149              (S.subst ~avoid_beta_redexes:true arg t));
 150 *)
 151           if R.are_convertible ~subst context ty_arg s then
 152             aux (S.subst ~avoid_beta_redexes:true arg t) tl
 153           else
 154             raise
 155               (TypeCheckerFailure
 156                 (lazy (Printf.sprintf
 157                   ("Appl: wrong application of %s: the parameter %s has type"^^
 158                    "\n%s\nbut it should have type \n%s\nContext:\n%s\n")
 159                   (PP.ppterm ~subst ~metasenv ~context he)
 160                   (PP.ppterm ~subst ~metasenv ~context arg)
 161                   (PP.ppterm ~subst ~metasenv ~context ty_arg)
 162                   (PP.ppterm ~subst ~metasenv ~context s)
 163                   (PP.ppcontext ~subst ~metasenv context))))
 164        | _ ->
 165           raise
 166             (TypeCheckerFailure
 167               (lazy (Printf.sprintf
 168                 "Appl: %s is not a function, it cannot be applied"
 169                 (PP.ppterm ~subst ~metasenv ~context
 170                  (let res = List.length tl in
 171                   let eaten = List.length args_with_ty - res in
 172                    (C.Appl
 173                     (he::List.map fst
 174                      (fst (HExtlib.split_nth eaten args_with_ty)))))))))
 175   in
 176     aux ty_he args_with_ty
 177 ;;
 178
 179 (* instantiate_parameters ps (x1:T1)...(xn:Tn)C                             *)
 180 (* returns ((x_|ps|:T_|ps|)...(xn:Tn)C){ps_1 / x1 ; ... ; ps_|ps| / x_|ps|} *)
 181 let rec instantiate_parameters params c =
 182   match c, params with
 183   | c,[] -> c
 184   | C.Prod (_,_,ta), he::tl -> instantiate_parameters tl (S.subst he ta)
 185   | t,l -> raise (AssertFailure (lazy "1"))
 186 ;;
 187
 188 let specialize_inductive_type_constrs ~subst context ty_term =
 189   match R.whd ~subst context ty_term with
 190   | C.Const (Ref.Ref (_,uri,Ref.Ind (_,i)) as ref)
 191   | C.Appl (C.Const (Ref.Ref (_,uri,Ref.Ind (_,i)) as ref) :: _ ) as ty ->
 192       let args = match ty with C.Appl (_::tl) -> tl | _ -> [] in
 193       let is_ind, leftno, itl, attrs, i = E.get_checked_indtys ref in
 194       let left_args,_ = HExtlib.split_nth leftno args in
 195       let _,_,_,cl = List.nth itl i in
 196       List.map
 197         (fun (rel,name,ty) -> rel, name, instantiate_parameters left_args ty) cl
 198   | _ -> assert false
 199 ;;
 200
 201 let specialize_and_abstract_constrs ~subst r_uri r_len context ty_term =
 202   let cl = specialize_inductive_type_constrs ~subst context ty_term in
 203   let len = List.length context in
 204   let context_dcl =
 205     match E.get_checked_obj r_uri with
 206     | _,_,_,_, NCic.Inductive (_,_,tys,_) ->
 207         context @ List.map (fun (_,name,arity,_) -> name,C.Decl arity) tys
 208     | _ -> assert false
 209   in
 210   context_dcl,
 211   List.map (fun (_,id,ty) -> id, debruijn r_uri r_len context ty) cl,
 212   len, len + r_len
 213 ;;
 214
 215 exception DoesOccur;;
 216
 217 let does_not_occur ~subst context n nn t =
 218   let rec aux k _ = function
 219     | C.Rel m when m > n+k && m <= nn+k -> raise DoesOccur
 220     | C.Rel m when m <= k || m > nn+k -> ()
 221     | C.Rel m ->
 222         (try match List.nth context (m-1-k) with
 223           | _,C.Def (bo,_) -> aux (n-m) () bo
 224           | _ -> ()
 225          with Failure _ -> assert false)
 226     | C.Meta (_,(_,(C.Irl 0 | C.Ctx []))) -> (* closed meta *) ()
 227     | C.Meta (mno,(s,l)) ->
 228          (try
 229             (* possible optimization here: try does_not_occur on l and
 230                perform substitution only if DoesOccur is raised *)
 231             let _,_,term,_ = U.lookup_subst mno subst in
 232             aux (k-s) () (S.subst_meta (0,l) term)
 233           with U.Subst_not_found _ -> match l with
 234           | C.Irl len -> if not (n+k >= s+len || s > nn+k) then raise DoesOccur
 235           | C.Ctx lc -> List.iter (aux (k-s) ()) lc)
 236     | t -> U.fold (fun _ k -> k + 1) k aux () t
 237   in
 238    try aux 0 () t; true
 239    with DoesOccur -> false
 240 ;;
 241
 242 let rec eat_lambdas ~subst ~metasenv context n te =
 243   match (n, R.whd ~subst context te) with
 244   | (0, _) -> (te, context)
 245   | (n, C.Lambda (name,so,ta)) when n > 0 ->
 246       eat_lambdas ~subst ~metasenv ((name,(C.Decl so))::context) (n - 1) ta
 247    | (n, te) ->
 248       raise (AssertFailure (lazy (Printf.sprintf "eat_lambdas (%d, %s)" n
 249         (PP.ppterm ~subst ~metasenv ~context te))))
 250 ;;
 251
 252 let rec eat_or_subst_lambdas ~subst ~metasenv n te to_be_subst args
 253      (context, recfuns, x as k)
 254 =
 255   match n, R.whd ~subst context te, to_be_subst, args with
 256   | (n, C.Lambda (name,so,ta),true::to_be_subst,arg::args) when n > 0 ->
 257       eat_or_subst_lambdas ~subst ~metasenv (n - 1) (S.subst arg ta)
 258        to_be_subst args k
 259   | (n, C.Lambda (name,so,ta),false::to_be_subst,arg::args) when n > 0 ->
 260       eat_or_subst_lambdas ~subst ~metasenv (n - 1) ta to_be_subst args
 261        (shift_k (name,(C.Decl so)) k)
 262   | (_, te, _, _) -> te, k
 263 ;;
 264
 265
 266 (*CSC l'indice x dei tipi induttivi e' t.c. n < x <= nn *)
 267 (*CSC questa funzione e' simile alla are_all_occurrences_positive, ma fa *)
 268 (*CSC dei controlli leggermente diversi. Viene invocata solamente dalla  *)
 269 (*CSC strictly_positive                                                  *)
 270 (*CSC definizione (giusta???) tratta dalla mail di Hugo ;-)              *)
 271 let rec weakly_positive ~subst context n nn uri te =
 272 (*CSC: Che schifo! Bisogna capire meglio e trovare una soluzione ragionevole!*)
 273   let dummy = C.Sort (C.Type ~-1) in
 274   (*CSC: mettere in cicSubstitution *)
 275   let rec subst_inductive_type_with_dummy _ = function
 276     | C.Const (Ref.Ref (_,uri',Ref.Ind (true,0))) when NUri.eq uri' uri -> dummy
 277     | C.Appl ((C.Const (Ref.Ref (_,uri',Ref.Ind (true,0))))::tl)
 278         when NUri.eq uri' uri -> dummy
 279     | t -> U.map (fun _ x->x) () subst_inductive_type_with_dummy t
 280   in
 281   match R.whd context te with
 282    | C.Const (Ref.Ref (_,uri',Ref.Ind _))
 283    | C.Appl ((C.Const (Ref.Ref (_,uri',Ref.Ind _)))::_)
 284       when NUri.eq uri' uri -> true
 285    | C.Prod (name,source,dest) when
 286       does_not_occur ~subst ((name,C.Decl source)::context) 0 1 dest ->
 287        (* dummy abstraction, so we behave as in the anonimous case *)
 288        strictly_positive ~subst context n nn
 289         (subst_inductive_type_with_dummy () source) &&
 290        weakly_positive ~subst ((name,C.Decl source)::context)
 291         (n + 1) (nn + 1) uri dest
 292    | C.Prod (name,source,dest) ->
 293        does_not_occur ~subst context n nn
 294         (subst_inductive_type_with_dummy () source)&&
 295        weakly_positive ~subst ((name,C.Decl source)::context)
 296         (n + 1) (nn + 1) uri dest
 297    | _ ->
 298      raise (TypeCheckerFailure (lazy "Malformed inductive constructor type"))
 299
 300 and strictly_positive ~subst context n nn te =
 301   match R.whd context te with
 302    | t when does_not_occur ~subst context n nn t -> true
 303    | C.Rel _ -> true
 304    | C.Prod (name,so,ta) ->
 305       does_not_occur ~subst context n nn so &&
 306        strictly_positive ~subst ((name,C.Decl so)::context) (n+1) (nn+1) ta
 307    | C.Appl ((C.Rel m)::tl) when m > n && m <= nn ->
 308       List.for_all (does_not_occur ~subst context n nn) tl
 309    | C.Appl (C.Const (Ref.Ref (_,uri,Ref.Ind (_,i)) as r)::tl) ->
 310       let _,paramsno,tyl,_,i = E.get_checked_indtys r in
 311       let _,name,ity,cl = List.nth tyl i in
 312       let ok = List.length tyl = 1 in
 313       let params, arguments = HExtlib.split_nth paramsno tl in
 314       let lifted_params = List.map (S.lift 1) params in
 315       let cl =
 316         List.map (fun (_,_,te) -> instantiate_parameters lifted_params te) cl
 317       in
 318       ok &&
 319       List.for_all (does_not_occur ~subst context n nn) arguments &&
 320       List.for_all
 321        (weakly_positive ~subst ((name,C.Decl ity)::context) (n+1) (nn+1) uri) cl
 322    | _ -> false
 323
 324 (* the inductive type indexes are s.t. n < x <= nn *)
 325 and are_all_occurrences_positive ~subst context uri indparamsno i n nn te =
 326   match R.whd context te with
 327   |  C.Appl ((C.Rel m)::tl) as reduct when m = i ->
 328       let last =
 329        List.fold_left
 330         (fun k x ->
 331           if k = 0 then 0
 332           else
 333            match R.whd context x with
 334            |  C.Rel m when m = n - (indparamsno - k) -> k - 1
 335            | y -> raise (TypeCheckerFailure (lazy
 336               ("Argument "^string_of_int (indparamsno - k + 1) ^ " (of " ^
 337               string_of_int indparamsno ^ " fixed) is not homogeneous in "^
 338               "appl:\n"^ PP.ppterm ~context ~subst ~metasenv:[] reduct))))
 339         indparamsno tl
 340       in
 341        if last = 0 then
 342         List.for_all (does_not_occur ~subst context n nn) tl
 343        else
 344         raise (TypeCheckerFailure
 345          (lazy ("Non-positive occurence in mutual inductive definition(s) [2]"^
 346           NUri.string_of_uri uri)))
 347   | C.Rel m when m = i ->
 348       if indparamsno = 0 then
 349        true
 350       else
 351         raise (TypeCheckerFailure
 352          (lazy ("Non-positive occurence in mutual inductive definition(s) [3]"^
 353           NUri.string_of_uri uri)))
 354   | C.Prod (name,source,dest) when
 355       does_not_occur ~subst ((name,C.Decl source)::context) 0 1 dest ->
 356       strictly_positive ~subst context n nn source &&
 357        are_all_occurrences_positive ~subst
 358         ((name,C.Decl source)::context) uri indparamsno
 359         (i+1) (n + 1) (nn + 1) dest
 360    | C.Prod (name,source,dest) ->
 361        if not (does_not_occur ~subst context n nn source) then
 362          raise (TypeCheckerFailure (lazy ("Non-positive occurrence in "^
 363          PP.ppterm ~context ~metasenv:[] ~subst te)));
 364        are_all_occurrences_positive ~subst ((name,C.Decl source)::context)
 365         uri indparamsno (i+1) (n + 1) (nn + 1) dest
 366    | _ ->
 367      raise
 368       (TypeCheckerFailure (lazy ("Malformed inductive constructor type " ^
 369         (NUri.string_of_uri uri))))
 370 ;;
 371
 372 exception NotGuarded of string Lazy.t;;
 373
 374 let rec typeof ~subst ~metasenv context term =
 375   let rec typeof_aux context =
 376     fun t -> (*prerr_endline (PP.ppterm ~metasenv ~subst ~context t);*)
 377     match t with
 378     | C.Rel n ->
 379        (try
 380          match List.nth context (n - 1) with
 381          | (_,C.Decl ty) -> S.lift n ty
 382          | (_,C.Def (_,ty)) -> S.lift n ty
 383         with Failure _ -> raise (TypeCheckerFailure (lazy "unbound variable")))
 384     | C.Sort (C.Type i) -> C.Sort (C.Type (i+1))
 385     | C.Sort s -> C.Sort (C.Type 0)
 386     | C.Implicit _ -> raise (AssertFailure (lazy "Implicit found"))
 387     | C.Meta (n,l) as t ->
 388        let canonical_ctx,ty =
 389         try
 390          let _,c,_,ty = U.lookup_subst n subst in c,ty
 391         with U.Subst_not_found _ -> try
 392          let _,c,ty = U.lookup_meta n metasenv in c,ty
 393         with U.Meta_not_found _ ->
 394          raise (AssertFailure (lazy (Printf.sprintf
 395           "%s not found" (PP.ppterm ~subst ~metasenv ~context t))))
 396        in
 397         check_metasenv_consistency t ~subst ~metasenv context canonical_ctx l;
 398         S.subst_meta l ty
 399     | C.Const ref -> type_of_constant ref
 400     | C.Prod (name,s,t) ->
 401        let sort1 = typeof_aux context s in
 402        let sort2 = typeof_aux ((name,(C.Decl s))::context) t in
 403        sort_of_prod ~metasenv ~subst context (name,s) (sort1,sort2)
 404     | C.Lambda (n,s,t) ->
 405        let sort = typeof_aux context s in
 406        (match R.whd ~subst context sort with
 407        | C.Meta _ | C.Sort _ -> ()
 408        | _ ->
 409          raise
 410            (TypeCheckerFailure (lazy (Printf.sprintf
 411              ("Not well-typed lambda-abstraction: " ^^
 412              "the source %s should be a type; instead it is a term " ^^
 413              "of type %s") (PP.ppterm ~subst ~metasenv ~context s)
 414              (PP.ppterm ~subst ~metasenv ~context sort)))));
 415        let ty = typeof_aux ((n,(C.Decl s))::context) t in
 416          C.Prod (n,s,ty)
 417     | C.LetIn (n,ty,t,bo) ->
 418        let ty_t = typeof_aux context t in
 419        let _ = typeof_aux context ty in
 420        if not (R.are_convertible ~subst context ty ty_t) then
 421          raise
 422           (TypeCheckerFailure
 423             (lazy (Printf.sprintf
 424               "The type of %s is %s but it is expected to be %s"
 425                 (PP.ppterm ~subst ~metasenv ~context t)
 426                 (PP.ppterm ~subst ~metasenv ~context ty_t)
 427                 (PP.ppterm ~subst ~metasenv ~context ty))))
 428        else
 429          let ty_bo = typeof_aux  ((n,C.Def (t,ty))::context) bo in
 430          S.subst ~avoid_beta_redexes:true t ty_bo
 431     | C.Appl (he::(_::_ as args)) ->
 432        let ty_he = typeof_aux context he in
 433        let args_with_ty = List.map (fun t -> t, typeof_aux context t) args in
 434 (*
 435        prerr_endline ("HEAD: " ^ PP.ppterm ~subst ~metasenv ~context ty_he);
 436        prerr_endline ("TARGS: " ^ String.concat " | " (List.map (PP.ppterm
 437        ~subst ~metasenv ~context) (List.map snd args_with_ty)));
 438        prerr_endline ("ARGS: " ^ String.concat " | " (List.map (PP.ppterm
 439        ~subst ~metasenv ~context) (List.map fst args_with_ty)));
 440 *)
 441        eat_prods ~subst ~metasenv context he ty_he args_with_ty
 442    | C.Appl _ -> raise (AssertFailure (lazy "Appl of length < 2"))
 443    | C.Match (Ref.Ref (_,_,Ref.Ind (_,tyno)) as r,outtype,term,pl) ->
 444       let outsort = typeof_aux context outtype in
 445       let inductive,leftno,itl,_,_ = E.get_checked_indtys r in
 446       let constructorsno =
 447         let _,_,_,cl = List.nth itl tyno in List.length cl
 448       in
 449       let parameters, arguments =
 450         let ty = R.whd ~subst context (typeof_aux context term) in
 451         let r',tl =
 452          match ty with
 453             C.Const (Ref.Ref (_,_,Ref.Ind _) as r') -> r',[]
 454           | C.Appl (C.Const (Ref.Ref (_,_,Ref.Ind _) as r') :: tl) -> r',tl
 455           | _ ->
 456              raise
 457                (TypeCheckerFailure (lazy (Printf.sprintf
 458                  "Case analysis: analysed term %s is not an inductive one"
 459                  (PP.ppterm ~subst ~metasenv ~context term)))) in
 460         if not (Ref.eq r r') then
 461          raise
 462           (TypeCheckerFailure (lazy (Printf.sprintf
 463             ("Case analysys: analysed term type is %s, but is expected " ^^
 464              "to be (an application of) %s")
 465             (PP.ppterm ~subst ~metasenv ~context ty)
 466             (PP.ppterm ~subst ~metasenv ~context (C.Const r')))))
 467         else
 468          try HExtlib.split_nth leftno tl
 469          with
 470           Failure _ ->
 471            raise (TypeCheckerFailure (lazy (Printf.sprintf
 472            "%s is partially applied"
 473            (PP.ppterm  ~subst ~metasenv ~context ty)))) in
 474       (* let's control if the sort elimination is allowed: [(I q1 ... qr)|B] *)
 475       let sort_of_ind_type =
 476         if parameters = [] then C.Const r
 477         else C.Appl ((C.Const r)::parameters) in
 478       let type_of_sort_of_ind_ty = typeof_aux context sort_of_ind_type in
 479       check_allowed_sort_elimination ~subst ~metasenv r context
 480        sort_of_ind_type type_of_sort_of_ind_ty outsort;
 481       (* let's check if the type of branches are right *)
 482       if List.length pl <> constructorsno then
 483        raise (TypeCheckerFailure (lazy ("Wrong number of cases in a match")));
 484       let j,branches_ok,p_ty, exp_p_ty =
 485         List.fold_left
 486           (fun (j,b,old_p_ty,old_exp_p_ty) p ->
 487             if b then
 488               let cons =
 489                 let cons = Ref.mk_constructor j r in
 490                 if parameters = [] then C.Const cons
 491                 else C.Appl (C.Const cons::parameters)
 492               in
 493               let ty_p = typeof_aux context p in
 494               let ty_cons = typeof_aux context cons in
 495               let ty_branch =
 496                 type_of_branch ~subst context leftno outtype cons ty_cons 0
 497               in
 498               j+1, R.are_convertible ~subst context ty_p ty_branch,
 499               ty_p, ty_branch
 500             else
 501               j,false,old_p_ty,old_exp_p_ty
 502           ) (1,true,C.Sort C.Prop,C.Sort C.Prop) pl
 503       in
 504       if not branches_ok then
 505         raise
 506          (TypeCheckerFailure
 507           (lazy (Printf.sprintf ("Branch for constructor %s :=\n%s\n"^^
 508           "has type %s\nnot convertible with %s")
 509           (PP.ppterm  ~subst ~metasenv ~context
 510             (C.Const (Ref.mk_constructor (j-1) r)))
 511           (PP.ppterm ~metasenv ~subst ~context (List.nth pl (j-2)))
 512           (PP.ppterm ~metasenv ~subst ~context p_ty)
 513           (PP.ppterm ~metasenv ~subst ~context exp_p_ty))));
 514       let res = outtype::arguments@[term] in
 515       R.head_beta_reduce (C.Appl res)
 516     | C.Match _ -> assert false
 517
 518   and type_of_branch ~subst context leftno outty cons tycons liftno =
 519     match R.whd ~subst context tycons with
 520     | C.Const (Ref.Ref (_,_,Ref.Ind _)) -> C.Appl [S.lift liftno outty ; cons]
 521     | C.Appl (C.Const (Ref.Ref (_,_,Ref.Ind _))::tl) ->
 522         let _,arguments = HExtlib.split_nth leftno tl in
 523         C.Appl (S.lift liftno outty::arguments@[cons])
 524     | C.Prod (name,so,de) ->
 525         let cons =
 526          match S.lift 1 cons with
 527          | C.Appl l -> C.Appl (l@[C.Rel 1])
 528          | t -> C.Appl [t ; C.Rel 1]
 529         in
 530          C.Prod (name,so,
 531            type_of_branch ~subst ((name,(C.Decl so))::context)
 532             leftno outty cons de (liftno+1))
 533     | _ -> raise (AssertFailure (lazy "type_of_branch"))
 534
 535   (* check_metasenv_consistency checks that the "canonical" context of a
 536      metavariable is consitent - up to relocation via the relocation list l -
 537      with the actual context *)
 538   and check_metasenv_consistency
 539     ~subst ~metasenv term context canonical_context l
 540   =
 541    match l with
 542     | shift, C.Irl n ->
 543        let context = snd (HExtlib.split_nth shift context) in
 544         let rec compare = function
 545          | 0,_,[] -> ()
 546          | 0,_,_::_
 547          | _,_,[] ->
 548             raise (AssertFailure (lazy (Printf.sprintf
 549              "Local and canonical context %s have different lengths"
 550              (PP.ppterm ~subst ~context ~metasenv term))))
 551          | m,[],_::_ ->
 552             raise (TypeCheckerFailure (lazy (Printf.sprintf
 553              "Unbound variable -%d in %s" m
 554              (PP.ppterm ~subst ~metasenv ~context term))))
 555          | m,t::tl,ct::ctl ->
 556             (match t,ct with
 557                 (_,C.Decl t1), (_,C.Decl t2)
 558               | (_,C.Def (t1,_)), (_,C.Def (t2,_))
 559               | (_,C.Def (_,t1)), (_,C.Decl t2) ->
 560                  if not (R.are_convertible ~subst tl t1 t2) then
 561                   raise
 562                       (TypeCheckerFailure
 563                         (lazy (Printf.sprintf
 564                       ("Not well typed metavariable local context for %s: " ^^
 565                        "%s expected, which is not convertible with %s")
 566                       (PP.ppterm ~subst ~metasenv ~context term)
 567                       (PP.ppterm ~subst ~metasenv ~context t2)
 568                       (PP.ppterm ~subst ~metasenv ~context t1))))
 569               | _,_ ->
 570                raise
 571                    (TypeCheckerFailure (lazy (Printf.sprintf
 572                     ("Not well typed metavariable local context for %s: " ^^
 573                      "a definition expected, but a declaration found")
 574                     (PP.ppterm ~subst ~metasenv ~context term)))));
 575             compare (m - 1,tl,ctl)
 576         in
 577          compare (n,context,canonical_context)
 578     | shift, lc_kind ->
 579        (* we avoid useless lifting by shortening the context*)
 580        let l,context = (0,lc_kind), snd (HExtlib.split_nth shift context) in
 581        let lifted_canonical_context =
 582          let rec lift_metas i = function
 583            | [] -> []
 584            | (n,C.Decl t)::tl ->
 585                (n,C.Decl (S.subst_meta l (S.lift i t)))::(lift_metas (i+1) tl)
 586            | (n,C.Def (t,ty))::tl ->
 587                (n,C.Def ((S.subst_meta l (S.lift i t)),
 588                           S.subst_meta l (S.lift i ty)))::(lift_metas (i+1) tl)
 589          in
 590           lift_metas 1 canonical_context in
 591        let l = U.expand_local_context lc_kind in
 592        try
 593         List.iter2
 594         (fun t ct ->
 595           match (t,ct) with
 596           | t, (_,C.Def (ct,_)) ->
 597              (*CSC: the following optimization is to avoid a possibly expensive
 598                     reduction that can be easily avoided and that is quite
 599                     frequent. However, this is better handled using levels to
 600                     control reduction *)
 601              let optimized_t =
 602               match t with
 603               | C.Rel n ->
 604                   (try
 605                     match List.nth context (n - 1) with
 606                     | (_,C.Def (te,_)) -> S.lift n te
 607                     | _ -> t
 608                     with Failure _ -> t)
 609               | _ -> t
 610              in
 611              if not (R.are_convertible ~subst context optimized_t ct)
 612              then
 613                raise
 614                  (TypeCheckerFailure
 615                    (lazy (Printf.sprintf
 616                      ("Not well typed metavariable local context: " ^^
 617                       "expected a term convertible with %s, found %s")
 618                      (PP.ppterm ~subst ~metasenv ~context ct)
 619                      (PP.ppterm ~subst ~metasenv ~context t))))
 620           | t, (_,C.Decl ct) ->
 621               let type_t = typeof_aux context t in
 622               if not (R.are_convertible ~subst context type_t ct) then
 623                 raise (TypeCheckerFailure
 624                  (lazy (Printf.sprintf
 625                   ("Not well typed metavariable local context: "^^
 626                   "expected a term of type %s, found %s of type %s")
 627                   (PP.ppterm ~subst ~metasenv ~context ct)
 628                   (PP.ppterm ~subst ~metasenv ~context t)
 629                   (PP.ppterm ~subst ~metasenv ~context type_t))))
 630         ) l lifted_canonical_context
 631        with
 632         Invalid_argument _ ->
 633           raise (AssertFailure (lazy (Printf.sprintf
 634            "Local and canonical context %s have different lengths"
 635            (PP.ppterm ~subst ~metasenv ~context term))))
 636
 637   and is_non_informative context paramsno c =
 638    let rec aux context c =
 639      match R.whd context c with
 640       | C.Prod (n,so,de) ->
 641          let s = typeof_aux context so in
 642          s = C.Sort C.Prop && aux ((n,(C.Decl so))::context) de
 643       | _ -> true in
 644    let context',dx = split_prods ~subst:[] context paramsno c in
 645     aux context' dx
 646
 647   and check_allowed_sort_elimination ~subst ~metasenv r =
 648    let mkapp he arg =
 649      match he with
 650      | C.Appl l -> C.Appl (l @ [arg])
 651      | t -> C.Appl [t;arg] in
 652    let rec aux context ind arity1 arity2 =
 653     let arity1 = R.whd ~subst context arity1 in
 654     let arity2 = R.whd ~subst context arity2 in
 655       match arity1,arity2 with
 656        | C.Prod (name,so1,de1), C.Prod (_,so2,de2) ->
 657           if not (R.are_convertible ~subst context so1 so2) then
 658            raise (TypeCheckerFailure (lazy (Printf.sprintf
 659             "In outtype: expected %s, found %s"
 660             (PP.ppterm ~subst ~metasenv ~context so1)
 661             (PP.ppterm ~subst ~metasenv ~context so2)
 662             )));
 663           aux ((name, C.Decl so1)::context)
 664            (mkapp (S.lift 1 ind) (C.Rel 1)) de1 de2
 665        | C.Sort _, C.Prod (name,so,ta) ->
 666           if not (R.are_convertible ~subst context so ind) then
 667            raise (TypeCheckerFailure (lazy (Printf.sprintf
 668             "In outtype: expected %s, found %s"
 669             (PP.ppterm ~subst ~metasenv ~context ind)
 670             (PP.ppterm ~subst ~metasenv ~context so)
 671             )));
 672           (match arity1,ta with
 673             | (C.Sort (C.CProp | C.Type _), C.Sort _)
 674             | (C.Sort C.Prop, C.Sort C.Prop) -> ()
 675             | (C.Sort C.Prop, C.Sort (C.CProp | C.Type _)) ->
 676         (* TODO: we should pass all these parameters since we
 677          * have them already *)
 678                 let inductive,leftno,itl,_,i = E.get_checked_indtys r in
 679                 let itl_len = List.length itl in
 680                 let _,name,ty,cl = List.nth itl i in
 681                 let cl_len = List.length cl in
 682                  (* is it a singleton or empty non recursive and non informative
 683                     definition? *)
 684                  if not
 685                   (cl_len = 0 ||
 686                    (itl_len = 1 && cl_len = 1 &&
 687                     is_non_informative [name,C.Decl ty] leftno
 688                      (let _,_,x = List.nth cl 0 in x)))
 689                  then
 690                   raise (TypeCheckerFailure (lazy
 691                    ("Sort elimination not allowed")));
 692           | _,_ -> ())
 693        | _,_ -> ()
 694    in
 695     aux
 696
 697  in
 698    typeof_aux context term
 699
 700 and check_mutual_inductive_defs uri ~metasenv ~subst is_ind leftno tyl =
 701   (* let's check if the arity of the inductive types are well formed *)
 702   List.iter (fun (_,_,x,_) -> ignore (typeof ~subst ~metasenv [] x)) tyl;
 703   (* let's check if the types of the inductive constructors are well formed. *)
 704   let len = List.length tyl in
 705   let tys = List.rev (List.map (fun (_,n,ty,_) -> (n,(C.Decl ty))) tyl) in
 706   ignore
 707    (List.fold_right
 708     (fun (_,_,_,cl) i ->
 709        List.iter
 710          (fun (_,name,te) ->
 711            let debruijnedte = debruijn uri len [] te in
 712            ignore (typeof ~subst ~metasenv tys debruijnedte);
 713            (* let's check also the positivity conditions *)
 714            if
 715              not
 716                (are_all_occurrences_positive ~subst tys uri leftno i 0 len
 717                   debruijnedte)
 718            then
 719              raise
 720                (TypeCheckerFailure
 721                  (lazy ("Non positive occurence in "^NUri.string_of_uri uri))))
 722          cl;
 723         i + 1)
 724     tyl 1)
 725
 726 and guarded_by_destructors r_uri r_len ~subst ~metasenv context recfuns t =
 727  let recursor f k t = U.fold shift_k k (fun k () -> f k) () t in
 728  let rec aux (context, recfuns, x as k) t =
 729 (*
 730    prerr_endline ("GB:\n" ^
 731      PP.ppcontext ~subst ~metasenv context^
 732      PP.ppterm ~metasenv ~subst ~context t^
 733        string_of_recfuns ~subst ~metasenv ~context recfuns);
 734 *)
 735   try
 736   match t with
 737   | C.Rel m as t when is_dangerous m recfuns ->
 738       raise (NotGuarded (lazy
 739         (PP.ppterm ~subst ~metasenv ~context t ^
 740          " is a partial application of a fix")))
 741   | C.Appl ((C.Rel m)::tl) as t when is_dangerous m recfuns ->
 742      let rec_no = get_recno m recfuns in
 743      if not (List.length tl > rec_no) then
 744        raise (NotGuarded (lazy
 745          (PP.ppterm ~context ~subst ~metasenv t ^
 746          " is a partial application of a fix")))
 747      else
 748        let rec_arg = List.nth tl rec_no in
 749        if not (is_really_smaller r_uri r_len ~subst ~metasenv k rec_arg) then
 750          raise (NotGuarded (lazy (Printf.sprintf ("Recursive call %s, %s is not"
 751           ^^ " smaller.\ncontext:\n%s") (PP.ppterm ~context ~subst ~metasenv
 752           t) (PP.ppterm ~context ~subst ~metasenv rec_arg)
 753           (PP.ppcontext ~subst ~metasenv context))));
 754        List.iter (aux k) tl
 755   | C.Appl ((C.Rel m)::tl) when is_unfolded m recfuns ->
 756        let fixed_args = get_fixed_args m recfuns in
 757        list_iter_default2 (fun x b -> if not b then aux k x) tl false fixed_args
 758   | C.Rel m ->
 759      (match List.nth context (m-1) with
 760      | _,C.Decl _ -> ()
 761      | _,C.Def (bo,_) -> aux k (S.lift m bo))
 762   | C.Meta _ -> ()
 763   | C.Appl (C.Const ((Ref.Ref (_,uri,Ref.Fix (i,recno))) as r)::args) ->
 764       if List.exists (fun t -> try aux k t;false with NotGuarded _ -> true) args
 765       then
 766       let fl,_,_ = E.get_checked_fixes_or_cofixes r in
 767       let ctx_tys, bos =
 768         List.split (List.map (fun (_,name,_,ty,bo) -> (name, C.Decl ty), bo) fl)
 769       in
 770       let fl_len = List.length fl in
 771       let bos = List.map (debruijn uri fl_len context) bos in
 772       let j = List.fold_left min max_int (List.map (fun (_,_,i,_,_)->i) fl) in
 773       let ctx_len = List.length context in
 774         (* we may look for fixed params not only up to j ... *)
 775       let fa = fixed_args bos j ctx_len (ctx_len + fl_len) in
 776       list_iter_default2 (fun x b -> if not b then aux k x) args false fa;
 777       let context = context@ctx_tys in
 778       let ctx_len = List.length context in
 779       let extra_recfuns =
 780         HExtlib.list_mapi (fun _ i -> ctx_len - i, UnfFix fa) ctx_tys
 781       in
 782       let new_k = context, extra_recfuns@recfuns, x in
 783       let bos_and_ks =
 784         HExtlib.list_mapi
 785          (fun bo fno ->
 786           let bo_and_k =
 787             eat_or_subst_lambdas ~subst ~metasenv j bo fa args new_k
 788           in
 789            if
 790             fno = i &&
 791             List.length args > recno &&
 792             (*case where the recursive argument is already really_smaller *)
 793             is_really_smaller r_uri r_len ~subst ~metasenv k
 794              (List.nth args recno)
 795            then
 796             let bo,(context, _, _ as new_k) = bo_and_k in
 797             let bo, context' =
 798              eat_lambdas ~subst ~metasenv context (recno + 1 - j) bo in
 799             let new_context_part,_ =
 800              HExtlib.split_nth (List.length context' - List.length context)
 801               context' in
 802             let k = List.fold_right shift_k new_context_part new_k in
 803             let context, recfuns, x = k in
 804             let k = context, (1,Safe)::recfuns, x in
 805               bo,k
 806            else
 807             bo_and_k
 808          ) bos
 809       in
 810        List.iter (fun (bo,k) -> aux k bo) bos_and_ks
 811   | C.Match (Ref.Ref (_,uri,Ref.Ind (true,_)),outtype,term,pl) as t ->
 812      (match R.whd ~subst context term with
 813      | C.Rel m | C.Appl (C.Rel m :: _ ) as t when is_safe m recfuns || m = x ->
 814          let ty = typeof ~subst ~metasenv context term in
 815          let dc_ctx, dcl, start, stop =
 816            specialize_and_abstract_constrs ~subst r_uri r_len context ty in
 817          let args = match t with C.Appl (_::tl) -> tl | _ -> [] in
 818          aux k outtype;
 819          List.iter (aux k) args;
 820          List.iter2
 821            (fun p (_,dc) ->
 822              let rl = recursive_args ~subst ~metasenv dc_ctx start stop dc in
 823              let p, k = get_new_safes ~subst k p rl in
 824              aux k p)
 825            pl dcl
 826      | _ -> recursor aux k t)
 827   | t -> recursor aux k t
 828   with
 829    NotGuarded _ as exc ->
 830     let t' = R.whd ~delta:0 ~subst context t in
 831     if t = t' then raise exc
 832     else aux k t'
 833  in
 834   try aux (context, recfuns, 1) t
 835   with NotGuarded s -> raise (TypeCheckerFailure s)
 836
 837 and guarded_by_constructors ~subst ~metasenv context t indURI indlen nn =
 838  let rec aux context n nn h te =
 839   match R.whd ~subst context te with
 840    | C.Rel m when m > n && m <= nn -> h
 841    | C.Rel _ | C.Meta _ -> true
 842    | C.Sort _
 843    | C.Implicit _
 844    | C.Prod _
 845    | C.Const (Ref.Ref (_,_,Ref.Ind _))
 846    | C.LetIn _ -> raise (AssertFailure (lazy "17"))
 847    | C.Lambda (name,so,de) ->
 848       does_not_occur ~subst context n nn so &&
 849       aux ((name,C.Decl so)::context) (n + 1) (nn + 1) h de
 850    | C.Appl ((C.Rel m)::tl) when m > n && m <= nn ->
 851       h && List.for_all (does_not_occur ~subst context n nn) tl
 852    | C.Const (Ref.Ref (_,_,Ref.Con _)) -> true
 853    | C.Appl (C.Const (Ref.Ref (_,uri, Ref.Con (_,j)) as ref) :: tl) as t ->
 854       let _, paramsno, _, _, _ = E.get_checked_indtys ref in
 855       let ty_t = typeof ~subst ~metasenv context t in
 856       let dc_ctx, dcl, start, stop =
 857         specialize_and_abstract_constrs ~subst indURI indlen context ty_t in
 858       let _, dc = List.nth dcl (j-1) in
 859 (*
 860         prerr_endline (PP.ppterm ~subst ~metasenv ~context:dc_ctx dc);
 861         prerr_endline (PP.ppcontext ~subst ~metasenv dc_ctx);
 862  *)
 863       let rec_params = recursive_args ~subst ~metasenv dc_ctx start stop dc in
 864       let rec analyse_instantiated_type rec_spec args =
 865        match rec_spec, args with
 866        | h::rec_spec, he::args ->
 867            aux context n nn h he && analyse_instantiated_type rec_spec args
 868        | _,[] -> true
 869        | _ -> raise (AssertFailure (lazy
 870          ("Too many args for constructor: " ^ String.concat " "
 871          (List.map (fun x-> PP.ppterm ~subst ~metasenv ~context x) args))))
 872       in
 873       let left, args = HExtlib.split_nth paramsno tl in
 874       List.for_all (does_not_occur ~subst context n nn) left &&
 875       analyse_instantiated_type rec_params args
 876    | C.Appl ((C.Match (_,out,te,pl))::_)
 877    | C.Match (_,out,te,pl) as t ->
 878        let tl = match t with C.Appl (_::tl) -> tl | _ -> [] in
 879        List.for_all (does_not_occur ~subst context n nn) tl &&
 880        does_not_occur ~subst context n nn out &&
 881        does_not_occur ~subst context n nn te &&
 882        List.for_all (aux context n nn h) pl
 883    | C.Const (Ref.Ref (_,u,(Ref.Fix _| Ref.CoFix _)) as ref)
 884    | C.Appl(C.Const (Ref.Ref(_,u,(Ref.Fix _| Ref.CoFix _)) as ref) :: _) as t ->
 885       let tl = match t with C.Appl (_::tl) -> tl | _ -> [] in
 886       let fl,_,_ = E.get_checked_fixes_or_cofixes ref in
 887       let len = List.length fl in
 888       let tys = List.map (fun (_,n,_,ty,_) -> n, C.Decl ty) fl in
 889       List.for_all (does_not_occur ~subst context n nn) tl &&
 890       List.for_all
 891        (fun (_,_,_,_,bo) ->
 892           aux (context@tys) n nn h (debruijn u len context bo))
 893        fl
 894    | C.Const _
 895    | C.Appl _ as t -> does_not_occur ~subst context n nn t
 896  in
 897    aux context 0 nn false t
 898
 899 and recursive_args ~subst ~metasenv context n nn te =
 900   match R.whd context te with
 901   | C.Rel _ | C.Appl _ | C.Const _ -> []
 902   | C.Prod (name,so,de) ->
 903      (not (does_not_occur ~subst context n nn so)) ::
 904       (recursive_args ~subst ~metasenv
 905         ((name,(C.Decl so))::context) (n+1) (nn + 1) de)
 906   | t ->
 907      raise (AssertFailure (lazy ("recursive_args:" ^ PP.ppterm ~subst
 908      ~metasenv ~context:[] t)))
 909
 910 and get_new_safes ~subst (context, recfuns, x as k) p rl =
 911   match R.whd ~subst context p, rl with
 912   | C.Lambda (name,so,ta), b::tl ->
 913       let recfuns = (if b then [0,Safe] else []) @ recfuns in
 914       get_new_safes ~subst
 915         (shift_k (name,(C.Decl so)) (context, recfuns, x)) ta tl
 916   | C.Meta _ as e, _ | e, [] -> e, k
 917   | _ -> raise (AssertFailure (lazy "Ill formed pattern"))
 918
 919 and is_really_smaller
 920   r_uri r_len ~subst ~metasenv (context, recfuns, x as k) te
 921 =
 922  match R.whd ~subst context te with
 923  | C.Rel m when is_safe m recfuns -> true
 924  | C.Lambda (name, s, t) ->
 925     is_really_smaller r_uri r_len ~subst ~metasenv (shift_k (name,C.Decl s) k) t
 926  | C.Appl (he::_) ->
 927     is_really_smaller r_uri r_len ~subst ~metasenv k he
 928  | C.Rel _
 929  | C.Const (Ref.Ref (_,_,Ref.Con _)) -> false
 930  | C.Appl []
 931  | C.Const (Ref.Ref (_,_,Ref.Fix _)) -> assert false
 932  | C.Meta _ -> true
 933  | C.Match (Ref.Ref (_,uri,_) as ref,outtype,term,pl) ->
 934     (match term with
 935     | C.Rel m | C.Appl (C.Rel m :: _ ) when is_safe m recfuns || m = x ->
 936         (* TODO: add CoInd to references so that this call is useless *)
 937         let isinductive, _, _, _, _ = E.get_checked_indtys ref in
 938         if not isinductive then
 939           List.for_all (is_really_smaller r_uri r_len ~subst ~metasenv k) pl
 940         else
 941           let ty = typeof ~subst ~metasenv context term in
 942           let dc_ctx, dcl, start, stop =
 943             specialize_and_abstract_constrs ~subst r_uri r_len context ty in
 944           List.for_all2
 945            (fun p (_,dc) ->
 946              let rl = recursive_args ~subst ~metasenv dc_ctx start stop dc in
 947              let e, k = get_new_safes ~subst k p rl in
 948              is_really_smaller r_uri r_len ~subst ~metasenv k e)
 949            pl dcl
 950     | _ -> List.for_all (is_really_smaller r_uri r_len ~subst ~metasenv k) pl)
 951  | _ -> assert false
 952
 953 and returns_a_coinductive ~subst context ty =
 954   match R.whd ~subst context ty with
 955   | C.Const (Ref.Ref (_,uri,Ref.Ind (false,_)) as ref)
 956   | C.Appl (C.Const (Ref.Ref (_,uri,Ref.Ind (false,_)) as ref)::_) ->
 957      let _, _, itl, _, _ = E.get_checked_indtys ref in
 958      Some (uri,List.length itl)
 959   | C.Prod (n,so,de) ->
 960      returns_a_coinductive ~subst ((n,C.Decl so)::context) de
 961   | _ -> None
 962
 963 and type_of_constant ((Ref.Ref (_,uri,_)) as ref) =
 964   match E.get_checked_obj uri, ref with
 965   | (_,_,_,_,C.Inductive (_,_,tl,_)), Ref.Ref (_,_,Ref.Ind (_,i))  ->
 966       let _,_,arity,_ = List.nth tl i in arity
 967   | (_,_,_,_,C.Inductive (_,_,tl,_)), Ref.Ref (_,_,Ref.Con (i,j))  ->
 968       let _,_,_,cl = List.nth tl i in
 969       let _,_,arity = List.nth cl (j-1) in
 970       arity
 971   | (_,_,_,_,C.Fixpoint (_,fl,_)), Ref.Ref (_,_,(Ref.Fix (i,_)|Ref.CoFix i)) ->
 972       let _,_,_,arity,_ = List.nth fl i in
 973       arity
 974   | (_,_,_,_,C.Constant (_,_,_,ty,_)), Ref.Ref (_,_,(Ref.Def |Ref.Decl)) -> ty
 975   | _ -> raise (AssertFailure (lazy "type_of_constant: environment/reference"))
 976 ;;
 977
 978 let typecheck_context ~metasenv ~subst context =
 979  ignore
 980   (List.fold_right
 981    (fun d context  ->
 982      begin
 983       match d with
 984          _,C.Decl t -> ignore (typeof ~metasenv ~subst:[] context t)
 985        | name,C.Def (te,ty) ->
 986          ignore (typeof ~metasenv ~subst:[] context ty);
 987          let ty' = typeof ~metasenv ~subst:[] context te in
 988           if not (R.are_convertible ~subst context ty' ty) then
 989            raise (AssertFailure (lazy (Printf.sprintf (
 990             "the type of the definiens for %s in the context is not "^^
 991             "convertible with the declared one.\n"^^
 992             "inferred type:\n%s\nexpected type:\n%s")
 993             name
 994             (PP.ppterm ~subst ~metasenv ~context ty')
 995             (PP.ppterm ~subst ~metasenv ~context ty))))
 996      end;
 997      d::context
 998    ) context [])
 999 ;;
1000
1001 let typecheck_metasenv metasenv =
1002  ignore
1003   (List.fold_left
1004     (fun metasenv (i,(_,context,ty) as conj) ->
1005       if List.mem_assoc i metasenv then
1006        raise (TypeCheckerFailure (lazy ("duplicate meta " ^ string_of_int i ^
1007         " in metasenv")));
1008       typecheck_context ~metasenv ~subst:[] context;
1009       ignore (typeof ~metasenv ~subst:[] context ty);
1010       metasenv @ [conj]
1011     ) [] metasenv)
1012 ;;
1013
1014 let typecheck_subst ~metasenv subst =
1015  ignore
1016   (List.fold_left
1017     (fun subst (i,(_,context,ty,bo) as conj) ->
1018       if List.mem_assoc i subst then
1019        raise (AssertFailure (lazy ("duplicate meta " ^ string_of_int i ^
1020         " in substitution")));
1021       if List.mem_assoc i metasenv then
1022        raise (AssertFailure (lazy ("meta " ^ string_of_int i ^
1023         " is both in the metasenv and in the substitution")));
1024       typecheck_context ~metasenv ~subst context;
1025       ignore (typeof ~metasenv ~subst context ty);
1026       let ty' = typeof ~metasenv ~subst context bo in
1027        if not (R.are_convertible ~subst context ty' ty) then
1028         raise (AssertFailure (lazy (Printf.sprintf (
1029          "the type of the definiens for %d in the substitution is not "^^
1030          "convertible with the declared one.\n"^^
1031          "inferred type:\n%s\nexpected type:\n%s")
1032          i
1033          (PP.ppterm ~subst ~metasenv ~context ty')
1034          (PP.ppterm ~subst ~metasenv ~context ty))));
1035       subst @ [conj]
1036     ) [] subst)
1037 ;;
1038
1039 let typecheck_obj (uri,height,metasenv,subst,kind) =
1040  typecheck_metasenv metasenv;
1041  typecheck_subst ~metasenv subst;
1042  match kind with
1043    | C.Constant (_,_,Some te,ty,_) ->
1044       let _ = typeof ~subst ~metasenv [] ty in
1045       let ty_te = typeof ~subst ~metasenv [] te in
1046       if not (R.are_convertible ~subst [] ty_te ty) then
1047        raise (TypeCheckerFailure (lazy (Printf.sprintf (
1048         "the type of the body is not convertible with the declared one.\n"^^
1049         "inferred type:\n%s\nexpected type:\n%s")
1050         (PP.ppterm ~subst ~metasenv ~context:[] ty_te)
1051         (PP.ppterm ~subst ~metasenv ~context:[] ty))))
1052    | C.Constant (_,_,None,ty,_) -> ignore (typeof ~subst ~metasenv [] ty)
1053    | C.Inductive (is_ind, leftno, tyl, _) ->
1054        check_mutual_inductive_defs uri ~metasenv ~subst is_ind leftno tyl
1055    | C.Fixpoint (inductive,fl,_) ->
1056       let types, kl =
1057         List.fold_left
1058          (fun (types,kl) (_,name,k,ty,_) ->
1059            let _ = typeof ~subst ~metasenv [] ty in
1060             ((name,C.Decl ty)::types, k::kl)
1061          ) ([],[]) fl
1062       in
1063       let len = List.length types in
1064       let dfl, kl =
1065         List.split (List.map2
1066           (fun (_,_,_,_,bo) rno ->
1067              let dbo = debruijn uri len [] bo in
1068              dbo, Evil rno)
1069           fl kl)
1070       in
1071       List.iter2 (fun (_,name,x,ty,_) bo ->
1072        let ty_bo = typeof ~subst ~metasenv types bo in
1073        if not (R.are_convertible ~subst types ty_bo ty)
1074        then raise (TypeCheckerFailure (lazy ("(Co)Fix: ill-typed bodies")))
1075        else
1076         if inductive then begin
1077           let m, context = eat_lambdas ~subst ~metasenv types (x + 1) bo in
1078           let r_uri, r_len =
1079             let he =
1080              match List.hd context with _,C.Decl t -> t | _ -> assert false
1081             in
1082             match R.whd ~subst (List.tl context) he with
1083             | C.Const (Ref.Ref (_,uri,Ref.Ind _) as ref)
1084             | C.Appl (C.Const (Ref.Ref (_,uri,Ref.Ind _) as ref) :: _) ->
1085                 let _,_,itl,_,_ = E.get_checked_indtys ref in
1086                   uri, List.length itl
1087             | _ -> assert false
1088           in
1089           (* guarded by destructors conditions D{f,k,x,M} *)
1090           let rec enum_from k =
1091             function [] -> [] | v::tl -> (k,v)::enum_from (k+1) tl
1092           in
1093           guarded_by_destructors r_uri r_len
1094            ~subst ~metasenv context (enum_from (x+2) kl) m
1095         end else
1096          match returns_a_coinductive ~subst [] ty with
1097           | None ->
1098              raise (TypeCheckerFailure
1099                (lazy "CoFix: does not return a coinductive type"))
1100           | Some (r_uri, r_len) ->
1101              (* guarded by constructors conditions C{f,M} *)
1102              if not
1103              (guarded_by_constructors ~subst ~metasenv types bo r_uri r_len len)
1104              then
1105                raise (TypeCheckerFailure
1106                 (lazy "CoFix: not guarded by constructors"))
1107         ) fl dfl
1108 ;;
1109
1110 (* trust *)
1111
1112 let trust = ref  (fun _ -> false);;
1113 let set_trust f = trust := f
1114 let trust_obj obj = !trust obj
1115
1116
1117 (* web interface stuff *)
1118
1119 let logger =
1120  ref (function (`Start_type_checking _|`Type_checking_completed _|`Type_checking_interrupted _|`Type_checking_failed _|`Trust_obj _) -> ())
1121 ;;
1122
1123 let set_logger f = logger := f;;
1124
1125 let typecheck_obj obj =
1126  let u,_,_,_,_ = obj in
1127  try
1128   !logger (`Start_type_checking u);
1129   typecheck_obj obj;
1130   !logger (`Type_checking_completed u)
1131  with
1132     Sys.Break as e ->
1133      !logger (`Type_checking_interrupted u);
1134      raise e
1135   | e ->
1136      !logger (`Type_checking_failed u);
1137      raise e
1138 ;;
1139
1140 E.set_typecheck_obj
1141  (fun obj ->
1142    if trust_obj obj then
1143     let u,_,_,_,_ = obj in
1144      !logger (`Trust_obj u)
1145    else
1146     typecheck_obj obj)
1147 ;;
1148
1149 (* EOF *)