helm/software/components/ng_refiner/nCicRefiner.ml

   1 (*
   2     ||M||  This file is part of HELM, an Hypertextual, Electronic
   3     ||A||  Library of Mathematics, developed at the Computer Science
   4     ||T||  Department, University of Bologna, Italy.
   5     ||I||
   6     ||T||  HELM is free software; you can redistribute it and/or
   7     ||A||  modify it under the terms of the GNU General Public License
   8     \   /  version 2 or (at your option) any later version.
   9      \ /   This software is distributed as is, NO WARRANTY.
  10       V_______________________________________________________________ *)
  11
  12 (* $Id$ *)
  13
  14 exception RefineFailure of (Stdpp.location * string) Lazy.t;;
  15 exception Uncertain of (Stdpp.location * string) Lazy.t;;
  16 exception AssertFailure of string Lazy.t;;
  17
  18 module C = NCic
  19 module Ref = NReference
  20
  21 let indent = ref "";;
  22 let inside c = indent := !indent ^ String.make 1 c;;
  23 let outside () = indent := String.sub !indent 0 (String.length !indent -1);;
  24
  25 (*
  26 let pp s =
  27   prerr_endline (Printf.sprintf "%-20s" !indent ^ " " ^ Lazy.force s)
  28 ;;
  29 *)
  30
  31 let pp _ = ();;
  32
  33 let wrap_exc msg = function
  34   | NCicUnification.Uncertain _ -> Uncertain msg
  35   | NCicUnification.UnificationFailure _ -> RefineFailure msg
  36   | NCicTypeChecker.TypeCheckerFailure _ -> RefineFailure msg
  37   | e -> raise e
  38 ;;
  39
  40 let exp_implicit metasenv context expty =
  41  let foo x = match expty with Some t -> `WithType t | None -> x in
  42  function
  43   | `Closed -> NCicMetaSubst.mk_meta metasenv [] (foo `Term)
  44   | `Type -> NCicMetaSubst.mk_meta metasenv context (foo `Type)
  45   | `Term -> NCicMetaSubst.mk_meta metasenv context (foo `Term)
  46   | _ -> assert false
  47 ;;
  48
  49 let force_to_sort metasenv subst context orig localise t =
  50   match NCicReduction.whd ~subst context t with
  51   | C.Meta (_,(0,(C.Irl 0 | C.Ctx []))) as t ->
  52      metasenv, subst, t
  53   | C.Meta (i,(_,(C.Irl 0 | C.Ctx []))) ->
  54      metasenv, subst, C.Meta(i,(0,C.Irl 0))
  55   | C.Meta (i,(_,lc)) ->
  56      let len = match lc with C.Irl len->len | C.Ctx l->List.length l in
  57      let metasenv, subst, newmeta =
  58        if len > 0 then
  59          NCicMetaSubst.restrict metasenv subst i (HExtlib.list_seq 1 (len+1))
  60        else metasenv, subst, i
  61      in
  62      metasenv, subst, C.Meta (newmeta,(0,C.Irl 0))
  63   | C.Sort _ as t -> metasenv, subst, t
  64   | t ->
  65       raise (RefineFailure (lazy
  66         (localise orig,
  67         "Not a sort: " ^
  68         NCicPp.ppterm ~metasenv ~subst ~context t)))
  69 ;;
  70
  71 let sort_of_prod
  72   localise metasenv subst context orig_s orig_t (name,s) t (t1, t2)
  73 =
  74    let metasenv, subst, t1 =
  75      force_to_sort metasenv subst context orig_s localise t1 in
  76    let metasenv, subst, t2 =
  77      force_to_sort metasenv subst ((name,C.Decl s)::context)
  78        orig_t localise t2 in
  79    match t1, t2 with
  80    | C.Sort _, C.Sort C.Prop -> metasenv, subst, t2
  81    | C.Sort (C.Type u1), C.Sort (C.Type u2) ->
  82         metasenv, subst, C.Sort (C.Type (u1@u2))
  83    | C.Sort C.Prop,C.Sort (C.Type _) -> metasenv, subst, t2
  84    | C.Meta _, C.Sort _
  85    | C.Meta _, C.Meta (_,(_,_))
  86    | C.Sort _, C.Meta (_,(_,_)) -> metasenv, subst, t2
  87    | x, (C.Sort _ | C.Meta _) | _, x ->
  88       let y, context, orig =
  89         if x == t1 then s, context, orig_s
  90         else t, ((name,C.Decl s)::context), orig_t
  91       in
  92       raise (RefineFailure (lazy (localise orig,Printf.sprintf
  93         "%s is expected to be a type, but its type is %s that is not a sort"
  94          (NCicPp.ppterm ~subst ~metasenv ~context y)
  95          (NCicPp.ppterm ~subst ~metasenv ~context x))))
  96 ;;
  97
  98 let check_allowed_sort_elimination localise r orig =
  99    let mkapp he arg =
 100      match he with
 101      | C.Appl l -> C.Appl (l @ [arg])
 102      | t -> C.Appl [t;arg] in
 103    (* ctx, ind_type @ lefts, sort_of_ind_ty@lefts, outsort *)
 104    let rec aux metasenv subst context ind arity1 arity2 =
 105      (*D*)inside 'S'; try let rc =
 106      let arity1 = NCicReduction.whd ~subst context arity1 in
 107      pp (lazy(NCicPp.ppterm ~subst ~metasenv ~context arity1 ^ "   elimsto   " ^
 108         NCicPp.ppterm ~subst ~metasenv ~context arity2 ^ "\nMENV:\n"^
 109         NCicPp.ppmetasenv ~subst metasenv));
 110      match arity1 with
 111      | C.Prod (name,so1,de1) (* , t ==?== C.Prod _ *) ->
 112         let metasenv, meta, _ =
 113           NCicMetaSubst.mk_meta metasenv ((name,C.Decl so1)::context) `Type
 114         in
 115         let metasenv, subst =
 116           try NCicUnification.unify metasenv subst context
 117                 arity2 (C.Prod (name, so1, meta))
 118           with exc -> raise (wrap_exc (lazy (localise orig, Printf.sprintf
 119             "expected %s, found %s" (* XXX localizzare meglio *)
 120             (NCicPp.ppterm ~subst ~metasenv ~context (C.Prod (name, so1, meta)))
 121             (NCicPp.ppterm ~subst ~metasenv ~context arity2))) exc)
 122         in
 123         aux metasenv subst ((name, C.Decl so1)::context)
 124          (mkapp (NCicSubstitution.lift 1 ind) (C.Rel 1)) de1 meta
 125      | C.Sort _ (* , t ==?== C.Prod _ *) ->
 126         let metasenv, meta, _ = NCicMetaSubst.mk_meta metasenv [] `Type in
 127         let metasenv, subst =
 128           try NCicUnification.unify metasenv subst context
 129                 arity2 (C.Prod ("_", ind, meta))
 130           with exc -> raise (wrap_exc (lazy (localise orig, Printf.sprintf
 131             "expected %s, found %s" (* XXX localizzare meglio *)
 132             (NCicPp.ppterm ~subst ~metasenv ~context (C.Prod ("_", ind, meta)))
 133             (NCicPp.ppterm ~subst ~metasenv ~context arity2))) exc)
 134         in
 135         (try NCicTypeChecker.check_allowed_sort_elimination
 136             ~metasenv ~subst r context ind arity1 arity2;
 137             metasenv, subst
 138         with exc -> raise (wrap_exc (lazy (localise orig,
 139           "Sort elimination not allowed ")) exc))
 140      | _ -> assert false
 141      (*D*)in outside(); rc with exc -> outside (); raise exc
 142    in
 143     aux
 144 ;;
 145
 146 let rec typeof
 147   ?(localise=fun _ -> Stdpp.dummy_loc) metasenv subst context term expty
 148 =
 149   let force_ty metasenv subst context orig t infty expty =
 150     (*D*)inside 'F'; try let rc =
 151     match expty with
 152     | Some expty ->
 153        (match t with
 154        | C.Implicit _
 155        | C.Lambda _ -> metasenv, subst, t, expty
 156        | _ ->
 157           pp (lazy (
 158           (NCicPp.ppterm ~metasenv ~subst ~context infty) ^  " === " ^
 159           (NCicPp.ppterm ~metasenv ~subst ~context expty)));
 160          let metasenv, subst =
 161            try NCicUnification.unify metasenv subst context infty expty
 162            with exc -> raise (wrap_exc (lazy (localise orig, Printf.sprintf
 163              "The term %s has type %s but is here used with type %s"
 164              (NCicPp.ppterm ~metasenv ~subst ~context t)
 165              (NCicPp.ppterm ~metasenv ~subst ~context infty)
 166              (NCicPp.ppterm ~metasenv ~subst ~context expty))) exc)
 167          in
 168          metasenv, subst, t, expty)
 169     | None -> metasenv, subst, t, infty
 170     (*D*)in outside(); rc with exc -> outside (); raise exc
 171   in
 172   let rec typeof_aux metasenv subst context expty =
 173     fun t as orig ->
 174     (*D*)inside 'R'; try let rc =
 175     pp (lazy (NCicPp.ppterm ~metasenv ~subst ~context t));
 176     pp (lazy (NCicPp.ppmetasenv ~subst metasenv));
 177     let metasenv, subst, t, infty =
 178     match t with
 179     | C.Rel n ->
 180         let infty =
 181          (try
 182            match List.nth context (n - 1) with
 183            | (_,C.Decl ty) -> NCicSubstitution.lift n ty
 184            | (_,C.Def (_,ty)) -> NCicSubstitution.lift n ty
 185          with Failure _ ->
 186            raise (RefineFailure (lazy (localise t,"unbound variable"))))
 187         in
 188         metasenv, subst, t, infty
 189     | C.Sort (C.Type [false,u]) -> metasenv,subst,t,(C.Sort (C.Type [true, u]))
 190     | C.Sort (C.Type _) ->
 191         raise (AssertFailure (lazy ("Cannot type an inferred type: "^
 192           NCicPp.ppterm ~subst ~metasenv ~context t)))
 193     | C.Sort _ -> metasenv,subst,t,(C.Sort (C.Type NCicEnvironment.type0))
 194     | C.Implicit infos ->
 195          let metasenv,t,ty = exp_implicit metasenv context expty infos in
 196          metasenv, subst, t, ty
 197     | C.Meta (n,l) as t ->
 198        let ty =
 199         try
 200          let _,_,_,ty = NCicUtils.lookup_subst n subst in ty
 201         with NCicUtils.Subst_not_found _ -> try
 202          let _,_,ty = NCicUtils.lookup_meta n metasenv in
 203          match ty with C.Implicit _ -> assert false | _ -> ty
 204         with NCicUtils.Meta_not_found _ ->
 205          raise (AssertFailure (lazy (Printf.sprintf
 206           "%s not found" (NCicPp.ppterm ~subst ~metasenv ~context t))))
 207        in
 208        metasenv, subst, t, NCicSubstitution.subst_meta l ty
 209     | C.Const _ ->
 210        metasenv, subst, t, NCicTypeChecker.typeof ~subst ~metasenv context t
 211     | C.Prod (name,(s as orig_s),(t as orig_t)) ->
 212        let metasenv, subst, s, s1 = typeof_aux metasenv subst context None s in
 213        let context1 = (name,(C.Decl s))::context in
 214        let metasenv, subst, t, s2 = typeof_aux metasenv subst context1 None t in
 215        let metasenv, subst, ty =
 216          sort_of_prod localise metasenv subst
 217            context orig_s orig_t (name,s) t (s1,s2)
 218        in
 219        metasenv, subst, NCic.Prod(name,s,t), ty
 220     | C.Lambda (n,(s as orig_s),t) ->
 221        let exp_s, exp_ty_t =
 222          match expty with
 223          | None -> None, None
 224          | Some expty ->
 225              match NCicReduction.whd ~subst context expty with
 226              | C.Prod (_,s,t) -> Some s, Some t
 227              | _ -> None, None
 228        in
 229        let metasenv, subst, s, ty_s =
 230          typeof_aux metasenv subst context None s in
 231        let metasenv, subst, _ =
 232          force_to_sort metasenv subst context orig_s localise ty_s in
 233        let (metasenv,subst), exp_ty_t =
 234          match exp_s with
 235          | Some exp_s ->
 236              (try NCicUnification.unify metasenv subst context s exp_s,exp_ty_t
 237              with exc -> raise (wrap_exc (lazy (localise orig_s, Printf.sprintf
 238                "Source type %s was expected to be %s" (NCicPp.ppterm ~metasenv
 239                ~subst ~context s) (NCicPp.ppterm ~metasenv ~subst ~context
 240                exp_s))) exc))
 241          | None -> (metasenv, subst), None
 242        in
 243        (* XXX coerce_to_sort s *)
 244        let context = (n,C.Decl s) :: context in
 245        let metasenv, subst, t, ty_t =
 246          typeof_aux metasenv subst context exp_ty_t t
 247        in
 248        metasenv, subst, C.Lambda(n,s,t), C.Prod (n,s,ty_t)
 249     | C.LetIn (n,(ty as orig_ty),t,bo) ->
 250        let metasenv, subst, ty, ty_ty =
 251          typeof_aux metasenv subst context None ty in
 252        let metasenv, subst, _ =
 253          force_to_sort metasenv subst context orig_ty localise ty_ty in
 254        let metasenv, subst, t, _ =
 255          typeof_aux metasenv subst context (Some ty) t in
 256        let context1 = (n, C.Def (t,ty)) :: context in
 257        let metasenv, subst, bo, bo_ty =
 258          typeof_aux metasenv subst context1 None bo
 259        in
 260        let bo_ty = NCicSubstitution.subst ~avoid_beta_redexes:true t bo_ty in
 261        metasenv, subst, C.LetIn (n, ty, t, bo), bo_ty
 262     | C.Appl ((he as orig_he)::(_::_ as args)) ->
 263        let metasenv, subst, he, ty_he =
 264          typeof_aux metasenv subst context None he in
 265        eat_prods localise metasenv subst context orig_he he ty_he args
 266    | C.Appl _ -> raise (AssertFailure (lazy "Appl of length < 2"))
 267    | C.Match (Ref.Ref (_,Ref.Ind (_,tyno,_)) as r,
 268           outtype,(term as orig_term),pl) as orig ->
 269       let _, leftno, itl, _, _ = NCicEnvironment.get_checked_indtys r in
 270       let _, _, arity, cl = List.nth itl tyno in
 271       let constructorsno = List.length cl in
 272       let _, metasenv, args =
 273         NCicMetaSubst.saturate metasenv context arity 0 in
 274       let ind = if args = [] then C.Const r else C.Appl (C.Const r::args) in
 275       let metasenv, subst, term, _ =
 276         typeof_aux metasenv subst context (Some ind) term in
 277       let metasenv, subst, outtype, outsort =
 278         typeof_aux metasenv subst context None outtype in
 279       let parameters, arguments = HExtlib.split_nth leftno args in
 280       (* let's control if the sort elimination is allowed: [(I q1 ... qr)|B] *)
 281       let ind =
 282         if parameters = [] then C.Const r
 283         else C.Appl ((C.Const r)::parameters) in
 284       let metasenv, subst, ind, ind_ty =
 285         typeof_aux metasenv subst context None ind in
 286       let metasenv, subst =
 287          check_allowed_sort_elimination localise r orig_term metasenv subst
 288            context ind ind_ty outsort
 289       in
 290       (* let's check if the type of branches are right *)
 291       if List.length pl <> constructorsno then
 292        raise (RefineFailure (lazy (localise orig,
 293          "Wrong number of cases in a match")));
 294       let _, metasenv, subst, pl_rev =
 295         List.fold_left
 296           (fun (j, metasenv, subst, branches) p ->
 297               let cons =
 298                 let cons = Ref.mk_constructor j r in
 299                 if parameters = [] then C.Const cons
 300                 else C.Appl (C.Const cons::parameters)
 301               in
 302               let metasenv, subst, cons, ty_cons =
 303                 typeof_aux metasenv subst context None cons in
 304               let ty_branch =
 305                 NCicTypeChecker.type_of_branch
 306                   ~subst context leftno outtype cons ty_cons in
 307               pp (lazy ("TYPEOFBRANCH: " ^
 308                NCicPp.ppterm ~metasenv ~subst ~context p ^ " ::: " ^
 309                NCicPp.ppterm ~metasenv ~subst ~context ty_branch ));
 310               let metasenv, subst, p, _ =
 311                 typeof_aux metasenv subst context (Some ty_branch) p in
 312               j+1, metasenv, subst, p :: branches)
 313           (1, metasenv, subst, []) pl
 314       in
 315       metasenv, subst,
 316       C.Match (r, outtype, term, List.rev pl_rev),
 317       NCicReduction.head_beta_reduce (C.Appl (outtype::arguments@[term]))
 318     | C.Match _ as orig ->
 319         prerr_endline (NCicPp.ppterm ~metasenv ~subst ~context orig);
 320         assert false
 321     in
 322     pp (lazy (NCicPp.ppterm ~metasenv ~subst ~context t ^ " :: "^
 323          NCicPp.ppterm ~metasenv ~subst ~context infty ));
 324       force_ty metasenv subst context orig t infty expty
 325     (*D*)in outside(); rc with exc -> outside (); raise exc
 326   in
 327     typeof_aux metasenv subst context expty term
 328
 329 and eat_prods localise metasenv subst context orig_he he ty_he args =
 330   (*D*)inside 'E'; try let rc =
 331   let rec aux metasenv subst args_so_far ty_he = function
 332   | [] -> metasenv, subst, NCic.Appl (he :: List.rev args_so_far), ty_he
 333   | arg::tl ->
 334       match NCicReduction.whd ~subst context ty_he with
 335       | C.Prod (_,s,t) ->
 336           let metasenv, subst, arg, _ =
 337             typeof ~localise metasenv subst context arg (Some s) in
 338           let t = NCicSubstitution.subst ~avoid_beta_redexes:true arg t in
 339           aux metasenv subst (arg :: args_so_far) t tl
 340       | C.Meta _
 341       | C.Appl (C.Meta _ :: _) as t ->
 342           let metasenv, subst, arg, ty_arg =
 343             typeof ~localise metasenv subst context arg None in
 344           let metasenv, meta, _ =
 345             NCicMetaSubst.mk_meta metasenv
 346               (("_",C.Decl ty_arg) :: context) `Type
 347           in
 348           let flex_prod = C.Prod ("_", ty_arg, meta) in
 349           pp (lazy ( "UNIFICATION in CTX:\n"^
 350             NCicPp.ppcontext ~metasenv ~subst context
 351             ^ "\nOF: " ^
 352             NCicPp.ppterm ~metasenv ~subst ~context t ^  " === " ^
 353             NCicPp.ppterm ~metasenv ~subst ~context flex_prod ^ "\n"));
 354           let metasenv, subst =
 355              try NCicUnification.unify metasenv subst context t flex_prod
 356              with exc -> raise (wrap_exc (lazy (localise orig_he, Printf.sprintf
 357               ("The term %s has an inferred type %s, but is applied to the" ^^
 358                " argument %s of type %s")
 359               (NCicPp.ppterm ~metasenv ~subst ~context he)
 360               (NCicPp.ppterm ~metasenv ~subst ~context t)
 361               (NCicPp.ppterm ~metasenv ~subst ~context arg)
 362               (NCicPp.ppterm ~metasenv ~subst ~context ty_arg))) exc)
 363               (* XXX coerce to funclass *)
 364           in
 365           let meta = NCicSubstitution.subst ~avoid_beta_redexes:true arg meta in
 366           aux metasenv subst (arg :: args_so_far) meta tl
 367       | C.Match (_,_,C.Meta _,_)
 368       | C.Match (_,_,C.Appl (C.Meta _ :: _),_)
 369       | C.Appl (C.Const (NReference.Ref (_, NReference.Fix _)) :: _) ->
 370           raise (Uncertain (lazy (localise orig_he, Printf.sprintf
 371             ("The term %s is here applied to %d arguments but expects " ^^
 372             "only %d arguments") (NCicPp.ppterm ~metasenv ~subst ~context he)
 373             (List.length args) (List.length args_so_far))))
 374       | _ ->
 375           raise (RefineFailure (lazy (localise orig_he, Printf.sprintf
 376             ("The term %s is here applied to %d arguments but expects " ^^
 377             "only %d arguments") (NCicPp.ppterm ~metasenv ~subst ~context he)
 378             (List.length args) (List.length args_so_far))))
 379   in
 380    aux metasenv subst [] ty_he args
 381   (*D*)in outside(); rc with exc -> outside (); raise exc
 382 ;;
 383 (* vim:set foldmethod=marker: *)