helm/software/components/ng_refiner/nCicRefiner.ml

   1 (*
   2     ||M||  This file is part of HELM, an Hypertextual, Electronic
   3     ||A||  Library of Mathematics, developed at the Computer Science
   4     ||T||  Department, University of Bologna, Italy.
   5     ||I||
   6     ||T||  HELM is free software; you can redistribute it and/or
   7     ||A||  modify it under the terms of the GNU General Public License
   8     \   /  version 2 or (at your option) any later version.
   9      \ /   This software is distributed as is, NO WARRANTY.
  10       V_______________________________________________________________ *)
  11
  12 (* $Id$ *)
  13
  14 exception RefineFailure of (Stdpp.location * string) Lazy.t;;
  15 exception Uncertain of (Stdpp.location * string) Lazy.t;;
  16 exception AssertFailure of string Lazy.t;;
  17
  18 module C = NCic
  19 module Ref = NReference
  20
  21 let indent = ref "";;
  22 let inside c = indent := !indent ^ String.make 1 c;;
  23 let outside () = indent := String.sub !indent 0 (String.length !indent -1);;
  24
  25
  26 let pp s =
  27   prerr_endline (Printf.sprintf "%-20s" !indent ^ " " ^ Lazy.force s)
  28 ;;
  29
  30 let pp _ = ();;
  31
  32 let wrap_exc msg = function
  33   | NCicUnification.Uncertain _ -> Uncertain msg
  34   | NCicUnification.UnificationFailure _ -> RefineFailure msg
  35   | NCicTypeChecker.TypeCheckerFailure _ -> RefineFailure msg
  36   | e -> raise e
  37 ;;
  38
  39 let exp_implicit ~localise metasenv context expty t =
  40  let foo x = match expty with Some t -> `WithType t | None -> x in
  41  function
  42   | `Closed -> NCicMetaSubst.mk_meta metasenv [] (foo `Term)
  43   | `Type -> NCicMetaSubst.mk_meta metasenv context (foo `Type)
  44   | `Term -> NCicMetaSubst.mk_meta metasenv context (foo `Term)
  45   | `Vector ->
  46       raise (RefineFailure (lazy (localise t, "A vector of implicit terms " ^
  47        "can only be used in argument position")))
  48   | _ -> assert false
  49 ;;
  50
  51 let check_allowed_sort_elimination rdb localise r orig =
  52    let mkapp he arg =
  53      match he with
  54      | C.Appl l -> C.Appl (l @ [arg])
  55      | t -> C.Appl [t;arg] in
  56    (* ctx, ind_type @ lefts, sort_of_ind_ty@lefts, outsort *)
  57    let rec aux metasenv subst context ind arity1 arity2 =
  58      (*D*)inside 'S'; try let rc =
  59      let arity1 = NCicReduction.whd ~subst context arity1 in
  60      pp (lazy(NCicPp.ppterm ~subst ~metasenv ~context arity1 ^ "   elimsto   " ^
  61         NCicPp.ppterm ~subst ~metasenv ~context arity2 ^ "\nMENV:\n"^
  62         NCicPp.ppmetasenv ~subst metasenv));
  63      match arity1 with
  64      | C.Prod (name,so1,de1) (* , t ==?== C.Prod _ *) ->
  65         let metasenv, _, meta, _ =
  66           NCicMetaSubst.mk_meta metasenv ((name,C.Decl so1)::context) `Type
  67         in
  68         let metasenv, subst =
  69           try NCicUnification.unify rdb metasenv subst context
  70                 arity2 (C.Prod (name, so1, meta))
  71           with exc -> raise (wrap_exc (lazy (localise orig, Printf.sprintf
  72             "expected %s, found %s" (* XXX localizzare meglio *)
  73             (NCicPp.ppterm ~subst ~metasenv ~context (C.Prod (name, so1, meta)))
  74             (NCicPp.ppterm ~subst ~metasenv ~context arity2))) exc)
  75         in
  76         aux metasenv subst ((name, C.Decl so1)::context)
  77          (mkapp (NCicSubstitution.lift 1 ind) (C.Rel 1)) de1 meta
  78      | C.Sort _ (* , t ==?== C.Prod _ *) ->
  79         let metasenv, _, meta, _ = NCicMetaSubst.mk_meta metasenv [] `Type in
  80         let metasenv, subst =
  81           try NCicUnification.unify rdb metasenv subst context
  82                 arity2 (C.Prod ("_", ind, meta))
  83           with exc -> raise (wrap_exc (lazy (localise orig, Printf.sprintf
  84             "expected %s, found %s" (* XXX localizzare meglio *)
  85             (NCicPp.ppterm ~subst ~metasenv ~context (C.Prod ("_", ind, meta)))
  86             (NCicPp.ppterm ~subst ~metasenv ~context arity2))) exc)
  87         in
  88         (try NCicTypeChecker.check_allowed_sort_elimination
  89             ~metasenv ~subst r context ind arity1 arity2;
  90             metasenv, subst
  91         with exc -> raise (wrap_exc (lazy (localise orig,
  92           "Sort elimination not allowed ")) exc))
  93      | _ -> assert false
  94      (*D*)in outside(); rc with exc -> outside (); raise exc
  95    in
  96     aux
  97 ;;
  98
  99 let rec typeof rdb
 100   ?(localise=fun _ -> Stdpp.dummy_loc)
 101   metasenv subst context term expty
 102 =
 103   let force_ty skip_lambda skip_appl metasenv subst context orig t infty expty =
 104     (*D*)inside 'F'; try let rc =
 105     match expty with
 106     | Some expty ->
 107        (match t with
 108        | C.Implicit _ -> assert false
 109        | C.Lambda _ when skip_lambda -> metasenv, subst, t, expty
 110        | C.Appl _ when skip_appl -> metasenv, subst, t, expty
 111        | _ ->
 112           pp (lazy ("forcing infty=expty: "^
 113           (NCicPp.ppterm ~metasenv ~subst ~context infty) ^  " === " ^
 114           (NCicPp.ppterm ~metasenv ~subst:[] ~context expty)));
 115            try
 116              let metasenv, subst =
 117     (*D*)inside 'U'; try let rc =
 118                NCicUnification.unify rdb metasenv subst context infty expty
 119     (*D*)in outside(); rc with exc -> outside (); raise exc
 120              in
 121              metasenv, subst, t, expty
 122            with
 123            | NCicUnification.Uncertain _
 124            | NCicUnification.UnificationFailure _ as exc ->
 125              try_coercions rdb ~localise
 126                metasenv subst context t orig infty expty true exc)
 127     | None -> metasenv, subst, t, infty
 128     (*D*)in outside(); rc with exc -> outside (); raise exc
 129   in
 130   let rec typeof_aux metasenv subst context expty =
 131     fun t as orig ->
 132     (*D*)inside 'R'; try let rc =
 133     pp (lazy (NCicPp.ppterm ~metasenv ~subst ~context t ^ " ::exp:: " ^
 134        match expty with None -> "None" | Some e ->
 135        NCicPp.ppterm ~metasenv ~subst ~context e));
 136     let metasenv, subst, t, infty =
 137     match t with
 138     | C.Rel n ->
 139         let infty =
 140          (try
 141            match List.nth context (n - 1) with
 142            | (_,C.Decl ty) -> NCicSubstitution.lift n ty
 143            | (_,C.Def (_,ty)) -> NCicSubstitution.lift n ty
 144          with Failure _ ->
 145            raise (RefineFailure (lazy (localise t,"unbound variable"))))
 146         in
 147         metasenv, subst, t, infty
 148     | C.Sort s ->
 149          (try metasenv, subst, t, C.Sort (NCicEnvironment.typeof_sort s)
 150          with
 151          | NCicEnvironment.UntypableSort msg ->
 152               raise (RefineFailure (lazy (localise t, Lazy.force msg)))
 153          | NCicEnvironment.AssertFailure msg -> raise (AssertFailure msg))
 154     | C.Implicit infos ->
 155          let metasenv,_,t,ty =
 156            exp_implicit ~localise metasenv context expty t infos
 157          in
 158           metasenv, subst, t, ty
 159     | C.Meta (n,l) as t ->
 160        let ty =
 161         try
 162          let _,_,_,ty = NCicUtils.lookup_subst n subst in ty
 163         with NCicUtils.Subst_not_found _ -> try
 164          let _,_,ty = NCicUtils.lookup_meta n metasenv in
 165          match ty with C.Implicit _ ->
 166                  prerr_endline (string_of_int n);
 167                  prerr_endline (NCicPp.ppmetasenv ~subst metasenv);
 168                  prerr_endline (NCicPp.ppsubst ~metasenv subst);
 169                  assert false | _ -> ty
 170         with NCicUtils.Meta_not_found _ ->
 171          raise (AssertFailure (lazy (Printf.sprintf
 172           "%s not found" (NCicPp.ppterm ~subst ~metasenv ~context t))))
 173        in
 174        metasenv, subst, t, NCicSubstitution.subst_meta l ty
 175     | C.Const _ ->
 176        metasenv, subst, t, NCicTypeChecker.typeof ~subst ~metasenv context t
 177     | C.Prod (name,(s as orig_s),(t as orig_t)) ->
 178        let metasenv, subst, s, s1 = typeof_aux metasenv subst context None s in
 179        let metasenv, subst, s, s1 =
 180          force_to_sort rdb
 181            metasenv subst context s orig_s localise s1 in
 182        let context1 = (name,(C.Decl s))::context in
 183        let metasenv, subst, t, s2 = typeof_aux metasenv subst context1 None t in
 184        let metasenv, subst, t, s2 =
 185          force_to_sort rdb
 186            metasenv subst context1 t orig_t localise s2 in
 187        let metasenv, subst, s, t, ty =
 188          sort_of_prod localise metasenv subst
 189            context orig_s orig_t (name,s) t (s1,s2)
 190        in
 191        metasenv, subst, NCic.Prod(name,s,t), ty
 192     | C.Lambda (n,(s as orig_s),t) as orig ->
 193        let exp_s, exp_ty_t, force_after =
 194          match expty with
 195          | None -> None, None, false
 196          | Some expty ->
 197              match NCicReduction.whd ~subst context expty with
 198              | C.Prod (_,s,t) -> Some s, Some t, false
 199              | _ -> None, None, true
 200        in
 201        let metasenv, subst, s, ty_s =
 202          typeof_aux metasenv subst context None s in
 203        let metasenv, subst, s, _ =
 204          force_to_sort rdb
 205            metasenv subst context s orig_s localise ty_s in
 206        let (metasenv,subst), exp_ty_t =
 207          match exp_s with
 208          | Some exp_s ->
 209              (try
 210                pp(lazy("Force source to: "^NCicPp.ppterm ~metasenv ~subst
 211                   ~context exp_s));
 212                NCicUnification.unify rdb metasenv subst context s exp_s,exp_ty_t
 213              with exc -> raise (wrap_exc (lazy (localise orig_s, Printf.sprintf
 214                "Source type %s was expected to be %s" (NCicPp.ppterm ~metasenv
 215                ~subst ~context s) (NCicPp.ppterm ~metasenv ~subst ~context
 216                exp_s))) exc))
 217          | None -> (metasenv, subst), None
 218        in
 219        let context_for_t = (n,C.Decl s) :: context in
 220        let metasenv, subst, t, ty_t =
 221          typeof_aux metasenv subst context_for_t exp_ty_t t
 222        in
 223        if force_after then
 224          force_ty false true metasenv subst context orig
 225            (C.Lambda(n,s,t)) (C.Prod (n,s,ty_t)) expty
 226        else
 227          metasenv, subst, C.Lambda(n,s,t), C.Prod (n,s,ty_t)
 228     | C.LetIn (n,(ty as orig_ty),t,bo) ->
 229        let metasenv, subst, ty, ty_ty =
 230          typeof_aux metasenv subst context None ty in
 231        let metasenv, subst, ty, _ =
 232          force_to_sort rdb
 233            metasenv subst context ty orig_ty localise ty_ty in
 234        let metasenv, subst, t, _ =
 235          typeof_aux metasenv subst context (Some ty) t in
 236        let context1 = (n, C.Def (t,ty)) :: context in
 237        let metasenv, subst, expty1 =
 238          match expty with
 239          | None -> metasenv, subst, None
 240          | Some x ->
 241              let m, s, x =
 242                NCicUnification.delift_type_wrt_terms
 243                  rdb metasenv subst context x [t]
 244              in
 245                m, s, Some x
 246        in
 247        let metasenv, subst, bo, bo_ty =
 248          typeof_aux metasenv subst context1 expty1 bo
 249        in
 250        let bo_ty = NCicSubstitution.subst ~avoid_beta_redexes:true t bo_ty in
 251        metasenv, subst, C.LetIn (n, ty, t, bo), bo_ty
 252     | C.Appl ((he as orig_he)::(_::_ as args)) ->
 253        let upto = match orig_he with C.Meta _ -> List.length args | _ -> 0 in
 254        let hbr t =
 255          if upto > 0 then NCicReduction.head_beta_reduce ~upto t else t
 256        in
 257        let refine_appl () =
 258          let metasenv, subst, he, ty_he =
 259             typeof_aux metasenv subst context None he in
 260          let metasenv, subst, t, ty =
 261            eat_prods rdb ~localise force_ty metasenv subst context expty t
 262             orig_he he ty_he args in
 263          metasenv, subst, hbr t, ty
 264        in
 265        if args = [C.Implicit `Vector] && expty <> None then
 266          (* we try here to expand the vector a 0 implicits, but we use
 267           * the expected type *)
 268          try
 269            let metasenv, subst, he, ty_he =
 270               typeof_aux metasenv subst context expty he in
 271            metasenv, subst, hbr he, ty_he
 272          with Uncertain _ | RefineFailure _ -> refine_appl ()
 273        else refine_appl ()
 274    | C.Appl _ -> raise (AssertFailure (lazy "Appl of length < 2"))
 275    | C.Match (Ref.Ref (_,Ref.Ind (_,tyno,_)) as r,
 276           outtype,(term as orig_term),pl) as orig ->
 277       let _, leftno, itl, _, _ = NCicEnvironment.get_checked_indtys r in
 278       let _, _, arity, cl = List.nth itl tyno in
 279       let constructorsno = List.length cl in
 280       let _, metasenv, args =
 281         NCicMetaSubst.saturate metasenv subst context arity 0 in
 282       let ind = if args = [] then C.Const r else C.Appl (C.Const r::args) in
 283       let metasenv, subst, term, _ =
 284         typeof_aux metasenv subst context (Some ind) term in
 285       let parameters, arguments = HExtlib.split_nth leftno args in
 286       let outtype =
 287         match outtype with
 288         | C.Implicit _ as ot ->
 289              let rec aux = function
 290                | [] -> NCic.Lambda ("_",NCic.Implicit `Type,ot)
 291                | _::tl -> NCic.Lambda ("_",NCic.Implicit `Type,aux tl)
 292              in
 293                aux arguments
 294         | _ -> outtype
 295       in
 296       let metasenv, subst, outtype, outsort =
 297         typeof_aux metasenv subst context None outtype in
 298
 299       (* next lines are to do a subst-expansion of the outtype, so
 300          that when it becomes a beta-abstraction, the beta-redex is
 301          fired during substitution *)
 302       (*CSC: this is instantiate! should we move it from tactics to the
 303              refiner? I think so! *)
 304       let metasenv,metanoouttype,newouttype,metaoutsort =
 305        NCicMetaSubst.mk_meta metasenv context `Term in
 306       let metasenv,subst =
 307        NCicUnification.unify rdb metasenv subst context outsort metaoutsort in
 308       let metasenv =
 309        List.filter (function (j,_) -> j <> metanoouttype) metasenv in
 310       let subst =
 311        (metanoouttype,(Some "outtype",context,outtype,metaoutsort))::subst in
 312       let outtype = newouttype in
 313
 314       (* let's control if the sort elimination is allowed: [(I q1 ... qr)|B] *)
 315       let ind =
 316         if parameters = [] then C.Const r
 317         else C.Appl ((C.Const r)::parameters) in
 318       let metasenv, subst, ind, ind_ty =
 319         typeof_aux metasenv subst context None ind in
 320       let metasenv, subst =
 321          check_allowed_sort_elimination rdb localise r orig_term metasenv subst
 322            context ind ind_ty outsort
 323       in
 324       (* let's check if the type of branches are right *)
 325       if List.length pl <> constructorsno then
 326        raise (RefineFailure (lazy (localise orig,
 327          "Wrong number of cases in a match")));
 328 (*
 329       let metasenv, subst =
 330         match expty with
 331         | None -> metasenv, subst
 332         | Some expty ->
 333            NCicUnification.unify rdb metasenv subst context resty expty
 334       in
 335 *)
 336       let _, metasenv, subst, pl =
 337         List.fold_right
 338           (fun p (j, metasenv, subst, branches) ->
 339               let cons =
 340                 let cons = Ref.mk_constructor j r in
 341                 if parameters = [] then C.Const cons
 342                 else C.Appl (C.Const cons::parameters)
 343               in
 344               let metasenv, subst, cons, ty_cons =
 345                 typeof_aux metasenv subst context None cons in
 346               let ty_branch =
 347                 NCicTypeChecker.type_of_branch
 348                   ~subst context leftno outtype cons ty_cons in
 349               pp (lazy ("TYPEOFBRANCH: " ^
 350                NCicPp.ppterm ~metasenv ~subst ~context p ^ " ::inf:: " ^
 351                NCicPp.ppterm ~metasenv ~subst ~context ty_branch ));
 352               let metasenv, subst, p, _ =
 353                 typeof_aux metasenv subst context (Some ty_branch) p in
 354               j-1, metasenv, subst, p :: branches)
 355           pl (List.length pl, metasenv, subst, [])
 356       in
 357       let resty = C.Appl (outtype::arguments@[term]) in
 358       let resty = NCicReduction.head_beta_reduce ~subst resty in
 359       metasenv, subst, C.Match (r, outtype, term, pl),resty
 360     | C.Match _ -> assert false
 361     in
 362     pp (lazy (NCicPp.ppterm ~metasenv ~subst ~context t ^ " ::inf:: "^
 363          NCicPp.ppterm ~metasenv ~subst ~context infty ));
 364       force_ty true true metasenv subst context orig t infty expty
 365     (*D*)in outside(); rc with exc -> outside (); raise exc
 366   in
 367     typeof_aux metasenv subst context expty term
 368
 369 and try_coercions rdb
 370   ~localise
 371   metasenv subst context t orig_t infty expty perform_unification exc
 372 =
 373   (* we try with a coercion *)
 374   let rec first exc = function
 375   | [] ->
 376       raise (wrap_exc (lazy (localise orig_t, Printf.sprintf
 377         "The term %s has type %s but is here used with type %s"
 378         (NCicPp.ppterm ~metasenv ~subst ~context t)
 379         (NCicPp.ppterm ~metasenv ~subst ~context infty)
 380         (NCicPp.ppterm ~metasenv ~subst ~context expty))) exc)
 381   | (_,metasenv, newterm, newtype, meta)::tl ->
 382       try
 383           pp (lazy("K=" ^ NCicPp.ppterm ~metasenv ~subst ~context newterm));
 384           pp (lazy ( "UNIFICATION in CTX:\n"^
 385             NCicPp.ppcontext ~metasenv ~subst context
 386             ^ "\nMENV: " ^
 387             NCicPp.ppmetasenv metasenv ~subst
 388             ^ "\nOF: " ^
 389             NCicPp.ppterm ~metasenv ~subst ~context t ^  " === " ^
 390             NCicPp.ppterm ~metasenv ~subst ~context meta ^ "\n"));
 391         let metasenv, subst =
 392           NCicUnification.unify rdb metasenv subst context t meta
 393         in
 394           pp (lazy ( "UNIFICATION in CTX:\n"^
 395             NCicPp.ppcontext ~metasenv ~subst context
 396             ^ "\nMENV: " ^
 397             NCicPp.ppmetasenv metasenv ~subst
 398             ^ "\nOF: " ^
 399             NCicPp.ppterm ~metasenv ~subst ~context newtype ^  " === " ^
 400             NCicPp.ppterm ~metasenv ~subst ~context expty ^ "\n"));
 401         let metasenv, subst =
 402           if perform_unification then
 403             NCicUnification.unify rdb metasenv subst context newtype expty
 404           else metasenv, subst
 405         in
 406         metasenv, subst, newterm, newtype
 407       with
 408       | NCicUnification.UnificationFailure _ -> first exc tl
 409       | NCicUnification.Uncertain _ as exc -> first exc tl
 410   in
 411   pp(lazy("try_coercion " ^
 412     NCicPp.ppterm ~metasenv ~subst ~context infty ^ " |---> " ^
 413     NCicPp.ppterm ~metasenv ~subst ~context expty));
 414     first exc
 415       (NCicCoercion.look_for_coercion
 416         rdb metasenv subst context infty expty)
 417
 418 and force_to_sort rdb metasenv subst context t orig_t localise ty =
 419   match NCicReduction.whd ~subst context ty with
 420   | C.Meta (_,(0,(C.Irl 0 | C.Ctx []))) as ty ->
 421      metasenv, subst, t, ty
 422   | C.Meta (_i,(_,(C.Irl 0 | C.Ctx []))) -> assert false (*CSC: ???
 423      metasenv, subst, t, C.Meta(i,(0,C.Irl 0)) *)
 424   | C.Meta (i,(_,lc)) ->
 425      let len = match lc with C.Irl len->len | C.Ctx l->List.length l in
 426      let metasenv, subst, newmeta =
 427        if len > 0 then
 428          NCicMetaSubst.restrict metasenv subst i (HExtlib.list_seq 1 (len+1))
 429        else metasenv, subst, i
 430      in
 431      metasenv, subst, t, C.Meta (newmeta,(0,C.Irl 0))
 432   | C.Sort _ as ty -> metasenv, subst, t, ty
 433   | ty ->
 434       try_coercions rdb ~localise metasenv subst context
 435         t orig_t ty (NCic.Sort (NCic.Type NCicEnvironment.type0)) false
 436          (Uncertain (lazy (localise orig_t,
 437          "The type of " ^ NCicPp.ppterm ~metasenv ~subst ~context t
 438          ^ " is not a sort: " ^ NCicPp.ppterm ~metasenv ~subst ~context ty)))
 439
 440 and sort_of_prod
 441   localise metasenv subst context orig_s orig_t (name,s) t (t1, t2)
 442 =
 443    (* force to sort is done in the Prod case in typeof *)
 444    match t1, t2 with
 445    | C.Sort _, C.Sort C.Prop -> metasenv, subst, s, t, t2
 446    | C.Sort (C.Type u1), C.Sort (C.Type u2) ->
 447         metasenv, subst, s, t, C.Sort (C.Type (NCicEnvironment.max u1 u2))
 448    | C.Sort C.Prop,C.Sort (C.Type _) -> metasenv, subst, s, t, t2
 449    | C.Meta _, C.Sort _
 450    | C.Meta _, C.Meta (_,(_,_))
 451    | C.Sort _, C.Meta (_,(_,_)) -> metasenv, subst, s, t, t2
 452    | x, (C.Sort _ | C.Meta _) | _, x ->
 453       let y, context, orig =
 454         if x == t1 then s, context, orig_s
 455         else t, ((name,C.Decl s)::context), orig_t
 456       in
 457       raise (RefineFailure (lazy (localise orig,Printf.sprintf
 458         "%s is expected to be a type, but its type is %s that is not a sort"
 459          (NCicPp.ppterm ~subst ~metasenv ~context y)
 460          (NCicPp.ppterm ~subst ~metasenv ~context x))))
 461
 462 and guess_name subst ctx ty =
 463   let aux initial = "#" ^ String.make 1 initial in
 464   match ty with
 465   | C.Const (NReference.Ref (u,_))
 466   | C.Appl (C.Const (NReference.Ref (u,_)) :: _) ->
 467       aux (String.sub (NUri.name_of_uri u) 0 1).[0]
 468   | C.Prod _ -> aux 'f'
 469   | C.Meta (n,lc) ->
 470       (try
 471          let _,_,t,_ = NCicUtils.lookup_subst n subst in
 472          guess_name subst ctx (NCicSubstitution.subst_meta lc t)
 473       with NCicUtils.Subst_not_found _ -> aux 'M')
 474   | _ -> aux 'H'
 475
 476 and eat_prods rdb ~localise force_ty metasenv subst context expty orig_t orig_he he ty_he args =
 477   (*D*)inside 'E'; try let rc =
 478   let rec aux metasenv subst args_so_far he ty_he = function
 479   | [] ->
 480      let res = NCicUntrusted.mk_appl he (List.rev args_so_far) in
 481      pp(lazy("FORCE FINAL APPL: " ^
 482        NCicPp.ppterm ~metasenv ~subst ~context res ^
 483        " of type " ^ NCicPp.ppterm ~metasenv ~subst ~context ty_he
 484        ^ " to type " ^ match expty with None -> "None" | Some x ->
 485        NCicPp.ppterm ~metasenv ~subst ~context x));
 486      (* whatever the term is, we force the type. in case of ((Lambda..) ?...)
 487       * the application may also be a lambda! *)
 488      force_ty false false metasenv subst context orig_t res ty_he expty
 489   | NCic.Implicit `Vector::tl ->
 490       let has_some_more_pis x =
 491         match NCicReduction.whd ~subst context x with
 492         |  NCic.Meta _ | NCic.Appl (NCic.Meta _::_) -> false
 493         | _ -> true
 494       in
 495      (try
 496        aux metasenv subst args_so_far he ty_he tl
 497       with
 498       | Uncertain _
 499       | RefineFailure _ as exc when has_some_more_pis ty_he ->
 500           (try
 501            aux metasenv subst args_so_far he ty_he
 502             (NCic.Implicit `Term :: NCic.Implicit `Vector :: tl)
 503           with
 504            Uncertain msg | RefineFailure msg -> raise (wrap_exc msg exc)))
 505   | arg::tl ->
 506       match NCicReduction.whd ~subst context ty_he with
 507       | C.Prod (_,s,t) ->
 508           let metasenv, subst, arg, _ =
 509             typeof rdb ~localise
 510               metasenv subst context arg (Some s) in
 511           let t = NCicSubstitution.subst ~avoid_beta_redexes:true arg t in
 512           aux metasenv subst (arg :: args_so_far) he t tl
 513       | C.Meta _
 514       | C.Appl (C.Meta _ :: _) as t ->
 515           let metasenv, subst, arg, ty_arg =
 516             typeof rdb ~localise
 517               metasenv subst context arg None in
 518           let name = guess_name subst context ty_arg in
 519           let metasenv, _, meta, _ =
 520             NCicMetaSubst.mk_meta metasenv
 521               ((name,C.Decl ty_arg) :: context) `Type
 522           in
 523           let flex_prod = C.Prod (name, ty_arg, meta) in
 524           (* next line grants that ty_args is a type *)
 525           let metasenv,subst, flex_prod, _ =
 526            typeof rdb ~localise metasenv subst
 527             context flex_prod None in
 528 (*
 529           pp (lazy ( "UNIFICATION in CTX:\n"^
 530             NCicPp.ppcontext ~metasenv ~subst context
 531             ^ "\nOF: " ^
 532             NCicPp.ppterm ~metasenv ~subst ~context t ^  " === " ^
 533             NCicPp.ppterm ~metasenv ~subst ~context flex_prod ^ "\n"));
 534 *)
 535           let metasenv, subst =
 536              try NCicUnification.unify rdb metasenv subst context t flex_prod
 537              with exc -> raise (wrap_exc (lazy (localise orig_he, Printf.sprintf
 538               ("The term %s has an inferred type %s, but is applied to the" ^^
 539                " argument %s of type %s")
 540               (NCicPp.ppterm ~metasenv ~subst ~context he)
 541               (NCicPp.ppterm ~metasenv ~subst ~context t)
 542               (NCicPp.ppterm ~metasenv ~subst ~context arg)
 543               (NCicPp.ppterm ~metasenv ~subst ~context ty_arg)))
 544                  (match exc with
 545                  | NCicUnification.UnificationFailure m ->
 546                      NCicUnification.Uncertain m
 547                  | x -> x))
 548               (* XXX coerce to funclass *)
 549           in
 550           let meta = NCicSubstitution.subst ~avoid_beta_redexes:true arg meta in
 551           aux metasenv subst (arg :: args_so_far) he meta tl
 552       | C.Match (_,_,C.Meta _,_)
 553       | C.Match (_,_,C.Appl (C.Meta _ :: _),_)
 554       | C.Appl (C.Const (NReference.Ref (_, NReference.Fix _)) :: _) ->
 555           raise (Uncertain (lazy (localise orig_he, Printf.sprintf
 556             ("The term %s is here applied to %d arguments but expects " ^^
 557             "only %d arguments") (NCicPp.ppterm ~metasenv ~subst ~context he)
 558             (List.length args) (List.length args_so_far))))
 559       | ty ->
 560           let metasenv, subst, newhead, newheadty =
 561             try_coercions rdb ~localise metasenv subst context
 562               (NCicUntrusted.mk_appl he (List.rev args_so_far)) orig_he ty
 563               (NCic.Prod ("_",NCic.Implicit `Term,NCic.Implicit `Term))
 564               false
 565               (RefineFailure (lazy (localise orig_he, Printf.sprintf
 566                ("The term %s is here applied to %d arguments but expects " ^^
 567                "only %d arguments") (NCicPp.ppterm ~metasenv ~subst ~context he)
 568                (List.length args) (List.length args_so_far))))
 569           in
 570            aux metasenv subst [] newhead newheadty (arg :: tl)
 571   in
 572    (* We need to reverse the order of the new created metas since they
 573       are pushed on top of the metasenv in the wrong order *)
 574    let highest_meta = NCicMetaSubst.maxmeta () in
 575    let metasenv, subst, newhead, newheadty =
 576     aux metasenv subst [] he ty_he args in
 577    let metasenv_old,metasenv_new =
 578     List.partition (fun (i,_) -> i <= highest_meta) metasenv
 579    in
 580     (List.rev metasenv_new) @ metasenv_old, subst, newhead, newheadty
 581   (*D*)in outside(); rc with exc -> outside (); raise exc
 582 ;;
 583
 584 let rec first f l1 l2 =
 585   match l1,l2 with
 586   | x1::tl1, x2::tl2 ->
 587       (try f x1 x2 with Not_found -> first f tl1 tl2)
 588   | _ -> raise Not_found
 589 ;;
 590
 591 let rec find add dt t =
 592   if dt == add then t
 593   else
 594     let dl, l =
 595       match dt, t with
 596       | C.Meta (_,(_,C.Ctx dl)), C.Meta (_,(_,C.Ctx l))
 597       | C.Appl dl,C.Appl l -> dl,l
 598       | C.Lambda (_,ds,dt), C.Lambda (_,s,t)
 599       | C.Prod (_,ds,dt), C.Prod (_,s,t) -> [ds;dt],[s;t]
 600       | C.LetIn (_,ds,db,dt), C.LetIn (_,s,b,t) -> [ds;db;dt],[s;b;t]
 601       | C.Match (_,dot,dt,dl),  C.Match (_,ot,t,l) -> (dot::dt::dl),(ot::t::l)
 602       | _ -> raise Not_found
 603     in
 604       first (find add) dl l
 605 ;;
 606
 607 let relocalise old_localise dt t add =
 608   old_localise
 609     (try find add dt t with Not_found -> assert false)
 610 ;;
 611
 612 let undebruijnate inductive ref t rev_fl =
 613   NCicSubstitution.psubst (fun x -> x)
 614    (List.rev (HExtlib.list_mapi
 615       (fun (_,_,rno,_,_,_) i ->
 616          NCic.Const
 617            (if inductive then NReference.mk_fix i rno ref
 618             else NReference.mk_cofix i ref))
 619       rev_fl))
 620     t
 621 ;;
 622
 623
 624 let typeof_obj
 625   rdb ?(localise=fun _ -> Stdpp.dummy_loc) (uri,height,metasenv,subst,obj)
 626 =
 627   let check_type metasenv subst context (ty as orig_ty) =  (* XXX fattorizza *)
 628     let metasenv, subst, ty, sort =
 629       typeof rdb ~localise metasenv subst context ty None
 630     in
 631     let metasenv, subst, ty, sort =
 632       force_to_sort rdb metasenv subst context ty orig_ty localise sort
 633     in
 634       metasenv, subst, ty, sort
 635   in
 636   match obj with
 637   | C.Constant (relevance, name, bo, ty , attr) ->
 638        let metasenv, subst, ty, _ = check_type metasenv subst [] ty in
 639        let metasenv, subst, bo, ty, height =
 640          match bo with
 641          | Some bo ->
 642              let metasenv, subst, bo, ty =
 643                typeof rdb ~localise metasenv subst [] bo (Some ty) in
 644              let height = (* XXX recalculate *) height in
 645                metasenv, subst, Some bo, ty, height
 646          | None -> metasenv, subst, None, ty, 0
 647        in
 648        uri, height, metasenv, subst,
 649          C.Constant (relevance, name, bo, ty, attr)
 650   | C.Fixpoint (inductive, fl, attr) ->
 651       let len = List.length fl in
 652       let types, metasenv, subst, rev_fl =
 653         List.fold_left
 654          (fun (types, metasenv, subst, fl) (relevance,name,k,ty,bo) ->
 655            let metasenv, subst, ty, _ = check_type metasenv subst [] ty in
 656            let dbo = NCicTypeChecker.debruijn uri len [] ~subst bo in
 657            let localise = relocalise localise dbo bo in
 658             (name,C.Decl ty)::types,
 659               metasenv, subst, (relevance,name,k,ty,dbo,localise)::fl
 660          ) ([], metasenv, subst, []) fl (* XXX kl rimosso nel nucleo *)
 661       in
 662       let metasenv, subst, fl =
 663         List.fold_left
 664           (fun (metasenv,subst,fl) (relevance,name,k,ty,dbo,localise) ->
 665             let metasenv, subst, dbo, ty =
 666               typeof rdb ~localise metasenv subst types dbo (Some ty)
 667             in
 668             metasenv, subst, (relevance,name,k,ty,dbo)::fl)
 669           (metasenv, subst, []) rev_fl
 670       in
 671       let height = (* XXX recalculate *) height in
 672       let fl =
 673         List.map
 674           (fun (relevance,name,k,ty,dbo) ->
 675             let bo =
 676               undebruijnate inductive
 677                (NReference.reference_of_spec uri
 678                  (if inductive then NReference.Fix (0,k,0)
 679                   else NReference.CoFix 0)) dbo rev_fl
 680             in
 681               relevance,name,k,ty,bo)
 682           fl
 683       in
 684        uri, height, metasenv, subst,
 685          C.Fixpoint (inductive, fl, attr)
 686   | C.Inductive (ind, leftno, itl, attr) ->
 687      let len = List.length itl in
 688      let metasenv,subst,rev_itl,tys =
 689       List.fold_left
 690        (fun (metasenv,subst,res,ctx) (relevance,n,ty,cl) ->
 691           let metasenv, subst, ty, _ = check_type metasenv subst [] ty in
 692           metasenv,subst,(relevance,n,ty,cl)::res,(n,NCic.Decl ty)::ctx
 693        ) (metasenv,subst,[],[]) itl in
 694      let metasenv,subst,itl,_ =
 695       List.fold_left
 696        (fun (metasenv,subst,res,i) (it_relev,n,ty,cl) ->
 697          let context,ty_sort = NCicReduction.split_prods ~subst [] ~-1 ty in
 698          let sx_context_ty_rev,_= HExtlib.split_nth leftno (List.rev context) in
 699          let metasenv,subst,cl =
 700           List.fold_right
 701            (fun (k_relev,n,te) (metasenv,subst,res) ->
 702              let k_relev =
 703               try snd (HExtlib.split_nth leftno k_relev)
 704               with Failure _ -> k_relev in
 705              let te = NCicTypeChecker.debruijn uri len [] ~subst te in
 706              let metasenv, subst, te, _ = check_type metasenv subst tys te in
 707              let context,te = NCicReduction.split_prods ~subst tys leftno te in
 708              let _,chopped_context_rev =
 709               HExtlib.split_nth (List.length tys) (List.rev context) in
 710              let sx_context_te_rev,_ =
 711               HExtlib.split_nth leftno chopped_context_rev in
 712              let metasenv,subst,_ =
 713               try
 714                List.fold_left2
 715                 (fun (metasenv,subst,context) item1 item2 ->
 716                   let (metasenv,subst),convertible =
 717                    try
 718                     match item1,item2 with
 719                       (n1,C.Decl ty1),(n2,C.Decl ty2) ->
 720                         if n1 = n2 then
 721                          NCicUnification.unify rdb ~test_eq_only:true metasenv
 722                           subst context ty1 ty2,true
 723                         else
 724                          (metasenv,subst),false
 725                     | (n1,C.Def (bo1,ty1)),(n2,C.Def (bo2,ty2)) ->
 726                         if n1 = n2 then
 727                          let metasenv,subst =
 728                           NCicUnification.unify rdb ~test_eq_only:true metasenv
 729                            subst context ty1 ty2
 730                          in
 731                           NCicUnification.unify rdb ~test_eq_only:true metasenv
 732                            subst context bo1 bo2,true
 733                         else
 734                          (metasenv,subst),false
 735                     | _,_ -> (metasenv,subst),false
 736                    with
 737                    | NCicUnification.Uncertain _
 738                    | NCicUnification.UnificationFailure _ ->
 739                       (metasenv,subst),false
 740                   in
 741                    let term2 =
 742                     match item2 with
 743                        _,C.Decl t -> t
 744                      | _,C.Def (b,_) -> b in
 745                    if not convertible then
 746                     raise (RefineFailure (lazy (localise term2,
 747                      ("Mismatch between the left parameters of the constructor " ^
 748                       "and those of its inductive type"))))
 749                    else
 750                     metasenv,subst,item1::context
 751                 ) (metasenv,subst,tys) sx_context_ty_rev sx_context_te_rev
 752               with Invalid_argument "List.fold_left2" -> assert false in
 753              let con_sort= NCicTypeChecker.typeof ~subst ~metasenv context te in
 754               (match
 755                 NCicReduction.whd ~subst context con_sort,
 756                 NCicReduction.whd ~subst [] ty_sort
 757                with
 758                   (C.Sort (C.Type u1) as s1), (C.Sort (C.Type u2) as s2) ->
 759                    if not (NCicEnvironment.universe_leq u1 u2) then
 760                     raise
 761                      (RefineFailure
 762                        (lazy(localise te, "The type " ^
 763                          NCicPp.ppterm ~metasenv ~subst ~context s1 ^
 764                          " of the constructor is not included in the inductive"^
 765                          " type sort " ^
 766                          NCicPp.ppterm ~metasenv ~subst ~context s2)))
 767                 | C.Sort _, C.Sort C.Prop
 768                 | C.Sort _, C.Sort C.Type _ -> ()
 769                 | _, _ ->
 770                    raise
 771                     (RefineFailure
 772                       (lazy (localise te,
 773                         "Wrong constructor or inductive arity shape"))));
 774               (* let's check also the positivity conditions *)
 775               if
 776                not
 777                (NCicTypeChecker.are_all_occurrences_positive
 778                  ~subst context uri leftno (i+leftno) leftno (len+leftno) te)
 779               then
 780                 raise
 781                   (RefineFailure
 782                     (lazy (localise te,
 783                       "Non positive occurence in " ^
 784                         NCicPp.ppterm ~metasenv ~subst ~context te)))
 785               else
 786                let relsno = List.length itl + leftno in
 787                let te =
 788                  NCicSubstitution.psubst
 789                   (fun i ->
 790                     if i <= leftno  then
 791                      NCic.Rel i
 792                     else
 793                      NCic.Const (NReference.reference_of_spec uri
 794                       (NReference.Ind (ind,relsno - i,leftno))))
 795                   (HExtlib.list_seq 1 (relsno+1))
 796                    te in
 797                let te =
 798                 List.fold_right
 799                  (fun (name,decl) te ->
 800                    match decl with
 801                       NCic.Decl ty -> NCic.Prod (name,ty,te)
 802                     | NCic.Def (bo,ty) -> NCic.LetIn (name,ty,bo,te)
 803                  ) sx_context_te_rev te
 804                in
 805                 metasenv,subst,(k_relev,n,te)::res
 806               ) cl (metasenv,subst,[])
 807          in
 808           metasenv,subst,(it_relev,n,ty,cl)::res,i+1
 809        ) (metasenv,subst,[],1) rev_itl
 810      in
 811       uri, height, metasenv, subst, C.Inductive (ind, leftno, itl, attr)
 812 ;;
 813
 814 NCicUnification.set_refiner_typeof typeof;;
 815
 816 (* vim:set foldmethod=marker: *)