helm/software/components/ng_paramodulation/superposition.ml

   1 (*
   2     ||M||  This file is part of HELM, an Hypertextual, Electronic
   3     ||A||  Library of Mathematics, developed at the Computer Science
   4     ||T||  Department, University of Bologna, Italy.
   5     ||I||
   6     ||T||  HELM is free software; you can redistribute it and/or
   7     ||A||  modify it under the terms of the GNU General Public License
   8     \   /  version 2 or (at your option) any later version.
   9      \ /   This software is distributed as is, NO WARRANTY.
  10       V_______________________________________________________________ *)
  11
  12 (* $Id: index.mli 9822 2009-06-03 15:37:06Z tassi $ *)
  13
  14 module Superposition (B : Terms.Blob) =
  15   struct
  16     module IDX = Index.Index(B)
  17     module Unif = FoUnif.Founif(B)
  18     module Subst = FoSubst (*.Subst(B)*)
  19     module Order = Orderings.Orderings(B)
  20     module Utils = FoUtils.Utils(B)
  21     module Pp = Pp.Pp(B)
  22
  23     exception Success of B.t Terms.bag * int * B.t Terms.unit_clause
  24
  25     let debug s =
  26        () (* prerr_endline s *)
  27     ;;
  28
  29     let rec list_first f = function
  30       | [] -> None
  31       | x::tl -> match f x with Some _ as x -> x | _ -> list_first f tl
  32     ;;
  33
  34     let first_position pos ctx t f =
  35       let rec aux pos ctx = function
  36       | Terms.Leaf _ as t -> f t pos ctx
  37       | Terms.Var _ -> None
  38       | Terms.Node l as t->
  39           match f t pos ctx with
  40           | Some _ as x -> x
  41           | None ->
  42               let rec first pre post = function
  43                 | [] -> None
  44                 | t :: tl ->
  45                      let newctx = fun x -> ctx (Terms.Node (pre@[x]@post)) in
  46                      match aux (List.length pre :: pos) newctx t with
  47                      | Some _ as x -> x
  48                      | None ->
  49                          if post = [] then None (* tl is also empty *)
  50                          else first (pre @ [t]) (List.tl post) tl
  51               in
  52                 first [] (List.tl l) l
  53       in
  54         aux pos ctx t
  55     ;;
  56
  57     let all_positions pos ctx t f =
  58       let rec aux pos ctx = function
  59       | Terms.Leaf _ as t -> f t pos ctx
  60       | Terms.Var _ -> []
  61       | Terms.Node l as t->
  62           let acc, _, _ =
  63             List.fold_left
  64             (fun (acc,pre,post) t -> (* Invariant: pre @ [t] @ post = l *)
  65                 let newctx = fun x -> ctx (Terms.Node (pre@[x]@post)) in
  66                 let acc = aux (List.length pre :: pos) newctx t @ acc in
  67                 if post = [] then acc, l, []
  68                 else acc, pre @ [t], List.tl post)
  69              (f t pos ctx, [], List.tl l) l
  70           in
  71            acc
  72       in
  73         aux pos ctx t
  74     ;;
  75
  76     let vars_of_term t =
  77       let rec aux acc = function
  78         | Terms.Leaf _ -> acc
  79         | Terms.Var i -> if (List.mem i acc) then acc else i::acc
  80         | Terms.Node l -> List.fold_left aux acc l
  81       in aux [] t
  82     ;;
  83
  84     let build_clause bag filter rule t subst vl id id2 pos dir =
  85       let proof = Terms.Step(rule,id,id2,dir,pos,subst) in
  86       let t = Subst.apply_subst subst t in
  87       if filter t then
  88         let literal =
  89           match t with
  90           | Terms.Node [ Terms.Leaf eq ; ty; l; r ] when B.eq B.eqP eq ->
  91                let o = Order.compare_terms l r in
  92                Terms.Equation (l, r, ty, o)
  93           | t -> Terms.Predicate t
  94         in
  95         let bag, uc =
  96           Utils.add_to_bag bag (0, literal, vars_of_term t, proof)
  97         in
  98         Some (bag, uc)
  99       else
 100         ((*prerr_endline ("Filtering: " ^ Pp.pp_foterm t);*)None)
 101     ;;
 102
 103
 104     (* ============ simplification ================= *)
 105
 106     let demod table varlist subterm pos context =
 107       let cands = IDX.DT.retrieve_generalizations table subterm in
 108       list_first
 109         (fun (dir, (id,lit,vl,_)) ->
 110            match lit with
 111            | Terms.Predicate _ -> assert false
 112            | Terms.Equation (l,r,_,o) ->
 113                let side, newside = if dir=Terms.Left2Right then l,r else r,l in
 114                try
 115                  let subst, varlist =
 116                    Unif.unification (varlist@vl) varlist subterm side
 117                  in
 118                  if o = Terms.Incomparable then
 119                    let side = Subst.apply_subst subst side in
 120                    let newside = Subst.apply_subst subst newside in
 121                    let o = Order.compare_terms newside side in
 122                    (* Riazanov, pp. 45 (ii) *)
 123                    if o = Terms.Lt then
 124                      Some (context newside, subst, varlist, id, pos, dir)
 125                    else
 126                      ((*prerr_endline ("Filtering: " ^
 127                         Pp.pp_foterm side ^ " =(< || =)" ^
 128                         Pp.pp_foterm newside ^ " coming from " ^
 129                         Pp.pp_unit_clause uc );*)None)
 130                  else
 131                    Some (context newside, subst, varlist, id, pos, dir)
 132                with FoUnif.UnificationFailure _ -> None)
 133         (IDX.ClauseSet.elements cands)
 134     ;;
 135
 136     let demodulate_once ~jump_to_right bag (id, literal, vl, pr) table =
 137       (* debug ("Demodulating : " ^ (Pp.pp_unit_clause (id, literal, vl, pr)));*)
 138       match literal with
 139       | Terms.Predicate t -> assert false
 140       | Terms.Equation (l,r,ty,_) ->
 141         let left_position = if jump_to_right then None else
 142           first_position [2]
 143             (fun x -> Terms.Node [ Terms.Leaf B.eqP; ty; x; r ]) l
 144             (demod table vl)
 145         in
 146         match left_position with
 147           | Some (newt, subst, varlist, id2, pos, dir) ->
 148               begin
 149                 match build_clause bag (fun _ -> true) Terms.Demodulation
 150                   newt subst varlist id id2 pos dir
 151                 with
 152                   | None -> assert false
 153                   | Some x -> Some (x,false)
 154               end
 155           | None ->
 156               match first_position
 157                 [3] (fun x -> Terms.Node [ Terms.Leaf B.eqP; ty; l; x ]) r
 158                 (demod table vl)
 159               with
 160                 | None -> None
 161                 | Some (newt, subst, varlist, id2, pos, dir) ->
 162                     match build_clause bag (fun _ -> true)
 163                       Terms.Demodulation newt subst varlist id id2 pos dir
 164                     with
 165                         | None -> assert false
 166                         | Some x -> Some (x,true)
 167     ;;
 168
 169     let rec demodulate ~jump_to_right bag clause table =
 170       match demodulate_once ~jump_to_right bag clause table with
 171       | None -> bag, clause
 172       | Some ((bag, clause),r) -> demodulate ~jump_to_right:r
 173           bag clause table
 174     ;;
 175
 176     let demodulate bag clause table = demodulate ~jump_to_right:false
 177       bag clause table
 178     ;;
 179
 180     (* move away *)
 181     let is_identity_clause ~unify = function
 182       | _, Terms.Equation (_,_,_,Terms.Eq), _, _ -> true
 183       | _, Terms.Equation (l,r,_,_), vl, proof when unify ->
 184           (try ignore(Unif.unification vl [] l r); true
 185           with FoUnif.UnificationFailure _ -> false)
 186       | _, Terms.Predicate _, _, _ -> assert false
 187       | _ -> false
 188     ;;
 189
 190     let build_new_clause bag maxvar filter rule t subst vl id id2 pos dir =
 191       let maxvar, vl, relocsubst = Utils.relocate maxvar vl in
 192       let subst = Subst.concat relocsubst subst in
 193       match build_clause bag filter rule t subst vl id id2 pos dir with
 194       | Some (bag, c) -> Some ((bag, maxvar), c)
 195       | None -> None
 196     ;;
 197
 198
 199     let fold_build_new_clause bag maxvar id rule filter res =
 200       let (bag, maxvar), res =
 201        HExtlib.filter_map_acc
 202          (fun (bag, maxvar) (t,subst,vl,id2,pos,dir) ->
 203             build_new_clause bag maxvar filter rule t subst vl id id2 pos dir)
 204          (bag, maxvar) res
 205       in
 206        bag, maxvar, res
 207     ;;
 208
 209
 210     let rewrite_eq ~unify l r ty vl table =
 211       let retrieve = if unify then IDX.DT.retrieve_unifiables
 212       else IDX.DT.retrieve_generalizations in
 213       let lcands = retrieve table l in
 214       let rcands = retrieve table r in
 215       let f b c =
 216         let id, dir, l, r, vl =
 217           match c with
 218             | (d, (id,Terms.Equation (l,r,ty,_),vl,_))-> id, d, l, r, vl
 219             |_ -> assert false
 220         in
 221         let reverse = (dir = Terms.Left2Right) = b in
 222         let l, r, proof_rewrite_dir = if reverse then l,r,Terms.Left2Right
 223         else r,l, Terms.Right2Left in
 224           (id,proof_rewrite_dir,Terms.Node [ Terms.Leaf B.eqP; ty; l; r ], vl)
 225       in
 226       let cands1 = List.map (f true) (IDX.ClauseSet.elements lcands) in
 227       let cands2 = List.map (f false) (IDX.ClauseSet.elements rcands) in
 228       let t = Terms.Node [ Terms.Leaf B.eqP; ty; l; r ] in
 229       let locked_vars = if unify then [] else vl in
 230       let rec aux = function
 231         | [] -> None
 232         | (id2,dir,c,vl1)::tl ->
 233             try
 234               let subst,vl1 = Unif.unification (vl@vl1) locked_vars c t in
 235               Some (id2, dir, subst)
 236             with FoUnif.UnificationFailure _ -> aux tl
 237       in
 238         aux (cands1 @ cands2)
 239     ;;
 240
 241     let is_subsumed ~unify bag maxvar (id, lit, vl, _) table =
 242       match lit with
 243       | Terms.Predicate _ -> assert false
 244       | Terms.Equation (l,r,ty,_) ->
 245           match rewrite_eq ~unify l r ty vl table with
 246             | None -> None
 247             | Some (id2, dir, subst) ->
 248                 let id_t = Terms.Node [ Terms.Leaf B.eqP; ty; r; r ] in
 249                   build_new_clause bag maxvar (fun _ -> true)
 250                     Terms.Superposition id_t subst [] id id2 [2] dir
 251     ;;
 252
 253 (*
 254     let rec deeply_subsumed ~unify bag maxvar (id, lit, vl, _) table =
 255       match lit with
 256       | Terms.Predicate _ -> assert false
 257       | Terms.Equation (l,r,ty,_) ->
 258         (match is_subsumed ~unify bag maxvar (id, lit, vl, _) table with
 259          | Some((bag,maxvar),c) -> Some((bag,maxvar),c)
 260          | None ->
 261              match l,r with ->
 262                Var i, _ ->
 263     ;;
 264 *)
 265
 266
 267     (* demodulate and check for subsumption *)
 268     let simplify table maxvar bag clause =
 269       let bag, clause = demodulate bag clause table in
 270       if is_identity_clause ~unify:false clause then bag,None
 271       else
 272         match is_subsumed ~unify:false bag maxvar clause table with
 273           | None -> bag, Some clause
 274           | Some _ -> bag, None
 275     ;;
 276
 277     let one_pass_simplification new_clause (alist,atable) bag maxvar =
 278       match simplify atable maxvar bag new_clause with
 279         | bag,None -> None (* new_clause has been discarded *)
 280         | bag,(Some clause) ->
 281             let ctable = IDX.index_unit_clause IDX.DT.empty clause in
 282             let bag, alist, atable =
 283               List.fold_left
 284                 (fun (bag, alist, atable as acc) c ->
 285                    match simplify ctable maxvar bag c with
 286                      |bag,None -> acc (* an active clause as been discarded *)
 287                      |bag,Some c1 ->
 288                         bag, c :: alist, IDX.index_unit_clause atable c)
 289                 (bag,[],IDX.DT.empty) alist
 290             in
 291               Some (clause, bag, (alist,atable))
 292     ;;
 293
 294     let simplification_step ~new_cl cl (alist,atable) bag maxvar new_clause =
 295       let atable1 =
 296         if new_cl then atable else
 297         IDX.index_unit_clause atable cl
 298       in
 299         (* Simplification of new_clause with :      *
 300          * - actives and cl if new_clause is not cl *
 301          * - only actives otherwise                 *)
 302         match simplify atable1 maxvar bag new_clause with
 303           | bag,None -> (Some cl, None) (* new_clause has been discarded *)
 304           | bag,Some clause ->
 305               (* Simplification of each active clause with clause *
 306                * which is the simplified form of new_clause       *)
 307               let ctable = IDX.index_unit_clause IDX.DT.empty clause in
 308               let bag, newa, alist, atable =
 309                 List.fold_left
 310                   (fun (bag, newa, alist, atable as acc) c ->
 311                      match simplify ctable maxvar bag c with
 312                        |bag,None -> acc (* an active clause as been discarded *)
 313                        |bag,Some c1 ->
 314                             if (c1 == c) then
 315                               bag, newa, c :: alist,
 316                             IDX.index_unit_clause atable c
 317                             else
 318                               bag, c1 :: newa, alist, atable)
 319                   (bag,[],[],IDX.DT.empty) alist
 320               in
 321                 if new_cl then
 322                   (Some cl, Some (clause, (alist,atable), newa, bag))
 323                 else
 324                   (* if new_clause is not cl, we simplify cl with clause *)
 325                   match simplify ctable maxvar bag cl with
 326                     | bag,None ->
 327                         (* cl has been discarded *)
 328                         (None, Some (clause, (alist,atable), newa, bag))
 329                     | bag,Some cl1 ->
 330                         (Some cl1, Some (clause, (alist,atable), newa, bag))
 331     ;;
 332
 333     let keep_simplified cl (alist,atable) bag maxvar =
 334       let rec keep_simplified_aux ~new_cl cl (alist,atable) bag newc =
 335         if new_cl then
 336           match simplification_step ~new_cl cl (alist,atable) bag maxvar cl with
 337             | (None, _) -> assert false
 338             | (Some _, None) -> None
 339             | (Some _, Some (clause, (alist,atable), newa, bag)) ->
 340                 keep_simplified_aux ~new_cl:(cl!=clause) clause (alist,atable)
 341                   bag (newa@newc)
 342         else
 343           match newc with
 344             | [] -> Some (cl, bag, (alist,atable))
 345             | hd::tl ->
 346                 match simplification_step ~new_cl cl
 347                   (alist,atable) bag maxvar hd with
 348                   | (None,None) -> assert false
 349                   | (Some _,None) ->
 350                       keep_simplified_aux ~new_cl cl (alist,atable) bag tl
 351                   | (None, Some _) -> None
 352                   | (Some cl1, Some (clause, (alist,atable), newa, bag)) ->
 353                       let alist,atable =
 354                         (clause::alist, IDX.index_unit_clause atable clause)
 355                       in
 356                         keep_simplified_aux ~new_cl:(cl!=cl1) cl1 (alist,atable)
 357                           bag (newa@tl)
 358       in
 359         keep_simplified_aux ~new_cl:true cl (alist,atable) bag []
 360     ;;
 361
 362     let are_alpha_eq cl1 cl2 =
 363       let get_term (_,lit,_,_) =
 364         match lit with
 365           | Terms.Predicate _ -> assert false
 366           | Terms.Equation (l,r,ty,_) ->
 367               Terms.Node [Terms.Leaf B.eqP; ty; l ; r]
 368       in
 369         try ignore(Unif.alpha_eq (get_term cl1) (get_term cl2)) ; true
 370         with FoUnif.UnificationFailure _ -> false
 371 ;;
 372
 373     (* this is like simplify but raises Success *)
 374     let simplify_goal maxvar table bag g_actives clause =
 375       let bag, clause = demodulate bag clause table in
 376       if (is_identity_clause ~unify:true clause)
 377       then raise (Success (bag, maxvar, clause))
 378       else match is_subsumed ~unify:true bag maxvar clause table with
 379         | None ->
 380             if List.exists (are_alpha_eq clause) g_actives then None
 381             else Some (bag, clause)
 382         | Some ((bag,maxvar),c) ->
 383             debug "Goal subsumed";
 384             raise (Success (bag,maxvar,c))
 385     ;;
 386
 387     (* =================== inference ===================== *)
 388
 389     (* this is OK for both the sup_left and sup_right inference steps *)
 390     let superposition table varlist subterm pos context =
 391       let cands = IDX.DT.retrieve_unifiables table subterm in
 392       HExtlib.filter_map
 393         (fun (dir, (id,lit,vl,_ (*as uc*))) ->
 394            match lit with
 395            | Terms.Predicate _ -> assert false
 396            | Terms.Equation (l,r,_,o) ->
 397                let side, newside = if dir=Terms.Left2Right then l,r else r,l in
 398                try
 399                  let subst, varlist =
 400                    Unif.unification (varlist@vl) [] subterm side
 401                  in
 402                  if o = Terms.Incomparable then
 403                    let side = Subst.apply_subst subst side in
 404                    let newside = Subst.apply_subst subst newside in
 405                    let o = Order.compare_terms side newside in
 406                    (* XXX: check Riazanov p. 33 (iii) *)
 407                    if o <> Terms.Lt && o <> Terms.Eq then
 408                      Some (context newside, subst, varlist, id, pos, dir)
 409                    else
 410                      ((*prerr_endline ("Filtering: " ^
 411                         Pp.pp_foterm side ^ " =(< || =)" ^
 412                         Pp.pp_foterm newside ^ " coming from " ^
 413                         Pp.pp_unit_clause uc );*)None)
 414                  else
 415                    Some (context newside, subst, varlist, id, pos, dir)
 416                with FoUnif.UnificationFailure _ -> None)
 417         (IDX.ClauseSet.elements cands)
 418     ;;
 419
 420     (* Superposes selected equation with equalities in table *)
 421     let superposition_with_table bag maxvar (id,selected,vl,_) table =
 422       match selected with
 423       | Terms.Predicate _ -> assert false
 424       | Terms.Equation (l,r,ty,Terms.Lt) ->
 425           fold_build_new_clause bag maxvar id Terms.Superposition
 426             (fun _ -> true)
 427             (all_positions [3]
 428               (fun x -> Terms.Node [ Terms.Leaf B.eqP; ty; l; x ])
 429               r (superposition table vl))
 430       | Terms.Equation (l,r,ty,Terms.Gt) ->
 431           fold_build_new_clause bag maxvar id Terms.Superposition
 432             (fun _ -> true)
 433             (all_positions [2]
 434               (fun x -> Terms.Node [ Terms.Leaf B.eqP; ty; x; r ])
 435               l (superposition table vl))
 436       | Terms.Equation (l,r,ty,Terms.Incomparable) ->
 437           fold_build_new_clause bag maxvar id Terms.Superposition
 438             (function (* Riazanov: p.33 condition (iv) *)
 439               | Terms.Node [Terms.Leaf eq; ty; l; r ] when B.eq B.eqP eq ->
 440                   Order.compare_terms l r <> Terms.Eq
 441               | _ -> assert false)
 442             ((all_positions [3]
 443                (fun x -> Terms.Node [ Terms.Leaf B.eqP; ty; l; x ])
 444                r (superposition table vl)) @
 445              (all_positions [2]
 446                (fun x -> Terms.Node [ Terms.Leaf B.eqP; ty; x; r ])
 447                l (superposition table vl)))
 448       | _ -> assert false
 449     ;;
 450
 451     (* the current equation is normal w.r.t. demodulation with atable
 452      * (and is not the identity) *)
 453     let infer_right bag maxvar current (alist,atable) =
 454       (* We demodulate actives clause with current until all *
 455        * active clauses are reduced w.r.t each other         *)
 456       (* let bag, (alist,atable) = keep_simplified (alist,atable) bag [current] in *)
 457       let ctable = IDX.index_unit_clause IDX.DT.empty current in
 458       (* let bag, (alist, atable) =
 459         let bag, alist =
 460           HExtlib.filter_map_acc (simplify ctable) bag alist
 461         in
 462         bag, (alist, List.fold_left IDX.index_unit_clause IDX.DT.empty alist)
 463       in*)
 464         debug "Simplified active clauses with fact";
 465       (* We superpose active clauses with current *)
 466       let bag, maxvar, new_clauses =
 467         List.fold_left
 468           (fun (bag, maxvar, acc) active ->
 469              let bag, maxvar, newc =
 470                superposition_with_table bag maxvar active ctable
 471              in
 472              bag, maxvar, newc @ acc)
 473           (bag, maxvar, []) alist
 474       in
 475         debug "First superpositions";
 476         (* We add current to active clauses so that it can be *
 477          * superposed with itself                             *)
 478       let alist, atable =
 479         current :: alist, IDX.index_unit_clause atable current
 480       in
 481         debug "Indexed";
 482       let fresh_current, maxvar = Utils.fresh_unit_clause maxvar current in
 483         (* We need to put fresh_current into the bag so that all *
 484          * variables clauses refer to are known.                 *)
 485       let bag, fresh_current = Utils.add_to_bag bag fresh_current in
 486         (* We superpose current with active clauses *)
 487       let bag, maxvar, additional_new_clauses =
 488         superposition_with_table bag maxvar fresh_current atable
 489       in
 490         debug "Another superposition";
 491       let new_clauses = new_clauses @ additional_new_clauses in
 492         debug (Printf.sprintf "Demodulating %d clauses"
 493                  (List.length new_clauses));
 494       let bag, new_clauses =
 495         HExtlib.filter_map_monad (simplify atable maxvar) bag new_clauses
 496       in
 497         debug "Demodulated new clauses";
 498       bag, maxvar, (alist, atable), new_clauses
 499     ;;
 500
 501     let infer_left bag maxvar goal (_alist, atable) =
 502         (* We superpose the goal with active clauses *)
 503       let bag, maxvar, new_goals =
 504         superposition_with_table bag maxvar goal atable
 505       in
 506         debug "Superposed goal with active clauses";
 507         (* We simplify the new goals with active clauses *)
 508       let bag, new_goals =
 509         List.fold_left
 510          (fun (bag, acc) g ->
 511             match simplify_goal maxvar atable bag [] g with
 512               | None -> assert false
 513               | Some (bag,g) -> bag,g::acc)
 514          (bag, []) new_goals
 515       in
 516         debug "Simplified new goals with active clauses";
 517       bag, maxvar, List.rev new_goals
 518     ;;
 519
 520   end