helm/software/components/ng_paramodulation/superposition.ml

   1 (*
   2     ||M||  This file is part of HELM, an Hypertextual, Electronic
   3     ||A||  Library of Mathematics, developed at the Computer Science
   4     ||T||  Department, University of Bologna, Italy.
   5     ||I||
   6     ||T||  HELM is free software; you can redistribute it and/or
   7     ||A||  modify it under the terms of the GNU General Public License
   8     \   /  version 2 or (at your option) any later version.
   9      \ /   This software is distributed as is, NO WARRANTY.
  10       V_______________________________________________________________ *)
  11
  12 (* $Id: index.mli 9822 2009-06-03 15:37:06Z tassi $ *)
  13
  14 module Superposition (B : Terms.Blob) =
  15   struct
  16     module IDX = Index.Index(B)
  17     module Unif = FoUnif.Founif(B)
  18     module Subst = FoSubst (*.Subst(B)*)
  19     module Order = Orderings.Orderings(B)
  20     module Utils = FoUtils.Utils(B)
  21     module Pp = Pp.Pp(B)
  22
  23     exception Success of B.t Terms.bag * int * B.t Terms.unit_clause
  24
  25     let debug s =
  26        () (* prerr_endline s *)
  27     ;;
  28
  29     let rec list_first f = function
  30       | [] -> None
  31       | x::tl -> match f x with Some _ as x -> x | _ -> list_first f tl
  32     ;;
  33
  34     let first_position pos ctx t f =
  35       let rec aux pos ctx = function
  36       | Terms.Leaf _ as t -> f t pos ctx
  37       | Terms.Var _ -> None
  38       | Terms.Node l as t->
  39           match f t pos ctx with
  40           | Some _ as x -> x
  41           | None ->
  42               let rec first pre post = function
  43                 | [] -> None
  44                 | t :: tl ->
  45                      let newctx = fun x -> ctx (Terms.Node (pre@[x]@post)) in
  46                      match aux (List.length pre :: pos) newctx t with
  47                      | Some _ as x -> x
  48                      | None ->
  49                          if post = [] then None (* tl is also empty *)
  50                          else first (pre @ [t]) (List.tl post) tl
  51               in
  52                 first [] (List.tl l) l
  53       in
  54         aux pos ctx t
  55     ;;
  56
  57     let all_positions pos ctx t f =
  58       let rec aux pos ctx = function
  59       | Terms.Leaf _ as t -> f t pos ctx
  60       | Terms.Var _ -> []
  61       | Terms.Node l as t->
  62           let acc, _, _ =
  63             List.fold_left
  64             (fun (acc,pre,post) t -> (* Invariant: pre @ [t] @ post = l *)
  65                 let newctx = fun x -> ctx (Terms.Node (pre@[x]@post)) in
  66                 let acc = aux (List.length pre :: pos) newctx t @ acc in
  67                 if post = [] then acc, l, []
  68                 else acc, pre @ [t], List.tl post)
  69              (f t pos ctx, [], List.tl l) l
  70           in
  71            acc
  72       in
  73         aux pos ctx t
  74     ;;
  75
  76     let vars_of_term t =
  77       let rec aux acc = function
  78         | Terms.Leaf _ -> acc
  79         | Terms.Var i -> if (List.mem i acc) then acc else i::acc
  80         | Terms.Node l -> List.fold_left aux acc l
  81       in aux [] t
  82     ;;
  83
  84     let build_clause bag filter rule t subst vl id id2 pos dir =
  85       let proof = Terms.Step(rule,id,id2,dir,pos,subst) in
  86       let t = Subst.apply_subst subst t in
  87       if filter t then
  88         let literal =
  89           match t with
  90           | Terms.Node [ Terms.Leaf eq ; ty; l; r ] when B.eq B.eqP eq ->
  91                let o = Order.compare_terms l r in
  92                Terms.Equation (l, r, ty, o)
  93           | t -> Terms.Predicate t
  94         in
  95         let bag, uc =
  96           Utils.add_to_bag bag (0, literal, vars_of_term t, proof)
  97         in
  98         Some (bag, uc)
  99       else
 100         ((*prerr_endline ("Filtering: " ^ Pp.pp_foterm t);*)None)
 101     ;;
 102
 103
 104     (* ============ simplification ================= *)
 105
 106     let demod table varlist subterm pos context =
 107       let cands = IDX.DT.retrieve_generalizations table subterm in
 108       list_first
 109         (fun (dir, (id,lit,vl,_)) ->
 110            match lit with
 111            | Terms.Predicate _ -> assert false
 112            | Terms.Equation (l,r,_,o) ->
 113                let side, newside = if dir=Terms.Left2Right then l,r else r,l in
 114                try
 115                  let subst, varlist =
 116                    Unif.unification (varlist@vl) varlist subterm side
 117                  in
 118                  if o = Terms.Incomparable then
 119                    let side = Subst.apply_subst subst side in
 120                    let newside = Subst.apply_subst subst newside in
 121                    let o = Order.compare_terms newside side in
 122                    (* Riazanov, pp. 45 (ii) *)
 123                    if o = Terms.Lt then
 124                      Some (context newside, subst, varlist, id, pos, dir)
 125                    else
 126                      ((*prerr_endline ("Filtering: " ^
 127                         Pp.pp_foterm side ^ " =(< || =)" ^
 128                         Pp.pp_foterm newside ^ " coming from " ^
 129                         Pp.pp_unit_clause uc );*)None)
 130                  else
 131                    Some (context newside, subst, varlist, id, pos, dir)
 132                with FoUnif.UnificationFailure _ -> None)
 133         (IDX.ClauseSet.elements cands)
 134     ;;
 135
 136     let demodulate_once ~jump_to_right bag (id, literal, vl, pr) table =
 137       (* debug ("Demodulating : " ^ (Pp.pp_unit_clause (id, literal, vl, pr)));*)
 138       match literal with
 139       | Terms.Predicate t -> assert false
 140       | Terms.Equation (l,r,ty,_) ->
 141         let left_position = if jump_to_right then None else
 142           first_position [2]
 143             (fun x -> Terms.Node [ Terms.Leaf B.eqP; ty; x; r ]) l
 144             (demod table vl)
 145         in
 146         match left_position with
 147           | Some (newt, subst, varlist, id2, pos, dir) ->
 148               begin
 149                 match build_clause bag (fun _ -> true) Terms.Demodulation
 150                   newt subst varlist id id2 pos dir
 151                 with
 152                   | None -> assert false
 153                   | Some x -> Some (x,false)
 154               end
 155           | None ->
 156               match first_position
 157                 [3] (fun x -> Terms.Node [ Terms.Leaf B.eqP; ty; l; x ]) r
 158                 (demod table vl)
 159               with
 160                 | None -> None
 161                 | Some (newt, subst, varlist, id2, pos, dir) ->
 162                     match build_clause bag (fun _ -> true)
 163                       Terms.Demodulation newt subst varlist id id2 pos dir
 164                     with
 165                         | None -> assert false
 166                         | Some x -> Some (x,true)
 167     ;;
 168
 169     let rec demodulate ~jump_to_right bag clause table =
 170       match demodulate_once ~jump_to_right bag clause table with
 171       | None -> bag, clause
 172       | Some ((bag, clause),r) -> demodulate ~jump_to_right:r
 173           bag clause table
 174     ;;
 175
 176     let demodulate bag clause table = demodulate ~jump_to_right:false
 177       bag clause table
 178     ;;
 179
 180     (* move away *)
 181     let is_identity_clause = function
 182       | _, Terms.Equation (_,_,_,Terms.Eq), _, _ -> true
 183       | _, Terms.Predicate _, _, _ -> assert false
 184       | _ -> false
 185     ;;
 186
 187     let build_new_clause bag maxvar filter rule t subst vl id id2 pos dir =
 188       let maxvar, vl, relocsubst = Utils.relocate maxvar vl in
 189       let subst = Subst.concat relocsubst subst in
 190       match build_clause bag filter rule t subst vl id id2 pos dir with
 191       | Some (bag, c) -> Some ((bag, maxvar), c)
 192       | None -> None
 193     ;;
 194
 195
 196     let fold_build_new_clause bag maxvar id rule filter res =
 197       let (bag, maxvar), res =
 198        HExtlib.filter_map_acc
 199          (fun (bag, maxvar) (t,subst,vl,id2,pos,dir) ->
 200             build_new_clause bag maxvar filter rule t subst vl id id2 pos dir)
 201          (bag, maxvar) res
 202       in
 203        bag, maxvar, res
 204     ;;
 205
 206     let is_subsumed ~unify bag maxvar (id, lit, vl, _) table =
 207       match lit with
 208       | Terms.Predicate _ -> assert false
 209       | Terms.Equation (l,r,ty,_) ->
 210           let retrieve = if unify then IDX.DT.retrieve_unifiables
 211           else IDX.DT.retrieve_generalizations in
 212           let lcands = retrieve table l in
 213           let rcands = retrieve table r in
 214           let f b c =
 215             let id, dir, l, r, vl =
 216               match c with
 217               | (d, (id,Terms.Equation (l,r,ty,_),vl,_))-> id, d, l, r, vl
 218               |_ -> assert false
 219             in
 220             let reverse = (dir = Terms.Left2Right) = b in
 221             let l, r, proof_rewrite_dir = if reverse then l,r,Terms.Left2Right
 222             else r,l, Terms.Right2Left in
 223             (id,proof_rewrite_dir,Terms.Node [ Terms.Leaf B.eqP; ty; l; r ], vl)
 224           in
 225           let cands1 = List.map (f true) (IDX.ClauseSet.elements lcands) in
 226           let cands2 = List.map (f false) (IDX.ClauseSet.elements rcands) in
 227           let t = Terms.Node [ Terms.Leaf B.eqP; ty; l; r ] in
 228           let locked_vars = if unify then [] else vl in
 229           let rec aux = function
 230             | [] -> None
 231             | (id2,dir,c,vl1)::tl ->
 232                 try
 233                   let subst,vl1 = Unif.unification (vl@vl1) locked_vars c t in
 234                   let id_t = Terms.Node [ Terms.Leaf B.eqP; ty; r; r ] in
 235                     build_new_clause bag maxvar (fun _ -> true)
 236                       Terms.Superposition id_t subst [] id id2 [2] dir
 237                 with FoUnif.UnificationFailure _ -> aux tl
 238           in
 239             aux (cands1 @ cands2)
 240     ;;
 241
 242     (* demodulate and check for subsumption *)
 243     let simplify table maxvar bag clause =
 244       let bag, clause = demodulate bag clause table in
 245       if is_identity_clause clause then None
 246       else
 247         match is_subsumed ~unify:false bag maxvar clause table with
 248           | None -> Some (bag, clause)
 249           | Some _ -> None
 250     ;;
 251
 252     let one_pass_simplification new_clause (alist,atable) bag maxvar =
 253       match simplify atable maxvar bag new_clause with
 254         | None -> None (* new_clause has been discarded *)
 255         | Some (bag, clause) ->
 256             let ctable = IDX.index_unit_clause IDX.DT.empty clause in
 257             let bag, alist, atable =
 258               List.fold_left
 259                 (fun (bag, alist, atable as acc) c ->
 260                    match simplify ctable maxvar bag c with
 261                      |None -> acc (* an active clause as been discarded *)
 262                      |Some (bag, c1) ->
 263                         bag, c :: alist, IDX.index_unit_clause atable c)
 264                 (bag,[],IDX.DT.empty) alist
 265             in
 266               Some (clause, bag, (alist,atable))
 267     ;;
 268
 269     let simplification_step ~new_cl cl (alist,atable) bag maxvar new_clause =
 270       let atable1 =
 271         if new_cl then atable else
 272         IDX.index_unit_clause atable cl
 273       in
 274         (* Simplification of new_clause with :      *
 275          * - actives and cl if new_clause is not cl *
 276          * - only actives otherwise                 *)
 277         match simplify atable1 maxvar bag new_clause with
 278           | None -> (Some cl, None) (* new_clause has been discarded *)
 279           | Some (bag, clause) ->
 280               (* Simplification of each active clause with clause *
 281                * which is the simplified form of new_clause       *)
 282               let ctable = IDX.index_unit_clause IDX.DT.empty clause in
 283               let bag, newa, alist, atable =
 284                 List.fold_left
 285                   (fun (bag, newa, alist, atable as acc) c ->
 286                      match simplify ctable maxvar bag c with
 287                        |None -> acc (* an active clause as been discarded *)
 288                        |Some (bag, c1) ->
 289                             if (c1 == c) then
 290                               bag, newa, c :: alist,
 291                             IDX.index_unit_clause atable c
 292                             else
 293                               bag, c1 :: newa, alist, atable)
 294                   (bag,[],[],IDX.DT.empty) alist
 295               in
 296                 if new_cl then
 297                   (Some cl, Some (clause, (alist,atable), newa, bag))
 298                 else
 299                   (* if new_clause is not cl, we simplify cl with clause *)
 300                   match simplify ctable maxvar bag cl with
 301                     | None ->
 302                         (* cl has been discarded *)
 303                         (None, Some (clause, (alist,atable), newa, bag))
 304                     | Some (bag,cl1) ->
 305                         (Some cl1, Some (clause, (alist,atable), newa, bag))
 306     ;;
 307
 308     let keep_simplified cl (alist,atable) bag maxvar =
 309       let rec keep_simplified_aux ~new_cl cl (alist,atable) bag newc =
 310         if new_cl then
 311           match simplification_step ~new_cl cl (alist,atable) bag maxvar cl with
 312             | (None, _) -> assert false
 313             | (Some _, None) -> None
 314             | (Some _, Some (clause, (alist,atable), newa, bag)) ->
 315                 keep_simplified_aux ~new_cl:(cl!=clause) clause (alist,atable)
 316                   bag (newa@newc)
 317         else
 318           match newc with
 319             | [] -> Some (cl, bag, (alist,atable))
 320             | hd::tl ->
 321                 match simplification_step ~new_cl cl
 322                   (alist,atable) bag maxvar hd with
 323                   | (None,None) -> assert false
 324                   | (Some _,None) ->
 325                       keep_simplified_aux ~new_cl cl (alist,atable) bag tl
 326                   | (None, Some _) -> None
 327                   | (Some cl1, Some (clause, (alist,atable), newa, bag)) ->
 328                       let alist,atable =
 329                         (clause::alist, IDX.index_unit_clause atable clause)
 330                       in
 331                         keep_simplified_aux ~new_cl:(cl!=cl1) cl1 (alist,atable)
 332                           bag (newa@tl)
 333       in
 334         keep_simplified_aux ~new_cl:true cl (alist,atable) bag []
 335     ;;
 336
 337     let are_alpha_eq cl1 cl2 =
 338       let get_term (_,lit,_,_) =
 339         match lit with
 340           | Terms.Predicate _ -> assert false
 341           | Terms.Equation (l,r,ty,_) ->
 342               Terms.Node [Terms.Leaf B.eqP; ty; l ; r]
 343       in
 344         try ignore(Unif.alpha_eq (get_term cl1) (get_term cl2)) ; true
 345         with FoUnif.UnificationFailure _ -> false
 346 ;;
 347
 348     (* this is like simplify but raises Success *)
 349     let simplify_goal maxvar table bag g_actives clause =
 350       let bag, clause = demodulate bag clause table in
 351       if (is_identity_clause clause)
 352       then raise (Success (bag, maxvar, clause))
 353       else match is_subsumed ~unify:true bag maxvar clause table with
 354         | None ->
 355             if List.exists (are_alpha_eq clause) g_actives then None
 356             else Some (bag, clause)
 357         | Some ((bag,maxvar),c) ->
 358             debug "Goal subsumed";
 359             raise (Success (bag,maxvar,c))
 360     ;;
 361
 362     (* =================== inference ===================== *)
 363
 364     (* this is OK for both the sup_left and sup_right inference steps *)
 365     let superposition table varlist subterm pos context =
 366       let cands = IDX.DT.retrieve_unifiables table subterm in
 367       HExtlib.filter_map
 368         (fun (dir, (id,lit,vl,_ (*as uc*))) ->
 369            match lit with
 370            | Terms.Predicate _ -> assert false
 371            | Terms.Equation (l,r,_,o) ->
 372                let side, newside = if dir=Terms.Left2Right then l,r else r,l in
 373                try
 374                  let subst, varlist =
 375                    Unif.unification (varlist@vl) [] subterm side
 376                  in
 377                  if o = Terms.Incomparable then
 378                    let side = Subst.apply_subst subst side in
 379                    let newside = Subst.apply_subst subst newside in
 380                    let o = Order.compare_terms side newside in
 381                    (* XXX: check Riazanov p. 33 (iii) *)
 382                    if o <> Terms.Lt && o <> Terms.Eq then
 383                      Some (context newside, subst, varlist, id, pos, dir)
 384                    else
 385                      ((*prerr_endline ("Filtering: " ^
 386                         Pp.pp_foterm side ^ " =(< || =)" ^
 387                         Pp.pp_foterm newside ^ " coming from " ^
 388                         Pp.pp_unit_clause uc );*)None)
 389                  else
 390                    Some (context newside, subst, varlist, id, pos, dir)
 391                with FoUnif.UnificationFailure _ -> None)
 392         (IDX.ClauseSet.elements cands)
 393     ;;
 394
 395     (* Superposes selected equation with equalities in table *)
 396     let superposition_with_table bag maxvar (id,selected,vl,_) table =
 397       match selected with
 398       | Terms.Predicate _ -> assert false
 399       | Terms.Equation (l,r,ty,Terms.Lt) ->
 400           fold_build_new_clause bag maxvar id Terms.Superposition
 401             (fun _ -> true)
 402             (all_positions [3]
 403               (fun x -> Terms.Node [ Terms.Leaf B.eqP; ty; l; x ])
 404               r (superposition table vl))
 405       | Terms.Equation (l,r,ty,Terms.Gt) ->
 406           fold_build_new_clause bag maxvar id Terms.Superposition
 407             (fun _ -> true)
 408             (all_positions [2]
 409               (fun x -> Terms.Node [ Terms.Leaf B.eqP; ty; x; r ])
 410               l (superposition table vl))
 411       | Terms.Equation (l,r,ty,Terms.Incomparable) ->
 412           fold_build_new_clause bag maxvar id Terms.Superposition
 413             (function (* Riazanov: p.33 condition (iv) *)
 414               | Terms.Node [Terms.Leaf eq; ty; l; r ] when B.eq B.eqP eq ->
 415                   Order.compare_terms l r <> Terms.Eq
 416               | _ -> assert false)
 417             ((all_positions [3]
 418                (fun x -> Terms.Node [ Terms.Leaf B.eqP; ty; l; x ])
 419                r (superposition table vl)) @
 420              (all_positions [2]
 421                (fun x -> Terms.Node [ Terms.Leaf B.eqP; ty; x; r ])
 422                l (superposition table vl)))
 423       | _ -> assert false
 424     ;;
 425
 426     (* the current equation is normal w.r.t. demodulation with atable
 427      * (and is not the identity) *)
 428     let infer_right bag maxvar current (alist,atable) =
 429       (* We demodulate actives clause with current until all *
 430        * active clauses are reduced w.r.t each other         *)
 431       (* let bag, (alist,atable) = keep_simplified (alist,atable) bag [current] in *)
 432       let ctable = IDX.index_unit_clause IDX.DT.empty current in
 433       (* let bag, (alist, atable) =
 434         let bag, alist =
 435           HExtlib.filter_map_acc (simplify ctable) bag alist
 436         in
 437         bag, (alist, List.fold_left IDX.index_unit_clause IDX.DT.empty alist)
 438       in*)
 439         debug "Simplified active clauses with fact";
 440       (* We superpose active clauses with current *)
 441       let bag, maxvar, new_clauses =
 442         List.fold_left
 443           (fun (bag, maxvar, acc) active ->
 444              let bag, maxvar, newc =
 445                superposition_with_table bag maxvar active ctable
 446              in
 447              bag, maxvar, newc @ acc)
 448           (bag, maxvar, []) alist
 449       in
 450         debug "First superpositions";
 451         (* We add current to active clauses so that it can be *
 452          * superposed with itself                             *)
 453       let alist, atable =
 454         current :: alist, IDX.index_unit_clause atable current
 455       in
 456         debug "Indexed";
 457       let fresh_current, maxvar = Utils.fresh_unit_clause maxvar current in
 458         (* We need to put fresh_current into the bag so that all *
 459          * variables clauses refer to are known.                 *)
 460       let bag, fresh_current = Utils.add_to_bag bag fresh_current in
 461         (* We superpose current with active clauses *)
 462       let bag, maxvar, additional_new_clauses =
 463         superposition_with_table bag maxvar fresh_current atable
 464       in
 465         debug "Another superposition";
 466       let new_clauses = new_clauses @ additional_new_clauses in
 467         debug (Printf.sprintf "Demodulating %d clauses"
 468                  (List.length new_clauses));
 469       let bag, new_clauses =
 470         HExtlib.filter_map_acc (simplify atable maxvar) bag new_clauses
 471       in
 472         debug "Demodulated new clauses";
 473       bag, maxvar, (alist, atable), new_clauses
 474     ;;
 475
 476     let infer_left bag maxvar goal (_alist, atable) =
 477         (* We superpose the goal with active clauses *)
 478       let bag, maxvar, new_goals =
 479         superposition_with_table bag maxvar goal atable
 480       in
 481         debug "Superposed goal with active clauses";
 482         (* We simplify the new goals with active clauses *)
 483       let bag, new_goals =
 484         List.fold_left
 485          (fun (bag, acc) g ->
 486             match simplify_goal maxvar atable bag [] g with
 487               | None -> assert false
 488               | Some (bag,g) -> bag,g::acc)
 489          (bag, []) new_goals
 490       in
 491         debug "Simplified new goals with active clauses";
 492       bag, maxvar, List.rev new_goals
 493     ;;
 494
 495   end