helm/software/components/ng_paramodulation/superposition.ml

   1 (*
   2     ||M||  This file is part of HELM, an Hypertextual, Electronic
   3     ||A||  Library of Mathematics, developed at the Computer Science
   4     ||T||  Department, University of Bologna, Italy.
   5     ||I||
   6     ||T||  HELM is free software; you can redistribute it and/or
   7     ||A||  modify it under the terms of the GNU General Public License
   8     \   /  version 2 or (at your option) any later version.
   9      \ /   This software is distributed as is, NO WARRANTY.
  10       V_______________________________________________________________ *)
  11
  12 (* $Id: index.mli 9822 2009-06-03 15:37:06Z tassi $ *)
  13
  14 module Superposition (B : Orderings.Blob) =
  15   struct
  16     module IDX = Index.Index(B)
  17     module Unif = FoUnif.Founif(B)
  18     module Subst = FoSubst
  19     module Order = B
  20     module Utils = FoUtils.Utils(B)
  21     module Pp = Pp.Pp(B)
  22
  23     exception Success of
  24       B.t Terms.bag
  25       * int
  26       * B.t Terms.unit_clause
  27       * B.t Terms.substitution
  28
  29     let print s = prerr_endline (Lazy.force s);;
  30     let debug _ = ();;
  31     let enable = true;;
  32
  33     let rec list_first f = function
  34       | [] -> None
  35       | x::tl -> match f x with Some _ as x -> x | _ -> list_first f tl
  36     ;;
  37
  38     let first_position pos ctx t f =
  39       let inject_pos pos ctx = function
  40         | None -> None
  41         | Some (a,b,c,d) -> Some(ctx a,b,c,d,pos)
  42       in
  43       let rec aux pos ctx = function
  44       | Terms.Leaf _ as t -> inject_pos pos ctx (f t)
  45       | Terms.Var _ -> None
  46       | Terms.Node l as t->
  47           match f t with
  48           | Some _ as x -> inject_pos pos ctx x
  49           | None ->
  50               let rec first pre post = function
  51                 | [] -> None
  52                 | t :: tl ->
  53                      let newctx = fun x -> ctx (Terms.Node (pre@[x]@post)) in
  54                      match aux (List.length pre :: pos) newctx t with
  55                      | Some _ as x -> x
  56                      | None ->
  57                          if post = [] then None (* tl is also empty *)
  58                          else first (pre @ [t]) (List.tl post) tl
  59               in
  60                 first [] (List.tl l) l
  61       in
  62         aux pos ctx t
  63     ;;
  64
  65     let all_positions pos ctx t f =
  66       let rec aux pos ctx = function
  67       | Terms.Leaf _ as t -> f t pos ctx
  68       | Terms.Var _ -> []
  69       | Terms.Node l as t->
  70           let acc, _, _ =
  71             List.fold_left
  72             (fun (acc,pre,post) t -> (* Invariant: pre @ [t] @ post = l *)
  73                 let newctx = fun x -> ctx (Terms.Node (pre@[x]@post)) in
  74                 let acc = aux (List.length pre :: pos) newctx t @ acc in
  75                 if post = [] then acc, l, []
  76                 else acc, pre @ [t], List.tl post)
  77              (f t pos ctx, [], List.tl l) l
  78           in
  79            acc
  80       in
  81         aux pos ctx t
  82     ;;
  83
  84     let parallel_positions bag pos ctx id t f =
  85       let rec aux bag pos ctx id = function
  86       | Terms.Leaf _ as t -> f bag t pos ctx id
  87       | Terms.Var _ as t -> bag,t,id
  88       | Terms.Node (hd::l) as t->
  89           let bag,t,id1 = f bag t pos ctx id in
  90             if id = id1 then
  91               let bag, l, _, id =
  92                 List.fold_left
  93                   (fun (bag,pre,post,id) t ->
  94                      let newctx = fun x -> ctx (Terms.Node (pre@[x]@post)) in
  95                      let newpos = (List.length pre)::pos in
  96                      let bag,newt,id = aux bag newpos newctx id t in
  97                        if post = [] then bag, pre@[newt], [], id
  98                        else bag, pre @ [newt], List.tl post, id)
  99                   (bag, [hd], List.tl l, id) l
 100               in
 101                 bag, Terms.Node l, id
 102             else bag,t,id1
 103             (* else aux bag pos ctx id1 t *)
 104       | _ -> assert false
 105       in
 106         aux bag pos ctx id t
 107     ;;
 108
 109     let visit bag pos ctx id t f =
 110       let rec aux bag pos ctx id subst = function
 111       | Terms.Leaf _ as t ->
 112           let  bag,subst,t,id = f bag t pos ctx id
 113           in assert (subst=[]); bag,t,id
 114       | Terms.Var i as t ->
 115           let t= Subst.apply_subst subst t in
 116             bag,t,id
 117       | Terms.Node (hd::l) ->
 118           let bag, l, _, id =
 119             List.fold_left
 120               (fun (bag,pre,post,id) t ->
 121                  let newctx = fun x -> ctx (Terms.Node (pre@[x]@post)) in
 122                  let newpos = (List.length pre)::pos in
 123                  let bag,newt,id = aux bag newpos newctx id subst t in
 124                    if post = [] then bag, pre@[newt], [], id
 125                    else bag, pre @ [newt], List.tl post, id)
 126               (bag, [hd], List.map (Subst.apply_subst subst) (List.tl l), id) l
 127           in
 128           let bag,subst,t,id1 = f bag (Terms.Node l) pos ctx id
 129           in
 130             if id1 = id then (assert (subst=[]); bag,t,id)
 131             else aux bag pos ctx id1 subst t
 132       | _ -> assert false
 133       in
 134         aux bag pos ctx id [] t
 135     ;;
 136
 137     let build_clause bag filter rule t subst id id2 pos dir =
 138       let proof = Terms.Step(rule,id,id2,dir,pos,subst) in
 139       let t = Subst.apply_subst subst t in
 140       if filter subst then
 141         let literal =
 142           match t with
 143           | Terms.Node [ Terms.Leaf eq ; ty; l; r ] when B.eq B.eqP eq ->
 144                let o = Order.compare_terms l r in
 145                Terms.Equation (l, r, ty, o)
 146           | t -> Terms.Predicate t
 147         in
 148         let bag, uc =
 149           Terms.add_to_bag (0, literal, Terms.vars_of_term t, proof) bag
 150         in
 151         Some (bag, uc)
 152       else
 153         ((*prerr_endline ("Filtering: " ^ Pp.pp_foterm t);*)None)
 154     ;;
 155     let prof_build_clause = HExtlib.profile ~enable "build_clause";;
 156     let build_clause bag filter rule t subst id id2 pos x =
 157       prof_build_clause.HExtlib.profile (build_clause bag filter rule t subst id id2 pos) x
 158     ;;
 159
 160
 161     (* ============ simplification ================= *)
 162     let prof_demod_u = HExtlib.profile ~enable "demod.unify";;
 163     let prof_demod_r = HExtlib.profile ~enable "demod.retrieve_generalizations";;
 164     let prof_demod_o = HExtlib.profile ~enable "demod.compare_terms";;
 165     let prof_demod_s = HExtlib.profile ~enable "demod.apply_subst";;
 166
 167     let demod table varlist subterm =
 168       let cands =
 169         prof_demod_r.HExtlib.profile
 170          (IDX.DT.retrieve_generalizations table) subterm
 171       in
 172       list_first
 173         (fun (dir, (id,lit,vl,_)) ->
 174            match lit with
 175            | Terms.Predicate _ -> assert false
 176            | Terms.Equation (l,r,_,o) ->
 177                let side, newside = if dir=Terms.Left2Right then l,r else r,l in
 178                try
 179                  let subst =
 180                    prof_demod_u.HExtlib.profile
 181                      (Unif.unification (* (varlist@vl) *) varlist subterm) side
 182                  in
 183                  let side =
 184                    prof_demod_s.HExtlib.profile
 185                      (Subst.apply_subst subst) side
 186                  in
 187                  let newside =
 188                    prof_demod_s.HExtlib.profile
 189                      (Subst.apply_subst subst) newside
 190                  in
 191                  if o = Terms.Incomparable || o = Terms.Invertible then
 192                    let o =
 193                      prof_demod_o.HExtlib.profile
 194                       (Order.compare_terms newside) side in
 195                    (* Riazanov, pp. 45 (ii) *)
 196                    if o = Terms.Lt then
 197                      Some (newside, subst, id, dir)
 198                    else
 199                      ((*prerr_endline ("Filtering: " ^
 200                         Pp.pp_foterm side ^ " =(< || =)" ^
 201                         Pp.pp_foterm newside ^ " coming from " ^
 202                         Pp.pp_unit_clause uc );*)None)
 203                  else
 204                    Some (newside, subst, id, dir)
 205                with FoUnif.UnificationFailure _ -> None)
 206         (IDX.ClauseSet.elements cands)
 207     ;;
 208     let prof_demod = HExtlib.profile ~enable "demod";;
 209     let demod table varlist x =
 210       prof_demod.HExtlib.profile (demod table varlist) x
 211     ;;
 212
 213     let mydemod table varlist subterm =
 214       let cands =
 215         prof_demod_r.HExtlib.profile
 216          (IDX.DT.retrieve_generalizations table) subterm
 217       in
 218       list_first
 219         (fun (dir, ((id,lit,vl,_) as c)) ->
 220            debug (lazy("candidate: "
 221                        ^ Pp.pp_unit_clause c));
 222            match lit with
 223            | Terms.Predicate _ -> assert false
 224            | Terms.Equation (l,r,_,o) ->
 225                let side, newside = if dir=Terms.Left2Right then l,r else r,l in
 226                try
 227                  let subst =
 228                    prof_demod_u.HExtlib.profile
 229                      (Unif.unification (* (varlist@vl) *) varlist subterm) side
 230                  in
 231                  let iside =
 232                    prof_demod_s.HExtlib.profile
 233                      (Subst.apply_subst subst) side
 234                  in
 235                  let inewside =
 236                    prof_demod_s.HExtlib.profile
 237                      (Subst.apply_subst subst) newside
 238                  in
 239                  if o = Terms.Incomparable || o = Terms.Invertible then
 240                    let o =
 241                      prof_demod_o.HExtlib.profile
 242                       (Order.compare_terms inewside) iside in
 243                    (* Riazanov, pp. 45 (ii) *)
 244                    if o = Terms.Lt then
 245                      Some (newside, subst, id, dir)
 246                    else
 247                      ((*prerr_endline ("Filtering: " ^
 248                         Pp.pp_foterm side ^ " =(< || =)" ^
 249                         Pp.pp_foterm newside ^ " coming from " ^
 250                         Pp.pp_unit_clause uc );*)
 251                        debug (lazy "not applied");None)
 252                  else
 253                    Some (newside, subst, id, dir)
 254                with FoUnif.UnificationFailure _ ->
 255                  debug (lazy "not applied"); None)
 256         (IDX.ClauseSet.elements cands)
 257     ;;
 258
 259     let ctx_demod table vl bag t pos ctx id =
 260       match mydemod table vl t with
 261         | None -> (bag,[],t,id)
 262         | Some (newside, subst, id2, dir) ->
 263             let inewside = Subst.apply_subst subst newside in
 264             match build_clause bag (fun _ -> true)
 265               Terms.Demodulation (ctx inewside) subst id id2 pos dir
 266             with
 267               | None -> assert false
 268               | Some (bag,(id,_,_,_)) ->
 269                     (bag,subst,newside,id)
 270     ;;
 271
 272     let rec demodulate bag (id, literal, vl, pr) table =
 273       debug (lazy ("demodulate " ^ (string_of_int id)));
 274        match literal with
 275       | Terms.Predicate t -> assert false
 276       | Terms.Equation (l,r,ty,_) ->
 277           let bag,l,id1 =
 278             visit bag [2]
 279             (fun x -> Terms.Node [ Terms.Leaf B.eqP; ty; x; r ]) id l
 280             (ctx_demod table vl)
 281           in
 282           let bag,_,id2 =
 283             visit bag [3]
 284               (fun x -> Terms.Node [ Terms.Leaf B.eqP; ty; l; x ]) id1 r
 285               (ctx_demod table vl)
 286           in
 287           let cl,_,_ = Terms.get_from_bag id2 bag in
 288             bag,cl
 289     ;;
 290
 291     let parallel_demod table vl bag t pos ctx id =
 292       match demod table vl t with
 293         | None -> (bag,t,id)
 294         | Some (newside, subst, id2, dir) ->
 295             match build_clause bag (fun _ -> true)
 296               Terms.Demodulation (ctx newside) subst id id2 pos dir
 297             with
 298               | None -> assert false
 299               | Some (bag,(id,_,_,_)) ->
 300                     (bag,newside,id)
 301     ;;
 302
 303     let are_alpha_eq cl1 cl2 =
 304       let get_term (_,lit,_,_) =
 305         match lit with
 306           | Terms.Predicate _ -> assert false
 307           | Terms.Equation (l,r,ty,_) ->
 308               Terms.Node [Terms.Leaf B.eqP; ty; l ; r]
 309       in
 310         try ignore(Unif.alpha_eq (get_term cl1) (get_term cl2)) ; true
 311         with FoUnif.UnificationFailure _ -> false
 312     ;;
 313
 314     let prof_demodulate = HExtlib.profile ~enable "demodulate";;
 315     let demodulate bag clause x =
 316       prof_demodulate.HExtlib.profile (demodulate bag clause) x
 317     ;;
 318
 319     (* move away *)
 320     let is_identity_clause = function
 321       | _, Terms.Equation (_,_,_,Terms.Eq), _, _ -> true
 322       | _, Terms.Equation (_,_,_,_), _, _ -> false
 323       | _, Terms.Predicate _, _, _ -> assert false
 324     ;;
 325
 326     let is_identity_goal = function
 327       | _, Terms.Equation (_,_,_,Terms.Eq), _, _ -> Some []
 328       | _, Terms.Equation (l,r,_,_), vl, proof ->
 329           (try Some (Unif.unification (* vl *) [] l r)
 330            with FoUnif.UnificationFailure _ -> None)
 331       | _, Terms.Predicate _, _, _ -> assert false
 332     ;;
 333
 334     let build_new_clause_reloc bag maxvar filter rule t subst id id2 pos dir =
 335       let maxvar, _vl, subst = Utils.relocate maxvar (Terms.vars_of_term
 336       (Subst.apply_subst subst t)) subst in
 337       match build_clause bag filter rule t subst id id2 pos dir with
 338       | Some (bag, c) -> Some ((bag, maxvar), c), subst
 339       | None -> None,subst
 340     ;;
 341
 342     let build_new_clause bag maxvar filter rule t subst id id2 pos dir =
 343       fst (build_new_clause_reloc bag maxvar filter rule t
 344              subst id id2 pos dir)
 345     ;;
 346
 347     let prof_build_new_clause = HExtlib.profile ~enable "build_new_clause";;
 348     let build_new_clause bag maxvar filter rule t subst id id2 pos x =
 349       prof_build_new_clause.HExtlib.profile (build_new_clause bag maxvar filter
 350       rule t subst id id2 pos) x
 351     ;;
 352
 353     let fold_build_new_clause bag maxvar id rule filter res =
 354       let (bag, maxvar), res =
 355        HExtlib.filter_map_acc
 356          (fun (bag, maxvar) (t,subst,id2,pos,dir) ->
 357             build_new_clause bag maxvar filter rule t subst id id2 pos dir)
 358          (bag, maxvar) res
 359       in
 360        bag, maxvar, res
 361     ;;
 362
 363     let rewrite_eq ~unify l r ty vl table =
 364       let retrieve = if unify then IDX.DT.retrieve_unifiables
 365       else IDX.DT.retrieve_generalizations in
 366       let lcands = retrieve table l in
 367       let rcands = retrieve table r in
 368       let f b c =
 369         let id, dir, l, r, vl =
 370           match c with
 371             | (d, (id,Terms.Equation (l,r,ty,_),vl,_))-> id, d, l, r, vl
 372             |_ -> assert false
 373         in
 374         let reverse = (dir = Terms.Left2Right) = b in
 375         let l, r, proof_rewrite_dir = if reverse then l,r,Terms.Left2Right
 376         else r,l, Terms.Right2Left in
 377           (id,proof_rewrite_dir,Terms.Node [ Terms.Leaf B.eqP; ty; l; r ], vl)
 378       in
 379       let cands1 = List.map (f true) (IDX.ClauseSet.elements lcands) in
 380       let cands2 = List.map (f false) (IDX.ClauseSet.elements rcands) in
 381       let t = Terms.Node [ Terms.Leaf B.eqP; ty; l; r ] in
 382       let locked_vars = if unify then [] else vl in
 383       let rec aux = function
 384         | [] -> None
 385         | (id2,dir,c,vl1)::tl ->
 386             try
 387               let subst = Unif.unification (* (vl@vl1) *) locked_vars c t in
 388               Some (id2, dir, subst)
 389             with FoUnif.UnificationFailure _ -> aux tl
 390       in
 391         aux (cands1 @ cands2)
 392     ;;
 393
 394     let is_subsumed ~unify bag maxvar (id, lit, vl, _) table =
 395       match lit with
 396       | Terms.Predicate _ -> assert false
 397       | Terms.Equation (l,r,ty,_) ->
 398           match rewrite_eq ~unify l r ty vl table with
 399             | None -> None
 400             | Some (id2, dir, subst) ->
 401                 let id_t = Terms.Node [ Terms.Leaf B.eqP; ty; r; r ] in
 402                   build_new_clause bag maxvar (fun _ -> true)
 403                   Terms.Superposition id_t subst id id2 [2] dir
 404     ;;
 405     let prof_is_subsumed = HExtlib.profile ~enable "is_subsumed";;
 406     let is_subsumed ~unify bag maxvar c x =
 407       prof_is_subsumed.HExtlib.profile (is_subsumed ~unify bag maxvar c) x
 408     ;;
 409     (* id refers to a clause proving contextl l = contextr r *)
 410
 411     let rec deep_eq ~unify l r ty pos contextl contextr table acc =
 412       match acc with
 413       | None -> None
 414       | Some(bag,maxvar,(id,lit,vl,p),subst) ->
 415           (* prerr_endline ("input subst = "^Pp.pp_substitution subst); *)
 416           let l = Subst.apply_subst subst l in
 417           let r = Subst.apply_subst subst r in
 418             try
 419               let subst1 = Unif.unification (* vl *) [] l r in
 420               let lit =
 421                 match lit with Terms.Predicate _ -> assert false
 422                   | Terms.Equation (l,r,ty,o) ->
 423                      Terms.Equation (FoSubst.apply_subst subst1 l,
 424                        FoSubst.apply_subst subst1 r, ty, o)
 425               in
 426                 Some(bag,maxvar,(id,lit,vl,p),Subst.concat subst1 subst)
 427             with FoUnif.UnificationFailure _ ->
 428               match rewrite_eq ~unify l r ty vl table with
 429               | Some (id2, dir, subst1) ->
 430                   (* prerr_endline ("subst1 = "^Pp.pp_substitution subst1);
 431                      prerr_endline ("old subst = "^Pp.pp_substitution subst);*)
 432                   let newsubst = Subst.concat subst1 subst in
 433                   let id_t =
 434                     FoSubst.apply_subst newsubst
 435                       (Terms.Node[Terms.Leaf B.eqP;ty;contextl r;contextr r])
 436                   in
 437                     (match
 438                       build_new_clause_reloc bag maxvar (fun _ -> true)
 439                         Terms.Superposition id_t
 440                         subst1 id id2 (pos@[2]) dir
 441                     with
 442                     | Some ((bag, maxvar), c), r ->
 443                         (* prerr_endline ("r = "^Pp.pp_substitution r); *)
 444                         let newsubst = Subst.flat
 445                           (Subst.concat r subst) in
 446                         Some(bag,maxvar,c,newsubst)
 447                     | None, _ -> assert false)
 448               | None ->
 449                   match l,r with
 450                   | Terms.Node (a::la), Terms.Node (b::lb) when
 451                       a = b && List.length la = List.length lb ->
 452                       let acc,_,_,_ =
 453                         List.fold_left2
 454                           (fun (acc,pre,postl,postr) a b ->
 455                              let newcl =
 456                               fun x -> contextl(Terms.Node (pre@(x::postl))) in
 457                              let newcr =
 458                               fun x -> contextr(Terms.Node (pre@(x::postr))) in
 459                              let newpos = List.length pre::pos in
 460                              let footail l =
 461                                if l = [] then [] else List.tl l in
 462                                (deep_eq ~unify a b ty
 463                                  newpos newcl newcr table acc,pre@[b],
 464                                  footail postl, footail postr))
 465                           (acc,[a],List.tl la,List.tl lb) la lb
 466                       in acc
 467                   | _,_ -> None
 468     ;;
 469
 470     let prof_deep_eq = HExtlib.profile ~enable "deep_eq";;
 471     let deep_eq ~unify l r ty pos contextl contextr table x =
 472       prof_deep_eq.HExtlib.profile (deep_eq ~unify l r ty pos contextl contextr table) x
 473     ;;
 474
 475     let rec orphan_murder bag acc i =
 476       match Terms.get_from_bag i bag with
 477         | (_,_,_,Terms.Exact _),discarded,_ -> (discarded,acc)
 478         | (_,_,_,Terms.Step (_,i1,i2,_,_,_)),true,_ -> (true,acc)
 479         | (_,_,_,Terms.Step (_,i1,i2,_,_,_)),false,_ ->
 480             if (List.mem i acc) then (false,acc)
 481             else match orphan_murder bag acc i1 with
 482               | (true,acc) -> (true,acc)
 483               | (false,acc) ->
 484                   let (res,acc) = orphan_murder bag acc i2 in
 485                   if res then res,acc else res,i::acc
 486     ;;
 487
 488     let orphan_murder bag actives cl =
 489       let (id,_,_,_) = cl in
 490       let actives = List.map (fun (i,_,_,_) -> i) actives in
 491       let (res,_) = orphan_murder bag actives id in
 492         if res then debug (lazy "Orphan murdered"); res
 493     ;;
 494     let prof_orphan_murder = HExtlib.profile ~enable "orphan_murder";;
 495     let orphan_murder bag actives x =
 496       prof_orphan_murder.HExtlib.profile (orphan_murder bag actives) x
 497     ;;
 498
 499     (* demodulate and check for subsumption *)
 500     let simplify table maxvar bag clause =
 501       debug (lazy "simplify...");
 502       if is_identity_clause clause then bag,None
 503       (* else if orphan_murder bag actives clause then bag,None *)
 504       else let bag, clause = demodulate bag clause table in
 505       if is_identity_clause clause then bag,None
 506       else
 507         match is_subsumed ~unify:false bag maxvar clause table with
 508           | None -> bag, Some clause
 509           | Some _ -> bag, None
 510     ;;
 511
 512     let simplify table maxvar bag clause =
 513       match simplify table maxvar bag clause with
 514         | bag, None ->
 515             let (id,_,_,_) = clause in
 516             let (_,_,iter) = Terms.get_from_bag id bag in
 517             Terms.replace_in_bag (clause,true,iter) bag, None
 518         | bag, Some clause -> bag, Some clause
 519     (*let (id,_,_,_) = clause in
 520             if orphan_murder bag clause then
 521               Terms.M.add id (clause,true) bag, Some clause
 522             else bag, Some clause*)
 523     ;;
 524     let prof_simplify = HExtlib.profile ~enable "simplify";;
 525     let simplify table maxvar bag x =
 526       prof_simplify.HExtlib.profile (simplify table maxvar bag ) x
 527     ;;
 528
 529     let one_pass_simplification new_clause (alist,atable) bag maxvar =
 530       match simplify atable maxvar bag new_clause with
 531         | bag,None -> bag,None (* new_clause has been discarded *)
 532         | bag,(Some clause) ->
 533             let ctable = IDX.index_unit_clause IDX.DT.empty clause in
 534             let bag, alist, atable =
 535               List.fold_left
 536                 (fun (bag, alist, atable) c ->
 537                    match simplify ctable maxvar bag c with
 538                      |bag,None -> (bag,alist,atable)
 539                         (* an active clause as been discarded *)
 540                      |bag,Some c1 ->
 541                         bag, c :: alist, IDX.index_unit_clause atable c)
 542                 (bag,[],IDX.DT.empty) alist
 543             in
 544               bag, Some (clause, (alist,atable))
 545     ;;
 546     let prof_one_pass_simplification = HExtlib.profile ~enable "one_pass_simplification";;
 547     let one_pass_simplification new_clause t bag x =
 548       prof_one_pass_simplification.HExtlib.profile (one_pass_simplification new_clause t bag ) x
 549     ;;
 550
 551     let simplification_step ~new_cl cl (alist,atable) bag maxvar new_clause =
 552       let atable1 =
 553         if new_cl then atable else
 554         IDX.index_unit_clause atable cl
 555       in
 556         (* Simplification of new_clause with :      *
 557          * - actives and cl if new_clause is not cl *
 558          * - only actives otherwise                 *)
 559         match
 560           simplify atable1 maxvar bag new_clause with
 561           | bag,None -> bag,(Some cl, None) (* new_clause has been discarded *)
 562           | bag,Some clause ->
 563               (* Simplification of each active clause with clause *
 564                * which is the simplified form of new_clause       *)
 565               let ctable = IDX.index_unit_clause IDX.DT.empty clause in
 566               let bag, newa, alist, atable =
 567                 List.fold_left
 568                   (fun (bag, newa, alist, atable) c ->
 569                      match simplify ctable maxvar bag c with
 570                        |bag,None -> (bag, newa, alist, atable)
 571                           (* an active clause as been discarded *)
 572                        |bag,Some c1 ->
 573                             if (c1 == c) then
 574                               bag, newa, c :: alist,
 575                             IDX.index_unit_clause atable c
 576                             else
 577                               bag, c1 :: newa, alist, atable)
 578                   (bag,[],[],IDX.DT.empty) alist
 579               in
 580                 if new_cl then
 581                   bag, (Some cl, Some (clause, (alist,atable), newa))
 582                 else
 583                   (* if new_clause is not cl, we simplify cl with clause *)
 584                   match simplify ctable maxvar bag cl with
 585                     | bag,None ->
 586                         (* cl has been discarded *)
 587                         bag,(None, Some (clause, (alist,atable), newa))
 588                     | bag,Some cl1 ->
 589                         bag,(Some cl1, Some (clause, (alist,atable), newa))
 590     ;;
 591     let prof_simplification_step = HExtlib.profile ~enable "simplification_step";;
 592     let simplification_step ~new_cl cl (alist,atable) bag maxvar x =
 593       prof_simplification_step.HExtlib.profile (simplification_step ~new_cl cl (alist,atable) bag maxvar) x
 594     ;;
 595
 596     let keep_simplified cl (alist,atable) bag maxvar =
 597       let rec keep_simplified_aux ~new_cl cl (alist,atable) bag newc =
 598         if new_cl then
 599           match simplification_step ~new_cl cl (alist,atable) bag maxvar cl with
 600             | _,(None, _) -> assert false
 601             | bag,(Some _, None) -> bag,None
 602             | bag,(Some _, Some (clause, (alist,atable), newa)) ->
 603                 keep_simplified_aux ~new_cl:(cl!=clause) clause (alist,atable)
 604                   bag (newa@newc)
 605         else
 606           match newc with
 607             | [] -> bag, Some (cl, (alist,atable))
 608             | hd::tl ->
 609                 match simplification_step ~new_cl cl
 610                   (alist,atable) bag maxvar hd with
 611                   | _,(None,None) -> assert false
 612                   | bag,(Some _,None) ->
 613                       keep_simplified_aux ~new_cl cl (alist,atable) bag tl
 614                   | bag,(None, Some _) -> bag,None
 615                   | bag,(Some cl1, Some (clause, (alist,atable), newa)) ->
 616                       let alist,atable =
 617                      (clause::alist, IDX.index_unit_clause atable clause)
 618                       in
 619                         keep_simplified_aux ~new_cl:(cl!=cl1) cl1 (alist,atable)
 620                           bag (newa@tl)
 621       in
 622         keep_simplified_aux ~new_cl:true cl (alist,atable) bag []
 623     ;;
 624     let prof_keep_simplified = HExtlib.profile ~enable "keep_simplified";;
 625     let keep_simplified cl t bag x =
 626       prof_keep_simplified.HExtlib.profile (keep_simplified cl t bag) x
 627     ;;
 628
 629     (* this is like simplify but raises Success *)
 630     let simplify_goal ~no_demod maxvar table bag g_actives clause =
 631       let bag, clause =
 632         if no_demod then bag, clause else demodulate bag clause table
 633       in
 634       let _ = debug (lazy ("demodulated goal  : "
 635                              ^ Pp.pp_unit_clause clause))
 636       in
 637       if List.exists (are_alpha_eq clause) g_actives then None
 638       else match (is_identity_goal clause) with
 639         | Some subst -> raise (Success (bag,maxvar,clause,subst))
 640         | None ->
 641         let (id,lit,vl,_) = clause in
 642         (* this optimization makes sense only if we demodulated, since in
 643            that case the clause should have been turned into an identity *)
 644         if (vl = [] && not(no_demod))
 645         then Some (bag,clause)
 646         else
 647          let l,r,ty =
 648            match lit with
 649              | Terms.Equation(l,r,ty,_) -> l,r,ty
 650              | _ -> assert false
 651          in
 652          match deep_eq ~unify:true l r ty [] (fun x -> x) (fun x -> x)
 653            table (Some(bag,maxvar,clause,Subst.id_subst)) with
 654          | None -> Some (bag,clause)
 655          | Some (bag,maxvar,cl,subst) ->
 656              debug (lazy "Goal subsumed");
 657              raise (Success (bag,maxvar,cl,subst))
 658 (*
 659         match is_subsumed ~unify:true bag maxvar clause table with
 660         | None -> Some (bag, clause)
 661         | Some ((bag,maxvar),c) ->
 662             prerr_endline "Goal subsumed";
 663             raise (Success (bag,maxvar,c))
 664 *)
 665     ;;
 666
 667     let prof_simplify_goal = HExtlib.profile ~enable "simplify_goal";;
 668     let  simplify_goal ~no_demod maxvar table bag g_actives x =
 669       prof_simplify_goal.HExtlib.profile ( simplify_goal ~no_demod maxvar table bag g_actives) x
 670     ;;
 671
 672     (* =================== inference ===================== *)
 673
 674     (* this is OK for both the sup_left and sup_right inference steps *)
 675     let superposition table varlist subterm pos context =
 676       let cands = IDX.DT.retrieve_unifiables table subterm in
 677       HExtlib.filter_map
 678         (fun (dir, (id,lit,vl,_ (*as uc*))) ->
 679            match lit with
 680            | Terms.Predicate _ -> assert false
 681            | Terms.Equation (l,r,_,o) ->
 682                let side, newside = if dir=Terms.Left2Right then l,r else r,l in
 683                try
 684                  let subst =
 685                    Unif.unification (* (varlist@vl)*)  [] subterm side
 686                  in
 687                  if o = Terms.Incomparable || o = Terms.Invertible then
 688                    let side = Subst.apply_subst subst side in
 689                    let newside = Subst.apply_subst subst newside in
 690                    let o = Order.compare_terms side newside in
 691                    (* XXX: check Riazanov p. 33 (iii) *)
 692                    if o <> Terms.Lt && o <> Terms.Eq then
 693                      Some (context newside, subst, id, pos, dir)
 694                    else
 695                      ((*prerr_endline ("Filtering: " ^
 696                         Pp.pp_foterm side ^ " =(< || =)" ^
 697                         Pp.pp_foterm newside);*)None)
 698                  else
 699                    Some (context newside, subst, id, pos, dir)
 700                with FoUnif.UnificationFailure _ -> None)
 701         (IDX.ClauseSet.elements cands)
 702     ;;
 703
 704     (* Superposes selected equation with equalities in table *)
 705     let superposition_with_table bag maxvar (id,selected,vl,_) table =
 706       match selected with
 707       | Terms.Predicate _ -> assert false
 708       | Terms.Equation (l,r,ty,Terms.Lt) ->
 709           fold_build_new_clause bag maxvar id Terms.Superposition
 710             (fun _ -> true)
 711             (all_positions [3]
 712               (fun x -> Terms.Node [ Terms.Leaf B.eqP; ty; l; x ])
 713               r (superposition table vl))
 714       | Terms.Equation (l,r,ty,Terms.Invertible)
 715       | Terms.Equation (l,r,ty,Terms.Gt) ->
 716           fold_build_new_clause bag maxvar id Terms.Superposition
 717             (fun _ -> true)
 718             (all_positions [2]
 719               (fun x -> Terms.Node [ Terms.Leaf B.eqP; ty; x; r ])
 720               l (superposition table vl))
 721       | Terms.Equation (l,r,ty,Terms.Incomparable) ->
 722           let filtering avoid subst = (* Riazanov: p.33 condition (iv) *)
 723             let l = Subst.apply_subst subst l in
 724             let r = Subst.apply_subst subst r in
 725             let o = Order.compare_terms l r in
 726             o <> avoid && o <> Terms.Eq
 727           in
 728           let bag, maxvar,r_terms =
 729             fold_build_new_clause bag maxvar id Terms.Superposition
 730               (filtering Terms.Gt)
 731               (all_positions [3]
 732                  (fun x -> Terms.Node [ Terms.Leaf B.eqP; ty; l; x ])
 733                  r (superposition table vl))
 734           in
 735           let bag, maxvar, l_terms =
 736             fold_build_new_clause bag maxvar id Terms.Superposition
 737               (filtering Terms.Lt)
 738               (all_positions [2]
 739                  (fun x -> Terms.Node [ Terms.Leaf B.eqP; ty; x; r ])
 740                  l (superposition table vl))
 741           in
 742             bag, maxvar, r_terms @ l_terms
 743       | _ -> assert false
 744     ;;
 745
 746     (* the current equation is normal w.r.t. demodulation with atable
 747      * (and is not the identity) *)
 748     let infer_right bag maxvar current (alist,atable) =
 749       (* We demodulate actives clause with current until all *
 750        * active clauses are reduced w.r.t each other         *)
 751       (* let bag, (alist,atable) = keep_simplified (alist,atable) bag [current] in *)
 752       let ctable = IDX.index_unit_clause IDX.DT.empty current in
 753       (* let bag, (alist, atable) =
 754         let bag, alist =
 755           HExtlib.filter_map_acc (simplify ctable) bag alist
 756         in
 757         bag, (alist, List.fold_left IDX.index_unit_clause IDX.DT.empty alist)
 758       in*)
 759         debug (lazy "Simplified active clauses with fact");
 760       (* We superpose active clauses with current *)
 761       let bag, maxvar, new_clauses =
 762         List.fold_left
 763           (fun (bag, maxvar, acc) active ->
 764              let bag, maxvar, newc =
 765                superposition_with_table bag maxvar active ctable
 766              in
 767              bag, maxvar, newc @ acc)
 768           (bag, maxvar, []) alist
 769       in
 770         debug
 771         (lazy
 772          ("New clauses :" ^ (String.concat ";\n"
 773             (List.map Pp.pp_unit_clause new_clauses))));
 774         debug (lazy "First superpositions");
 775         (* We add current to active clauses so that it can be *
 776          * superposed with itself                             *)
 777       let alist, atable =
 778         current :: alist, IDX.index_unit_clause atable current
 779       in
 780         debug (lazy "Indexed");
 781       let fresh_current, maxvar = Utils.fresh_unit_clause maxvar current in
 782         (* We need to put fresh_current into the bag so that all *
 783          * variables clauses refer to are known.                 *)
 784       let bag, fresh_current = Terms.add_to_bag fresh_current bag in
 785         (* We superpose current with active clauses *)
 786       let bag, maxvar, additional_new_clauses =
 787         superposition_with_table bag maxvar fresh_current atable
 788       in
 789         debug (lazy "Another superposition");
 790       let new_clauses = new_clauses @ additional_new_clauses in
 791         (* debug (lazy (Printf.sprintf "Demodulating %d clauses"
 792                  (List.length new_clauses))); *)
 793       let bag, new_clauses =
 794         HExtlib.filter_map_monad (simplify atable maxvar) bag new_clauses
 795       in
 796         debug (lazy "Demodulated new clauses");
 797       bag, maxvar, (alist, atable), new_clauses
 798     ;;
 799
 800     let prof_ir = HExtlib.profile ~enable "infer_right";;
 801     let infer_right bag maxvar current t =
 802       prof_ir.HExtlib.profile (infer_right bag maxvar current) t
 803     ;;
 804
 805     let infer_left bag maxvar goal (_alist, atable) =
 806         (* We superpose the goal with active clauses *)
 807      if (match goal with (_,_,[],_) -> true | _ -> false) then bag, maxvar, []
 808      else
 809       let bag, maxvar, new_goals =
 810         superposition_with_table bag maxvar goal atable
 811       in
 812         debug(lazy  "Superposed goal with active clauses");
 813         (* We simplify the new goals with active clauses *)
 814       let bag, new_goals =
 815         List.fold_left
 816          (fun (bag, acc) g ->
 817             match simplify_goal ~no_demod:false maxvar atable bag [] g with
 818               | None -> assert false
 819               | Some (bag,g) -> bag,g::acc)
 820          (bag, []) new_goals
 821       in
 822         debug (lazy "Simplified new goals with active clauses");
 823       bag, maxvar, List.rev new_goals
 824     ;;
 825
 826     let prof_il = HExtlib.profile ~enable "infer_left";;
 827     let infer_left bag maxvar goal t =
 828       prof_il.HExtlib.profile (infer_left bag maxvar goal) t
 829     ;;
 830
 831   end