helm/software/components/ng_refiner/nCicMetaSubst.ml

   1 (*
   2     ||M||  This file is part of HELM, an Hypertextual, Electronic
   3     ||A||  Library of Mathematics, developed at the Computer Science
   4     ||T||  Department, University of Bologna, Italy.
   5     ||I||
   6     ||T||  HELM is free software; you can redistribute it and/or
   7     ||A||  modify it under the terms of the GNU General Public License
   8     \   /  version 2 or (at your option) any later version.
   9      \ /   This software is distributed as is, NO WARRANTY.
  10       V_______________________________________________________________ *)
  11
  12 (* $Id$ *)
  13
  14 exception MetaSubstFailure of string Lazy.t
  15 exception Uncertain of string Lazy.t
  16
  17 let newmeta =
  18   let maxmeta = ref 0 in
  19   fun () -> incr maxmeta; !maxmeta
  20 ;;
  21
  22 exception NotInTheList;;
  23
  24 let position to_skip n (shift, lc) =
  25   match lc with
  26   | NCic.Irl _ when to_skip > 0 -> assert false  (* unclear to me *)
  27   | NCic.Irl len when n <= shift || n > shift + len -> raise NotInTheList
  28   | NCic.Irl _ -> n - shift
  29   | NCic.Ctx tl ->
  30       let rec aux to_skip k = function
  31          | [] -> raise NotInTheList
  32          | _ :: tl when to_skip > 0 -> aux (to_skip - 1) (k+1) tl
  33          | (NCic.Rel m)::_ when m + shift = n -> k
  34          | _::tl -> aux to_skip (k+1) tl
  35       in
  36        aux to_skip 1 tl
  37 ;;
  38
  39 let pack_lc orig =
  40   let rec are_contiguous k = function
  41     | [] -> true
  42     | (NCic.Rel j) :: tl when j = k+1 -> are_contiguous j tl
  43     | _ -> false
  44   in
  45   match orig with
  46   | _, NCic.Ctx [] -> 0, NCic.Irl 0
  47   | shift, NCic.Ctx (NCic.Rel k::tl as l) when are_contiguous k tl ->
  48       shift+k-1, NCic.Irl (List.length l)
  49   | _ -> orig
  50 ;;
  51
  52
  53
  54 let mk_perforated_irl shift len restrictions =
  55   let rec aux n =
  56     if n = 0 then [] else
  57      if List.mem (n+shift) restrictions then aux (n-1)
  58      else (NCic.Rel n) :: aux (n-1)
  59   in
  60     pack_lc (shift, NCic.Ctx (List.rev (aux len)))
  61 ;;
  62
  63 exception Occur;;
  64
  65 let rec force_does_not_occur metasenv subst restrictions t =
  66  let rec aux k ms = function
  67     | NCic.Rel r when List.mem (r - k) restrictions -> raise Occur
  68     | NCic.Rel r as orig ->
  69         let amount =
  70           List.length (List.filter (fun x -> x < r - k) restrictions)
  71         in
  72         if amount > 0 then ms, NCic.Rel (r - amount) else ms, orig
  73     | NCic.Meta (n, (shift,lc as l)) as orig ->
  74        (* we ignore the subst since restrict will take care of already
  75         * instantiated/restricted metavariabels *)
  76        let (metasenv,subst as ms), restrictions_for_n, l' =
  77          let l = NCicUtils.expand_local_context lc in
  78
  79          let ms, _, restrictions_for_n, l =
  80           List.fold_right
  81             (fun t (ms, i, restrictions_for_n, l) ->
  82               try
  83                 let ms, t = aux (k-shift) ms t in
  84                 ms, i-1, restrictions_for_n, t::l
  85               with Occur ->
  86                 ms, i-1, i::restrictions_for_n, l)
  87             l (ms, List.length l, [], [])
  88          in
  89
  90           ms, restrictions_for_n, pack_lc (shift, NCic.Ctx l)
  91        in
  92        if restrictions_for_n = [] then
  93          ms, if l = l' then orig else NCic.Meta (n, l')
  94        else
  95          let metasenv, subst, newmeta =
  96            restrict metasenv subst n restrictions_for_n
  97          in
  98            (metasenv, subst), NCic.Meta (newmeta, l')
  99     | t -> NCicUntrusted.map_term_fold_a (fun _ k -> k+1) k aux ms t
 100  in
 101    aux 0 (metasenv,subst) t
 102
 103 and force_does_not_occur_in_context metasenv subst restrictions = function
 104   | name, NCic.Decl t as orig ->
 105       let (metasenv, subst), t' =
 106         force_does_not_occur metasenv subst restrictions t in
 107       metasenv, subst, (if t == t' then orig else (name,NCic.Decl t'))
 108   | name, NCic.Def (bo, ty) as orig ->
 109       let (metasenv, subst), bo' =
 110         force_does_not_occur metasenv subst restrictions bo in
 111       let (metasenv, subst), ty' =
 112         force_does_not_occur metasenv subst restrictions ty in
 113       metasenv, subst,
 114        (if bo == bo' && ty == ty' then orig else (name, NCic.Def (bo', ty')))
 115
 116 and erase_in_context metasenv subst pos restrictions = function
 117   | [] -> metasenv, subst, restrictions, []
 118   | hd::tl as orig ->
 119       let metasenv, subst, restricted, tl' =
 120         erase_in_context metasenv subst (pos+1) restrictions tl in
 121       if List.mem pos restricted then
 122         metasenv, subst, restricted, tl'
 123       else
 124         try
 125           let metasenv, subst, hd' =
 126             let delifted_restricted =
 127               List.map ((+) ~-pos) (List.filter ((<=) pos) restricted) in
 128             force_does_not_occur_in_context
 129               metasenv subst delifted_restricted hd
 130           in
 131            metasenv, subst, restricted,
 132             (if hd' == hd && tl' == tl then orig else (hd' :: tl'))
 133         with Occur ->
 134             metasenv, subst, (pos :: restricted), tl'
 135
 136 and restrict metasenv subst i restrictions =
 137   assert (restrictions <> []);
 138   try
 139     let name, ctx, bo, ty = NCicUtils.lookup_subst i subst in
 140       try
 141         let metasenv, subst, restrictions, newctx =
 142           erase_in_context metasenv subst 1 restrictions ctx in
 143         let (metasenv, subst), newty =
 144           force_does_not_occur metasenv subst restrictions ty in
 145         let (metasenv, subst), newbo =
 146           force_does_not_occur metasenv subst restrictions bo in
 147         let j = newmeta () in
 148         let subst_entry_j = j, (name, newctx, newbo, newty) in
 149         let reloc_irl = mk_perforated_irl 0 (List.length ctx) restrictions in
 150         let subst_entry_i = i, (name, ctx, NCic.Meta (j, reloc_irl), ty) in
 151         let new_subst =
 152           subst_entry_j :: List.map
 153             (fun (n,_) as orig -> if i = n then subst_entry_i else orig) subst
 154         in
 155 (*
 156     prerr_endline ("restringo nella subst: " ^string_of_int i ^ " -> " ^
 157       string_of_int j ^ "\n" ^
 158       NCicPp.ppsubst ~metasenv [subst_entry_j] ^ "\n\n" ^
 159       NCicPp.ppsubst ~metasenv [subst_entry_i] ^ "\n" ^
 160       NCicPp.ppterm ~metasenv ~subst ~context:ctx bo ^ " ---- " ^
 161       NCicPp.ppterm ~metasenv ~subst ~context:newctx newbo
 162             );
 163 *)
 164         metasenv, new_subst, j
 165       with Occur -> raise (MetaSubstFailure (lazy (Printf.sprintf
 166             ("Cannot restrict the context of the metavariable ?%d over "^^
 167             "the hypotheses %s since ?%d is already instantiated "^^
 168             "with %s and at least one of the hypotheses occurs in "^^
 169             "the substituted term") i  (String.concat ", "
 170             (List.map (fun x -> fst (List.nth ctx (x-1))) restrictions)) i
 171             (NCicPp.ppterm ~metasenv ~subst ~context:ctx bo))))
 172   with NCicUtils.Subst_not_found _ ->
 173     try
 174       let name, ctx, ty = NCicUtils.lookup_meta i metasenv in
 175       try
 176         let metasenv, subst, restrictions, newctx =
 177           erase_in_context metasenv subst 1 restrictions ctx in
 178         let (metasenv, subst), newty =
 179           force_does_not_occur metasenv subst restrictions ty in
 180         let j = newmeta () in
 181         let metasenv_entry = j, (name, newctx, newty) in
 182         let reloc_irl =
 183           mk_perforated_irl 0 (List.length ctx) restrictions in
 184         let subst_entry = i, (name, ctx, NCic.Meta (j, reloc_irl), ty) in
 185         List.map
 186           (fun (n,_) as orig -> if i = n then metasenv_entry else orig)
 187           metasenv,
 188         subst_entry :: subst, j
 189       with Occur -> raise (MetaSubstFailure (lazy (Printf.sprintf
 190           ("Cannot restrict the context of the metavariable ?%d "^^
 191           "over the hypotheses %s since metavariable's type depends "^^
 192           "on at least one of them") i (String.concat ", "
 193           (List.map (fun x -> fst (List.nth ctx (x-1))) restrictions)))))
 194     with
 195     | NCicUtils.Meta_not_found _ -> assert false
 196 ;;
 197
 198 let rec flexible_arg subst = function
 199   | NCic.Meta (i,_) | NCic.Appl (NCic.Meta (i,_) :: _)->
 200       (try
 201         let _,_,t,_ = List.assoc i subst in
 202         flexible_arg subst t
 203       with Not_found -> true)
 204   | _ -> false
 205 ;;
 206
 207 let flexible subst l = List.exists (flexible_arg subst) l;;
 208
 209 let in_scope_tag  = "tag:in_scope" ;;
 210 let out_scope_tag_prefix = "tag:out_scope:"
 211 let out_scope_tag n = out_scope_tag_prefix ^ string_of_int n ;;
 212 let is_out_scope_tag tag =
 213    String.length tag > String.length out_scope_tag_prefix &&
 214    String.sub tag 0 (String.length out_scope_tag_prefix) = out_scope_tag_prefix
 215 ;;
 216 let int_of_out_scope_tag tag =
 217   int_of_string
 218    (String.sub tag (String.length out_scope_tag_prefix)
 219      (String.length tag - (String.length out_scope_tag_prefix)))
 220 ;;
 221
 222
 223 (* INVARIANT: we suppose that t is not another occurrence of Meta(n,_),
 224    otherwise the occur check does not make sense in case of unification
 225    of ?n with ?n *)
 226 let delift ~unify metasenv subst context n l t =
 227   let is_in_scope_meta subst = function
 228     | NCic.Meta (i,_) ->
 229         (try
 230            let tag, _, _, _ = NCicUtils.lookup_subst i subst in
 231            tag = Some in_scope_tag
 232         with NCicUtils.Subst_not_found _ -> false)
 233     | _ -> false
 234   in
 235   let unify_list in_scope =
 236     match l with
 237     | _, NCic.Irl _ -> fun _ _ _ _ _ -> None
 238     | shift, NCic.Ctx l -> fun metasenv subst context k t ->
 239        if flexible_arg subst t || is_in_scope_meta subst t then None else
 240          let lb = List.map (fun t -> t, flexible_arg subst t) l in
 241          HExtlib.list_findopt
 242           (fun (li,flexible) i ->
 243             if flexible || i < in_scope then None else
 244              let li = NCicSubstitution.lift (k+shift) li in
 245              match unify metasenv subst context li t with
 246              | Some (metasenv,subst) ->
 247                  Some ((metasenv, subst), NCic.Rel (i+1+k))
 248              | None -> None)
 249           lb
 250   in
 251   let rec aux (context,k,in_scope) (metasenv, subst as ms) t =
 252    match unify_list in_scope metasenv subst context k t with
 253    | Some x -> x
 254    | None ->
 255     match t with
 256     | NCic.Rel n as t when n <= k -> ms, t
 257     | NCic.Rel n ->
 258         (try
 259           match List.nth context (n-k-1) with
 260           | _,NCic.Def (bo,_) ->
 261                 (try ms, NCic.Rel ((position in_scope (n-k) l) + k)
 262                  with NotInTheList ->
 263                 (* CSC: This bit of reduction hurts performances since it is
 264                  * possible to  have an exponential explosion of the size of the
 265                  * proof. required for nat/nth_prime.ma *)
 266                   aux (context,k,in_scope) ms (NCicSubstitution.lift n bo))
 267           | _,NCic.Decl _ -> ms, NCic.Rel ((position in_scope (n-k) l) + k)
 268         with Failure _ -> assert false) (*Unbound variable found in delift*)
 269     | NCic.Meta (i,_) when i=n ->
 270          raise (MetaSubstFailure (lazy (Printf.sprintf (
 271            "Cannot unify the metavariable ?%d with a term that has "^^
 272            "as subterm %s in which the same metavariable "^^
 273            "occurs (occur check)") i
 274             (NCicPp.ppterm ~context ~metasenv ~subst t))))
 275     | NCic.Meta (i,l1) as orig ->
 276         (try
 277            let tag,c,t,ty = NCicUtils.lookup_subst i subst in
 278            let in_scope, clear =
 279              match tag with
 280              | Some tag when tag = in_scope_tag -> 0, true
 281              | Some tag when is_out_scope_tag tag->int_of_out_scope_tag tag,true
 282              | _ -> in_scope, false
 283            in
 284            let ms =
 285              if not clear then ms
 286              else
 287                metasenv,
 288                (i,(None,c,t,ty)) :: List.filter (fun j,_ -> i <> j) subst
 289            in
 290            aux (context,k,in_scope) ms (NCicSubstitution.subst_meta l1 t)
 291          with NCicUtils.Subst_not_found _ ->
 292            if snd l1 = NCic.Irl 0 || snd l1 = NCic.Ctx [] then ms, orig
 293            else
 294               let shift1,lc1 = l1 in
 295               let shift,lc = l in
 296               let shift = shift + k in
 297               match lc, lc1 with
 298               | NCic.Irl len, NCic.Irl len1
 299                 when shift1 + len1 < shift || shift1 > shift + len ->
 300                   let restrictions = HExtlib.list_seq 1 (len1 + 1) in
 301                   let metasenv, subst, newmeta =
 302                      restrict metasenv subst i restrictions
 303                   in
 304                   (metasenv, subst),
 305                     NCic.Meta (newmeta, (0,NCic.Irl (max 0 (k-shift1))))
 306               | NCic.Irl len, NCic.Irl len1 ->
 307                   let low_restrictions, new_shift =
 308                     if k <= shift1 && shift1 < shift then
 309                       HExtlib.list_seq 1 (shift - shift1 + 1), k
 310                     else if shift1 < k (* <= shift *) then
 311                       let save_below = k - shift1 in
 312                       HExtlib.list_seq (save_below + 1) (shift - shift1 + 1),
 313                       shift1
 314                     else [], shift1 - shift + k
 315                   in
 316                   let high_restrictions =
 317                     let last = shift + len in
 318                     let last1 = shift1 + len1 in
 319                     if last1 > last then
 320                       let high_gap = last1 - last in
 321                       HExtlib.list_seq (len1 - high_gap + 1) (len1 + 1)
 322                     else []
 323                   in
 324                   let restrictions = low_restrictions @ high_restrictions in
 325                   if restrictions = [] then
 326                     if shift = k then ms, orig
 327                     else ms, NCic.Meta (i, (new_shift, lc1))
 328                   else
 329                     let metasenv, subst, newmeta =
 330                        restrict metasenv subst i restrictions
 331                     in
 332 (* {{{
 333                   prerr_endline ("RESTRICTIONS FOR: " ^
 334                     NCicPp.ppterm ~metasenv ~subst ~context:[]
 335                     (NCic.Meta (i,l1))^" that was part of a term unified with "
 336                     ^ NCicPp.ppterm ~metasenv ~subst ~context:[] (NCic.Meta
 337                     (n,l)) ^ " ====> " ^ String.concat "," (List.map
 338                     string_of_int restrictions) ^ "\nMENV:\n" ^
 339                     NCicPp.ppmetasenv ~subst metasenv ^ "\nSUBST:\n" ^
 340                     NCicPp.ppsubst subst ~metasenv);
 341 }}} *)
 342                     let newlc_len = len1 - List.length restrictions in
 343                     let meta =
 344                        NCic.Meta(newmeta,(new_shift, NCic.Irl newlc_len))
 345                     in
 346                     assert (
 347                       let _, cctx, _ = NCicUtils.lookup_meta newmeta metasenv in
 348                       List.length cctx = newlc_len);
 349                     (metasenv, subst), meta
 350
 351               | _ ->
 352                   let lc1 = NCicUtils.expand_local_context lc1 in
 353                   let lc1 = List.map (NCicSubstitution.lift shift1) lc1 in
 354                   let rec deliftl tbr j ms = function
 355                     | [] -> ms, tbr, []
 356                     | t::tl ->
 357                         let ms, tbr, tl = deliftl tbr (j+1) ms tl in
 358                         try
 359                           let ms, t = aux (context,k,in_scope) ms t in
 360                           ms, tbr, t::tl
 361                         with
 362                         | NotInTheList | MetaSubstFailure _ -> ms, j::tbr, tl
 363                   in
 364                   let (metasenv, subst), to_be_r, lc1' = deliftl [] 1 ms lc1 in
 365 (*
 366                   prerr_endline ("TO BE RESTRICTED: " ^
 367                    (String.concat "," (List.map string_of_int to_be_r)));
 368 *)
 369                   let l1 = pack_lc (0, NCic.Ctx lc1') in
 370 (*
 371                   prerr_endline ("newmeta:" ^ NCicPp.ppterm
 372                    ~metasenv ~subst ~context (NCic.Meta (999,l1)));
 373 *)
 374                   if to_be_r = [] then
 375                     (metasenv, subst),
 376                     (if lc1' = lc1 then orig else NCic.Meta (i,l1))
 377                   else
 378                     let metasenv, subst, newmeta =
 379                       restrict metasenv subst i to_be_r in
 380                     (metasenv, subst), NCic.Meta(newmeta,l1))
 381
 382     | t ->
 383         NCicUntrusted.map_term_fold_a
 384           (fun e (c,k,s) -> (e::c,k+1,s)) (context,k,in_scope) aux ms t
 385   in
 386    try aux (context,0,0) (metasenv,subst) t
 387    with NotInTheList ->
 388       (* This is the case where we fail even first order unification. *)
 389       (* The reason is that our delift function is weaker than first  *)
 390       (* order (in the sense of alpha-conversion). See comment above  *)
 391       (* related to the delift function.                              *)
 392       let msg = (lazy (Printf.sprintf
 393         ("Error trying to abstract %s over [%s]: the algorithm only tried to "^^
 394         "abstract over bound variables") (NCicPp.ppterm ~metasenv ~subst
 395         ~context t) (String.concat "; " (List.map (NCicPp.ppterm ~metasenv
 396         ~subst ~context) (let shift, lc = l in List.map (NCicSubstitution.lift
 397         shift) (NCicUtils.expand_local_context lc))))))
 398       in
 399       let shift, lc = l in
 400       let lc = NCicUtils.expand_local_context lc in
 401       let l = List.map (NCicSubstitution.lift shift) lc in
 402        if
 403          List.exists
 404           (fun t ->
 405                   NCicUntrusted.metas_of_term subst context t = [])
 406             l
 407        then
 408         raise (Uncertain msg)
 409        else
 410         raise (MetaSubstFailure msg)
 411 ;;
 412
 413 let mk_meta ?name metasenv context ty =
 414   let tyof = function Some s -> Some ("typeof_"^s) | None -> None in
 415   let rec mk_meta name n metasenv context = function
 416   | `WithType ty ->
 417     let len = List.length context in
 418     let menv_entry = (n, (name, context, ty)) in
 419     menv_entry :: metasenv, n, NCic.Meta (n, (0,NCic.Irl len)), ty
 420   | `Sort ->
 421     let ty = NCic.Implicit (`Typeof n) in
 422     mk_meta (tyof name) n metasenv [] (`WithType ty)
 423   | `Type ->
 424     let metasenv, _, ty, _ =
 425       mk_meta (tyof name) (newmeta ()) metasenv context `Sort in
 426     mk_meta name n metasenv context (`WithType ty)
 427   | `Term ->
 428     let metasenv, _, ty, _ =
 429       mk_meta (tyof name) (newmeta ()) metasenv context `Type in
 430     mk_meta name n metasenv context (`WithType ty)
 431   in
 432     mk_meta name (newmeta ()) metasenv context ty
 433 ;;
 434
 435 let saturate ?(delta=0) metasenv subst context ty goal_arity =
 436  assert (goal_arity >= 0);
 437   let rec aux metasenv = function
 438    | NCic.Prod (name,s,t) as ty ->
 439        let metasenv1, _, arg,_ =
 440           mk_meta ~name:name metasenv context (`WithType s) in
 441        let t, metasenv1, args, pno =
 442            aux metasenv1 (NCicSubstitution.subst arg t)
 443        in
 444        if pno + 1 = goal_arity then
 445          ty, metasenv, [], goal_arity+1
 446        else
 447          t, metasenv1, arg::args, pno+1
 448    | ty ->
 449         match NCicReduction.whd ~subst context ty ~delta with
 450         | NCic.Prod _ as ty -> aux metasenv ty
 451         | ty -> ty, metasenv, [], 0
 452   in
 453   let res, newmetasenv, arguments, _ = aux metasenv ty in
 454   res, newmetasenv, arguments
 455 ;;