helm/software/components/ng_kernel/oCic2NCic.ml

   1 module Ref = NReference
   2
   3 type ctx =
   4   | Ce of (NCic.hypothesis * NCic.obj list) Lazy.t
   5   | Fix of (Ref.reference * string * NCic.term) Lazy.t
   6
   7 let strictify =
   8  function
   9     Ce l -> `Ce (Lazy.force l)
  10   | Fix l -> `Fix (Lazy.force l)
  11 ;;
  12
  13 (***** A function to restrict the context of a term getting rid of unsed
  14        variables *******)
  15
  16 let restrict octx ctx ot =
  17  let odummy = Cic.Implicit None in
  18  let dummy = NCic.Meta (~-1,(0,NCic.Irl 0)) in
  19  let rec aux m acc ot t =
  20   function
  21      [],[] -> (ot,t),acc
  22    | ohe::otl as octx,he::tl ->
  23       if CicTypeChecker.does_not_occur octx 0 1 ot then
  24        aux (m+1) acc (CicSubstitution.subst odummy ot)
  25         (NCicSubstitution.subst dummy t) (otl,tl)
  26       else
  27        (match ohe,strictify he with
  28            None,_ -> assert false
  29          | Some (name,Cic.Decl oty),`Ce ((name', NCic.Decl ty),objs) ->
  30             aux (m+1) ((m+1,objs,None)::acc) (Cic.Lambda (name,oty,ot))
  31              (NCic.Lambda (name',ty,t)) (otl,tl)
  32          | Some (name,Cic.Decl oty),`Fix (ref,name',ty) ->
  33             aux (m+1) ((m+1,[],Some ref)::acc) (Cic.Lambda (name,oty,ot))
  34              (NCic.Lambda (name',ty,t)) (otl,tl)
  35          | Some (name,Cic.Def (obo,oty)),`Ce ((name', NCic.Def (bo,ty)),objs) ->
  36             aux (m+1) ((m+1,objs,None)::acc) (Cic.LetIn (name,obo,oty,ot))
  37              (NCic.LetIn (name',bo,ty,t)) (otl,tl)
  38          | _,_ -> assert false)
  39    | _,_ -> assert false in
  40  let rec split_lambdas_and_letins octx ctx infos (ote,te) =
  41   match infos, ote, te with
  42      ([], _, _) -> octx,ctx,ote
  43    | ((_,objs,None)::tl, Cic.Lambda(name,oso,ota), NCic.Lambda(name',so,ta)) ->
  44        split_lambdas_and_letins ((Some(name,(Cic.Decl oso)))::octx)
  45         (Ce (lazy ((name',NCic.Decl so),objs))::ctx) tl (ota,ta)
  46    | ((_,objs,Some r)::tl,Cic.Lambda(name,oso,ota),NCic.Lambda(name',so,ta)) ->
  47        split_lambdas_and_letins ((Some(name,(Cic.Decl oso)))::octx)
  48         (Fix (lazy (r,name',so))::ctx) tl (ota,ta)
  49    | ((_,objs,None)::tl,Cic.LetIn(name,obo,oty,ota),NCic.LetIn(nam',bo,ty,ta))->
  50        split_lambdas_and_letins ((Some (name,(Cic.Def (obo,oty))))::octx)
  51         (Ce (lazy ((nam',NCic.Def (bo,ty)),objs))::ctx) tl (ota,ta)
  52    | (_, _, _) -> assert false
  53  in
  54   let long_t,infos = aux 0 [] ot dummy (octx,ctx) in
  55   let clean_octx,clean_ctx,clean_ot= split_lambdas_and_letins [] [] infos long_t
  56   in
  57 (*prerr_endline ("RESTRICT PRIMA: " ^ CicPp.pp ot (List.map (function None -> None | Some (name,_) -> Some name) octx));
  58 prerr_endline ("RESTRICT DOPO: " ^ CicPp.pp clean_ot (List.map (function None -> None | Some (name,_) -> Some name) clean_octx));
  59 *)
  60    clean_octx,clean_ctx,clean_ot, List.map (fun (rel,_,_) -> rel) infos
  61 ;;
  62
  63
  64 (**** The translation itself ****)
  65
  66 let cn_to_s = function
  67   | Cic.Anonymous -> "_"
  68   | Cic.Name s -> s
  69 ;;
  70
  71 let splat mk_pi ctx t =
  72   List.fold_left
  73     (fun (t,l) c ->
  74       match strictify c with
  75       | `Ce ((name, NCic.Def (bo,ty)),l') -> NCic.LetIn (name, ty, bo, t),l@l'
  76       | `Ce ((name, NCic.Decl ty),l') when mk_pi -> NCic.Prod (name, ty, t),l@l'
  77       | `Ce ((name, NCic.Decl ty),l') -> NCic.Lambda (name, ty, t),l@l'
  78       | `Fix (_,name,ty) when mk_pi -> NCic.Prod (name, ty, t),l
  79       | `Fix (_,name,ty) -> NCic.Lambda (name,ty,t),l)
  80     (t,[]) ctx
  81 ;;
  82
  83 let context_tassonomy ctx =
  84     let rec split inner acc acc1 = function
  85       | Ce _ :: tl when inner -> split inner (acc+1) (acc1+1) tl
  86       | Fix _ ::tl -> split false acc (acc1+1) tl
  87       | _ as l ->
  88         let only_decl () =
  89          List.filter
  90           (function
  91               Ce _ as ce ->
  92                (match strictify ce with
  93                    `Ce ((_, NCic.Decl _),_) -> true
  94                  | _ -> false)
  95             | Fix _ -> true) l
  96         in
  97          acc, List.length l, lazy (List.length (only_decl ())), acc1
  98     in
  99       split true 0 1 ctx
 100 ;;
 101
 102 let splat_args_for_rel ctx t ?rels n_fix =
 103   let rels =
 104    match rels with
 105       Some rels -> rels
 106     | None ->
 107        let rec mk_irl = function 0 -> [] | n -> n::mk_irl (n - 1) in
 108         mk_irl (List.length ctx)
 109   in
 110   let bound, free, _, primo_ce_dopo_fix = context_tassonomy ctx in
 111   if free = 0 then t
 112   else
 113     let rec aux = function
 114       | n,_ when n = bound + n_fix -> []
 115       | n,he::tl ->
 116          (match strictify (List.nth ctx (n-1)) with
 117           | `Fix (refe, _, _) when n < primo_ce_dopo_fix ->
 118              NCic.Const refe :: aux (n-1,tl)
 119           | `Fix _ | `Ce ((_, NCic.Decl _),_) ->
 120               NCic.Rel (he - n_fix)::aux(n-1,tl)
 121           | `Ce ((_, NCic.Def _),_) -> aux (n-1,tl))
 122       | _,_ -> assert false
 123     in
 124    let args = aux (List.length ctx,rels) in
 125     match args with
 126        [] -> t
 127      | _::_ -> NCic.Appl (t::args)
 128 ;;
 129
 130 let splat_args ctx t n_fix rels =
 131   let bound, free, _, primo_ce_dopo_fix = context_tassonomy ctx in
 132   if ctx = [] then t
 133   else
 134    let rec aux = function
 135      | 0,[] -> []
 136      | n,he::tl ->
 137         (match strictify (List.nth ctx (n-1)) with
 138          | `Ce ((_, NCic.Decl _),_) when n <= bound ->
 139              NCic.Rel he:: aux (n-1,tl)
 140          | `Fix (refe, _, _) when n < primo_ce_dopo_fix ->
 141             splat_args_for_rel ctx (NCic.Const refe) ~rels n_fix :: aux (n-1,tl)
 142          | `Fix _ | `Ce((_, NCic.Decl _),_)-> NCic.Rel (he - n_fix)::aux(n-1,tl)
 143          | `Ce ((_, NCic.Def _),_) -> aux (n - 1,tl)
 144         )
 145      | _,_ -> assert false
 146    in
 147    let args = aux  (List.length ctx,rels) in
 148     match args with
 149        [] -> t
 150      | _::_ -> NCic.Appl (t::args)
 151 ;;
 152
 153 exception Nothing_to_do;;
 154
 155 let fix_outty curi tyno t context outty =
 156  let leftno,rightno =
 157   match fst (CicEnvironment.get_obj CicUniv.oblivion_ugraph curi) with
 158      Cic.InductiveDefinition (tyl,_,leftno,_) ->
 159       let _,_,arity,_ = List.nth tyl tyno in
 160       let rec count_prods leftno context arity =
 161        match leftno, CicReduction.whd context arity with
 162           0, Cic.Sort _ -> 0
 163         | 0, Cic.Prod (name,so,ty) ->
 164            1 + count_prods 0 (Some (name, Cic.Decl so)::context) ty
 165         | n, Cic.Prod (name,so,ty) ->
 166            count_prods (leftno - 1) (Some (name, Cic.Decl so)::context) ty
 167         | _,_ -> assert false
 168       in
 169 (*prerr_endline (UriManager.string_of_uri curi);
 170 prerr_endline ("LEFTNO: " ^ string_of_int leftno ^ "  " ^ CicPp.ppterm arity);*)
 171        leftno, count_prods leftno [] arity
 172    | _ -> assert false in
 173  let ens,args =
 174   let tty,_= CicTypeChecker.type_of_aux' [] context t CicUniv.oblivion_ugraph in
 175   match CicReduction.whd context tty with
 176      Cic.MutInd (_,_,ens) -> ens,[]
 177    | Cic.Appl (Cic.MutInd (_,_,ens)::args) ->
 178       ens,fst (HExtlib.split_nth leftno args)
 179    | _ -> assert false
 180  in
 181   let rec aux n irl context outsort =
 182    match n, CicReduction.whd context outsort with
 183       0, Cic.Prod _ -> raise Nothing_to_do
 184     | 0, _ ->
 185        let irl = List.rev irl in
 186        let ty = CicSubstitution.lift rightno (Cic.MutInd (curi,tyno,ens)) in
 187        let ty =
 188         if args = [] && irl = [] then ty
 189         else
 190          Cic.Appl (ty::(List.map (CicSubstitution.lift rightno) args)@irl) in
 191        let he = CicSubstitution.lift (rightno + 1) outty in
 192        let t =
 193         if irl = [] then he
 194         else Cic.Appl (he::List.map (CicSubstitution.lift 1) irl)
 195        in
 196         Cic.Lambda (Cic.Anonymous, ty, t)
 197     | n, Cic.Prod (name,so,ty) ->
 198        let ty' =
 199         aux (n - 1) (Cic.Rel n::irl) (Some (name, Cic.Decl so)::context) ty
 200        in
 201         Cic.Lambda (name,so,ty')
 202     | _,_ -> assert false
 203   in
 204 (*prerr_endline ("RIGHTNO = " ^ string_of_int rightno ^ " OUTTY = " ^ CicPp.ppterm outty);*)
 205    let outsort =
 206     fst (CicTypeChecker.type_of_aux' [] context outty CicUniv.oblivion_ugraph)
 207    in
 208     try aux rightno [] context outsort
 209     with Nothing_to_do -> outty
 210 (*prerr_endline (CicPp.ppterm outty ^ " <==> " ^ CicPp.ppterm outty');*)
 211 ;;
 212
 213 let fix_outtype t =
 214  let module C = Cic in
 215  let rec aux context =
 216   function
 217      C.Rel _ as t -> t
 218    | C.Var (uri,exp_named_subst) ->
 219       let exp_named_subst' =
 220        List.map (function i,t -> i, (aux context t)) exp_named_subst in
 221         C.Var (uri,exp_named_subst')
 222    | C.Implicit _
 223    | C.Meta _ -> assert false
 224    | C.Sort _ as t -> t
 225    | C.Cast (v,t) -> C.Cast (aux context v, aux context t)
 226    | C.Prod (n,s,t) ->
 227         C.Prod (n, aux context s, aux ((Some (n, C.Decl s))::context) t)
 228    | C.Lambda (n,s,t) ->
 229        C.Lambda (n, aux context s, aux ((Some (n, C.Decl s))::context) t)
 230    | C.LetIn (n,s,ty,t) ->
 231       C.LetIn
 232        (n, aux context s, aux context ty,
 233         aux ((Some (n, C.Def(s,ty)))::context) t)
 234    | C.Appl l -> C.Appl (List.map (aux context) l)
 235    | C.Const (uri,exp_named_subst) ->
 236       let exp_named_subst' =
 237        List.map (function i,t -> i, (aux context t)) exp_named_subst
 238       in
 239        C.Const (uri,exp_named_subst')
 240    | C.MutInd (uri,tyno,exp_named_subst) ->
 241       let exp_named_subst' =
 242        List.map (function i,t -> i, (aux context t)) exp_named_subst
 243       in
 244        C.MutInd (uri, tyno, exp_named_subst')
 245    | C.MutConstruct (uri,tyno,consno,exp_named_subst) ->
 246       let exp_named_subst' =
 247        List.map (function i,t -> i, (aux context t)) exp_named_subst
 248       in
 249        C.MutConstruct (uri, tyno, consno, exp_named_subst')
 250    | C.MutCase (uri, tyno, outty, term, patterns) ->
 251       let outty = fix_outty uri tyno term context outty in
 252        C.MutCase (uri, tyno, aux context outty,
 253         aux context term, List.map (aux context) patterns)
 254    | C.Fix (funno, funs) ->
 255       let tys,_ =
 256         List.fold_left
 257           (fun (types,len) (n,_,ty,_) ->
 258             ((Some (C.Name n,(C.Decl (CicSubstitution.lift len ty)))))::types,
 259               len+1
 260           ) ([],0) funs
 261       in
 262        C.Fix (funno,
 263         List.map
 264          (fun (name, indidx, ty, bo) ->
 265            (name, indidx, aux context ty, aux (tys@context) bo)
 266          ) funs
 267       )
 268    | C.CoFix (funno, funs) ->
 269       let tys,_ =
 270         List.fold_left
 271           (fun (types,len) (n,ty,_) ->
 272             ((Some (C.Name n,(C.Decl (CicSubstitution.lift len ty)))))::types,
 273               len+1
 274           ) ([],0) funs
 275       in
 276        C.CoFix (funno,
 277         List.map
 278          (fun (name, ty, bo) ->
 279            (name, aux context ty, aux (tys@context) bo)
 280          ) funs
 281        )
 282  in
 283   aux [] t
 284 ;;
 285
 286 let get_fresh,reset_seed =
 287  let seed = ref 0 in
 288   (function () ->
 289    incr seed;
 290    string_of_int !seed),
 291   (function () -> seed := 0)
 292 ;;
 293
 294 exception NotSimilar
 295 let alpha t1 t2 ref ref' =
 296   let rec aux t1 t2 = match t1,t2 with
 297     | NCic.Rel n, NCic.Rel m when n=m -> ()
 298     | NCic.Appl l1, NCic.Appl l2 -> List.iter2 aux l1 l2
 299     | NCic.Lambda (_,s1,t1), NCic.Lambda (_,s2,t2)
 300     | NCic.Prod (_,s1,t1), NCic.Prod (_,s2,t2) -> aux s1 s2; aux t1 t2
 301     | NCic.LetIn (_,s1,ty1,t1), NCic.LetIn (_,s2,ty2,t2) ->
 302          aux s1 s2; aux ty1 ty2; aux t1 t2
 303     | NCic.Const (NReference.Ref (_,uu1,xp1)),
 304       NCic.Const (NReference.Ref (_,uu2,xp2))  when
 305          let NReference.Ref (_,u1,_) = ref in
 306          let NReference.Ref (_,u2,_) = ref' in
 307            NUri.eq uu1 u1 && NUri.eq uu2 u2 && xp1 = xp2
 308       -> ()
 309     | NCic.Const r1, NCic.Const r2 when NReference.eq r1 r2 -> ()
 310     | NCic.Meta _,NCic.Meta _ -> ()
 311     | NCic.Implicit _,NCic.Implicit _ -> ()
 312     | NCic.Sort x,NCic.Sort y when x=y -> ()
 313     | NCic.Match (_,t1,t11,tl1), NCic.Match (_,t2,t22,tl2) ->
 314          aux t1 t2;aux t11 t22;List.iter2 aux tl1 tl2
 315     | _-> raise NotSimilar
 316   in
 317   try aux t1 t2; true  with NotSimilar -> false
 318 ;;
 319
 320 exception Found of NReference.reference;;
 321 let cache = Hashtbl.create 313;;
 322 let same_obj ref ref' =
 323  function
 324   | (_,_,_,_,NCic.Fixpoint (_,l1,_)), (_,_,_,_,NCic.Fixpoint (_,l2,_))
 325     when List.for_all2 (fun (_,_,_,ty1,bo1) (_,_,_,ty2,bo2) ->
 326        alpha ty1 ty2 ref ref' && alpha bo1 bo2 ref ref') l1 l2 ->
 327      true
 328   | _ -> false
 329 ;;
 330 let find_in_cache name obj ref =
 331  try
 332   List.iter
 333    (function (ref',obj') ->
 334      let recno, fixno =
 335       match ref with
 336          NReference.Ref (_,_,NReference.Fix (fixno,recno)) -> recno,fixno
 337        | _ -> assert false in
 338      let recno',fixno' =
 339       match ref' with
 340          NReference.Ref (_,_,NReference.Fix (fixno',recno)) -> recno,fixno'
 341        | _ -> assert false in
 342      if recno = recno' && fixno = fixno' && same_obj ref ref' (obj,obj') then (
 343 (*
 344 prerr_endline ("!!!!!!!!!!! CACHE HIT !!!!!!!!!!\n" ^
 345 NReference.string_of_reference ref ^ "\n" ^
 346 NReference.string_of_reference ref' ^ "\n");
 347  *)
 348        raise (Found ref'));
 349 (*
 350 prerr_endline ("CACHE SAME NAME: " ^ NReference.string_of_reference ref ^ " <==> " ^ NReference.string_of_reference ref');
 351  *)
 352   ) (Hashtbl.find_all cache name);
 353 (*   prerr_endline "<<< CACHE MISS >>>";   *)
 354   begin
 355     match obj, ref with
 356     | (_,_,_,_,NCic.Fixpoint (true,fl,_)) , NReference.Ref (x,y,NReference.Fix _) ->
 357        ignore(List.fold_left (fun i (_,name,rno,_,_) ->
 358          let ref = NReference.mk_fix i rno ref in
 359          Hashtbl.add cache name (ref,obj);
 360          i+1
 361        ) 0 fl)
 362     | _ -> assert false
 363   end;
 364   None
 365  with Found ref -> Some ref
 366 ;;
 367
 368 (* we are lambda-lifting also variables that do not occur *)
 369 (* ctx does not distinguish successive blocks of cofix, since there may be no
 370  *   lambda separating them *)
 371 let convert_term uri t =
 372   (* k=true if we are converting a term to be pushed in a ctx or if we are
 373             converting the type of a fix;
 374      k=false if we are converting a term to be put in the body of a fix;
 375      in the latter case, we must permute Rels since the Fix abstraction will
 376      preceed its lefts parameters; in the former case, there is nothing to
 377      permute *)
 378   let rec aux k octx (ctx : ctx list) n_fix uri = function
 379     | Cic.CoFix _ as cofix ->
 380         let octx,ctx,fix,rels = restrict octx ctx cofix in
 381         let cofixno,fl =
 382          match fix with Cic.CoFix (cofixno,fl)->cofixno,fl | _-> assert false in
 383         let buri =
 384           UriManager.uri_of_string
 385            (UriManager.buri_of_uri uri^"/"^
 386             UriManager.name_of_uri uri ^ "___" ^ get_fresh () ^ ".con")
 387         in
 388         let bctx, fixpoints_tys, tys, _ =
 389           List.fold_right
 390             (fun (name,ty,_) (bctx, fixpoints, tys, idx) ->
 391               let ty, fixpoints_ty = aux true octx ctx n_fix uri ty in
 392               let r = Ref.reference_of_ouri buri(Ref.CoFix idx) in
 393               bctx @ [Fix (lazy (r,name,ty))],
 394                fixpoints_ty @ fixpoints,ty::tys,idx-1)
 395             fl ([], [], [], List.length fl-1)
 396         in
 397         let bctx = bctx @ ctx in
 398         let n_fl = List.length fl in
 399         let boctx,_ =
 400          List.fold_left
 401           (fun (types,len) (n,ty,_) ->
 402              (Some (Cic.Name n,(Cic.Decl (CicSubstitution.lift len ty)))::types,
 403               len+1)) (octx,0) fl
 404         in
 405         let fl, fixpoints =
 406           List.fold_right2
 407             (fun (name,_,bo) ty  (l,fixpoints) ->
 408                let bo, fixpoints_bo = aux false boctx bctx n_fl buri bo in
 409                let splty,fixpoints_splty = splat true ctx ty in
 410                let splbo,fixpoints_splbo = splat false ctx bo in
 411                (([],name,~-1,splty,splbo)::l),
 412                fixpoints_bo @ fixpoints_splty @ fixpoints_splbo @ fixpoints)
 413             fl tys ([],fixpoints_tys)
 414         in
 415         let obj =
 416           NUri.nuri_of_ouri buri,0,[],[],
 417             NCic.Fixpoint (false, fl, (`Generated, `Definition))
 418         in
 419         splat_args ctx
 420          (NCic.Const (Ref.reference_of_ouri buri (Ref.CoFix cofixno)))
 421          n_fix rels,
 422         fixpoints @ [obj]
 423     | Cic.Fix _ as fix ->
 424         let octx,ctx,fix,rels = restrict octx ctx fix in
 425         let fixno,fl =
 426          match fix with Cic.Fix (fixno,fl) -> fixno,fl | _ -> assert false in
 427         let buri =
 428           UriManager.uri_of_string
 429            (UriManager.buri_of_uri uri^"/"^
 430             UriManager.name_of_uri uri ^ "___" ^ get_fresh () ^ ".con")
 431         in
 432         let bad_bctx, fixpoints_tys, tys, _ =
 433           List.fold_right
 434             (fun (name,recno,ty,_) (bctx, fixpoints, tys, idx) ->
 435               let ty, fixpoints_ty = aux true octx ctx n_fix uri ty in
 436               let r =  (* recno is dummy here, must be lifted by the ctx len *)
 437                 Ref.reference_of_ouri buri (Ref.Fix (idx,recno))
 438               in
 439               bctx @ [Fix (lazy (r,name,ty))],
 440                fixpoints_ty@fixpoints,ty::tys,idx-1)
 441             fl ([], [], [], List.length fl-1)
 442         in
 443         let _, _, free_decls, _ = context_tassonomy (bad_bctx @ ctx) in
 444         let free_decls = Lazy.force free_decls in
 445         let bctx =
 446           List.map (function ce -> match strictify ce with
 447             | `Fix (Ref.Ref (_,_,Ref.Fix (idx, recno)),name, ty) ->
 448               Fix (lazy (Ref.reference_of_ouri buri
 449                     (Ref.Fix (idx,recno+free_decls)),name,ty))
 450             | _ -> assert false) bad_bctx @ ctx
 451         in
 452         let n_fl = List.length fl in
 453         let boctx,_ =
 454          List.fold_left
 455           (fun (types,len) (n,_,ty,_) ->
 456              (Some (Cic.Name n,(Cic.Decl (CicSubstitution.lift len ty)))::types,
 457               len+1)) (octx,0) fl
 458         in
 459         let rno_fixno = ref 0 in
 460         let fl, fixpoints,_ =
 461           List.fold_right2
 462             (fun (name,rno,_,bo) ty (l,fixpoints,idx) ->
 463                let bo, fixpoints_bo = aux false boctx bctx n_fl buri bo in
 464                let splty,fixpoints_splty = splat true ctx ty in
 465                let splbo,fixpoints_splbo = splat false ctx bo in
 466                let rno = rno + free_decls in
 467                if idx = fixno then rno_fixno := rno;
 468                (([],name,rno,splty,splbo)::l),
 469                fixpoints_bo@fixpoints_splty@fixpoints_splbo@fixpoints,idx+1)
 470             fl tys ([],fixpoints_tys,0)
 471         in
 472         let obj =
 473           NUri.nuri_of_ouri buri,max_int,[],[],
 474             NCic.Fixpoint (true, fl, (`Generated, `Definition)) in
 475         let r = Ref.reference_of_ouri buri (Ref.Fix (fixno,!rno_fixno)) in
 476         let obj,r =
 477          let _,name,_,_,_ = List.nth fl fixno in
 478          match find_in_cache name obj r with
 479             Some r' -> [],r'
 480           | None -> [obj],r
 481         in
 482         splat_args ctx (NCic.Const r) n_fix rels, fixpoints @ obj
 483     | Cic.Rel n ->
 484         let bound, _, _, primo_ce_dopo_fix = context_tassonomy ctx in
 485         (match List.nth ctx (n-1) with
 486         | Fix l when n < primo_ce_dopo_fix ->
 487            let r,_,_ = Lazy.force l in
 488             splat_args_for_rel ctx (NCic.Const r) n_fix, []
 489         | Ce _ when n <= bound -> NCic.Rel n, []
 490         | Fix _ when n <= bound -> assert false
 491         | Fix _ | Ce _ when k = true -> NCic.Rel n, []
 492         | Fix _ | Ce _ -> NCic.Rel (n-n_fix), [])
 493     | Cic.Lambda (name, (s as old_s), t) ->
 494         let s, fixpoints_s = aux k octx ctx n_fix uri s in
 495         let s'_and_fixpoints_s' = lazy (aux true octx ctx n_fix uri old_s) in
 496         let ctx =
 497          Ce (lazy
 498           let s',fixpoints_s' = Lazy.force s'_and_fixpoints_s' in
 499            ((cn_to_s name, NCic.Decl s'),fixpoints_s'))::ctx in
 500         let octx = Some (name, Cic.Decl old_s) :: octx in
 501         let t, fixpoints_t = aux k octx ctx n_fix uri t in
 502         NCic.Lambda (cn_to_s name, s, t), fixpoints_s @ fixpoints_t
 503     | Cic.Prod (name, (s as old_s), t) ->
 504         let s, fixpoints_s = aux k octx ctx n_fix uri s in
 505         let s'_and_fixpoints_s' = lazy (aux true octx ctx n_fix uri old_s) in
 506         let ctx =
 507          Ce (lazy
 508           let s',fixpoints_s' = Lazy.force s'_and_fixpoints_s' in
 509            ((cn_to_s name, NCic.Decl s'),fixpoints_s'))::ctx in
 510         let octx = Some (name, Cic.Decl old_s) :: octx in
 511         let t, fixpoints_t = aux k octx ctx n_fix uri t in
 512         NCic.Prod (cn_to_s name, s, t), fixpoints_s @ fixpoints_t
 513     | Cic.LetIn (name, (te as old_te), (ty as old_ty), t) ->
 514         let te, fixpoints_s = aux k octx ctx n_fix uri te in
 515         let te_and_fixpoints_s' = lazy (aux true octx ctx n_fix uri old_te) in
 516         let ty, fixpoints_ty = aux k octx ctx n_fix uri ty in
 517         let ty_and_fixpoints_ty' = lazy (aux true octx ctx n_fix uri old_ty) in
 518         let ctx =
 519          Ce (lazy
 520           let te',fixpoints_s' = Lazy.force te_and_fixpoints_s' in
 521           let ty',fixpoints_ty' = Lazy.force ty_and_fixpoints_ty' in
 522           let fixpoints' = fixpoints_s' @ fixpoints_ty' in
 523            ((cn_to_s name, NCic.Def (te', ty')),fixpoints'))::ctx in
 524         let octx = Some (name, Cic.Def (old_te, old_ty)) :: octx in
 525         let t, fixpoints_t = aux k octx ctx n_fix uri t in
 526         NCic.LetIn (cn_to_s name, ty, te, t),
 527         fixpoints_s @ fixpoints_t @ fixpoints_ty
 528     | Cic.Cast (t,ty) ->
 529         let t, fixpoints_t = aux k octx ctx n_fix uri t in
 530         let ty, fixpoints_ty = aux k octx ctx n_fix uri ty in
 531         NCic.LetIn ("cast", ty, t, NCic.Rel 1), fixpoints_t @ fixpoints_ty
 532     | Cic.Sort Cic.Prop -> NCic.Sort NCic.Prop,[]
 533     | Cic.Sort Cic.CProp -> NCic.Sort NCic.CProp,[]
 534     | Cic.Sort (Cic.Type u) ->
 535           NCic.Sort (NCic.Type (CicUniv.get_rank u)),[]
 536     | Cic.Sort Cic.Set -> NCic.Sort (NCic.Type 0),[]
 537        (* calculate depth in the univ_graph*)
 538     | Cic.Appl l ->
 539         let l, fixpoints =
 540           List.fold_right
 541              (fun t (l,acc) ->
 542                let t, fixpoints = aux k octx ctx n_fix uri t in
 543                (t::l,fixpoints@acc))
 544              l ([],[])
 545         in
 546         (match l with
 547         | (NCic.Appl l1)::l2 -> NCic.Appl (l1@l2), fixpoints
 548         | _ -> NCic.Appl l, fixpoints)
 549     | Cic.Const (curi, ens) ->
 550        aux_ens k curi octx ctx n_fix uri ens
 551         (match fst(CicEnvironment.get_obj CicUniv.oblivion_ugraph curi) with
 552         | Cic.Constant (_,Some _,_,_,_) ->
 553                NCic.Const (Ref.reference_of_ouri curi Ref.Def)
 554         | Cic.Constant (_,None,_,_,_) ->
 555                NCic.Const (Ref.reference_of_ouri curi Ref.Decl)
 556         | _ -> assert false)
 557     | Cic.MutInd (curi, tyno, ens) ->
 558        aux_ens k curi octx ctx n_fix uri ens
 559         (NCic.Const (Ref.reference_of_ouri curi (Ref.Ind tyno)))
 560     | Cic.MutConstruct (curi, tyno, consno, ens) ->
 561        aux_ens k curi octx ctx n_fix uri ens
 562         (NCic.Const (Ref.reference_of_ouri curi (Ref.Con (tyno,consno))))
 563     | Cic.Var (curi, ens) ->
 564        (match fst (CicEnvironment.get_obj CicUniv.oblivion_ugraph curi) with
 565            Cic.Variable (_,Some bo,_,_,_) ->
 566             aux k octx ctx n_fix uri (CicSubstitution.subst_vars ens bo)
 567          | _ -> assert false)
 568     | Cic.MutCase (curi, tyno, outty, t, branches) ->
 569         let r = Ref.reference_of_ouri curi (Ref.Ind tyno) in
 570         let outty, fixpoints_outty = aux k octx ctx n_fix uri outty in
 571         let t, fixpoints_t = aux k octx ctx n_fix uri t in
 572         let branches, fixpoints =
 573           List.fold_right
 574              (fun t (l,acc) ->
 575                let t, fixpoints = aux k octx ctx n_fix uri t in
 576                (t::l,fixpoints@acc))
 577              branches ([],[])
 578         in
 579         NCic.Match (r,outty,t,branches), fixpoints_outty@fixpoints_t@fixpoints
 580     | Cic.Implicit _ | Cic.Meta _ -> assert false
 581   and aux_ens k curi octx ctx n_fix uri ens he =
 582    match ens with
 583       [] -> he,[]
 584     | _::_ ->
 585       let params =
 586        match fst (CicEnvironment.get_obj CicUniv.oblivion_ugraph curi) with
 587           Cic.Constant (_,_,_,params,_)
 588         | Cic.InductiveDefinition (_,params,_,_) -> params
 589         | Cic.Variable _
 590         | Cic.CurrentProof _ -> assert false
 591       in
 592       let ens,objs =
 593        List.fold_right
 594         (fun luri (l,objs) ->
 595           match fst (CicEnvironment.get_obj CicUniv.oblivion_ugraph luri) with
 596              Cic.Variable (_,Some _,_,_,_) -> l, objs
 597            | Cic.Variable (_,None,_,_,_) ->
 598               let t = List.assoc luri ens in
 599               let t,o = aux k octx ctx n_fix uri t in
 600                t::l, o@objs
 601            | _ -> assert false
 602         ) params ([],[])
 603       in
 604        match ens with
 605           [] -> he,objs
 606         | _::_ -> NCic.Appl (he::ens),objs
 607   in
 608    aux false [] [] 0 uri t
 609 ;;
 610
 611 let cook mode vars t =
 612  let t = fix_outtype t in
 613  let varsno = List.length vars in
 614  let t = CicSubstitution.lift varsno t in
 615  let rec aux n acc l =
 616   let subst =
 617    snd(List.fold_left (fun (i,res) uri -> i+1,(uri,Cic.Rel i)::res) (1,[]) acc)
 618   in
 619   match l with
 620      [] -> CicSubstitution.subst_vars subst t
 621    | uri::uris ->
 622     let bo,ty =
 623      match fst (CicEnvironment.get_obj CicUniv.oblivion_ugraph uri) with
 624         Cic.Variable (_,bo,ty,_,_) ->
 625          HExtlib.map_option fix_outtype bo, fix_outtype ty
 626       | _ -> assert false in
 627     let ty = CicSubstitution.subst_vars subst ty in
 628     let bo = HExtlib.map_option (CicSubstitution.subst_vars subst) bo in
 629     let id = Cic.Name (UriManager.name_of_uri uri) in
 630     let t = aux (n-1) (uri::acc) uris in
 631      match bo,ty,mode with
 632         None,ty,`Lambda -> Cic.Lambda (id,ty,t)
 633       | None,ty,`Pi -> Cic.Prod (id,ty,t)
 634       | Some bo,ty,_ -> Cic.LetIn (id,bo,ty,t)
 635  in
 636   aux varsno [] vars
 637 ;;
 638
 639 let convert_obj_aux uri = function
 640  | Cic.Constant (name, None, ty, vars, _) ->
 641      let ty = cook `Pi vars ty in
 642      let nty, fixpoints = convert_term uri ty in
 643      assert(fixpoints = []);
 644      NCic.Constant ([], name, None, nty, (`Provided,`Theorem,`Regular)),
 645      fixpoints
 646  | Cic.Constant (name, Some bo, ty, vars, _) ->
 647      let bo = cook `Lambda vars bo in
 648      let ty = cook `Pi vars ty in
 649      let nbo, fixpoints_bo = convert_term uri bo in
 650      let nty, fixpoints_ty = convert_term uri ty in
 651      assert(fixpoints_ty = []);
 652      NCic.Constant ([], name, Some nbo, nty, (`Provided,`Theorem,`Regular)),
 653      fixpoints_bo @ fixpoints_ty
 654  | Cic.InductiveDefinition (itl,vars,leftno,_) ->
 655      let ind = let _,x,_,_ = List.hd itl in x in
 656      let itl, fix_itl =
 657        List.fold_right
 658          (fun (name, _, ty, cl) (itl,acc) ->
 659             let ty = cook `Pi vars ty in
 660             let ty, fix_ty = convert_term uri ty in
 661             let cl, fix_cl =
 662               List.fold_right
 663                (fun (name, ty) (cl,acc) ->
 664                  let ty = cook `Pi vars ty in
 665                  let ty, fix_ty = convert_term uri ty in
 666                  ([], name, ty)::cl, acc @ fix_ty)
 667                cl ([],[])
 668             in
 669             ([], name, ty, cl)::itl, fix_ty @ fix_cl @ acc)
 670          itl ([],[])
 671      in
 672      NCic.Inductive(ind, leftno + List.length
 673        (List.filter (fun v ->
 674           match fst (CicEnvironment.get_obj CicUniv.oblivion_ugraph v) with
 675              Cic.Variable (_,Some _,_,_,_) -> false
 676            | Cic.Variable (_,None,_,_,_) -> true
 677            | _ -> assert false)
 678           vars)
 679        , itl, (`Provided, `Regular)),
 680      fix_itl
 681  | Cic.Variable _
 682  | Cic.CurrentProof _ -> assert false
 683 ;;
 684
 685 let convert_obj uri obj =
 686   reset_seed ();
 687   let o, fixpoints = convert_obj_aux uri obj in
 688   let obj = NUri.nuri_of_ouri uri,max_int, [], [], o in
 689   fixpoints @ [obj]
 690 ;;