helm/software/components/ng_paramodulation/superposition.ml

   1 (*
   2     ||M||  This file is part of HELM, an Hypertextual, Electronic
   3     ||A||  Library of Mathematics, developed at the Computer Science
   4     ||T||  Department, University of Bologna, Italy.
   5     ||I||
   6     ||T||  HELM is free software; you can redistribute it and/or
   7     ||A||  modify it under the terms of the GNU General Public License
   8     \   /  version 2 or (at your option) any later version.
   9      \ /   This software is distributed as is, NO WARRANTY.
  10       V_______________________________________________________________ *)
  11
  12 (* $Id: index.mli 9822 2009-06-03 15:37:06Z tassi $ *)
  13
  14 module Superposition (B : Terms.Blob) =
  15   struct
  16     module IDX = Index.Index(B)
  17     module Unif = FoUnif.Founif(B)
  18     module Subst = FoSubst (*.Subst(B)*)
  19     module Order = Orderings.Orderings(B)
  20     module Utils = FoUtils.Utils(B)
  21     module Pp = Pp.Pp(B)
  22
  23     exception Success of B.t Terms.bag * int * B.t Terms.unit_clause
  24
  25     let debug s =
  26        () (* prerr_endline s *)
  27     ;;
  28
  29     let rec list_first f = function
  30       | [] -> None
  31       | x::tl -> match f x with Some _ as x -> x | _ -> list_first f tl
  32     ;;
  33
  34     let first_position pos ctx t f =
  35       let rec aux pos ctx = function
  36       | Terms.Leaf _ as t -> f t pos ctx
  37       | Terms.Var _ -> None
  38       | Terms.Node l as t->
  39           match f t pos ctx with
  40           | Some _ as x -> x
  41           | None ->
  42               let rec first pre post = function
  43                 | [] -> None
  44                 | t :: tl ->
  45                      let newctx = fun x -> ctx (Terms.Node (pre@[x]@post)) in
  46                      match aux (List.length pre :: pos) newctx t with
  47                      | Some _ as x -> x
  48                      | None ->
  49                          if post = [] then None (* tl is also empty *)
  50                          else first (pre @ [t]) (List.tl post) tl
  51               in
  52                 first [] (List.tl l) l
  53       in
  54         aux pos ctx t
  55     ;;
  56
  57     let all_positions pos ctx t f =
  58       let rec aux pos ctx = function
  59       | Terms.Leaf _ as t -> f t pos ctx
  60       | Terms.Var _ -> []
  61       | Terms.Node l as t->
  62           let acc, _, _ =
  63             List.fold_left
  64             (fun (acc,pre,post) t -> (* Invariant: pre @ [t] @ post = l *)
  65                 let newctx = fun x -> ctx (Terms.Node (pre@[x]@post)) in
  66                 let acc = aux (List.length pre :: pos) newctx t @ acc in
  67                 if post = [] then acc, l, []
  68                 else acc, pre @ [t], List.tl post)
  69              (f t pos ctx, [], List.tl l) l
  70           in
  71            acc
  72       in
  73         aux pos ctx t
  74     ;;
  75
  76     let vars_of_term t =
  77       let rec aux acc = function
  78         | Terms.Leaf _ -> acc
  79         | Terms.Var i -> if (List.mem i acc) then acc else i::acc
  80         | Terms.Node l -> List.fold_left aux acc l
  81       in aux [] t
  82     ;;
  83
  84     let build_clause bag filter rule t subst vl id id2 pos dir =
  85       let proof = Terms.Step(rule,id,id2,dir,pos,subst) in
  86       let t = Subst.apply_subst subst t in
  87       if filter t then
  88         let literal =
  89           match t with
  90           | Terms.Node [ Terms.Leaf eq ; ty; l; r ] when B.eq B.eqP eq ->
  91                let o = Order.compare_terms l r in
  92                Terms.Equation (l, r, ty, o)
  93           | t -> Terms.Predicate t
  94         in
  95         let bag, uc =
  96           Utils.add_to_bag bag (0, literal, vars_of_term t, proof)
  97         in
  98         Some (bag, uc)
  99       else
 100         ((*prerr_endline ("Filtering: " ^ Pp.pp_foterm t);*)None)
 101     ;;
 102
 103
 104     (* ============ simplification ================= *)
 105
 106     let demod table varlist subterm pos context =
 107       let cands = IDX.DT.retrieve_generalizations table subterm in
 108       list_first
 109         (fun (dir, (id,lit,vl,_)) ->
 110            match lit with
 111            | Terms.Predicate _ -> assert false
 112            | Terms.Equation (l,r,_,o) ->
 113                let side, newside = if dir=Terms.Left2Right then l,r else r,l in
 114                try
 115                  let subst, varlist =
 116                    Unif.unification (varlist@vl) varlist subterm side
 117                  in
 118                  if o = Terms.Incomparable then
 119                    let side = Subst.apply_subst subst side in
 120                    let newside = Subst.apply_subst subst newside in
 121                    let o = Order.compare_terms newside side in
 122                    (* Riazanov, pp. 45 (ii) *)
 123                    if o = Terms.Lt then
 124                      Some (context newside, subst, varlist, id, pos, dir)
 125                    else
 126                      ((*prerr_endline ("Filtering: " ^
 127                         Pp.pp_foterm side ^ " =(< || =)" ^
 128                         Pp.pp_foterm newside ^ " coming from " ^
 129                         Pp.pp_unit_clause uc );*)None)
 130                  else
 131                    Some (context newside, subst, varlist, id, pos, dir)
 132                with FoUnif.UnificationFailure _ -> None)
 133         (IDX.ClauseSet.elements cands)
 134     ;;
 135
 136     let demodulate_once ~jump_to_right bag (id, literal, vl, pr) table =
 137       (* debug ("Demodulating : " ^ (Pp.pp_unit_clause (id, literal, vl, pr)));*)
 138       match literal with
 139       | Terms.Predicate t -> assert false
 140       | Terms.Equation (l,r,ty,_) ->
 141         let left_position = if jump_to_right then None else
 142           first_position [2]
 143             (fun x -> Terms.Node [ Terms.Leaf B.eqP; ty; x; r ]) l
 144             (demod table vl)
 145         in
 146         match left_position with
 147           | Some (newt, subst, varlist, id2, pos, dir) ->
 148               begin
 149                 match build_clause bag (fun _ -> true) Terms.Demodulation
 150                   newt subst varlist id id2 pos dir
 151                 with
 152                   | None -> assert false
 153                   | Some x -> Some (x,false)
 154               end
 155           | None ->
 156               match first_position
 157                 [3] (fun x -> Terms.Node [ Terms.Leaf B.eqP; ty; l; x ]) r
 158                 (demod table vl)
 159               with
 160                 | None -> None
 161                 | Some (newt, subst, varlist, id2, pos, dir) ->
 162                     match build_clause bag (fun _ -> true)
 163                       Terms.Demodulation newt subst varlist id id2 pos dir
 164                     with
 165                         | None -> assert false
 166                         | Some x -> Some (x,true)
 167     ;;
 168
 169     let rec demodulate ~jump_to_right bag clause table =
 170       match demodulate_once ~jump_to_right bag clause table with
 171       | None -> bag, clause
 172       | Some ((bag, clause),r) -> demodulate ~jump_to_right:r
 173           bag clause table
 174     ;;
 175
 176     let demodulate bag clause table = demodulate ~jump_to_right:false
 177       bag clause table
 178     ;;
 179
 180     (* move away *)
 181     let is_identity_clause = function
 182       | _, Terms.Equation (_,_,_,Terms.Eq), _, _ -> true
 183       | _, Terms.Equation (l,r,_,_), vl, proof ->
 184           (try ignore(Unif.unification vl [] l r); true
 185           with FoUnif.UnificationFailure _ -> false)
 186       | _, Terms.Predicate _, _, _ -> assert false
 187     ;;
 188
 189     let build_new_clause bag maxvar filter rule t subst vl id id2 pos dir =
 190       let maxvar, vl, relocsubst = Utils.relocate maxvar vl in
 191       let subst = Subst.concat relocsubst subst in
 192       match build_clause bag filter rule t subst vl id id2 pos dir with
 193       | Some (bag, c) -> Some ((bag, maxvar), c)
 194       | None -> None
 195     ;;
 196
 197     let fold_build_new_clause bag maxvar id rule filter res =
 198       let (bag, maxvar), res =
 199        HExtlib.filter_map_acc
 200          (fun (bag, maxvar) (t,subst,vl,id2,pos,dir) ->
 201             build_new_clause bag maxvar filter rule t subst vl id id2 pos dir)
 202          (bag, maxvar) res
 203       in
 204        bag, maxvar, res
 205     ;;
 206
 207
 208     let rewrite_eq ~unify l r ty vl table =
 209       let retrieve = if unify then IDX.DT.retrieve_unifiables
 210       else IDX.DT.retrieve_generalizations in
 211       let lcands = retrieve table l in
 212       let rcands = retrieve table r in
 213       let f b c =
 214         let id, dir, l, r, vl =
 215           match c with
 216             | (d, (id,Terms.Equation (l,r,ty,_),vl,_))-> id, d, l, r, vl
 217             |_ -> assert false
 218         in
 219         let reverse = (dir = Terms.Left2Right) = b in
 220         let l, r, proof_rewrite_dir = if reverse then l,r,Terms.Left2Right
 221         else r,l, Terms.Right2Left in
 222           (id,proof_rewrite_dir,Terms.Node [ Terms.Leaf B.eqP; ty; l; r ], vl)
 223       in
 224       let cands1 = List.map (f true) (IDX.ClauseSet.elements lcands) in
 225       let cands2 = List.map (f false) (IDX.ClauseSet.elements rcands) in
 226       let t = Terms.Node [ Terms.Leaf B.eqP; ty; l; r ] in
 227       let locked_vars = if unify then [] else vl in
 228       let rec aux = function
 229         | [] -> None
 230         | (id2,dir,c,vl1)::tl ->
 231             try
 232               let subst,vl1 = Unif.unification (vl@vl1) locked_vars c t in
 233               Some (id2, dir, subst)
 234             with FoUnif.UnificationFailure _ -> aux tl
 235       in
 236         aux (cands1 @ cands2)
 237     ;;
 238
 239     let is_subsumed ~unify bag maxvar (id, lit, vl, _) table =
 240       match lit with
 241       | Terms.Predicate _ -> assert false
 242       | Terms.Equation (l,r,ty,_) ->
 243           match rewrite_eq ~unify l r ty vl table with
 244             | None -> None
 245             | Some (id2, dir, subst) ->
 246                 let id_t = Terms.Node [ Terms.Leaf B.eqP; ty; r; r ] in
 247                   build_new_clause bag maxvar (fun _ -> true)
 248                     Terms.Superposition id_t subst [] id id2 [2] dir
 249     ;;
 250     (* id refers to a clause proving contextl l = contextr r *)
 251
 252     let rec deep_eq ~unify l r ty pos contextl contextr table acc =
 253       match acc with
 254       | None -> None
 255       | Some(bag,maxvar,[],subst) -> assert false
 256       | Some(bag,maxvar,(id,_,vl,_)::clauses,subst) ->
 257           let l = Subst.apply_subst subst l in
 258           let r = Subst.apply_subst subst r in
 259             try
 260               let subst1,vl1 = Unif.unification vl [] l r in
 261                 Some(bag,maxvar,clauses,Subst.concat subst1 subst)
 262             with FoUnif.UnificationFailure _ ->
 263               match rewrite_eq ~unify l r ty vl table with
 264               | Some (id2, dir, subst1) ->
 265                   let id_t =
 266                     Terms.Node[Terms.Leaf B.eqP;ty;contextl r;contextr r] in
 267                     (match
 268                       build_new_clause bag maxvar (fun _ -> true)
 269                         Terms.Superposition id_t subst1 [] id id2 (2::pos) dir
 270                     with
 271                     | Some ((bag, maxvar), c) ->
 272                         Some(bag,maxvar,c::clauses,Subst.concat subst1 subst)
 273                     | None -> assert false)
 274               | None ->
 275                   match l,r with
 276                   | Terms.Node (a::la), Terms.Node (b::lb) when
 277                       a = b && List.length la = List.length lb ->
 278                       let acc,_,_,_ =
 279                         List.fold_left2
 280                           (fun (acc,pre,postl,postr) a b ->
 281                              let newcl =
 282                               fun x -> contextl(Terms.Node (pre@(x::postl))) in
 283                              let newcr =
 284                               fun x -> contextr(Terms.Node (pre@(x::postr))) in
 285                              let newpos = List.length pre::pos in
 286                              let footail l =
 287                                if l = [] then [] else List.tl l in
 288                                (deep_eq ~unify a b ty
 289                                  newpos newcl newcr table acc,pre@[b],
 290                                  footail postl, footail postr))
 291                           (acc,[a],List.tl la,List.tl lb) la lb
 292                       in acc
 293                   | Terms.Var _, _
 294                   | _, Terms.Var _ -> assert false
 295                   | _,_ -> None
 296     ;;
 297
 298     (* demodulate and check for subsumption *)
 299     let simplify table maxvar bag clause =
 300       let bag, clause = demodulate bag clause table in
 301       if is_identity_clause ~unify:false clause then bag,None
 302       else
 303         match is_subsumed ~unify:false bag maxvar clause table with
 304           | None -> bag, Some clause
 305           | Some _ -> bag, None
 306     ;;
 307
 308     let one_pass_simplification new_clause (alist,atable) bag maxvar =
 309       match simplify atable maxvar bag new_clause with
 310         | bag,None -> None (* new_clause has been discarded *)
 311         | bag,(Some clause) ->
 312             let ctable = IDX.index_unit_clause IDX.DT.empty clause in
 313             let bag, alist, atable =
 314               List.fold_left
 315                 (fun (bag, alist, atable as acc) c ->
 316                    match simplify ctable maxvar bag c with
 317                      |bag,None -> acc (* an active clause as been discarded *)
 318                      |bag,Some c1 ->
 319                         bag, c :: alist, IDX.index_unit_clause atable c)
 320                 (bag,[],IDX.DT.empty) alist
 321             in
 322               Some (clause, bag, (alist,atable))
 323     ;;
 324
 325     let simplification_step ~new_cl cl (alist,atable) bag maxvar new_clause =
 326       let atable1 =
 327         if new_cl then atable else
 328         IDX.index_unit_clause atable cl
 329       in
 330         (* Simplification of new_clause with :      *
 331          * - actives and cl if new_clause is not cl *
 332          * - only actives otherwise                 *)
 333         match simplify atable1 maxvar bag new_clause with
 334           | bag,None -> (Some cl, None) (* new_clause has been discarded *)
 335           | bag,Some clause ->
 336               (* Simplification of each active clause with clause *
 337                * which is the simplified form of new_clause       *)
 338               let ctable = IDX.index_unit_clause IDX.DT.empty clause in
 339               let bag, newa, alist, atable =
 340                 List.fold_left
 341                   (fun (bag, newa, alist, atable as acc) c ->
 342                      match simplify ctable maxvar bag c with
 343                        |bag,None -> acc (* an active clause as been discarded *)
 344                        |bag,Some c1 ->
 345                             if (c1 == c) then
 346                               bag, newa, c :: alist,
 347                             IDX.index_unit_clause atable c
 348                             else
 349                               bag, c1 :: newa, alist, atable)
 350                   (bag,[],[],IDX.DT.empty) alist
 351               in
 352                 if new_cl then
 353                   (Some cl, Some (clause, (alist,atable), newa, bag))
 354                 else
 355                   (* if new_clause is not cl, we simplify cl with clause *)
 356                   match simplify ctable maxvar bag cl with
 357                     | bag,None ->
 358                         (* cl has been discarded *)
 359                         (None, Some (clause, (alist,atable), newa, bag))
 360                     | bag,Some cl1 ->
 361                         (Some cl1, Some (clause, (alist,atable), newa, bag))
 362     ;;
 363
 364     let keep_simplified cl (alist,atable) bag maxvar =
 365       let rec keep_simplified_aux ~new_cl cl (alist,atable) bag newc =
 366         if new_cl then
 367           match simplification_step ~new_cl cl (alist,atable) bag maxvar cl with
 368             | (None, _) -> assert false
 369             | (Some _, None) -> None
 370             | (Some _, Some (clause, (alist,atable), newa, bag)) ->
 371                 keep_simplified_aux ~new_cl:(cl!=clause) clause (alist,atable)
 372                   bag (newa@newc)
 373         else
 374           match newc with
 375             | [] -> Some (cl, bag, (alist,atable))
 376             | hd::tl ->
 377                 match simplification_step ~new_cl cl
 378                   (alist,atable) bag maxvar hd with
 379                   | (None,None) -> assert false
 380                   | (Some _,None) ->
 381                       keep_simplified_aux ~new_cl cl (alist,atable) bag tl
 382                   | (None, Some _) -> None
 383                   | (Some cl1, Some (clause, (alist,atable), newa, bag)) ->
 384                       let alist,atable =
 385                         (clause::alist, IDX.index_unit_clause atable clause)
 386                       in
 387                         keep_simplified_aux ~new_cl:(cl!=cl1) cl1 (alist,atable)
 388                           bag (newa@tl)
 389       in
 390         keep_simplified_aux ~new_cl:true cl (alist,atable) bag []
 391     ;;
 392
 393     let are_alpha_eq cl1 cl2 =
 394       let get_term (_,lit,_,_) =
 395         match lit with
 396           | Terms.Predicate _ -> assert false
 397           | Terms.Equation (l,r,ty,_) ->
 398               Terms.Node [Terms.Leaf B.eqP; ty; l ; r]
 399       in
 400         try ignore(Unif.alpha_eq (get_term cl1) (get_term cl2)) ; true
 401         with FoUnif.UnificationFailure _ -> false
 402 ;;
 403
 404     (* this is like simplify but raises Success *)
 405     let simplify_goal maxvar table bag g_actives clause =
 406       let bag, clause = demodulate bag clause table in
 407       if (is_identity_clause clause)
 408       then raise (Success (bag, maxvar, clause))
 409 (*
 410       else
 411         let (id,lit,vl,_) = clause in
 412         let l,r,ty =
 413           match lit with
 414             | Terms.Equation(l,r,ty,_) -> l,r,ty
 415             | _ -> assert false
 416         in
 417         match deep_eq ~unify:true l r ty [] (fun x -> x) (fun x -> x)
 418           table (Some(bag,maxvar,[clause],Subst.id_subst)) with
 419         | None ->
 420             if List.exists (are_alpha_eq clause) g_actives then None
 421             else Some (bag, clause)
 422         | Some (bag,maxvar,cl,subst) ->
 423             debug "Goal subsumed";
 424             raise (Success (bag,maxvar,List.hd cl))
 425 *)
 426       else match is_subsumed ~unify:true bag maxvar clause table with
 427         | None ->
 428             if List.exists (are_alpha_eq clause) g_actives then None
 429             else Some (bag, clause)
 430         | Some ((bag,maxvar),c) ->
 431             debug "Goal subsumed";
 432             raise (Success (bag,maxvar,c))
 433     ;;
 434
 435     (* =================== inference ===================== *)
 436
 437     (* this is OK for both the sup_left and sup_right inference steps *)
 438     let superposition table varlist subterm pos context =
 439       let cands = IDX.DT.retrieve_unifiables table subterm in
 440       HExtlib.filter_map
 441         (fun (dir, (id,lit,vl,_ (*as uc*))) ->
 442            match lit with
 443            | Terms.Predicate _ -> assert false
 444            | Terms.Equation (l,r,_,o) ->
 445                let side, newside = if dir=Terms.Left2Right then l,r else r,l in
 446                try
 447                  let subst, varlist =
 448                    Unif.unification (varlist@vl) [] subterm side
 449                  in
 450                  if o = Terms.Incomparable then
 451                    let side = Subst.apply_subst subst side in
 452                    let newside = Subst.apply_subst subst newside in
 453                    let o = Order.compare_terms side newside in
 454                    (* XXX: check Riazanov p. 33 (iii) *)
 455                    if o <> Terms.Lt && o <> Terms.Eq then
 456                      Some (context newside, subst, varlist, id, pos, dir)
 457                    else
 458                      ((*prerr_endline ("Filtering: " ^
 459                         Pp.pp_foterm side ^ " =(< || =)" ^
 460                         Pp.pp_foterm newside ^ " coming from " ^
 461                         Pp.pp_unit_clause uc );*)None)
 462                  else
 463                    Some (context newside, subst, varlist, id, pos, dir)
 464                with FoUnif.UnificationFailure _ -> None)
 465         (IDX.ClauseSet.elements cands)
 466     ;;
 467
 468     (* Superposes selected equation with equalities in table *)
 469     let superposition_with_table bag maxvar (id,selected,vl,_) table =
 470       match selected with
 471       | Terms.Predicate _ -> assert false
 472       | Terms.Equation (l,r,ty,Terms.Lt) ->
 473           fold_build_new_clause bag maxvar id Terms.Superposition
 474             (fun _ -> true)
 475             (all_positions [3]
 476               (fun x -> Terms.Node [ Terms.Leaf B.eqP; ty; l; x ])
 477               r (superposition table vl))
 478       | Terms.Equation (l,r,ty,Terms.Gt) ->
 479           fold_build_new_clause bag maxvar id Terms.Superposition
 480             (fun _ -> true)
 481             (all_positions [2]
 482               (fun x -> Terms.Node [ Terms.Leaf B.eqP; ty; x; r ])
 483               l (superposition table vl))
 484       | Terms.Equation (l,r,ty,Terms.Incomparable) ->
 485           fold_build_new_clause bag maxvar id Terms.Superposition
 486             (function (* Riazanov: p.33 condition (iv) *)
 487               | Terms.Node [Terms.Leaf eq; ty; l; r ] when B.eq B.eqP eq ->
 488                   Order.compare_terms l r <> Terms.Eq
 489               | _ -> assert false)
 490             ((all_positions [3]
 491                (fun x -> Terms.Node [ Terms.Leaf B.eqP; ty; l; x ])
 492                r (superposition table vl)) @
 493              (all_positions [2]
 494                (fun x -> Terms.Node [ Terms.Leaf B.eqP; ty; x; r ])
 495                l (superposition table vl)))
 496       | _ -> assert false
 497     ;;
 498
 499     (* the current equation is normal w.r.t. demodulation with atable
 500      * (and is not the identity) *)
 501     let infer_right bag maxvar current (alist,atable) =
 502       (* We demodulate actives clause with current until all *
 503        * active clauses are reduced w.r.t each other         *)
 504       (* let bag, (alist,atable) = keep_simplified (alist,atable) bag [current] in *)
 505       let ctable = IDX.index_unit_clause IDX.DT.empty current in
 506       (* let bag, (alist, atable) =
 507         let bag, alist =
 508           HExtlib.filter_map_acc (simplify ctable) bag alist
 509         in
 510         bag, (alist, List.fold_left IDX.index_unit_clause IDX.DT.empty alist)
 511       in*)
 512         debug "Simplified active clauses with fact";
 513       (* We superpose active clauses with current *)
 514       let bag, maxvar, new_clauses =
 515         List.fold_left
 516           (fun (bag, maxvar, acc) active ->
 517              let bag, maxvar, newc =
 518                superposition_with_table bag maxvar active ctable
 519              in
 520              bag, maxvar, newc @ acc)
 521           (bag, maxvar, []) alist
 522       in
 523         debug "First superpositions";
 524         (* We add current to active clauses so that it can be *
 525          * superposed with itself                             *)
 526       let alist, atable =
 527         current :: alist, IDX.index_unit_clause atable current
 528       in
 529         debug "Indexed";
 530       let fresh_current, maxvar = Utils.fresh_unit_clause maxvar current in
 531         (* We need to put fresh_current into the bag so that all *
 532          * variables clauses refer to are known.                 *)
 533       let bag, fresh_current = Utils.add_to_bag bag fresh_current in
 534         (* We superpose current with active clauses *)
 535       let bag, maxvar, additional_new_clauses =
 536         superposition_with_table bag maxvar fresh_current atable
 537       in
 538         debug "Another superposition";
 539       let new_clauses = new_clauses @ additional_new_clauses in
 540         debug (Printf.sprintf "Demodulating %d clauses"
 541                  (List.length new_clauses));
 542       let bag, new_clauses =
 543         HExtlib.filter_map_monad (simplify atable maxvar) bag new_clauses
 544       in
 545         debug "Demodulated new clauses";
 546       bag, maxvar, (alist, atable), new_clauses
 547     ;;
 548
 549     let infer_left bag maxvar goal (_alist, atable) =
 550         (* We superpose the goal with active clauses *)
 551       let bag, maxvar, new_goals =
 552         superposition_with_table bag maxvar goal atable
 553       in
 554         debug "Superposed goal with active clauses";
 555         (* We simplify the new goals with active clauses *)
 556       let bag, new_goals =
 557         List.fold_left
 558          (fun (bag, acc) g ->
 559             match simplify_goal maxvar atable bag [] g with
 560               | None -> assert false
 561               | Some (bag,g) -> bag,g::acc)
 562          (bag, []) new_goals
 563       in
 564         debug "Simplified new goals with active clauses";
 565       bag, maxvar, List.rev new_goals
 566     ;;
 567
 568   end