helm/software/components/ng_paramodulation/nCicBlob.ml

   1 (*
   2     ||M||  This file is part of HELM, an Hypertextual, Electronic
   3     ||A||  Library of Mathematics, developed at the Computer Science
   4     ||T||  Department, University of Bologna, Italy.
   5     ||I||
   6     ||T||  HELM is free software; you can redistribute it and/or
   7     ||A||  modify it under the terms of the GNU General Public License
   8     \   /  version 2 or (at your option) any later version.
   9      \ /   This software is distributed as is, NO WARRANTY.
  10       V_______________________________________________________________ *)
  11
  12 (* $Id: terms.mli 9822 2009-06-03 15:37:06Z tassi $ *)
  13
  14 module type NCicContext =
  15   sig
  16     val metasenv : NCic.metasenv
  17     val subst : NCic.substitution
  18     val context : NCic.context
  19   end
  20
  21 module NCicBlob(C : NCicContext) : Terms.Blob with type t = NCic.term = struct
  22
  23   type t = NCic.term
  24
  25   let eq x y = NCicReduction.alpha_eq C.metasenv C.subst C.context x y;;
  26
  27   let rec compare x y =
  28     match x,y with
  29     | NCic.Rel i, NCic.Rel j -> i-j
  30     | NCic.Meta (i,_), NCic.Meta (j,_) -> i-j
  31     | NCic.Const r1, NCic.Const r2 -> NReference.compare r1 r2
  32     | NCic.Appl l1, NCic.Appl l2 -> FoUtils.lexicograph compare l1 l2
  33     | NCic.Rel _, ( NCic.Meta _ | NCic.Const _ | NCic.Appl _ ) -> ~-1
  34     | ( NCic.Meta _ | NCic.Const _ | NCic.Appl _ ), NCic.Rel _ -> 1
  35     | NCic.Const _, ( NCic.Meta _ | NCic.Appl _ ) -> ~-1
  36     | ( NCic.Meta _ | NCic.Appl _ ), NCic.Const _ -> 1
  37     | NCic.Appl _, NCic.Meta _ -> ~-1
  38     | NCic.Meta _, NCic.Appl _ -> 1
  39     | _ -> assert false
  40   ;;
  41
  42   let compare x y =
  43     if NCicReduction.alpha_eq C.metasenv C.subst C.context x y then 0
  44     else compare x y
  45   ;;
  46
  47   let pp t =
  48     NCicPp.ppterm ~context:C.context ~metasenv:C.metasenv ~subst:C.subst t;;
  49
  50   let rec embed = function
  51     | NCic.Meta (i,_) -> Terms.Var i, [i]
  52     | NCic.Appl l ->
  53         let rec aux acc l = function
  54           |[] -> acc@l
  55           |hd::tl -> if List.mem hd l then aux acc l tl else aux (hd::acc) l tl
  56         in
  57         let res,vars = List.fold_left
  58           (fun (r,v) t -> let r1,v1 = embed t in (r1::r),aux [] v v1) ([],[]) l
  59         in (Terms.Node (List.rev res)), vars
  60     | t -> Terms.Leaf t, []
  61   ;;
  62
  63   let embed t = fst (embed t) ;;
  64
  65   let saturate t ty =
  66     let sty, _, args =
  67       NCicMetaSubst.saturate ~delta:max_int C.metasenv C.subst C.context
  68         ty 0
  69     in
  70     let proof =
  71       if args = [] then Terms.Leaf t
  72       else Terms.Node (Terms.Leaf t :: List.map embed args)
  73     in
  74     let sty = embed sty in
  75     proof, sty
  76   ;;
  77
  78   let eqP =
  79     let r =
  80       OCic2NCic.reference_of_oxuri
  81        (UriManager.uri_of_string
  82          "cic:/matita/logic/equality/eq.ind#xpointer(1/1)")
  83     in
  84     NCic.Const r
  85   ;;
  86
  87   let eq_ind =
  88     let r =
  89       OCic2NCic.reference_of_oxuri
  90        (UriManager.uri_of_string
  91          "cic:/matita/logic/equality/eq_ind.con")
  92     in
  93     NCic.Const r
  94   ;;
  95
  96   let eq_ind_r =
  97     let r =
  98       OCic2NCic.reference_of_oxuri
  99        (UriManager.uri_of_string
 100          "cic:/matita/logic/equality/eq_elim_r.con")
 101     in
 102     NCic.Const r
 103   ;;
 104
 105   let extract lift vl t =
 106     let rec pos i = function
 107       | [] -> raise Not_found
 108       | j :: tl when j <> i -> 1+ pos i tl
 109       | _ -> 1
 110     in
 111     let vl_len = List.length vl in
 112     let rec extract = function
 113       | Terms.Leaf x -> NCicSubstitution.lift (vl_len+lift) x
 114       | Terms.Var j ->
 115            (try NCic.Rel (pos j vl) with Not_found -> NCic.Implicit `Term)
 116       | Terms.Node l -> NCic.Appl (List.map extract l)
 117     in
 118       extract t
 119   ;;
 120
 121    let rec ppfot = function
 122      | Terms.Leaf _ -> "."
 123      | Terms.Var i -> "?" ^ string_of_int i
 124      | Terms.Node l -> "(" ^ String.concat " " (List.map ppfot l) ^ ")"
 125    ;;
 126
 127    let mk_predicate amount ft p vl =
 128     let rec aux t p =
 129       match p with
 130       | [] -> NCic.Rel 1
 131       | n::tl ->
 132           match t with
 133           | Terms.Leaf _
 134           | Terms.Var _ ->
 135                prerr_endline ("term: " ^ ppfot ft);
 136                prerr_endline ("path: " ^ String.concat ","
 137                  (List.map string_of_int p));
 138                assert false
 139           | Terms.Node l ->
 140               let l =
 141                 HExtlib.list_mapi
 142                   (fun t i ->
 143                     if i = n then aux t tl
 144                     else extract amount (0::vl) t)
 145                   l
 146               in
 147               NCic.Appl l
 148     in
 149       NCic.Lambda("x", NCic.Implicit `Type, aux ft (List.rev p))
 150     ;;
 151
 152   let mk_proof (bag : NCic.term Terms.bag) steps =
 153     let module Subst = FoSubst in
 154     let position i l =
 155       let rec aux = function
 156        | [] -> assert false
 157        | (j,_) :: tl when i = j -> 1
 158        | _ :: tl -> 1 + aux tl
 159       in
 160         aux l
 161     in
 162     let vars_of i l = fst (List.assoc i l) in
 163     let ty_of i l = snd (List.assoc i l) in
 164     let close_with_lambdas vl t =
 165       List.fold_left
 166        (fun t i ->
 167           NCic.Lambda ("x"^string_of_int i, NCic.Implicit `Type, t))
 168        t vl
 169     in
 170     let rec aux seen = function
 171       | [] -> NCic.Rel 1
 172       | id :: tl ->
 173 (*           prerr_endline ("Let4 : " ^string_of_int id); *)
 174           let amount = List.length seen in
 175           let _, lit, vl, proof = Terms.M.find id bag in
 176           let lit =
 177             match lit with
 178             | Terms.Predicate t -> assert false
 179             | Terms.Equation (l,r,ty,_) ->
 180                  Terms.Node [ Terms.Leaf eqP; ty; l; r]
 181           in
 182 (*                 prerr_endline ("X" ^ ppfot lit); *)
 183           match proof with
 184           | Terms.Exact ft ->
 185                NCic.LetIn ("clause_" ^ string_of_int id, NCic.Implicit `Type,
 186                  close_with_lambdas vl (extract amount vl ft),
 187                  aux ((id,(List.map (fun x -> Terms.Var x) vl,lit))::seen) tl)
 188           | Terms.Step (_, id1, id2, dir, pos, subst) ->
 189               let proof_of_id id =
 190                 let vars = vars_of id seen in
 191                 let args = List.map (Subst.apply_subst subst) vars in
 192                 let args = List.map (extract amount vl) args in
 193                 NCic.Appl (NCic.Rel (List.length vl + position id seen) :: args)
 194               in
 195               let p_id1 = proof_of_id id1 in
 196               let p_id2 = proof_of_id id2 in
 197               let pred =
 198                 let id1_ty = ty_of id1 seen in
 199                 mk_predicate amount (Subst.apply_subst subst id1_ty) pos vl
 200               in
 201               let eq_ind = if dir=Terms.Left2Right then eq_ind else eq_ind_r in
 202                NCic.LetIn ("clause_" ^ string_of_int id, NCic.Implicit `Type,
 203                  close_with_lambdas vl
 204                    (NCic.Appl [ eq_ind ; NCic.Implicit `Type;
 205                      pred; NCic.Implicit `Term; p_id1;
 206                      NCic.Implicit `Term; p_id2 ]),
 207                  aux ((id,(List.map (fun x -> Terms.Var x) vl,lit))::seen) tl)
 208     in
 209       aux [] steps
 210   ;;
 211
 212  end