helm/software/components/ng_paramodulation/foUtils.ml

   1 (*
   2     ||M||  This file is part of HELM, an Hypertextual, Electronic
   3     ||A||  Library of Mathematics, developed at the Computer Science
   4     ||T||  Department, University of Bologna, Italy.
   5     ||I||
   6     ||T||  HELM is free software; you can redistribute it and/or
   7     ||A||  modify it under the terms of the GNU General Public License
   8     \   /  version 2 or (at your option) any later version.
   9      \ /   This software is distributed as is, NO WARRANTY.
  10       V_______________________________________________________________ *)
  11
  12 (* $Id: terms.ml 9836 2009-06-05 15:33:35Z denes $ *)
  13
  14 let rec lexicograph f l1 l2 =
  15   match l1, l2 with
  16   | [], [] -> 0
  17   | x::xs, y::ys ->
  18      let c = f x y in
  19      if c <> 0 then c else lexicograph f xs ys
  20   | [],_ -> ~-1
  21   | _,[] -> 1
  22 ;;
  23
  24 module Utils (B : Terms.Blob) = struct
  25   module Subst = FoSubst.Subst(B) ;;
  26   module Order = Orderings.Orderings(B) ;;
  27
  28   let rec eq_foterm x y =
  29     x == y ||
  30     match x, y with
  31     | Terms.Leaf t1, Terms.Leaf t2 -> B.eq t1 t2
  32     | Terms.Var i, Terms.Var j -> i = j
  33     | Terms.Node l1, Terms.Node l2 -> List.for_all2 eq_foterm l1 l2
  34     | _ -> false
  35   ;;
  36
  37
  38   let rec compare_foterm x y =
  39     match x, y with
  40     | Terms.Leaf t1, Terms.Leaf t2 -> B.compare t1 t2
  41     | Terms.Var i, Terms.Var j -> i - j
  42     | Terms.Node l1, Terms.Node l2 -> lexicograph compare_foterm l1 l2
  43     | Terms.Leaf _, ( Terms.Node _ | Terms.Var _ ) -> ~-1
  44     | Terms.Node _, Terms.Leaf _ -> 1
  45     | Terms.Node _, Terms.Var _ -> ~-1
  46     | Terms.Var _, _ ->  1
  47   ;;
  48
  49   let eq_literal l1 l2 =
  50     match l1, l2 with
  51     | Terms.Predicate p1, Terms.Predicate p2 -> eq_foterm p1 p2
  52     | Terms.Equation (l1,r1,ty1,o1), Terms.Equation (l2,r2,ty2,o2) ->
  53         o1 = o2 && eq_foterm l1 l2 && eq_foterm r1 r2 && eq_foterm ty1 ty2
  54     | _ -> false
  55   ;;
  56
  57   let compare_literal l1 l2 =
  58     match l1, l2 with
  59     | Terms.Predicate p1, Terms.Predicate p2 -> compare_foterm p1 p2
  60     | Terms.Equation (l1,r1,ty1,o1), Terms.Equation (l2,r2,ty2,o2) ->
  61         let c = Pervasives.compare o1 o2 in
  62         if c <> 0 then c else
  63           let c = compare_foterm l1 l2 in
  64           if c <> 0 then c else
  65             let c = compare_foterm r1 r2 in
  66             if c <> 0 then c else
  67               compare_foterm ty1 ty2
  68     | Terms.Predicate _, Terms.Equation _ -> ~-1
  69     | Terms.Equation _, Terms.Predicate _ -> 1
  70   ;;
  71
  72   let eq_unit_clause (id1,_,_,_) (id2,_,_,_) = id1 = id2
  73   let compare_unit_clause (id1,_,_,_) (id2,_,_,_) = Pervasives.compare id1 id2
  74
  75   let relocate maxvar varlist =
  76     List.fold_right
  77       (fun i (maxvar, varlist, s) ->
  78          maxvar+1, maxvar::varlist, Subst.build_subst i (Terms.Var maxvar) s)
  79       varlist (maxvar+1, [], Subst.id_subst)
  80   ;;
  81
  82   let fresh_unit_clause maxvar (id, lit, varlist, proof) =
  83     let maxvar, varlist, subst = relocate maxvar varlist in
  84     let lit =
  85       match lit with
  86       | Terms.Equation (l,r,ty,o) ->
  87           let l = Subst.apply_subst subst l in
  88           let r = Subst.apply_subst subst r in
  89           let ty = Subst.apply_subst subst ty in
  90           Terms.Equation (l,r,ty,o)
  91       | Terms.Predicate p ->
  92           let p = Subst.apply_subst subst p in
  93           Terms.Predicate p
  94     in
  95     let proof =
  96       match proof with
  97       | Terms.Exact t -> Terms.Exact (Subst.apply_subst subst t)
  98       | Terms.Step (rule,c1,c2,dir,pos,s) ->
  99           Terms.Step(rule,c1,c2,dir,pos,Subst.concat subst s)
 100     in
 101      (id, lit, varlist, proof), maxvar
 102   ;;
 103
 104   (* may be moved inside the bag *)
 105   let mk_id =
 106     let id = ref 0 in
 107     fun () -> incr id; !id
 108   ;;
 109
 110   let mk_unit_clause maxvar ty proofterm =
 111     let varlist =
 112       let rec aux acc = function
 113         | Terms.Leaf _ -> acc
 114         | Terms.Var i -> if List.mem i acc then acc else i::acc
 115         | Terms.Node l -> List.fold_left aux acc l
 116       in
 117        aux (aux [] ty) proofterm
 118     in
 119     let lit =
 120       match ty with
 121       | Terms.Node [ Terms.Leaf eq ; ty; l; r ] when B.eq B.eqP eq ->
 122            let o = Order.compare_terms l r in
 123            Terms.Equation (l, r, ty, o)
 124       | t -> Terms.Predicate t
 125     in
 126     let proof = Terms.Exact proofterm in
 127     fresh_unit_clause maxvar (mk_id (), lit, varlist, proof)
 128   ;;
 129
 130   let add_to_bag bag  (_,lit,vl,proof) =
 131     let id = mk_id () in
 132     let clause = (id, lit, vl, proof) in
 133     let bag = Terms.M.add id clause bag in
 134     bag, clause
 135    ;;
 136
 137   let empty_bag = Terms.M.empty ;;
 138
 139 end