helm/software/components/ng_paramodulation/paramod.ml

   1 (*
   2     ||M||  This file is part of HELM, an Hypertextual, Electronic
   3     ||A||  Library of Mathematics, developed at the Computer Science
   4     ||T||  Department, University of Bologna, Italy.
   5     ||I||
   6     ||T||  HELM is free software; you can redistribute it and/or
   7     ||A||  modify it under the terms of the GNU General Public License
   8     \   /  version 2 or (at your option) any later version.
   9      \ /   This software is distributed as is, NO WARRANTY.
  10       V_______________________________________________________________ *)
  11
  12 (* $Id: orderings.ml 9869 2009-06-11 22:52:38Z denes $ *)
  13
  14 let debug s = prerr_endline s ;;
  15 let debug _ = ();;
  16
  17 module Paramod (B : Terms.Blob) = struct
  18   exception Failure of string * B.t Terms.bag * int * int
  19   type bag = B.t Terms.bag * int
  20   module Pp = Pp.Pp (B)
  21   module FU = FoUnif.Founif(B)
  22   module IDX = Index.Index(B)
  23   module Sup = Superposition.Superposition(B)
  24   module Utils = FoUtils.Utils(B)
  25   module WeightOrderedPassives =
  26       struct
  27         type t = B.t Terms.passive_clause
  28         let compare = Utils.compare_passive_clauses_weight
  29       end
  30
  31   module AgeOrderedPassives =
  32       struct
  33         type t = B.t Terms.passive_clause
  34         let compare = Utils.compare_passive_clauses_age
  35       end
  36
  37   module WeightPassiveSet = Set.Make(WeightOrderedPassives)
  38   module AgePassiveSet = Set.Make(AgeOrderedPassives)
  39
  40   let add_passive_clause ?(no_weight=false) (passives_w,passives_a) cl =
  41     let cl = if no_weight then (0,cl)
  42     else Utils.mk_passive_clause cl in
  43     WeightPassiveSet.add cl passives_w, AgePassiveSet.add cl passives_a
  44   ;;
  45
  46   let remove_passive_clause (passives_w,passives_a) cl =
  47     let passives_w = WeightPassiveSet.remove cl passives_w in
  48     let passives_a = AgePassiveSet.remove cl passives_a in
  49       passives_w,passives_a
  50   ;;
  51
  52   let add_passive_clauses (passives_w,passives_a) new_clauses =
  53     let new_clauses_w,new_clauses_a = List.fold_left add_passive_clause
  54       (WeightPassiveSet.empty,AgePassiveSet.empty) new_clauses
  55     in
  56       (WeightPassiveSet.union new_clauses_w passives_w,
  57        AgePassiveSet.union new_clauses_a passives_a)
  58   ;;
  59
  60   let is_passive_set_empty (passives_w,passives_a) =
  61     if (WeightPassiveSet.is_empty passives_w) then begin
  62       assert (AgePassiveSet.is_empty passives_a); true
  63     end else begin
  64       assert (not (AgePassiveSet.is_empty passives_a)); false
  65     end
  66   ;;
  67
  68   let passive_set_cardinal (passives_w,_) = WeightPassiveSet.cardinal passives_w
  69
  70   let passive_empty_set =
  71     (WeightPassiveSet.empty,AgePassiveSet.empty)
  72   ;;
  73
  74   let pick_min_passive ~use_age (passives_w,passives_a) =
  75     if use_age then AgePassiveSet.min_elt passives_a
  76     else WeightPassiveSet.min_elt passives_w
  77   ;;
  78
  79   let mk_clause bag maxvar (t,ty) =
  80     let (proof,ty) = B.saturate t ty in
  81     let c, maxvar = Utils.mk_unit_clause maxvar ty proof in
  82     let bag, c = Utils.add_to_bag bag c in
  83     (bag, maxvar), c
  84   ;;
  85
  86   let mk_passive (bag,maxvar) = mk_clause bag maxvar;;
  87   let mk_goal (bag,maxvar) = mk_clause bag maxvar;;
  88
  89   (* TODO : global age over facts and goals (without comparing weights) *)
  90   let select ~use_age passives g_passives =
  91     if is_passive_set_empty passives then begin
  92       assert (not (is_passive_set_empty g_passives));
  93       let g_cl = pick_min_passive ~use_age:use_age g_passives in
  94         (true,snd g_cl,passives,remove_passive_clause g_passives g_cl)
  95     end
  96     else let cl = pick_min_passive ~use_age:use_age passives in
  97       if is_passive_set_empty g_passives then
  98         (false,snd cl,remove_passive_clause passives cl,g_passives)
  99       else
 100         let g_cl = pick_min_passive ~use_age:use_age g_passives in
 101           if (fst cl <= fst g_cl) then
 102             (false,snd cl,remove_passive_clause passives cl,g_passives)
 103           else
 104             (true,snd g_cl,passives,remove_passive_clause g_passives g_cl)
 105   ;;
 106
 107   let backward_infer_step bag maxvar actives passives
 108                           g_actives g_passives g_current =
 109     (* superposition left, simplifications on goals *)
 110       debug "infer_left step...";
 111       let bag, maxvar, new_goals =
 112         Sup.infer_left bag maxvar g_current actives
 113       in
 114         debug "Performed infer_left step";
 115         bag, maxvar, actives, passives, g_current::g_actives,
 116     (add_passive_clauses g_passives new_goals)
 117   ;;
 118
 119   let forward_infer_step bag maxvar actives passives g_actives
 120                          g_passives current =
 121     (* forward step *)
 122
 123     (* e = select P           *
 124      * e' = demod A e         *
 125      * A' = demod [e'] A      *
 126      * A'' = A' + e'          *
 127      * e'' = fresh e'         *
 128      * new = supright e'' A'' *
 129      * new'= demod A'' new    *
 130      * P' = P + new'          *)
 131     debug "Forward infer step...";
 132     let bag, maxvar, actives, new_clauses =
 133       Sup.infer_right bag maxvar current actives
 134     in
 135       debug "Demodulating goals with actives...";
 136       (* keep goals demodulated w.r.t. actives and check if solved *)
 137       let bag, g_actives =
 138         List.fold_left
 139           (fun (bag,acc) c ->
 140              match Sup.simplify_goal maxvar (snd actives) bag acc c with
 141                | None -> bag, acc
 142                | Some (bag,c) -> bag,c::acc)
 143           (bag,[]) g_actives
 144       in
 145       let ctable = IDX.index_unit_clause IDX.DT.empty current in
 146       let bag, maxvar, new_goals =
 147         List.fold_left
 148           (fun (bag,m,acc) g ->
 149              let bag, m, ng = Sup.infer_left bag m g
 150                ([current],ctable) in
 151                bag,m,ng@acc)
 152           (bag,maxvar,[]) g_actives
 153       in
 154         bag, maxvar, actives,
 155     add_passive_clauses passives new_clauses, g_actives,
 156     add_passive_clauses g_passives new_goals
 157   ;;
 158
 159   let rec given_clause
 160     bag maxvar iterno max_steps timeout
 161     actives passives g_actives g_passives
 162   =
 163     let iterno = iterno + 1 in
 164     if iterno = max_steps then
 165       raise (Failure ("No iterations left !",bag,maxvar,iterno));
 166     (* timeout check: gettimeofday called only if timeout set *)
 167     (match timeout with
 168     | None -> ()
 169     | Some timeout ->
 170         if Unix.gettimeofday () > timeout then
 171           raise (Failure ("Timeout !",bag,maxvar,iterno)));
 172
 173     let use_age = iterno mod 10 = 0 in
 174
 175     let rec aux_select passives g_passives =
 176       let backward,current,passives,g_passives =
 177         select ~use_age:false passives g_passives
 178       in
 179         if backward then
 180          match Sup.simplify_goal maxvar (snd actives) bag g_actives current with
 181             | None -> aux_select passives g_passives
 182             | Some x -> let bag,g_current = x in
 183                 backward_infer_step bag maxvar actives passives
 184                   g_actives g_passives g_current
 185         else
 186           (* debug ("Selected fact : " ^ Pp.pp_unit_clause current); *)
 187           match Sup.keep_simplified current actives bag maxvar with
 188         (*  match Sup.one_pass_simplification current actives bag maxvar with*)
 189               | None -> aux_select passives g_passives
 190               | Some x -> let (current, bag, actives) = x in
 191                   forward_infer_step bag maxvar actives passives
 192                                      g_actives g_passives current
 193     in
 194
 195     (* prerr_endline "Bag :"; prerr_endline (Pp.pp_bag bag);
 196       prerr_endline "Active table :";
 197        (List.iter (fun x -> prerr_endline (Pp.pp_unit_clause x))
 198           (fst actives)); *)
 199
 200     let bag,maxvar,actives,passives,g_actives,g_passives =
 201       aux_select passives g_passives
 202     in
 203       debug
 204         (Printf.sprintf "Number of active goals : %d"
 205            (List.length g_actives));
 206       debug
 207         (Printf.sprintf "Number of passive goals : %d"
 208            (passive_set_cardinal g_passives));
 209       debug
 210         (Printf.sprintf "Number of actives : %d" (List.length (fst actives)));
 211       debug
 212         (Printf.sprintf "Number of passives : %d"
 213            (passive_set_cardinal passives));
 214       given_clause
 215         bag maxvar iterno max_steps timeout
 216         actives passives g_actives g_passives
 217   ;;
 218
 219   let paramod ~max_steps ?timeout (bag,maxvar) ~g_passives ~passives =
 220     let initial_timestamp = Unix.gettimeofday () in
 221     let passives = add_passive_clauses passive_empty_set passives in
 222     let g_passives = add_passive_clauses passive_empty_set g_passives in
 223     let g_actives = [] in
 224     let actives = [], IDX.DT.empty in
 225     try
 226      given_clause
 227       bag maxvar 0 max_steps timeout actives passives g_actives g_passives
 228     with
 229     | Sup.Success (bag, _, (i,_,_,_)) ->
 230         let l =
 231           let rec traverse ongoal (accg,acce) i =
 232             match Terms.M.find i bag with
 233               | (id,_,_,Terms.Exact _),_ ->
 234                 if ongoal then [i],acce else
 235                   if (List.mem i acce) then accg,acce else accg,acce@[i]
 236               | (_,_,_,Terms.Step (_,i1,i2,_,_,_)),_ ->
 237                 if (not ongoal) && (List.mem i acce) then accg,acce
 238                 else
 239                     let accg,acce =
 240                     traverse false (traverse ongoal (accg,acce) i1) i2
 241                   in
 242                     if ongoal then i::accg,acce else accg,i::acce
 243           in
 244           let gsteps,esteps = traverse true ([],[]) i in
 245             (List.rev esteps)@gsteps
 246         in
 247         prerr_endline
 248           (Printf.sprintf "Found proof, %fs"
 249             (Unix.gettimeofday() -. initial_timestamp));
 250         (*
 251         prerr_endline "Proof:";
 252         List.iter (fun x ->
 253           prerr_endline (Pp.pp_unit_clause (fst(Terms.M.find x bag)))) l;
 254         *)
 255         [ bag, i, l ]
 256     | Failure (msg,_bag,_maxvar,iterno) ->
 257         prerr_endline msg;
 258         prerr_endline (Printf.sprintf "FAILURE in %d iterations" iterno);
 259         []
 260   ;;
 261
 262 end