helm/software/components/ng_paramodulation/superposition.ml

   1 (*
   2     ||M||  This file is part of HELM, an Hypertextual, Electronic
   3     ||A||  Library of Mathematics, developed at the Computer Science
   4     ||T||  Department, University of Bologna, Italy.
   5     ||I||
   6     ||T||  HELM is free software; you can redistribute it and/or
   7     ||A||  modify it under the terms of the GNU General Public License
   8     \   /  version 2 or (at your option) any later version.
   9      \ /   This software is distributed as is, NO WARRANTY.
  10       V_______________________________________________________________ *)
  11
  12 (* $Id: index.mli 9822 2009-06-03 15:37:06Z tassi $ *)
  13
  14 module Superposition (B : Orderings.Blob) =
  15   struct
  16     module IDX = Index.Index(B)
  17     module Unif = FoUnif.Founif(B)
  18     module Subst = FoSubst
  19     module Order = B
  20     module Utils = FoUtils.Utils(B)
  21     module Pp = Pp.Pp(B)
  22
  23     exception Success of
  24       B.t Terms.bag
  25       * int
  26       * B.t Terms.unit_clause
  27       * B.t Terms.substitution
  28
  29     (* let debug s = prerr_endline (Lazy.force s);; *)
  30     let debug _ = ();;
  31     let enable = true;;
  32
  33     let rec list_first f = function
  34       | [] -> None
  35       | x::tl -> match f x with Some _ as x -> x | _ -> list_first f tl
  36     ;;
  37
  38     let first_position pos ctx t f =
  39       let inject_pos pos ctx = function
  40         | None -> None
  41         | Some (a,b,c,d) -> Some(ctx a,b,c,d,pos)
  42       in
  43       let rec aux pos ctx = function
  44       | Terms.Leaf _ as t -> inject_pos pos ctx (f t)
  45       | Terms.Var _ -> None
  46       | Terms.Node l as t->
  47           match f t with
  48           | Some _ as x -> inject_pos pos ctx x
  49           | None ->
  50               let rec first pre post = function
  51                 | [] -> None
  52                 | t :: tl ->
  53                      let newctx = fun x -> ctx (Terms.Node (pre@[x]@post)) in
  54                      match aux (List.length pre :: pos) newctx t with
  55                      | Some _ as x -> x
  56                      | None ->
  57                          if post = [] then None (* tl is also empty *)
  58                          else first (pre @ [t]) (List.tl post) tl
  59               in
  60                 first [] (List.tl l) l
  61       in
  62         aux pos ctx t
  63     ;;
  64
  65     let all_positions pos ctx t f =
  66       let rec aux pos ctx = function
  67       | Terms.Leaf _ as t -> f t pos ctx
  68       | Terms.Var _ -> []
  69       | Terms.Node l as t->
  70           let acc, _, _ =
  71             List.fold_left
  72             (fun (acc,pre,post) t -> (* Invariant: pre @ [t] @ post = l *)
  73                 let newctx = fun x -> ctx (Terms.Node (pre@[x]@post)) in
  74                 let acc = aux (List.length pre :: pos) newctx t @ acc in
  75                 if post = [] then acc, l, []
  76                 else acc, pre @ [t], List.tl post)
  77              (f t pos ctx, [], List.tl l) l
  78           in
  79            acc
  80       in
  81         aux pos ctx t
  82     ;;
  83
  84     let parallel_positions bag pos ctx id t f =
  85       let rec aux bag pos ctx id = function
  86       | Terms.Leaf _ as t -> f bag t pos ctx id
  87       | Terms.Var _ as t -> bag,t,id
  88       | Terms.Node (hd::l) as t->
  89           let bag,t,id1 = f bag t pos ctx id in
  90             if id = id1 then
  91               let bag, l, _, id =
  92                 List.fold_left
  93                   (fun (bag,pre,post,id) t ->
  94                      let newctx = fun x -> ctx (Terms.Node (pre@[x]@post)) in
  95                      let newpos = (List.length pre)::pos in
  96                      let bag,newt,id = aux bag newpos newctx id t in
  97                        if post = [] then bag, pre@[newt], [], id
  98                        else bag, pre @ [newt], List.tl post, id)
  99                   (bag, [hd], List.tl l, id) l
 100               in
 101                 bag, Terms.Node l, id
 102             else bag,t,id1
 103             (* else aux bag pos ctx id1 t *)
 104       | _ -> assert false
 105       in
 106         aux bag pos ctx id t
 107     ;;
 108
 109     let visit bag pos ctx id t f =
 110       let rec aux bag pos ctx id subst = function
 111       | Terms.Leaf _ as t ->
 112           let  bag,subst,t,id = f bag t pos ctx id
 113           in assert (subst=[]); bag,t,id
 114       | Terms.Var i as t ->
 115           let t= Subst.apply_subst subst t in
 116             bag,t,id
 117       | Terms.Node (hd::l) ->
 118           let bag, l, _, id =
 119             List.fold_left
 120               (fun (bag,pre,post,id) t ->
 121                  let newctx = fun x -> ctx (Terms.Node (pre@[x]@post)) in
 122                  let newpos = (List.length pre)::pos in
 123                  let bag,newt,id = aux bag newpos newctx id subst t in
 124                    if post = [] then bag, pre@[newt], [], id
 125                    else bag, pre @ [newt], List.tl post, id)
 126               (bag, [hd], List.map (Subst.apply_subst subst) (List.tl l), id) l
 127           in
 128           let bag,subst,t,id1 = f bag (Terms.Node l) pos ctx id
 129           in
 130             if id1 = id then (assert (subst=[]); bag,t,id)
 131             else aux bag pos ctx id1 subst t
 132       | _ -> assert false
 133       in
 134         aux bag pos ctx id [] t
 135     ;;
 136
 137     let build_clause bag filter rule t subst id id2 pos dir =
 138       let proof = Terms.Step(rule,id,id2,dir,pos,subst) in
 139       let t = Subst.apply_subst subst t in
 140       if filter subst then
 141         let literal =
 142           match t with
 143           | Terms.Node [ Terms.Leaf eq ; ty; l; r ] when B.eq B.eqP eq ->
 144                let o = Order.compare_terms l r in
 145                Terms.Equation (l, r, ty, o)
 146           | t -> Terms.Predicate t
 147         in
 148         let bag, uc =
 149           Terms.add_to_bag (0, literal, Terms.vars_of_term t, proof) bag
 150         in
 151         Some (bag, uc)
 152       else
 153         ((*prerr_endline ("Filtering: " ^ Pp.pp_foterm t);*)None)
 154     ;;
 155     let prof_build_clause = HExtlib.profile ~enable "build_clause";;
 156     let build_clause bag filter rule t subst id id2 pos x =
 157       prof_build_clause.HExtlib.profile (build_clause bag filter rule t subst id id2 pos) x
 158     ;;
 159
 160
 161     (* ============ simplification ================= *)
 162     let prof_demod_u = HExtlib.profile ~enable "demod.unify";;
 163     let prof_demod_r = HExtlib.profile ~enable "demod.retrieve_generalizations";;
 164     let prof_demod_o = HExtlib.profile ~enable "demod.compare_terms";;
 165     let prof_demod_s = HExtlib.profile ~enable "demod.apply_subst";;
 166
 167     let demod table varlist subterm =
 168       let cands =
 169         prof_demod_r.HExtlib.profile
 170          (IDX.DT.retrieve_generalizations table) subterm
 171       in
 172       list_first
 173         (fun (dir, (id,lit,vl,_)) ->
 174            match lit with
 175            | Terms.Predicate _ -> assert false
 176            | Terms.Equation (l,r,_,o) ->
 177                let side, newside = if dir=Terms.Left2Right then l,r else r,l in
 178                try
 179                  let subst =
 180                    prof_demod_u.HExtlib.profile
 181                      (Unif.unification (* (varlist@vl) *) varlist subterm) side
 182                  in
 183                  let side =
 184                    prof_demod_s.HExtlib.profile
 185                      (Subst.apply_subst subst) side
 186                  in
 187                  let newside =
 188                    prof_demod_s.HExtlib.profile
 189                      (Subst.apply_subst subst) newside
 190                  in
 191                  if o = Terms.Incomparable || o = Terms.Invertible then
 192                    let o =
 193                      prof_demod_o.HExtlib.profile
 194                       (Order.compare_terms newside) side in
 195                    (* Riazanov, pp. 45 (ii) *)
 196                    if o = Terms.Lt then
 197                      Some (newside, subst, id, dir)
 198                    else
 199                      ((*prerr_endline ("Filtering: " ^
 200                         Pp.pp_foterm side ^ " =(< || =)" ^
 201                         Pp.pp_foterm newside ^ " coming from " ^
 202                         Pp.pp_unit_clause uc );*)None)
 203                  else
 204                    Some (newside, subst, id, dir)
 205                with FoUnif.UnificationFailure _ -> None)
 206         (IDX.ClauseSet.elements cands)
 207     ;;
 208     let prof_demod = HExtlib.profile ~enable "demod";;
 209     let demod table varlist x =
 210       prof_demod.HExtlib.profile (demod table varlist) x
 211     ;;
 212
 213     let mydemod table varlist subterm =
 214       let cands =
 215         prof_demod_r.HExtlib.profile
 216          (IDX.DT.retrieve_generalizations table) subterm
 217       in
 218       list_first
 219         (fun (dir, ((id,lit,vl,_) as c)) ->
 220            debug (lazy("candidate: "
 221                        ^ Pp.pp_unit_clause c));
 222            match lit with
 223            | Terms.Predicate _ -> assert false
 224            | Terms.Equation (l,r,_,o) ->
 225                let side, newside = if dir=Terms.Left2Right then l,r else r,l in
 226                try
 227                  let subst =
 228                    prof_demod_u.HExtlib.profile
 229                      (Unif.unification (* (varlist@vl) *) varlist subterm) side
 230                  in
 231                  let iside =
 232                    prof_demod_s.HExtlib.profile
 233                      (Subst.apply_subst subst) side
 234                  in
 235                  let inewside =
 236                    prof_demod_s.HExtlib.profile
 237                      (Subst.apply_subst subst) newside
 238                  in
 239                  if o = Terms.Incomparable || o = Terms.Invertible then
 240                    let o =
 241                      prof_demod_o.HExtlib.profile
 242                       (Order.compare_terms inewside) iside in
 243                    (* Riazanov, pp. 45 (ii) *)
 244                    if o = Terms.Lt then
 245                      Some (newside, subst, id, dir)
 246                    else
 247                      ((*prerr_endline ("Filtering: " ^
 248                         Pp.pp_foterm side ^ " =(< || =)" ^
 249                         Pp.pp_foterm newside ^ " coming from " ^
 250                         Pp.pp_unit_clause uc );*)
 251                        debug (lazy "not applied");None)
 252                  else
 253                    Some (newside, subst, id, dir)
 254                with FoUnif.UnificationFailure _ ->
 255                  debug (lazy "not applied"); None)
 256         (IDX.ClauseSet.elements cands)
 257     ;;
 258
 259     let ctx_demod table vl bag t pos ctx id =
 260       match mydemod table vl t with
 261         | None -> (bag,[],t,id)
 262         | Some (newside, subst, id2, dir) ->
 263             let inewside = Subst.apply_subst subst newside in
 264             match build_clause bag (fun _ -> true)
 265               Terms.Demodulation (ctx inewside) subst id id2 pos dir
 266             with
 267               | None -> assert false
 268               | Some (bag,(id,_,_,_)) ->
 269                     (bag,subst,newside,id)
 270     ;;
 271
 272     let rec demodulate bag (id, literal, vl, pr) table =
 273       debug (lazy ("demodulate " ^ (string_of_int id)));
 274        match literal with
 275       | Terms.Predicate t -> assert false
 276       | Terms.Equation (l,r,ty,_) ->
 277           let bag,l,id1 =
 278             visit bag [2]
 279             (fun x -> Terms.Node [ Terms.Leaf B.eqP; ty; x; r ]) id l
 280             (ctx_demod table vl)
 281           in
 282           let bag,_,id2 =
 283             visit bag [3]
 284               (fun x -> Terms.Node [ Terms.Leaf B.eqP; ty; l; x ]) id1 r
 285               (ctx_demod table vl)
 286           in
 287           let cl,_,_ = Terms.get_from_bag id2 bag in
 288             bag,cl
 289     ;;
 290
 291     let parallel_demod table vl bag t pos ctx id =
 292       match demod table vl t with
 293         | None -> (bag,t,id)
 294         | Some (newside, subst, id2, dir) ->
 295             match build_clause bag (fun _ -> true)
 296               Terms.Demodulation (ctx newside) subst id id2 pos dir
 297             with
 298               | None -> assert false
 299               | Some (bag,(id,_,_,_)) ->
 300                     (bag,newside,id)
 301     ;;
 302
 303     let are_alpha_eq cl1 cl2 =
 304       let get_term (_,lit,_,_) =
 305         match lit with
 306           | Terms.Predicate _ -> assert false
 307           | Terms.Equation (l,r,ty,_) ->
 308               Terms.Node [Terms.Leaf B.eqP; ty; l ; r]
 309       in
 310         try ignore(Unif.alpha_eq (get_term cl1) (get_term cl2)) ; true
 311         with FoUnif.UnificationFailure _ -> false
 312     ;;
 313
 314     let prof_demodulate = HExtlib.profile ~enable "demodulate";;
 315     let demodulate bag clause x =
 316       prof_demodulate.HExtlib.profile (demodulate bag clause) x
 317     ;;
 318
 319     (* move away *)
 320     let is_identity_clause = function
 321       | _, Terms.Equation (_,_,_,Terms.Eq), _, _ -> true
 322       | _, Terms.Equation (_,_,_,_), _, _ -> false
 323       | _, Terms.Predicate _, _, _ -> assert false
 324     ;;
 325
 326     let is_identity_goal = function
 327       | _, Terms.Equation (_,_,_,Terms.Eq), _, _ -> Some []
 328       | _, Terms.Equation (l,r,_,_), vl, proof ->
 329           (try Some (Unif.unification (* vl *) [] l r)
 330            with FoUnif.UnificationFailure _ -> None)
 331       | _, Terms.Equation (_,_,_,_), _, _ -> None
 332       | _, Terms.Predicate _, _, _ -> assert false
 333     ;;
 334
 335     let build_new_clause bag maxvar filter rule t subst id id2 pos dir =
 336       let maxvar, _vl, subst = Utils.relocate maxvar (Terms.vars_of_term
 337       (Subst.apply_subst subst t)) subst in
 338       match build_clause bag filter rule t subst id id2 pos dir with
 339       | Some (bag, c) -> Some ((bag, maxvar), c)
 340       | None -> None
 341     ;;
 342     let prof_build_new_clause = HExtlib.profile ~enable "build_new_clause";;
 343     let build_new_clause bag maxvar filter rule t subst id id2 pos x =
 344       prof_build_new_clause.HExtlib.profile (build_new_clause bag maxvar filter
 345       rule t subst id id2 pos) x
 346     ;;
 347
 348     let fold_build_new_clause bag maxvar id rule filter res =
 349       let (bag, maxvar), res =
 350        HExtlib.filter_map_acc
 351          (fun (bag, maxvar) (t,subst,id2,pos,dir) ->
 352             build_new_clause bag maxvar filter rule t subst id id2 pos dir)
 353          (bag, maxvar) res
 354       in
 355        bag, maxvar, res
 356     ;;
 357
 358     let rewrite_eq ~unify l r ty vl table =
 359       let retrieve = if unify then IDX.DT.retrieve_unifiables
 360       else IDX.DT.retrieve_generalizations in
 361       let lcands = retrieve table l in
 362       let rcands = retrieve table r in
 363       let f b c =
 364         let id, dir, l, r, vl =
 365           match c with
 366             | (d, (id,Terms.Equation (l,r,ty,_),vl,_))-> id, d, l, r, vl
 367             |_ -> assert false
 368         in
 369         let reverse = (dir = Terms.Left2Right) = b in
 370         let l, r, proof_rewrite_dir = if reverse then l,r,Terms.Left2Right
 371         else r,l, Terms.Right2Left in
 372           (id,proof_rewrite_dir,Terms.Node [ Terms.Leaf B.eqP; ty; l; r ], vl)
 373       in
 374       let cands1 = List.map (f true) (IDX.ClauseSet.elements lcands) in
 375       let cands2 = List.map (f false) (IDX.ClauseSet.elements rcands) in
 376       let t = Terms.Node [ Terms.Leaf B.eqP; ty; l; r ] in
 377       let locked_vars = if unify then [] else vl in
 378       let rec aux = function
 379         | [] -> None
 380         | (id2,dir,c,vl1)::tl ->
 381             try
 382               let subst = Unif.unification (* (vl@vl1) *) locked_vars c t in
 383               Some (id2, dir, subst)
 384             with FoUnif.UnificationFailure _ -> aux tl
 385       in
 386         aux (cands1 @ cands2)
 387     ;;
 388
 389     let is_subsumed ~unify bag maxvar (id, lit, vl, _) table =
 390       match lit with
 391       | Terms.Predicate _ -> assert false
 392       | Terms.Equation (l,r,ty,_) ->
 393           match rewrite_eq ~unify l r ty vl table with
 394             | None -> None
 395             | Some (id2, dir, subst) ->
 396                 let id_t = Terms.Node [ Terms.Leaf B.eqP; ty; r; r ] in
 397                   build_new_clause bag maxvar (fun _ -> true)
 398                   Terms.Superposition id_t subst id id2 [2] dir
 399     ;;
 400     let prof_is_subsumed = HExtlib.profile ~enable "is_subsumed";;
 401     let is_subsumed ~unify bag maxvar c x =
 402       prof_is_subsumed.HExtlib.profile (is_subsumed ~unify bag maxvar c) x
 403     ;;
 404     (* id refers to a clause proving contextl l = contextr r *)
 405
 406     let rec deep_eq ~unify l r ty pos contextl contextr table acc =
 407       match acc with
 408       | None -> None
 409       | Some(bag,maxvar,(id,lit,vl,p),subst) ->
 410           let l = Subst.apply_subst subst l in
 411           let r = Subst.apply_subst subst r in
 412             try
 413               let subst1 = Unif.unification (* vl *) [] l r in
 414               let lit =
 415                 match lit with Terms.Predicate _ -> assert false
 416                   | Terms.Equation (l,r,ty,o) ->
 417                      Terms.Equation (FoSubst.apply_subst subst1 l,
 418                        FoSubst.apply_subst subst1 r, ty, o)
 419               in
 420                 Some(bag,maxvar,(id,lit,vl,p),Subst.concat subst1 subst)
 421             with FoUnif.UnificationFailure _ ->
 422               match rewrite_eq ~unify l r ty vl table with
 423               | Some (id2, dir, subst1) ->
 424                   let newsubst = Subst.concat subst1 subst in
 425                   let id_t =
 426                     FoSubst.apply_subst newsubst
 427                       (Terms.Node[Terms.Leaf B.eqP;ty;contextl r;contextr r])
 428                   in
 429                     (match
 430                       build_new_clause bag maxvar (fun _ -> true)
 431                         Terms.Superposition id_t
 432                         subst1 id id2 (pos@[2]) dir
 433                     with
 434                     | Some ((bag, maxvar), c) ->
 435                         Some(bag,maxvar,c,newsubst)
 436                     | None -> assert false)
 437               | None ->
 438                   match l,r with
 439                   | Terms.Node (a::la), Terms.Node (b::lb) when
 440                       a = b && List.length la = List.length lb ->
 441                       let acc,_,_,_ =
 442                         List.fold_left2
 443                           (fun (acc,pre,postl,postr) a b ->
 444                              let newcl =
 445                               fun x -> contextl(Terms.Node (pre@(x::postl))) in
 446                              let newcr =
 447                               fun x -> contextr(Terms.Node (pre@(x::postr))) in
 448                              let newpos = List.length pre::pos in
 449                              let footail l =
 450                                if l = [] then [] else List.tl l in
 451                                (deep_eq ~unify a b ty
 452                                  newpos newcl newcr table acc,pre@[b],
 453                                  footail postl, footail postr))
 454                           (acc,[a],List.tl la,List.tl lb) la lb
 455                       in acc
 456                   | _,_ -> None
 457     ;;
 458     let prof_deep_eq = HExtlib.profile ~enable "deep_eq";;
 459     let deep_eq ~unify l r ty pos contextl contextr table x =
 460       prof_deep_eq.HExtlib.profile (deep_eq ~unify l r ty pos contextl contextr table) x
 461     ;;
 462
 463     let rec orphan_murder bag acc i =
 464       match Terms.get_from_bag i bag with
 465         | (_,_,_,Terms.Exact _),discarded,_ -> (discarded,acc)
 466         | (_,_,_,Terms.Step (_,i1,i2,_,_,_)),true,_ -> (true,acc)
 467         | (_,_,_,Terms.Step (_,i1,i2,_,_,_)),false,_ ->
 468             if (List.mem i acc) then (false,acc)
 469             else match orphan_murder bag acc i1 with
 470               | (true,acc) -> (true,acc)
 471               | (false,acc) ->
 472                   let (res,acc) = orphan_murder bag acc i2 in
 473                   if res then res,acc else res,i::acc
 474     ;;
 475
 476     let orphan_murder bag actives cl =
 477       let (id,_,_,_) = cl in
 478       let actives = List.map (fun (i,_,_,_) -> i) actives in
 479       let (res,_) = orphan_murder bag actives id in
 480         if res then debug (lazy "Orphan murdered"); res
 481     ;;
 482     let prof_orphan_murder = HExtlib.profile ~enable "orphan_murder";;
 483     let orphan_murder bag actives x =
 484       prof_orphan_murder.HExtlib.profile (orphan_murder bag actives) x
 485     ;;
 486
 487     (* demodulate and check for subsumption *)
 488     let simplify table maxvar bag clause =
 489       debug (lazy "simplify...");
 490       if is_identity_clause clause then bag,None
 491       (* else if orphan_murder bag actives clause then bag,None *)
 492       else let bag, clause = demodulate bag clause table in
 493       if is_identity_clause clause then bag,None
 494       else
 495         match is_subsumed ~unify:false bag maxvar clause table with
 496           | None -> bag, Some clause
 497           | Some _ -> bag, None
 498     ;;
 499
 500     let simplify table maxvar bag clause =
 501       match simplify table maxvar bag clause with
 502         | bag, None ->
 503             let (id,_,_,_) = clause in
 504             let (_,_,iter) = Terms.get_from_bag id bag in
 505             Terms.replace_in_bag (clause,true,iter) bag, None
 506         | bag, Some clause -> bag, Some clause
 507     (*let (id,_,_,_) = clause in
 508             if orphan_murder bag clause then
 509               Terms.M.add id (clause,true) bag, Some clause
 510             else bag, Some clause*)
 511     ;;
 512     let prof_simplify = HExtlib.profile ~enable "simplify";;
 513     let simplify table maxvar bag x =
 514       prof_simplify.HExtlib.profile (simplify table maxvar bag ) x
 515     ;;
 516
 517     let one_pass_simplification new_clause (alist,atable) bag maxvar =
 518       match simplify atable maxvar bag new_clause with
 519         | bag,None -> bag,None (* new_clause has been discarded *)
 520         | bag,(Some clause) ->
 521             let ctable = IDX.index_unit_clause IDX.DT.empty clause in
 522             let bag, alist, atable =
 523               List.fold_left
 524                 (fun (bag, alist, atable) c ->
 525                    match simplify ctable maxvar bag c with
 526                      |bag,None -> (bag,alist,atable)
 527                         (* an active clause as been discarded *)
 528                      |bag,Some c1 ->
 529                         bag, c :: alist, IDX.index_unit_clause atable c)
 530                 (bag,[],IDX.DT.empty) alist
 531             in
 532               bag, Some (clause, (alist,atable))
 533     ;;
 534     let prof_one_pass_simplification = HExtlib.profile ~enable "one_pass_simplification";;
 535     let one_pass_simplification new_clause t bag x =
 536       prof_one_pass_simplification.HExtlib.profile (one_pass_simplification new_clause t bag ) x
 537     ;;
 538
 539     let simplification_step ~new_cl cl (alist,atable) bag maxvar new_clause =
 540       let atable1 =
 541         if new_cl then atable else
 542         IDX.index_unit_clause atable cl
 543       in
 544         (* Simplification of new_clause with :      *
 545          * - actives and cl if new_clause is not cl *
 546          * - only actives otherwise                 *)
 547         match
 548           simplify atable1 maxvar bag new_clause with
 549           | bag,None -> bag,(Some cl, None) (* new_clause has been discarded *)
 550           | bag,Some clause ->
 551               (* Simplification of each active clause with clause *
 552                * which is the simplified form of new_clause       *)
 553               let ctable = IDX.index_unit_clause IDX.DT.empty clause in
 554               let bag, newa, alist, atable =
 555                 List.fold_left
 556                   (fun (bag, newa, alist, atable) c ->
 557                      match simplify ctable maxvar bag c with
 558                        |bag,None -> (bag, newa, alist, atable)
 559                           (* an active clause as been discarded *)
 560                        |bag,Some c1 ->
 561                             if (c1 == c) then
 562                               bag, newa, c :: alist,
 563                             IDX.index_unit_clause atable c
 564                             else
 565                               bag, c1 :: newa, alist, atable)
 566                   (bag,[],[],IDX.DT.empty) alist
 567               in
 568                 if new_cl then
 569                   bag, (Some cl, Some (clause, (alist,atable), newa))
 570                 else
 571                   (* if new_clause is not cl, we simplify cl with clause *)
 572                   match simplify ctable maxvar bag cl with
 573                     | bag,None ->
 574                         (* cl has been discarded *)
 575                         bag,(None, Some (clause, (alist,atable), newa))
 576                     | bag,Some cl1 ->
 577                         bag,(Some cl1, Some (clause, (alist,atable), newa))
 578     ;;
 579     let prof_simplification_step = HExtlib.profile ~enable "simplification_step";;
 580     let simplification_step ~new_cl cl (alist,atable) bag maxvar x =
 581       prof_simplification_step.HExtlib.profile (simplification_step ~new_cl cl (alist,atable) bag maxvar) x
 582     ;;
 583
 584     let keep_simplified cl (alist,atable) bag maxvar =
 585       let rec keep_simplified_aux ~new_cl cl (alist,atable) bag newc =
 586         if new_cl then
 587           match simplification_step ~new_cl cl (alist,atable) bag maxvar cl with
 588             | _,(None, _) -> assert false
 589             | bag,(Some _, None) -> bag,None
 590             | bag,(Some _, Some (clause, (alist,atable), newa)) ->
 591                 keep_simplified_aux ~new_cl:(cl!=clause) clause (alist,atable)
 592                   bag (newa@newc)
 593         else
 594           match newc with
 595             | [] -> bag, Some (cl, (alist,atable))
 596             | hd::tl ->
 597                 match simplification_step ~new_cl cl
 598                   (alist,atable) bag maxvar hd with
 599                   | _,(None,None) -> assert false
 600                   | bag,(Some _,None) ->
 601                       keep_simplified_aux ~new_cl cl (alist,atable) bag tl
 602                   | bag,(None, Some _) -> bag,None
 603                   | bag,(Some cl1, Some (clause, (alist,atable), newa)) ->
 604                       let alist,atable =
 605                      (clause::alist, IDX.index_unit_clause atable clause)
 606                       in
 607                         keep_simplified_aux ~new_cl:(cl!=cl1) cl1 (alist,atable)
 608                           bag (newa@tl)
 609       in
 610         keep_simplified_aux ~new_cl:true cl (alist,atable) bag []
 611     ;;
 612     let prof_keep_simplified = HExtlib.profile ~enable "keep_simplified";;
 613     let keep_simplified cl t bag x =
 614       prof_keep_simplified.HExtlib.profile (keep_simplified cl t bag) x
 615     ;;
 616
 617     (* this is like simplify but raises Success *)
 618     let simplify_goal ~no_demod maxvar table bag g_actives clause =
 619       let bag, clause =
 620         if no_demod then bag, clause else demodulate bag clause table
 621       in
 622       if List.exists (are_alpha_eq clause) g_actives then None
 623       else match (is_identity_goal clause) with
 624         | Some subst -> raise (Success (bag,maxvar,clause,subst))
 625         | None ->
 626         let (id,lit,vl,_) = clause in
 627         (* this optimization makes sense only if we demodulated, since in
 628            that case the clause should have been turned into an identity *)
 629         if (vl = [] && not(no_demod))
 630         then Some (bag,clause)
 631         else
 632          let l,r,ty =
 633            match lit with
 634              | Terms.Equation(l,r,ty,_) -> l,r,ty
 635              | _ -> assert false
 636          in
 637          match deep_eq ~unify:true l r ty [] (fun x -> x) (fun x -> x)
 638            table (Some(bag,maxvar,clause,Subst.id_subst)) with
 639          | None -> Some (bag,clause)
 640          | Some (bag,maxvar,cl,subst) ->
 641              debug (lazy "Goal subsumed");
 642              raise (Success (bag,maxvar,cl,subst))
 643 (*
 644         match is_subsumed ~unify:true bag maxvar clause table with
 645         | None -> Some (bag, clause)
 646         | Some ((bag,maxvar),c) ->
 647             prerr_endline "Goal subsumed";
 648             raise (Success (bag,maxvar,c))
 649 *)
 650     ;;
 651
 652     let prof_simplify_goal = HExtlib.profile ~enable "simplify_goal";;
 653     let  simplify_goal ~no_demod maxvar table bag g_actives x =
 654       prof_simplify_goal.HExtlib.profile ( simplify_goal ~no_demod maxvar table bag g_actives) x
 655     ;;
 656
 657     (* =================== inference ===================== *)
 658
 659     (* this is OK for both the sup_left and sup_right inference steps *)
 660     let superposition table varlist subterm pos context =
 661       let cands = IDX.DT.retrieve_unifiables table subterm in
 662       HExtlib.filter_map
 663         (fun (dir, (id,lit,vl,_ (*as uc*))) ->
 664            match lit with
 665            | Terms.Predicate _ -> assert false
 666            | Terms.Equation (l,r,_,o) ->
 667                let side, newside = if dir=Terms.Left2Right then l,r else r,l in
 668                try
 669                  let subst =
 670                    Unif.unification (* (varlist@vl)*)  [] subterm side
 671                  in
 672                  if o = Terms.Incomparable || o = Terms.Invertible then
 673                    let side = Subst.apply_subst subst side in
 674                    let newside = Subst.apply_subst subst newside in
 675                    let o = Order.compare_terms side newside in
 676                    (* XXX: check Riazanov p. 33 (iii) *)
 677                    if o <> Terms.Lt && o <> Terms.Eq then
 678                      Some (context newside, subst, id, pos, dir)
 679                    else
 680                      ((*prerr_endline ("Filtering: " ^
 681                         Pp.pp_foterm side ^ " =(< || =)" ^
 682                         Pp.pp_foterm newside);*)None)
 683                  else
 684                    Some (context newside, subst, id, pos, dir)
 685                with FoUnif.UnificationFailure _ -> None)
 686         (IDX.ClauseSet.elements cands)
 687     ;;
 688
 689     (* Superposes selected equation with equalities in table *)
 690     let superposition_with_table bag maxvar (id,selected,vl,_) table =
 691       match selected with
 692       | Terms.Predicate _ -> assert false
 693       | Terms.Equation (l,r,ty,Terms.Lt) ->
 694           fold_build_new_clause bag maxvar id Terms.Superposition
 695             (fun _ -> true)
 696             (all_positions [3]
 697               (fun x -> Terms.Node [ Terms.Leaf B.eqP; ty; l; x ])
 698               r (superposition table vl))
 699       | Terms.Equation (l,r,ty,Terms.Invertible)
 700       | Terms.Equation (l,r,ty,Terms.Gt) ->
 701           fold_build_new_clause bag maxvar id Terms.Superposition
 702             (fun _ -> true)
 703             (all_positions [2]
 704               (fun x -> Terms.Node [ Terms.Leaf B.eqP; ty; x; r ])
 705               l (superposition table vl))
 706       | Terms.Equation (l,r,ty,Terms.Incomparable) ->
 707           let filtering avoid subst = (* Riazanov: p.33 condition (iv) *)
 708             let l = Subst.apply_subst subst l in
 709             let r = Subst.apply_subst subst r in
 710             let o = Order.compare_terms l r in
 711             o <> avoid && o <> Terms.Eq
 712           in
 713           let bag, maxvar,r_terms =
 714             fold_build_new_clause bag maxvar id Terms.Superposition
 715               (filtering Terms.Gt)
 716               (all_positions [3]
 717                  (fun x -> Terms.Node [ Terms.Leaf B.eqP; ty; l; x ])
 718                  r (superposition table vl))
 719           in
 720           let bag, maxvar, l_terms =
 721             fold_build_new_clause bag maxvar id Terms.Superposition
 722               (filtering Terms.Lt)
 723               (all_positions [2]
 724                  (fun x -> Terms.Node [ Terms.Leaf B.eqP; ty; x; r ])
 725                  l (superposition table vl))
 726           in
 727             bag, maxvar, r_terms @ l_terms
 728       | _ -> assert false
 729     ;;
 730
 731     (* the current equation is normal w.r.t. demodulation with atable
 732      * (and is not the identity) *)
 733     let infer_right bag maxvar current (alist,atable) =
 734       (* We demodulate actives clause with current until all *
 735        * active clauses are reduced w.r.t each other         *)
 736       (* let bag, (alist,atable) = keep_simplified (alist,atable) bag [current] in *)
 737       let ctable = IDX.index_unit_clause IDX.DT.empty current in
 738       (* let bag, (alist, atable) =
 739         let bag, alist =
 740           HExtlib.filter_map_acc (simplify ctable) bag alist
 741         in
 742         bag, (alist, List.fold_left IDX.index_unit_clause IDX.DT.empty alist)
 743       in*)
 744         debug (lazy "Simplified active clauses with fact");
 745       (* We superpose active clauses with current *)
 746       let bag, maxvar, new_clauses =
 747         List.fold_left
 748           (fun (bag, maxvar, acc) active ->
 749              let bag, maxvar, newc =
 750                superposition_with_table bag maxvar active ctable
 751              in
 752              bag, maxvar, newc @ acc)
 753           (bag, maxvar, []) alist
 754       in
 755         debug
 756         (lazy
 757          ("New clauses :" ^ (String.concat ";\n"
 758             (List.map Pp.pp_unit_clause new_clauses))));
 759         debug (lazy "First superpositions");
 760         (* We add current to active clauses so that it can be *
 761          * superposed with itself                             *)
 762       let alist, atable =
 763         current :: alist, IDX.index_unit_clause atable current
 764       in
 765         debug (lazy "Indexed");
 766       let fresh_current, maxvar = Utils.fresh_unit_clause maxvar current in
 767         (* We need to put fresh_current into the bag so that all *
 768          * variables clauses refer to are known.                 *)
 769       let bag, fresh_current = Terms.add_to_bag fresh_current bag in
 770         (* We superpose current with active clauses *)
 771       let bag, maxvar, additional_new_clauses =
 772         superposition_with_table bag maxvar fresh_current atable
 773       in
 774         debug (lazy "Another superposition");
 775       let new_clauses = new_clauses @ additional_new_clauses in
 776         (* debug (lazy (Printf.sprintf "Demodulating %d clauses"
 777                  (List.length new_clauses))); *)
 778       let bag, new_clauses =
 779         HExtlib.filter_map_monad (simplify atable maxvar) bag new_clauses
 780       in
 781         debug (lazy "Demodulated new clauses");
 782       bag, maxvar, (alist, atable), new_clauses
 783     ;;
 784
 785     let prof_ir = HExtlib.profile ~enable "infer_right";;
 786     let infer_right bag maxvar current t =
 787       prof_ir.HExtlib.profile (infer_right bag maxvar current) t
 788     ;;
 789
 790     let infer_left bag maxvar goal (_alist, atable) =
 791         (* We superpose the goal with active clauses *)
 792      if (match goal with (_,_,[],_) -> true | _ -> false) then bag, maxvar, []
 793      else
 794       let bag, maxvar, new_goals =
 795         superposition_with_table bag maxvar goal atable
 796       in
 797         debug(lazy  "Superposed goal with active clauses");
 798         (* We simplify the new goals with active clauses *)
 799       let bag, new_goals =
 800         List.fold_left
 801          (fun (bag, acc) g ->
 802             match simplify_goal ~no_demod:false maxvar atable bag [] g with
 803               | None -> assert false
 804               | Some (bag,g) -> bag,g::acc)
 805          (bag, []) new_goals
 806       in
 807         debug (lazy "Simplified new goals with active clauses");
 808       bag, maxvar, List.rev new_goals
 809     ;;
 810
 811     let prof_il = HExtlib.profile ~enable "infer_left";;
 812     let infer_left bag maxvar goal t =
 813       prof_il.HExtlib.profile (infer_left bag maxvar goal) t
 814     ;;
 815
 816   end