helm/software/components/ng_paramodulation/superposition.ml

   1 (*
   2     ||M||  This file is part of HELM, an Hypertextual, Electronic
   3     ||A||  Library of Mathematics, developed at the Computer Science
   4     ||T||  Department, University of Bologna, Italy.
   5     ||I||
   6     ||T||  HELM is free software; you can redistribute it and/or
   7     ||A||  modify it under the terms of the GNU General Public License
   8     \   /  version 2 or (at your option) any later version.
   9      \ /   This software is distributed as is, NO WARRANTY.
  10       V_______________________________________________________________ *)
  11
  12 (* $Id: index.mli 9822 2009-06-03 15:37:06Z tassi $ *)
  13
  14 module Superposition (B : Terms.Blob) =
  15   struct
  16     module IDX = Index.Index(B)
  17     module Unif = FoUnif.Founif(B)
  18     module Subst = FoSubst (*.Subst(B)*)
  19     module Order = Orderings.Orderings(B)
  20     module Utils = FoUtils.Utils(B)
  21     module Pp = Pp.Pp(B)
  22
  23     exception Success of B.t Terms.bag * int * B.t Terms.unit_clause
  24
  25     let debug s =
  26        () (* prerr_endline s *)
  27     ;;
  28
  29     let rec list_first f = function
  30       | [] -> None
  31       | x::tl -> match f x with Some _ as x -> x | _ -> list_first f tl
  32     ;;
  33
  34     let first_position pos ctx t f =
  35       let rec aux pos ctx = function
  36       | Terms.Leaf _ as t -> f t pos ctx
  37       | Terms.Var _ -> None
  38       | Terms.Node l as t->
  39           match f t pos ctx with
  40           | Some _ as x -> x
  41           | None ->
  42               let rec first pre post = function
  43                 | [] -> None
  44                 | t :: tl ->
  45                      let newctx = fun x -> ctx (Terms.Node (pre@[x]@post)) in
  46                      match aux (List.length pre :: pos) newctx t with
  47                      | Some _ as x -> x
  48                      | None ->
  49                          if post = [] then None (* tl is also empty *)
  50                          else first (pre @ [t]) (List.tl post) tl
  51               in
  52                 first [] (List.tl l) l
  53       in
  54         aux pos ctx t
  55     ;;
  56
  57     let all_positions pos ctx t f =
  58       let rec aux pos ctx = function
  59       | Terms.Leaf _ as t -> f t pos ctx
  60       | Terms.Var _ -> []
  61       | Terms.Node l as t->
  62           let acc, _, _ =
  63             List.fold_left
  64             (fun (acc,pre,post) t -> (* Invariant: pre @ [t] @ post = l *)
  65                 let newctx = fun x -> ctx (Terms.Node (pre@[x]@post)) in
  66                 let acc = aux (List.length pre :: pos) newctx t @ acc in
  67                 if post = [] then acc, l, []
  68                 else acc, pre @ [t], List.tl post)
  69              (f t pos ctx, [], List.tl l) l
  70           in
  71            acc
  72       in
  73         aux pos ctx t
  74     ;;
  75
  76     let vars_of_term t =
  77       let rec aux acc = function
  78         | Terms.Leaf _ -> acc
  79         | Terms.Var i -> if (List.mem i acc) then acc else i::acc
  80         | Terms.Node l -> List.fold_left aux acc l
  81       in aux [] t
  82     ;;
  83
  84     let build_clause bag filter rule t subst vl id id2 pos dir =
  85       let proof = Terms.Step(rule,id,id2,dir,pos,subst) in
  86       let t = Subst.apply_subst subst t in
  87       if filter t then
  88         let literal =
  89           match t with
  90           | Terms.Node [ Terms.Leaf eq ; ty; l; r ] when B.eq B.eqP eq ->
  91                let o = Order.compare_terms l r in
  92                Terms.Equation (l, r, ty, o)
  93           | t -> Terms.Predicate t
  94         in
  95         let bag, uc =
  96           Utils.add_to_bag bag (0, literal, vars_of_term t, proof)
  97         in
  98         Some (bag, uc)
  99       else
 100         ((*prerr_endline ("Filtering: " ^ Pp.pp_foterm t);*)None)
 101     ;;
 102
 103
 104     (* ============ simplification ================= *)
 105
 106     let demod table varlist subterm pos context =
 107       let cands = IDX.DT.retrieve_generalizations table subterm in
 108       list_first
 109         (fun (dir, (id,lit,vl,_)) ->
 110            match lit with
 111            | Terms.Predicate _ -> assert false
 112            | Terms.Equation (l,r,_,o) ->
 113                let side, newside = if dir=Terms.Left2Right then l,r else r,l in
 114                try
 115                  let subst, varlist =
 116                    Unif.unification (varlist@vl) varlist subterm side
 117                  in
 118                  if o = Terms.Incomparable then
 119                    let side = Subst.apply_subst subst side in
 120                    let newside = Subst.apply_subst subst newside in
 121                    let o = Order.compare_terms newside side in
 122                    (* Riazanov, pp. 45 (ii) *)
 123                    if o = Terms.Lt then
 124                      Some (context newside, subst, varlist, id, pos, dir)
 125                    else
 126                      ((*prerr_endline ("Filtering: " ^
 127                         Pp.pp_foterm side ^ " =(< || =)" ^
 128                         Pp.pp_foterm newside ^ " coming from " ^
 129                         Pp.pp_unit_clause uc );*)None)
 130                  else
 131                    Some (context newside, subst, varlist, id, pos, dir)
 132                with FoUnif.UnificationFailure _ -> None)
 133         (IDX.ClauseSet.elements cands)
 134     ;;
 135
 136     let demodulate_once ~jump_to_right bag (id, literal, vl, pr) table =
 137       (* debug ("Demodulating : " ^ (Pp.pp_unit_clause (id, literal, vl, pr)));*)
 138       match literal with
 139       | Terms.Predicate t -> assert false
 140       | Terms.Equation (l,r,ty,_) ->
 141         let left_position = if jump_to_right then None else
 142           first_position [2]
 143             (fun x -> Terms.Node [ Terms.Leaf B.eqP; ty; x; r ]) l
 144             (demod table vl)
 145         in
 146         match left_position with
 147           | Some (newt, subst, varlist, id2, pos, dir) ->
 148               begin
 149                 match build_clause bag (fun _ -> true) Terms.Demodulation
 150                   newt subst varlist id id2 pos dir
 151                 with
 152                   | None -> assert false
 153                   | Some x -> Some (x,false)
 154               end
 155           | None ->
 156               match first_position
 157                 [3] (fun x -> Terms.Node [ Terms.Leaf B.eqP; ty; l; x ]) r
 158                 (demod table vl)
 159               with
 160                 | None -> None
 161                 | Some (newt, subst, varlist, id2, pos, dir) ->
 162                     match build_clause bag (fun _ -> true)
 163                       Terms.Demodulation newt subst varlist id id2 pos dir
 164                     with
 165                         | None -> assert false
 166                         | Some x -> Some (x,true)
 167     ;;
 168
 169     let rec demodulate ~jump_to_right bag clause table =
 170       match demodulate_once ~jump_to_right bag clause table with
 171       | None -> bag, clause
 172       | Some ((bag, clause),r) -> demodulate ~jump_to_right:r
 173           bag clause table
 174     ;;
 175
 176     let demodulate bag clause table = demodulate ~jump_to_right:false
 177       bag clause table
 178     ;;
 179
 180     (* move away *)
 181     let is_identity_clause = function
 182       | _, Terms.Equation (_,_,_,Terms.Eq), _, _ -> true
 183       | _, Terms.Equation (l,r,_,_), vl, proof ->
 184           (try ignore(Unif.unification vl [] l r); true
 185           with FoUnif.UnificationFailure _ -> false)
 186       | _, Terms.Predicate _, _, _ -> assert false
 187     ;;
 188
 189     let build_new_clause bag maxvar filter rule t subst vl id id2 pos dir =
 190       let maxvar, vl, relocsubst = Utils.relocate maxvar vl in
 191       let subst = Subst.concat relocsubst subst in
 192       match build_clause bag filter rule t subst vl id id2 pos dir with
 193       | Some (bag, c) -> Some ((bag, maxvar), c)
 194       | None -> None
 195     ;;
 196
 197
 198     let fold_build_new_clause bag maxvar id rule filter res =
 199       let (bag, maxvar), res =
 200        HExtlib.filter_map_acc
 201          (fun (bag, maxvar) (t,subst,vl,id2,pos,dir) ->
 202             build_new_clause bag maxvar filter rule t subst vl id id2 pos dir)
 203          (bag, maxvar) res
 204       in
 205        bag, maxvar, res
 206     ;;
 207
 208     let is_subsumed ~unify bag maxvar (id, lit, vl, _) table =
 209       match lit with
 210       | Terms.Predicate _ -> assert false
 211       | Terms.Equation (l,r,ty,_) ->
 212           let retrieve = if unify then IDX.DT.retrieve_unifiables
 213           else IDX.DT.retrieve_generalizations in
 214           let lcands = retrieve table l in
 215           let rcands = retrieve table r in
 216           let f b c =
 217             let id, dir, l, r, vl =
 218               match c with
 219               | (d, (id,Terms.Equation (l,r,ty,_),vl,_))-> id, d, l, r, vl
 220               |_ -> assert false
 221             in
 222             let reverse = (dir = Terms.Left2Right) = b in
 223             let l, r, proof_rewrite_dir = if reverse then l,r,Terms.Left2Right
 224             else r,l, Terms.Right2Left in
 225             (id,proof_rewrite_dir,Terms.Node [ Terms.Leaf B.eqP; ty; l; r ], vl)
 226           in
 227           let cands1 = List.map (f true) (IDX.ClauseSet.elements lcands) in
 228           let cands2 = List.map (f false) (IDX.ClauseSet.elements rcands) in
 229           let t = Terms.Node [ Terms.Leaf B.eqP; ty; l; r ] in
 230           let locked_vars = if unify then [] else vl in
 231           let rec aux = function
 232             | [] -> None
 233             | (id2,dir,c,vl1)::tl ->
 234                 try
 235                   let subst,vl1 = Unif.unification (vl@vl1) locked_vars c t in
 236                   let id_t = Terms.Node [ Terms.Leaf B.eqP; ty; r; r ] in
 237                     build_new_clause bag maxvar (fun _ -> true)
 238                       Terms.Superposition id_t subst [] id id2 [2] dir
 239                 with FoUnif.UnificationFailure _ -> aux tl
 240           in
 241             aux (cands1 @ cands2)
 242     ;;
 243
 244     (* demodulate and check for subsumption *)
 245     let simplify table maxvar bag clause =
 246       let bag, clause = demodulate bag clause table in
 247       if is_identity_clause clause then None
 248       else
 249         match is_subsumed ~unify:false bag maxvar clause table with
 250           | None -> Some (bag, clause)
 251           | Some _ -> None
 252     ;;
 253
 254     let one_pass_simplification new_clause (alist,atable) bag maxvar =
 255       match simplify atable maxvar bag new_clause with
 256         | None -> None (* new_clause has been discarded *)
 257         | Some (bag, clause) ->
 258             let ctable = IDX.index_unit_clause IDX.DT.empty clause in
 259             let bag, alist, atable =
 260               List.fold_left
 261                 (fun (bag, alist, atable as acc) c ->
 262                    match simplify ctable maxvar bag c with
 263                      |None -> acc (* an active clause as been discarded *)
 264                      |Some (bag, c1) ->
 265                         bag, c :: alist, IDX.index_unit_clause atable c)
 266                 (bag,[],IDX.DT.empty) alist
 267             in
 268               Some (clause, bag, (alist,atable))
 269     ;;
 270
 271     let simplification_step ~new_cl cl (alist,atable) bag maxvar new_clause =
 272       let atable1 =
 273         if new_cl then atable else
 274         IDX.index_unit_clause atable cl
 275       in
 276         (* Simplification of new_clause with :      *
 277          * - actives and cl if new_clause is not cl *
 278          * - only actives otherwise                 *)
 279         match simplify atable1 maxvar bag new_clause with
 280           | None -> (Some cl, None) (* new_clause has been discarded *)
 281           | Some (bag, clause) ->
 282               (* Simplification of each active clause with clause *
 283                * which is the simplified form of new_clause       *)
 284               let ctable = IDX.index_unit_clause IDX.DT.empty clause in
 285               let bag, newa, alist, atable =
 286                 List.fold_left
 287                   (fun (bag, newa, alist, atable as acc) c ->
 288                      match simplify ctable maxvar bag c with
 289                        |None -> acc (* an active clause as been discarded *)
 290                        |Some (bag, c1) ->
 291                             if (c1 == c) then
 292                               bag, newa, c :: alist,
 293                             IDX.index_unit_clause atable c
 294                             else
 295                               bag, c1 :: newa, alist, atable)
 296                   (bag,[],[],IDX.DT.empty) alist
 297               in
 298                 if new_cl then
 299                   (Some cl, Some (clause, (alist,atable), newa, bag))
 300                 else
 301                   (* if new_clause is not cl, we simplify cl with clause *)
 302                   match simplify ctable maxvar bag cl with
 303                     | None ->
 304                         (* cl has been discarded *)
 305                         (None, Some (clause, (alist,atable), newa, bag))
 306                     | Some (bag,cl1) ->
 307                         (Some cl1, Some (clause, (alist,atable), newa, bag))
 308     ;;
 309
 310     let keep_simplified cl (alist,atable) bag maxvar =
 311       let rec keep_simplified_aux ~new_cl cl (alist,atable) bag newc =
 312         if new_cl then
 313           match simplification_step ~new_cl cl (alist,atable) bag maxvar cl with
 314             | (None, _) -> assert false
 315             | (Some _, None) -> None
 316             | (Some _, Some (clause, (alist,atable), newa, bag)) ->
 317                 keep_simplified_aux ~new_cl:(cl!=clause) clause (alist,atable)
 318                   bag (newa@newc)
 319         else
 320           match newc with
 321             | [] -> Some (cl, bag, (alist,atable))
 322             | hd::tl ->
 323                 match simplification_step ~new_cl cl
 324                   (alist,atable) bag maxvar hd with
 325                   | (None,None) -> assert false
 326                   | (Some _,None) ->
 327                       keep_simplified_aux ~new_cl cl (alist,atable) bag tl
 328                   | (None, Some _) -> None
 329                   | (Some cl1, Some (clause, (alist,atable), newa, bag)) ->
 330                       let alist,atable =
 331                         (clause::alist, IDX.index_unit_clause atable clause)
 332                       in
 333                         keep_simplified_aux ~new_cl:(cl!=cl1) cl1 (alist,atable)
 334                           bag (newa@tl)
 335       in
 336         keep_simplified_aux ~new_cl:true cl (alist,atable) bag []
 337     ;;
 338
 339     let are_alpha_eq cl1 cl2 =
 340       let get_term (_,lit,_,_) =
 341         match lit with
 342           | Terms.Predicate _ -> assert false
 343           | Terms.Equation (l,r,ty,_) ->
 344               Terms.Node [Terms.Leaf B.eqP; ty; l ; r]
 345       in
 346         try ignore(Unif.alpha_eq (get_term cl1) (get_term cl2)) ; true
 347         with FoUnif.UnificationFailure _ -> false
 348 ;;
 349
 350     (* this is like simplify but raises Success *)
 351     let simplify_goal maxvar table bag g_actives clause =
 352       let bag, clause = demodulate bag clause table in
 353       if (is_identity_clause clause)
 354       then raise (Success (bag, maxvar, clause))
 355       else match is_subsumed ~unify:true bag maxvar clause table with
 356         | None ->
 357             if List.exists (are_alpha_eq clause) g_actives then None
 358             else Some (bag, clause)
 359         | Some ((bag,maxvar),c) ->
 360             debug "Goal subsumed";
 361             raise (Success (bag,maxvar,c))
 362     ;;
 363
 364     (* =================== inference ===================== *)
 365
 366     (* this is OK for both the sup_left and sup_right inference steps *)
 367     let superposition table varlist subterm pos context =
 368       let cands = IDX.DT.retrieve_unifiables table subterm in
 369       HExtlib.filter_map
 370         (fun (dir, (id,lit,vl,_ (*as uc*))) ->
 371            match lit with
 372            | Terms.Predicate _ -> assert false
 373            | Terms.Equation (l,r,_,o) ->
 374                let side, newside = if dir=Terms.Left2Right then l,r else r,l in
 375                try
 376                  let subst, varlist =
 377                    Unif.unification (varlist@vl) [] subterm side
 378                  in
 379                  if o = Terms.Incomparable then
 380                    let side = Subst.apply_subst subst side in
 381                    let newside = Subst.apply_subst subst newside in
 382                    let o = Order.compare_terms side newside in
 383                    (* XXX: check Riazanov p. 33 (iii) *)
 384                    if o <> Terms.Lt && o <> Terms.Eq then
 385                      Some (context newside, subst, varlist, id, pos, dir)
 386                    else
 387                      ((*prerr_endline ("Filtering: " ^
 388                         Pp.pp_foterm side ^ " =(< || =)" ^
 389                         Pp.pp_foterm newside ^ " coming from " ^
 390                         Pp.pp_unit_clause uc );*)None)
 391                  else
 392                    Some (context newside, subst, varlist, id, pos, dir)
 393                with FoUnif.UnificationFailure _ -> None)
 394         (IDX.ClauseSet.elements cands)
 395     ;;
 396
 397     (* Superposes selected equation with equalities in table *)
 398     let superposition_with_table bag maxvar (id,selected,vl,_) table =
 399       match selected with
 400       | Terms.Predicate _ -> assert false
 401       | Terms.Equation (l,r,ty,Terms.Lt) ->
 402           fold_build_new_clause bag maxvar id Terms.Superposition
 403             (fun _ -> true)
 404             (all_positions [3]
 405               (fun x -> Terms.Node [ Terms.Leaf B.eqP; ty; l; x ])
 406               r (superposition table vl))
 407       | Terms.Equation (l,r,ty,Terms.Gt) ->
 408           fold_build_new_clause bag maxvar id Terms.Superposition
 409             (fun _ -> true)
 410             (all_positions [2]
 411               (fun x -> Terms.Node [ Terms.Leaf B.eqP; ty; x; r ])
 412               l (superposition table vl))
 413       | Terms.Equation (l,r,ty,Terms.Incomparable) ->
 414           fold_build_new_clause bag maxvar id Terms.Superposition
 415             (function (* Riazanov: p.33 condition (iv) *)
 416               | Terms.Node [Terms.Leaf eq; ty; l; r ] when B.eq B.eqP eq ->
 417                   Order.compare_terms l r <> Terms.Eq
 418               | _ -> assert false)
 419             ((all_positions [3]
 420                (fun x -> Terms.Node [ Terms.Leaf B.eqP; ty; l; x ])
 421                r (superposition table vl)) @
 422              (all_positions [2]
 423                (fun x -> Terms.Node [ Terms.Leaf B.eqP; ty; x; r ])
 424                l (superposition table vl)))
 425       | _ -> assert false
 426     ;;
 427
 428     (* the current equation is normal w.r.t. demodulation with atable
 429      * (and is not the identity) *)
 430     let infer_right bag maxvar current (alist,atable) =
 431       (* We demodulate actives clause with current until all *
 432        * active clauses are reduced w.r.t each other         *)
 433       (* let bag, (alist,atable) = keep_simplified (alist,atable) bag [current] in *)
 434       let ctable = IDX.index_unit_clause IDX.DT.empty current in
 435       (* let bag, (alist, atable) =
 436         let bag, alist =
 437           HExtlib.filter_map_acc (simplify ctable) bag alist
 438         in
 439         bag, (alist, List.fold_left IDX.index_unit_clause IDX.DT.empty alist)
 440       in*)
 441         debug "Simplified active clauses with fact";
 442       (* We superpose active clauses with current *)
 443       let bag, maxvar, new_clauses =
 444         List.fold_left
 445           (fun (bag, maxvar, acc) active ->
 446              let bag, maxvar, newc =
 447                superposition_with_table bag maxvar active ctable
 448              in
 449              bag, maxvar, newc @ acc)
 450           (bag, maxvar, []) alist
 451       in
 452         debug "First superpositions";
 453         (* We add current to active clauses so that it can be *
 454          * superposed with itself                             *)
 455       let alist, atable =
 456         current :: alist, IDX.index_unit_clause atable current
 457       in
 458         debug "Indexed";
 459       let fresh_current, maxvar = Utils.fresh_unit_clause maxvar current in
 460         (* We need to put fresh_current into the bag so that all *
 461          * variables clauses refer to are known.                 *)
 462       let bag, fresh_current = Utils.add_to_bag bag fresh_current in
 463         (* We superpose current with active clauses *)
 464       let bag, maxvar, additional_new_clauses =
 465         superposition_with_table bag maxvar fresh_current atable
 466       in
 467         debug "Another superposition";
 468       let new_clauses = new_clauses @ additional_new_clauses in
 469         debug (Printf.sprintf "Demodulating %d clauses"
 470                  (List.length new_clauses));
 471       let bag, new_clauses =
 472         HExtlib.filter_map_acc (simplify atable maxvar) bag new_clauses
 473       in
 474         debug "Demodulated new clauses";
 475       bag, maxvar, (alist, atable), new_clauses
 476     ;;
 477
 478     let infer_left bag maxvar goal (_alist, atable) =
 479         (* We superpose the goal with active clauses *)
 480       let bag, maxvar, new_goals =
 481         superposition_with_table bag maxvar goal atable
 482       in
 483         debug "Superposed goal with active clauses";
 484         (* We simplify the new goals with active clauses *)
 485       let bag, new_goals =
 486         List.fold_left
 487          (fun (bag, acc) g ->
 488             match simplify_goal maxvar atable bag [] g with
 489               | None -> assert false
 490               | Some (bag,g) -> bag,g::acc)
 491          (bag, []) new_goals
 492       in
 493         debug "Simplified new goals with active clauses";
 494       bag, maxvar, List.rev new_goals
 495     ;;
 496
 497   end