helm/software/components/ng_paramodulation/paramod.ml

   1 (*
   2     ||M||  This file is part of HELM, an Hypertextual, Electronic
   3     ||A||  Library of Mathematics, developed at the Computer Science
   4     ||T||  Department, University of Bologna, Italy.
   5     ||I||
   6     ||T||  HELM is free software; you can redistribute it and/or
   7     ||A||  modify it under the terms of the GNU General Public License
   8     \   /  version 2 or (at your option) any later version.
   9      \ /   This software is distributed as is, NO WARRANTY.
  10       V_______________________________________________________________ *)
  11
  12 (* $Id: orderings.ml 9869 2009-06-11 22:52:38Z denes $ *)
  13
  14 let print s = prerr_endline (Lazy.force s) ;;
  15 let noprint s = ();;
  16 let debug = noprint;;
  17
  18 let monster = 100;;
  19
  20 module type Paramod =
  21   sig
  22     type t
  23     type input
  24     type szsontology =
  25       | Unsatisfiable of
  26           (t Terms.bag * int * t Terms.substitution * int list) list
  27       | GaveUp
  28       | Error of string
  29       | Timeout of int * t Terms.bag
  30     type bag = t Terms.bag * int
  31     type state
  32     val empty_state : state
  33     val bag_of_state : state -> bag
  34     val replace_bag: state -> bag -> state
  35     val mk_passive : bag -> input * input -> bag * t Terms.unit_clause
  36     val mk_goal : bag -> input * input -> bag * t Terms.unit_clause
  37     val forward_infer_step :
  38       state ->
  39       t Terms.unit_clause ->
  40       int ->
  41       state
  42     val goal_narrowing :
  43       int
  44       -> int
  45       -> float option
  46       -> state
  47       -> state
  48     val paramod :
  49       useage:bool ->
  50       max_steps:int ->
  51       ?timeout:float ->
  52       bag ->
  53       g_passives:t Terms.unit_clause list ->
  54       passives:t Terms.unit_clause list -> szsontology
  55     val demod :
  56       state -> input* input -> szsontology
  57     val fast_eq_check :
  58       state -> input* input -> szsontology
  59     val nparamod :
  60       useage:bool ->
  61       max_steps:int ->
  62       ?timeout:float ->
  63       state -> input* input -> szsontology
  64   end
  65
  66 module Paramod (B : Orderings.Blob) = struct
  67   module Pp = Pp.Pp (B)
  68   module FU = FoUnif.Founif(B)
  69   module IDX = Index.Index(B)
  70   module Sup = Superposition.Superposition(B)
  71   module Utils = FoUtils.Utils(B)
  72   module Order = B
  73   module WeightOrderedPassives =
  74       struct
  75         type t = B.t Terms.passive_clause
  76         let compare = Utils.compare_passive_clauses_weight
  77       end
  78
  79   module AgeOrderedPassives =
  80       struct
  81         type t = B.t Terms.passive_clause
  82         let compare = Utils.compare_passive_clauses_age
  83       end
  84
  85   module WeightPassiveSet = Set.Make(WeightOrderedPassives)
  86   module AgePassiveSet = Set.Make(AgeOrderedPassives)
  87
  88   type t = B.t
  89   type input = B.input
  90   type bag = B.t Terms.bag * int
  91   type szsontology =
  92     | Unsatisfiable of
  93         (B.t Terms.bag * int * B.t Terms.substitution * int list) list
  94     | GaveUp
  95     | Error of string
  96     | Timeout of int * B.t Terms.bag
  97   exception Stop of szsontology
  98   type state =
  99       t Terms.bag
 100       * int
 101       * Index.Index(B).active_set
 102       * (IDX.DT.t * WeightPassiveSet.t * AgePassiveSet.t)
 103       * B.t Terms.unit_clause list
 104       * (WeightPassiveSet.t * AgePassiveSet.t)
 105
 106   let empty_state =
 107     Terms.empty_bag,
 108     0,
 109     ([],IDX.DT.empty),
 110     (IDX.DT.empty,WeightPassiveSet.empty,AgePassiveSet.empty),
 111     [],
 112     (WeightPassiveSet.empty,AgePassiveSet.empty)
 113   ;;
 114
 115   let bag_of_state (bag,n,_,_,_,_) = bag,n
 116   ;;
 117
 118   let replace_bag (_,_,a,b,c,d) (bag,n) = bag,n,a,b,c,d
 119   ;;
 120
 121   let add_passive_clause ?(no_weight=false)
 122       (passive_t,passives_w,passives_a) cl =
 123     let pcl = if no_weight then (0,cl)
 124     else Utils.mk_passive_clause cl in
 125     IDX.index_unit_clause passive_t cl,
 126     WeightPassiveSet.add pcl passives_w,
 127     AgePassiveSet.add pcl passives_a
 128   ;;
 129
 130   let add_passive_goal ?(no_weight=false) (passives_w,passives_a) g =
 131     let g = if no_weight then (0,g)
 132     else Utils.mk_passive_goal g in
 133     WeightPassiveSet.add g passives_w, AgePassiveSet.add g passives_a
 134   ;;
 135
 136   let remove_passive_clause (passive_t,passives_w,passives_a) cl =
 137     let passive_t = IDX.remove_unit_clause passive_t (snd cl) in
 138     let passives_w = WeightPassiveSet.remove cl passives_w in
 139     let passives_a = AgePassiveSet.remove cl passives_a in
 140       passive_t,passives_w,passives_a
 141   ;;
 142
 143   let add_passive_clauses ?(no_weight=false) =
 144     List.fold_left (add_passive_clause ~no_weight)
 145   ;;
 146
 147   let add_passive_goals ?(no_weight=false)
 148       (passives_w,passives_a) new_clauses =
 149     let new_clauses_w,new_clauses_a =
 150       List.fold_left (add_passive_goal ~no_weight)
 151       (WeightPassiveSet.empty,AgePassiveSet.empty) new_clauses
 152     in
 153       (WeightPassiveSet.union new_clauses_w passives_w,
 154        AgePassiveSet.union new_clauses_a passives_a)
 155   ;;
 156
 157   let remove_passive_goal (passives_w,passives_a) cl =
 158     let passives_w = WeightPassiveSet.remove cl passives_w in
 159     let passives_a = AgePassiveSet.remove cl passives_a in
 160       passives_w,passives_a
 161   ;;
 162
 163   let is_passive_set_empty (_,passives_w,passives_a) =
 164     if (WeightPassiveSet.is_empty passives_w) then begin
 165       assert (AgePassiveSet.is_empty passives_a); true
 166     end else begin
 167       assert (not (AgePassiveSet.is_empty passives_a)); false
 168     end
 169   ;;
 170
 171   let is_passive_g_set_empty (passives_w,passives_a) =
 172     if (WeightPassiveSet.is_empty passives_w) then begin
 173       assert (AgePassiveSet.is_empty passives_a); true
 174     end else begin
 175       assert (not (AgePassiveSet.is_empty passives_a)); false
 176     end
 177   ;;
 178
 179   let passive_set_cardinal (_,passives_w,_)
 180       = WeightPassiveSet.cardinal passives_w
 181   ;;
 182
 183   let g_passive_set_cardinal (passives_w,_)
 184       = WeightPassiveSet.cardinal passives_w
 185   ;;
 186
 187   let passive_empty_set =
 188     (IDX.DT.empty,WeightPassiveSet.empty,AgePassiveSet.empty)
 189   ;;
 190
 191   let g_passive_empty_set =
 192     (WeightPassiveSet.empty,AgePassiveSet.empty)
 193   ;;
 194
 195   let pick_min_passive ~use_age (_,passives_w,passives_a) =
 196     if use_age then AgePassiveSet.min_elt passives_a
 197     else WeightPassiveSet.min_elt passives_w
 198   ;;
 199
 200   let pick_min_g_passive ~use_age (passives_w,passives_a) =
 201     if use_age then AgePassiveSet.min_elt passives_a
 202     else WeightPassiveSet.min_elt passives_w
 203   ;;
 204
 205   let mk_unit_clause bag maxvar (t,ty) =
 206     let c, maxvar = Utils.mk_unit_clause maxvar (B.embed ty) (B.embed t) in
 207     let bag, c = Terms.add_to_bag c bag in
 208     (bag, maxvar), c
 209   ;;
 210
 211   let mk_clause bag maxvar (t,ty) =
 212     let (proof,ty) = B.saturate t ty in
 213     let c, maxvar = Utils.mk_unit_clause maxvar ty proof in
 214     let bag, c = Terms.add_to_bag c bag in
 215     (bag, maxvar), c
 216   ;;
 217
 218   let mk_passive (bag,maxvar) = mk_clause bag maxvar;;
 219
 220   let mk_goal (bag,maxvar) = mk_clause bag maxvar;;
 221
 222   let initialize_goal (bag,maxvar,actives,passives,_,_) t =
 223     let (bag,maxvar), g = mk_unit_clause bag maxvar t in
 224     let g_passives = g_passive_empty_set in
 225     (* if the goal is not an equation we returns an empty
 226        passive set *)
 227     let g_passives =
 228       if Terms.is_eq_clause g then add_passive_goal g_passives g
 229       else g_passives
 230     in
 231       (bag,maxvar,actives,passives,[],g_passives)
 232
 233
 234   (* TODO : global age over facts and goals (without comparing weights) *)
 235   let select ~use_age passives g_passives =
 236     if is_passive_set_empty passives then begin
 237       if (is_passive_g_set_empty g_passives) then
 238         raise (Stop GaveUp) (* we say we are incomplete *)
 239       else
 240        let g_cl = pick_min_g_passive ~use_age:use_age g_passives in
 241         (true,g_cl,passives,remove_passive_goal g_passives g_cl)
 242     end
 243     else let cl = pick_min_passive ~use_age:use_age passives in
 244       if is_passive_g_set_empty g_passives then
 245         (false,cl,remove_passive_clause passives cl,g_passives)
 246       else
 247         let g_cl = pick_min_g_passive ~use_age:use_age g_passives in
 248         let (id1,_,_,_),(id2,_,_,_) = snd cl, snd g_cl in
 249         let cmp = if use_age then id1 <= id2
 250         else fst cl <= fst g_cl
 251         in
 252           if cmp then
 253             (false,cl,remove_passive_clause passives cl,g_passives)
 254           else
 255             (true,g_cl,passives,remove_passive_goal g_passives g_cl)
 256   ;;
 257
 258   let backward_infer_step bag maxvar actives passives
 259                           g_actives g_passives g_current iterno =
 260     (* superposition left, simplifications on goals *)
 261       debug (lazy "infer_left step...");
 262       let bag, maxvar, new_goals =
 263         Sup.infer_left bag maxvar g_current actives
 264       in
 265         debug (lazy "Performed infer_left step");
 266         let bag = Terms.replace_in_bag (g_current,false,iterno) bag in
 267           bag, maxvar, actives, passives, g_current::g_actives,
 268     (add_passive_goals g_passives new_goals)
 269   ;;
 270
 271   let pp_clauses actives passives =
 272     let actives_l, _ = actives in
 273     let passive_t,_,_ = passives in
 274     let wset = IDX.elems passive_t in
 275       ("Actives :" ^ (String.concat ";\n"
 276         (List.map Pp.pp_unit_clause actives_l)))
 277       ^
 278       ("Passives:" ^(String.concat ";\n"
 279         (List.map (fun (_,cl) -> Pp.pp_unit_clause cl)
 280                (IDX.ClauseSet.elements wset))))
 281   ;;
 282
 283   let forward_infer_step
 284       ((bag,maxvar,actives,passives,g_actives,g_passives) as s)
 285       current iterno =
 286     (* forward step *)
 287
 288     (* e = select P           *
 289      * e' = demod A e         *
 290      * A' = demod [e'] A      *
 291      * A'' = A' + e'          *
 292      * e'' = fresh e'         *
 293      * new = supright e'' A'' *
 294      * new'= demod A'' new    *
 295      * P' = P + new'          *)
 296     debug (lazy "Forward infer step...");
 297     debug (lazy("Number of actives : " ^ (string_of_int (List.length (fst actives)))));
 298     noprint (lazy (pp_clauses actives passives));
 299     match Sup.keep_simplified current actives bag maxvar
 300     with
 301       | _,None -> s
 302       | bag,Some (current,actives) ->
 303     debug (lazy ("simplified to " ^ (Pp.pp_unit_clause current)));
 304     let bag, maxvar, actives, new_clauses =
 305       Sup.infer_right bag maxvar current actives
 306     in
 307       debug
 308         (lazy
 309          ("New clauses :" ^ (String.concat ";\n"
 310             (List.map Pp.pp_unit_clause new_clauses))));
 311       debug (lazy "Demodulating goals with actives...");
 312       (* keep goals demodulated w.r.t. actives and check if solved *)
 313       let bag, g_actives =
 314         List.fold_left
 315           (fun (bag,acc) c ->
 316              match
 317                Sup.simplify_goal ~no_demod:false maxvar (snd actives) bag acc c
 318              with
 319                | None -> bag, acc
 320                | Some (bag,c1) -> bag,if c==c1 then c::acc else c::c1::acc)
 321           (bag,[]) g_actives
 322       in
 323       let ctable = IDX.index_unit_clause IDX.DT.empty current in
 324       let bag, maxvar, new_goals =
 325         List.fold_left
 326           (fun (bag,m,acc) g ->
 327              let bag, m, ng = Sup.infer_left bag m g ([current],ctable) in
 328                bag,m,ng@acc)
 329           (bag,maxvar,[]) g_actives
 330       in
 331       let bag = Terms.replace_in_bag (current,false,iterno) bag in
 332         (* prerr_endline (Pp.pp_bag bag); *)
 333     bag, maxvar, actives,
 334     add_passive_clauses passives new_clauses, g_actives,
 335     add_passive_goals g_passives new_goals
 336   ;;
 337
 338   let debug_status (_,_,actives,passives,g_actives,g_passives) =
 339     lazy
 340       ((Printf.sprintf "Number of active goals : %d\n"
 341           (List.length g_actives)) ^
 342        (Printf.sprintf "Number of passive goals : %d\n"
 343           (g_passive_set_cardinal g_passives)) ^
 344        (Printf.sprintf "Number of actives : %d\n"
 345           (List.length (fst actives))) ^
 346        (Printf.sprintf "Number of passives : %d\n"
 347          (passive_set_cardinal passives)))
 348   ;;
 349
 350
 351   (* we just check if any of the active goals is subsumed by a
 352      passive clause, or if any of the passive goal is subsumed
 353      by an active or passive clause *)
 354   let last_chance (bag,maxvar,actives,passives,g_actives,g_passives) =
 355     debug (lazy("Last chance " ^ string_of_float
 356                   (Unix.gettimeofday())));
 357     let actives_l, active_t = actives in
 358     let passive_t,wset,_ = passives in
 359     let _ = noprint
 360       (lazy
 361          ("Actives :" ^ (String.concat ";\n"
 362             (List.map Pp.pp_unit_clause actives_l)))) in
 363     let wset = IDX.elems passive_t in
 364     let _ = noprint
 365       (lazy
 366          ("Passives:" ^(String.concat ";\n"
 367             (List.map (fun (_,cl) -> Pp.pp_unit_clause cl)
 368                (IDX.ClauseSet.elements wset))))) in
 369     let g_passives =
 370       WeightPassiveSet.fold
 371         (fun (_,x) acc ->
 372           if List.exists (Sup.are_alpha_eq x) g_actives then acc
 373           else x::acc)
 374           (fst g_passives) []
 375     in
 376       ignore
 377       (List.iter
 378         (fun x ->
 379             ignore
 380              (debug (lazy("ckecking goal vs a: " ^ Pp.pp_unit_clause x));
 381                Sup.simplify_goal ~no_demod:true maxvar active_t bag [] x))
 382        g_passives);
 383       ignore
 384       (List.iter
 385          (fun x ->
 386             ignore
 387               (debug (lazy("ckecking goal vs p: " ^ Pp.pp_unit_clause x));
 388         Sup.simplify_goal ~no_demod:true maxvar passive_t bag [] x))
 389         (g_actives@g_passives));
 390     raise (Stop (Timeout (maxvar,bag)))
 391
 392   let check_timeout = function
 393     | None -> false
 394     | Some timeout -> Unix.gettimeofday () > timeout
 395
 396   let rec given_clause ~useage
 397     bag maxvar iterno weight_picks max_steps timeout
 398     actives passives g_actives g_passives
 399   =
 400     let iterno = iterno + 1 in
 401     if iterno = max_steps || check_timeout timeout then
 402       last_chance (bag,maxvar,actives,passives,g_actives,g_passives)
 403     else
 404     let use_age = useage && (weight_picks = (iterno / 6 + 1)) in
 405     let weight_picks = if use_age then 0 else weight_picks+1
 406     in
 407
 408     let rec aux_select bag
 409         (passives:IDX.DT.t * WeightPassiveSet.t * AgePassiveSet.t)
 410         g_passives =
 411       let backward,(weight,current),passives,g_passives =
 412         select ~use_age passives g_passives
 413       in
 414         if use_age && weight > monster then
 415           let bag,cl = Terms.add_to_bag current bag in
 416             if backward then
 417               aux_select bag passives (add_passive_goal g_passives cl)
 418             else
 419               aux_select bag (add_passive_clause passives cl) g_passives
 420         else
 421           let bag = Terms.replace_in_bag (current,false,iterno) bag in
 422         if backward then
 423           let _ = debug (lazy("Selected goal : " ^ Pp.pp_unit_clause current)) in
 424          match
 425            Sup.simplify_goal
 426              ~no_demod:false maxvar (snd actives) bag g_actives current
 427          with
 428            | None -> aux_select bag passives g_passives
 429            | Some (bag,g_current) ->
 430                backward_infer_step bag maxvar actives passives
 431                  g_actives g_passives g_current iterno
 432         else
 433           let _ = debug (lazy("Selected fact : " ^ Pp.pp_unit_clause current))
 434           in
 435             if Sup.orphan_murder bag (fst actives) current then
 436               let _ = debug (lazy "Orphan murdered") in
 437               let bag = Terms.replace_in_bag (current,true,iterno) bag in
 438                 aux_select bag passives g_passives
 439             else
 440               let s = bag,maxvar,actives,passives,g_actives,g_passives in
 441               let s1 = forward_infer_step s current iterno
 442               in
 443                 if s == s1 then aux_select bag passives g_passives
 444                 else s1
 445     in
 446       (*prerr_endline "Active table :";
 447        (List.iter (fun x -> prerr_endline (Pp.pp_unit_clause x))
 448           (fst actives)); *)
 449
 450     let (bag,maxvar,actives,passives,g_actives,g_passives) as status  =
 451       aux_select bag passives g_passives
 452     in
 453       debug (debug_status status);
 454       given_clause ~useage
 455         bag maxvar iterno weight_picks max_steps timeout
 456         actives passives g_actives g_passives
 457   ;;
 458
 459   let check_and_infer ~no_demod iterno status current =
 460     let bag,maxvar,actives,passives,g_actives,g_passives = status in
 461     match
 462       Sup.simplify_goal
 463         ~no_demod maxvar (snd actives) bag g_actives current
 464     with
 465       | None -> debug (lazy "None"); status
 466       | Some (bag,g_current) ->
 467           let _ =
 468             debug (lazy("Infer on goal : "
 469                         ^ Pp.pp_unit_clause g_current))
 470           in
 471             backward_infer_step bag maxvar actives passives
 472               g_actives g_passives g_current iterno
 473
 474   (* similar to given_clause, but it merely works on goals,
 475      in parallel, at each iteration *)
 476   let rec goal_narrowing iterno max_steps timeout status
 477   =
 478     debug (debug_status status);
 479     let iterno = iterno + 1 in
 480     if iterno = max_steps || check_timeout timeout then
 481       last_chance status
 482     else
 483     let _,_,_,_,_,g_passives = status in
 484     let passive_goals = WeightPassiveSet.elements (fst g_passives) in
 485     let newstatus =
 486       List.fold_left
 487         (fun acc g ->
 488            let bag,maxvar,actives,passives,g_actives,g_passives = acc in
 489            let g_passives =
 490              remove_passive_goal g_passives g in
 491            let current = snd g in
 492            let _ =
 493              debug (lazy("Selected goal : " ^ Pp.pp_unit_clause current))
 494            in
 495              (* we work both on the original goal and the demodulated one*)
 496            let acc = check_and_infer ~no_demod:false iterno acc current
 497            in check_and_infer ~no_demod:true iterno acc current)
 498         status passive_goals
 499     in
 500       goal_narrowing iterno max_steps timeout newstatus
 501
 502     let compute_result bag i subst =
 503       let l =
 504         let rec traverse ongoal (accg,acce) i =
 505           match Terms.get_from_bag i bag with
 506             | (id,_,_,Terms.Exact _),_,_ ->
 507                 if ongoal then [i],acce else
 508                   if (List.mem i acce) then accg,acce else accg,acce@[i]
 509             | (_,_,_,Terms.Step (_,i1,i2,_,_,_)),_,_ ->
 510                 if (not ongoal) && (List.mem i acce) then accg,acce
 511                 else
 512                   let accg,acce =
 513                     traverse false (traverse ongoal (accg,acce) i1) i2
 514                   in
 515                     if ongoal then i::accg,acce else accg,i::acce
 516         in
 517         let gsteps,esteps = traverse true ([],[]) i in
 518           (List.rev esteps)@gsteps
 519       in
 520       debug (lazy ("steps: " ^ (string_of_int (List.length l))));
 521       let max_w =
 522         List.fold_left
 523           (fun acc i ->
 524              let (cl,_,_) = Terms.get_from_bag i bag in
 525                max acc (Order.compute_unit_clause_weight cl)) 0 l in
 526         debug (lazy ("Max weight : " ^ (string_of_int max_w)));
 527 (*        List.iter (fun id -> let ((_,lit,_,proof as cl),d,it) =
 528             Terms.get_from_bag id bag in
 529               if d then
 530                 prerr_endline
 531                 (Printf.sprintf "Id : %d, selected at %d, weight %d,disc, by %s"
 532                    id it (Order.compute_unit_clause_weight cl)
 533                    (Pp.pp_proof_step proof))
 534               else
 535                prerr_endline
 536                 (Printf.sprintf "Id : %d, selected at %d, weight %d by %s"
 537                    id it (Order.compute_unit_clause_weight cl)
 538                    (Pp.pp_proof_step proof))) l;*)
 539         debug (lazy ("Proof:" ^
 540           (String.concat "\n"
 541              (List.map
 542                 (fun x ->
 543                    let cl,_,_ = Terms.get_from_bag x bag in
 544                      Pp.pp_unit_clause cl) l))));
 545         Unsatisfiable [ bag, i, subst, l ]
 546
 547   let paramod ~useage ~max_steps ?timeout (bag,maxvar) ~g_passives ~passives =
 548     let _initial_timestamp = Unix.gettimeofday () in
 549     let passives =
 550       add_passive_clauses ~no_weight:true passive_empty_set passives
 551     in
 552     let g_passives =
 553       add_passive_goals ~no_weight:true g_passive_empty_set g_passives
 554     in
 555     let g_actives = [] in
 556     let actives = [], IDX.DT.empty in
 557     try
 558      given_clause ~useage ~noinfer:false
 559       bag maxvar 0  0 max_steps timeout actives passives g_actives g_passives
 560     with
 561     | Sup.Success (bag, _, (i,_,_,_),subst) ->
 562         compute_result bag i subst
 563     | Stop (Unsatisfiable _) -> Error "solution found!"
 564     | Stop o -> o
 565   ;;
 566
 567 let demod s goal =
 568   let bag,maxvar,actives,passives,g_actives,g_passives = s in
 569   let (bag,maxvar), g = mk_goal (bag,maxvar) goal in
 570   let bag, ((i,_,_,_) as g1) = Sup.demodulate bag g (snd actives) in
 571     if g1 = g then GaveUp else compute_result bag i []
 572 (*
 573   if Terms.is_eq_clause g then
 574
 575   else GaveUp *)
 576
 577 let fast_eq_check s goal =
 578   let (_,_,_,_,_,g_passives) as s = initialize_goal s goal in
 579   if is_passive_g_set_empty g_passives then Error "not an equation"
 580   else
 581   try
 582     goal_narrowing 0 2 None s
 583   with
 584     | Sup.Success (bag, _, (i,_,_,_),subst) ->
 585         compute_result bag i subst
 586     | Stop (Unsatisfiable _) -> Error "solution found!"
 587     | Stop o -> o
 588   ;;
 589
 590 let nparamod ~useage ~max_steps ?timeout s goal =
 591   let bag,maxvar,actives,passives,g_actives,g_passives
 592       = initialize_goal s goal in
 593   if is_passive_g_set_empty g_passives then Error "not an equation"
 594   else
 595     try given_clause ~useage ~noinfer:false
 596       bag maxvar 0 0 max_steps timeout actives passives g_actives g_passives
 597   with
 598     | Sup.Success (bag, _, (i,_,_,_),subst) ->
 599         compute_result bag i subst
 600     | Stop (Unsatisfiable _) -> Error "solution found!"
 601     | Stop o -> o
 602   ;;
 603
 604 end