helm/software/components/ng_paramodulation/superposition.ml

   1 (*
   2     ||M||  This file is part of HELM, an Hypertextual, Electronic
   3     ||A||  Library of Mathematics, developed at the Computer Science
   4     ||T||  Department, University of Bologna, Italy.
   5     ||I||
   6     ||T||  HELM is free software; you can redistribute it and/or
   7     ||A||  modify it under the terms of the GNU General Public License
   8     \   /  version 2 or (at your option) any later version.
   9      \ /   This software is distributed as is, NO WARRANTY.
  10       V_______________________________________________________________ *)
  11
  12 (* $Id: index.mli 9822 2009-06-03 15:37:06Z tassi $ *)
  13
  14 module Superposition (B : Terms.Blob) =
  15   struct
  16     module IDX = Index.Index(B)
  17     module Unif = FoUnif.Founif(B)
  18     module Subst = FoSubst (*.Subst(B)*)
  19     module Order = Orderings.Orderings(B)
  20     module Utils = FoUtils.Utils(B)
  21     module Pp = Pp.Pp(B)
  22
  23     exception Success of B.t Terms.bag * int * B.t Terms.unit_clause
  24
  25 (*    let debug s = prerr_endline s;;*)
  26     let debug _ = ();;
  27
  28     let rec list_first f = function
  29       | [] -> None
  30       | x::tl -> match f x with Some _ as x -> x | _ -> list_first f tl
  31     ;;
  32
  33     let first_position pos ctx t f =
  34       let rec aux pos ctx = function
  35       | Terms.Leaf _ as t -> f t pos ctx
  36       | Terms.Var _ -> None
  37       | Terms.Node l as t->
  38           match f t pos ctx with
  39           | Some _ as x -> x
  40           | None ->
  41               let rec first pre post = function
  42                 | [] -> None
  43                 | t :: tl ->
  44                      let newctx = fun x -> ctx (Terms.Node (pre@[x]@post)) in
  45                      match aux (List.length pre :: pos) newctx t with
  46                      | Some _ as x -> x
  47                      | None ->
  48                          if post = [] then None (* tl is also empty *)
  49                          else first (pre @ [t]) (List.tl post) tl
  50               in
  51                 first [] (List.tl l) l
  52       in
  53         aux pos ctx t
  54     ;;
  55
  56     let all_positions pos ctx t f =
  57       let rec aux pos ctx = function
  58       | Terms.Leaf _ as t -> f t pos ctx
  59       | Terms.Var _ -> []
  60       | Terms.Node l as t->
  61           let acc, _, _ =
  62             List.fold_left
  63             (fun (acc,pre,post) t -> (* Invariant: pre @ [t] @ post = l *)
  64                 let newctx = fun x -> ctx (Terms.Node (pre@[x]@post)) in
  65                 let acc = aux (List.length pre :: pos) newctx t @ acc in
  66                 if post = [] then acc, l, []
  67                 else acc, pre @ [t], List.tl post)
  68              (f t pos ctx, [], List.tl l) l
  69           in
  70            acc
  71       in
  72         aux pos ctx t
  73     ;;
  74
  75     let vars_of_term t =
  76       let rec aux acc = function
  77         | Terms.Leaf _ -> acc
  78         | Terms.Var i -> if (List.mem i acc) then acc else i::acc
  79         | Terms.Node l -> List.fold_left aux acc l
  80       in aux [] t
  81     ;;
  82
  83     let build_clause bag filter rule t subst vl id id2 pos dir =
  84       let proof = Terms.Step(rule,id,id2,dir,pos,subst) in
  85       let t = Subst.apply_subst subst t in
  86       if filter t then
  87         let literal =
  88           match t with
  89           | Terms.Node [ Terms.Leaf eq ; ty; l; r ] when B.eq B.eqP eq ->
  90                let o = Order.compare_terms l r in
  91                Terms.Equation (l, r, ty, o)
  92           | t -> Terms.Predicate t
  93         in
  94         let bag, uc =
  95           Utils.add_to_bag bag (0, literal, vars_of_term t, proof)
  96         in
  97         Some (bag, uc)
  98       else
  99         ((*prerr_endline ("Filtering: " ^ Pp.pp_foterm t);*)None)
 100     ;;
 101
 102
 103     (* ============ simplification ================= *)
 104
 105     let demod table varlist subterm pos context =
 106       let cands = IDX.DT.retrieve_generalizations table subterm in
 107       list_first
 108         (fun (dir, (id,lit,vl,_)) ->
 109            match lit with
 110            | Terms.Predicate _ -> assert false
 111            | Terms.Equation (l,r,_,o) ->
 112                let side, newside = if dir=Terms.Left2Right then l,r else r,l in
 113                try
 114                  let subst, varlist =
 115                    Unif.unification (varlist@vl) varlist subterm side
 116                  in
 117                  if o = Terms.Incomparable then
 118                    let side = Subst.apply_subst subst side in
 119                    let newside = Subst.apply_subst subst newside in
 120                    let o = Order.compare_terms newside side in
 121                    (* Riazanov, pp. 45 (ii) *)
 122                    if o = Terms.Lt then
 123                      Some (context newside, subst, varlist, id, pos, dir)
 124                    else
 125                      ((*prerr_endline ("Filtering: " ^
 126                         Pp.pp_foterm side ^ " =(< || =)" ^
 127                         Pp.pp_foterm newside ^ " coming from " ^
 128                         Pp.pp_unit_clause uc );*)None)
 129                  else
 130                    Some (context newside, subst, varlist, id, pos, dir)
 131                with FoUnif.UnificationFailure _ -> None)
 132         (IDX.ClauseSet.elements cands)
 133     ;;
 134
 135     let demodulate_once ~jump_to_right bag (id, literal, vl, pr) table =
 136       (* debug ("Demodulating : " ^ (Pp.pp_unit_clause (id, literal, vl, pr)));*)
 137       match literal with
 138       | Terms.Predicate t -> assert false
 139       | Terms.Equation (l,r,ty,_) ->
 140         let left_position = if jump_to_right then None else
 141           first_position [2]
 142             (fun x -> Terms.Node [ Terms.Leaf B.eqP; ty; x; r ]) l
 143             (demod table vl)
 144         in
 145         match left_position with
 146           | Some (newt, subst, varlist, id2, pos, dir) ->
 147               begin
 148                 match build_clause bag (fun _ -> true) Terms.Demodulation
 149                   newt subst varlist id id2 pos dir
 150                 with
 151                   | None -> assert false
 152                   | Some x -> Some (x,false)
 153               end
 154           | None ->
 155               match first_position
 156                 [3] (fun x -> Terms.Node [ Terms.Leaf B.eqP; ty; l; x ]) r
 157                 (demod table vl)
 158               with
 159                 | None -> None
 160                 | Some (newt, subst, varlist, id2, pos, dir) ->
 161                     match build_clause bag (fun _ -> true)
 162                       Terms.Demodulation newt subst varlist id id2 pos dir
 163                     with
 164                         | None -> assert false
 165                         | Some x -> Some (x,true)
 166     ;;
 167
 168     let rec demodulate ~jump_to_right bag clause table =
 169       match demodulate_once ~jump_to_right bag clause table with
 170       | None -> bag, clause
 171       | Some ((bag, clause),r) -> demodulate ~jump_to_right:r
 172           bag clause table
 173     ;;
 174
 175     let demodulate bag clause table = demodulate ~jump_to_right:false
 176       bag clause table
 177     ;;
 178
 179     (* move away *)
 180     let is_identity_clause ~unify = function
 181       | _, Terms.Equation (_,_,_,Terms.Eq), _, _ -> true
 182       | _, Terms.Equation (l,r,_,_), vl, proof when unify ->
 183           (try ignore(Unif.unification vl [] l r); true
 184           with FoUnif.UnificationFailure _ -> false)
 185       | _, Terms.Equation (_,_,_,_), _, _ -> false
 186       | _, Terms.Predicate _, _, _ -> assert false
 187     ;;
 188
 189     let build_new_clause bag maxvar filter rule t subst vl id id2 pos dir =
 190       let maxvar, vl, relocsubst = Utils.relocate maxvar vl in
 191       let subst = Subst.concat relocsubst subst in
 192       match build_clause bag filter rule t subst vl id id2 pos dir with
 193       | Some (bag, c) -> Some ((bag, maxvar), c)
 194       | None -> None
 195     ;;
 196
 197     let fold_build_new_clause bag maxvar id rule filter res =
 198       let (bag, maxvar), res =
 199        HExtlib.filter_map_acc
 200          (fun (bag, maxvar) (t,subst,vl,id2,pos,dir) ->
 201             build_new_clause bag maxvar filter rule t subst vl id id2 pos dir)
 202          (bag, maxvar) res
 203       in
 204        bag, maxvar, res
 205     ;;
 206
 207
 208     let rewrite_eq ~unify l r ty vl table =
 209       let retrieve = if unify then IDX.DT.retrieve_unifiables
 210       else IDX.DT.retrieve_generalizations in
 211       let lcands = retrieve table l in
 212       let rcands = retrieve table r in
 213       let f b c =
 214         let id, dir, l, r, vl =
 215           match c with
 216             | (d, (id,Terms.Equation (l,r,ty,_),vl,_))-> id, d, l, r, vl
 217             |_ -> assert false
 218         in
 219         let reverse = (dir = Terms.Left2Right) = b in
 220         let l, r, proof_rewrite_dir = if reverse then l,r,Terms.Left2Right
 221         else r,l, Terms.Right2Left in
 222           (id,proof_rewrite_dir,Terms.Node [ Terms.Leaf B.eqP; ty; l; r ], vl)
 223       in
 224       let cands1 = List.map (f true) (IDX.ClauseSet.elements lcands) in
 225       let cands2 = List.map (f false) (IDX.ClauseSet.elements rcands) in
 226       let t = Terms.Node [ Terms.Leaf B.eqP; ty; l; r ] in
 227       let locked_vars = if unify then [] else vl in
 228       let rec aux = function
 229         | [] -> None
 230         | (id2,dir,c,vl1)::tl ->
 231             try
 232               let subst,vl1 = Unif.unification (vl@vl1) locked_vars c t in
 233               Some (id2, dir, subst)
 234             with FoUnif.UnificationFailure _ -> aux tl
 235       in
 236         aux (cands1 @ cands2)
 237     ;;
 238
 239     let is_subsumed ~unify bag maxvar (id, lit, vl, _) table =
 240       match lit with
 241       | Terms.Predicate _ -> assert false
 242       | Terms.Equation (l,r,ty,_) ->
 243           match rewrite_eq ~unify l r ty vl table with
 244             | None -> None
 245             | Some (id2, dir, subst) ->
 246                 let id_t = Terms.Node [ Terms.Leaf B.eqP; ty; r; r ] in
 247                   build_new_clause bag maxvar (fun _ -> true)
 248                     Terms.Superposition id_t subst [] id id2 [2] dir
 249     ;;
 250     (* id refers to a clause proving contextl l = contextr r *)
 251
 252     let rec deep_eq ~unify l r ty pos contextl contextr table acc =
 253       match acc with
 254       | None -> None
 255       | Some(bag,maxvar,[],subst) -> assert false
 256       | Some(bag,maxvar,(id,_,vl,_)::clauses,subst) ->
 257           let l = Subst.apply_subst subst l in
 258           let r = Subst.apply_subst subst r in
 259             try
 260               let subst1,vl1 = Unif.unification vl [] l r in
 261                 Some(bag,maxvar,clauses,Subst.concat subst1 subst)
 262             with FoUnif.UnificationFailure _ ->
 263               match rewrite_eq ~unify l r ty vl table with
 264               | Some (id2, dir, subst1) ->
 265                   let id_t =
 266                     Terms.Node[Terms.Leaf B.eqP;ty;contextl r;contextr r] in
 267                     (match
 268                       build_new_clause bag maxvar (fun _ -> true)
 269                         Terms.Superposition id_t subst1 [] id id2 (2::pos) dir
 270                     with
 271                     | Some ((bag, maxvar), c) ->
 272                         Some(bag,maxvar,c::clauses,Subst.concat subst1 subst)
 273                     | None -> assert false)
 274               | None ->
 275                   match l,r with
 276                   | Terms.Node (a::la), Terms.Node (b::lb) when
 277                       a = b && List.length la = List.length lb ->
 278                       let acc,_,_,_ =
 279                         List.fold_left2
 280                           (fun (acc,pre,postl,postr) a b ->
 281                              let newcl =
 282                               fun x -> contextl(Terms.Node (pre@(x::postl))) in
 283                              let newcr =
 284                               fun x -> contextr(Terms.Node (pre@(x::postr))) in
 285                              let newpos = List.length pre::pos in
 286                              let footail l =
 287                                if l = [] then [] else List.tl l in
 288                                (deep_eq ~unify a b ty
 289                                  newpos newcl newcr table acc,pre@[b],
 290                                  footail postl, footail postr))
 291                           (acc,[a],List.tl la,List.tl lb) la lb
 292                       in acc
 293                   | Terms.Var _, _
 294                   | _, Terms.Var _ -> assert false
 295                   | _,_ -> None
 296     ;;
 297
 298     let rec orphan_murder bag acc i =
 299       match Terms.M.find i bag with
 300         | (_,_,_,Terms.Exact _),discarded -> (discarded,acc)
 301         | (_,_,_,Terms.Step (_,i1,i2,_,_,_)),true -> (true,acc)
 302         | (_,_,_,Terms.Step (_,i1,i2,_,_,_)),false ->
 303             if (List.mem i acc) then (false,acc)
 304             else match orphan_murder bag acc i1 with
 305               | (true,acc) -> (true,acc)
 306               | (false,acc) ->
 307                   let (res,acc) = orphan_murder bag acc i2 in
 308                   if res then res,acc else res,i::acc
 309 ;;
 310
 311     let orphan_murder bag cl =
 312       let (id,_,_,_) = cl in
 313       let (res,_) = orphan_murder bag [] id in
 314         if res then debug "Orphan murdered"; res
 315 ;;
 316
 317     (* demodulate and check for subsumption *)
 318     let simplify table maxvar bag clause =
 319       if is_identity_clause ~unify:false clause then bag,None
 320       (* else if orphan_murder bag clause then bag,None *)
 321       else let bag, clause = demodulate bag clause table in
 322       if is_identity_clause ~unify:false clause then bag,None
 323       else
 324         match is_subsumed ~unify:false bag maxvar clause table with
 325           | None -> bag, Some clause
 326           | Some _ -> bag, None
 327     ;;
 328
 329     let simplify table maxvar bag clause =
 330       match simplify table maxvar bag clause with
 331         | bag, None -> let (id,_,_,_) = clause in
 332             Terms.M.add id (clause,true) bag, None
 333         | bag, Some clause -> bag, Some clause
 334 ;;
 335
 336     let one_pass_simplification new_clause (alist,atable) bag maxvar =
 337       match simplify atable maxvar bag new_clause with
 338         | bag,None -> bag,None (* new_clause has been discarded *)
 339         | bag,(Some clause) ->
 340             let ctable = IDX.index_unit_clause IDX.DT.empty clause in
 341             let bag, alist, atable =
 342               List.fold_left
 343                 (fun (bag, alist, atable) c ->
 344                    match simplify ctable maxvar bag c with
 345                      |bag,None -> (bag,alist,atable)
 346                         (* an active clause as been discarded *)
 347                      |bag,Some c1 ->
 348                         bag, c :: alist, IDX.index_unit_clause atable c)
 349                 (bag,[],IDX.DT.empty) alist
 350             in
 351               bag, Some (clause, (alist,atable))
 352     ;;
 353
 354     let simplification_step ~new_cl cl (alist,atable) bag maxvar new_clause =
 355       let atable1 =
 356         if new_cl then atable else
 357         IDX.index_unit_clause atable cl
 358       in
 359         (* Simplification of new_clause with :      *
 360          * - actives and cl if new_clause is not cl *
 361          * - only actives otherwise                 *)
 362         match simplify atable1 maxvar bag new_clause with
 363           | bag,None -> bag,(Some cl, None) (* new_clause has been discarded *)
 364           | bag,Some clause ->
 365               (* Simplification of each active clause with clause *
 366                * which is the simplified form of new_clause       *)
 367               let ctable = IDX.index_unit_clause IDX.DT.empty clause in
 368               let bag, newa, alist, atable =
 369                 List.fold_left
 370                   (fun (bag, newa, alist, atable) c ->
 371                      match simplify ctable maxvar bag c with
 372                        |bag,None -> (bag, newa, alist, atable)
 373                           (* an active clause as been discarded *)
 374                        |bag,Some c1 ->
 375                             if (c1 == c) then
 376                               bag, newa, c :: alist,
 377                             IDX.index_unit_clause atable c
 378                             else
 379                               bag, c1 :: newa, alist, atable)
 380                   (bag,[],[],IDX.DT.empty) alist
 381               in
 382                 if new_cl then
 383                   bag, (Some cl, Some (clause, (alist,atable), newa))
 384                 else
 385                   (* if new_clause is not cl, we simplify cl with clause *)
 386                   match simplify ctable maxvar bag cl with
 387                     | bag,None ->
 388                         (* cl has been discarded *)
 389                         bag,(None, Some (clause, (alist,atable), newa))
 390                     | bag,Some cl1 ->
 391                         bag,(Some cl1, Some (clause, (alist,atable), newa))
 392     ;;
 393
 394     let keep_simplified cl (alist,atable) bag maxvar =
 395       let rec keep_simplified_aux ~new_cl cl (alist,atable) bag newc =
 396         if new_cl then
 397           match simplification_step ~new_cl cl (alist,atable) bag maxvar cl with
 398             | _,(None, _) -> assert false
 399             | bag,(Some _, None) -> bag,None
 400             | bag,(Some _, Some (clause, (alist,atable), newa)) ->
 401                 keep_simplified_aux ~new_cl:(cl!=clause) clause (alist,atable)
 402                   bag (newa@newc)
 403         else
 404           match newc with
 405             | [] -> bag, Some (cl, (alist,atable))
 406             | hd::tl ->
 407                 match simplification_step ~new_cl cl
 408                   (alist,atable) bag maxvar hd with
 409                   | _,(None,None) -> assert false
 410                   | bag,(Some _,None) ->
 411                       keep_simplified_aux ~new_cl cl (alist,atable) bag tl
 412                   | bag,(None, Some _) -> bag,None
 413                   | bag,(Some cl1, Some (clause, (alist,atable), newa)) ->
 414                       let alist,atable =
 415                         (clause::alist, IDX.index_unit_clause atable clause)
 416                       in
 417                         keep_simplified_aux ~new_cl:(cl!=cl1) cl1 (alist,atable)
 418                           bag (newa@tl)
 419       in
 420         keep_simplified_aux ~new_cl:true cl (alist,atable) bag []
 421     ;;
 422
 423     let are_alpha_eq cl1 cl2 =
 424       let get_term (_,lit,_,_) =
 425         match lit with
 426           | Terms.Predicate _ -> assert false
 427           | Terms.Equation (l,r,ty,_) ->
 428               Terms.Node [Terms.Leaf B.eqP; ty; l ; r]
 429       in
 430         try ignore(Unif.alpha_eq (get_term cl1) (get_term cl2)) ; true
 431         with FoUnif.UnificationFailure _ -> false
 432 ;;
 433
 434     (* this is like simplify but raises Success *)
 435     let simplify_goal maxvar table bag g_actives clause =
 436       let bag, clause = demodulate bag clause table in
 437       if (is_identity_clause ~unify:true clause)
 438       then raise (Success (bag, maxvar, clause))
 439 (*
 440       else
 441         let (id,lit,vl,_) = clause in
 442         let l,r,ty =
 443           match lit with
 444             | Terms.Equation(l,r,ty,_) -> l,r,ty
 445             | _ -> assert false
 446         in
 447         match deep_eq ~unify:true l r ty [] (fun x -> x) (fun x -> x)
 448           table (Some(bag,maxvar,[clause],Subst.id_subst)) with
 449         | None ->
 450             if List.exists (are_alpha_eq clause) g_actives then None
 451             else Some (bag, clause)
 452         | Some (bag,maxvar,cl,subst) ->
 453             debug "Goal subsumed";
 454             raise (Success (bag,maxvar,List.hd cl))
 455 *)
 456       else match is_subsumed ~unify:true bag maxvar clause table with
 457         | None ->
 458             if List.exists (are_alpha_eq clause) g_actives then None
 459             else Some (bag, clause)
 460         | Some ((bag,maxvar),c) ->
 461             debug "Goal subsumed";
 462             raise (Success (bag,maxvar,c))
 463     ;;
 464
 465     (* =================== inference ===================== *)
 466
 467     (* this is OK for both the sup_left and sup_right inference steps *)
 468     let superposition table varlist subterm pos context =
 469       let cands = IDX.DT.retrieve_unifiables table subterm in
 470       HExtlib.filter_map
 471         (fun (dir, (id,lit,vl,_ (*as uc*))) ->
 472            match lit with
 473            | Terms.Predicate _ -> assert false
 474            | Terms.Equation (l,r,_,o) ->
 475                let side, newside = if dir=Terms.Left2Right then l,r else r,l in
 476                try
 477                  let subst, varlist =
 478                    Unif.unification (varlist@vl) [] subterm side
 479                  in
 480                  if o = Terms.Incomparable then
 481                    let side = Subst.apply_subst subst side in
 482                    let newside = Subst.apply_subst subst newside in
 483                    let o = Order.compare_terms side newside in
 484                    (* XXX: check Riazanov p. 33 (iii) *)
 485                    if o <> Terms.Lt && o <> Terms.Eq then
 486                      Some (context newside, subst, varlist, id, pos, dir)
 487                    else
 488                      ((*prerr_endline ("Filtering: " ^
 489                         Pp.pp_foterm side ^ " =(< || =)" ^
 490                         Pp.pp_foterm newside ^ " coming from " ^
 491                         Pp.pp_unit_clause uc );*)None)
 492                  else
 493                    Some (context newside, subst, varlist, id, pos, dir)
 494                with FoUnif.UnificationFailure _ -> None)
 495         (IDX.ClauseSet.elements cands)
 496     ;;
 497
 498     (* Superposes selected equation with equalities in table *)
 499     let superposition_with_table bag maxvar (id,selected,vl,_) table =
 500       match selected with
 501       | Terms.Predicate _ -> assert false
 502       | Terms.Equation (l,r,ty,Terms.Lt) ->
 503           fold_build_new_clause bag maxvar id Terms.Superposition
 504             (fun _ -> true)
 505             (all_positions [3]
 506               (fun x -> Terms.Node [ Terms.Leaf B.eqP; ty; l; x ])
 507               r (superposition table vl))
 508       | Terms.Equation (l,r,ty,Terms.Gt) ->
 509           fold_build_new_clause bag maxvar id Terms.Superposition
 510             (fun _ -> true)
 511             (all_positions [2]
 512               (fun x -> Terms.Node [ Terms.Leaf B.eqP; ty; x; r ])
 513               l (superposition table vl))
 514       | Terms.Equation (l,r,ty,Terms.Incomparable) ->
 515           fold_build_new_clause bag maxvar id Terms.Superposition
 516             (function (* Riazanov: p.33 condition (iv) *)
 517               | Terms.Node [Terms.Leaf eq; ty; l; r ] when B.eq B.eqP eq ->
 518                   Order.compare_terms l r <> Terms.Eq
 519               | _ -> assert false)
 520             ((all_positions [3]
 521                (fun x -> Terms.Node [ Terms.Leaf B.eqP; ty; l; x ])
 522                r (superposition table vl)) @
 523              (all_positions [2]
 524                (fun x -> Terms.Node [ Terms.Leaf B.eqP; ty; x; r ])
 525                l (superposition table vl)))
 526       | _ -> assert false
 527     ;;
 528
 529     (* the current equation is normal w.r.t. demodulation with atable
 530      * (and is not the identity) *)
 531     let infer_right bag maxvar current (alist,atable) =
 532       (* We demodulate actives clause with current until all *
 533        * active clauses are reduced w.r.t each other         *)
 534       (* let bag, (alist,atable) = keep_simplified (alist,atable) bag [current] in *)
 535       let ctable = IDX.index_unit_clause IDX.DT.empty current in
 536       (* let bag, (alist, atable) =
 537         let bag, alist =
 538           HExtlib.filter_map_acc (simplify ctable) bag alist
 539         in
 540         bag, (alist, List.fold_left IDX.index_unit_clause IDX.DT.empty alist)
 541       in*)
 542         debug "Simplified active clauses with fact";
 543       (* We superpose active clauses with current *)
 544       let bag, maxvar, new_clauses =
 545         List.fold_left
 546           (fun (bag, maxvar, acc) active ->
 547              let bag, maxvar, newc =
 548                superposition_with_table bag maxvar active ctable
 549              in
 550              bag, maxvar, newc @ acc)
 551           (bag, maxvar, []) alist
 552       in
 553         debug "First superpositions";
 554         (* We add current to active clauses so that it can be *
 555          * superposed with itself                             *)
 556       let alist, atable =
 557         current :: alist, IDX.index_unit_clause atable current
 558       in
 559         debug "Indexed";
 560       let fresh_current, maxvar = Utils.fresh_unit_clause maxvar current in
 561         (* We need to put fresh_current into the bag so that all *
 562          * variables clauses refer to are known.                 *)
 563       let bag, fresh_current = Utils.add_to_bag bag fresh_current in
 564         (* We superpose current with active clauses *)
 565       let bag, maxvar, additional_new_clauses =
 566         superposition_with_table bag maxvar fresh_current atable
 567       in
 568         debug "Another superposition";
 569       let new_clauses = new_clauses @ additional_new_clauses in
 570         debug (Printf.sprintf "Demodulating %d clauses"
 571                  (List.length new_clauses));
 572       let bag, new_clauses =
 573         HExtlib.filter_map_monad (simplify atable maxvar) bag new_clauses
 574       in
 575         debug "Demodulated new clauses";
 576       bag, maxvar, (alist, atable), new_clauses
 577     ;;
 578
 579     let infer_left bag maxvar goal (_alist, atable) =
 580         (* We superpose the goal with active clauses *)
 581       let bag, maxvar, new_goals =
 582         superposition_with_table bag maxvar goal atable
 583       in
 584         debug "Superposed goal with active clauses";
 585         (* We simplify the new goals with active clauses *)
 586       let bag, new_goals =
 587         List.fold_left
 588          (fun (bag, acc) g ->
 589             match simplify_goal maxvar atable bag [] g with
 590               | None -> assert false
 591               | Some (bag,g) -> bag,g::acc)
 592          (bag, []) new_goals
 593       in
 594         debug "Simplified new goals with active clauses";
 595       bag, maxvar, List.rev new_goals
 596     ;;
 597
 598   end