helm/software/components/ng_refiner/nCicUnifHint.ml

   1 (*
   2     ||M||  This file is part of HELM, an Hypertextual, Electronic
   3     ||A||  Library of Mathematics, developed at the Computer Science
   4     ||T||  Department, University of Bologna, Italy.
   5     ||I||
   6     ||T||  HELM is free software; you can redistribute it and/or
   7     ||A||  modify it under the terms of the GNU General Public License
   8     \   /  version 2 or (at your option) any later version.
   9      \ /   This software is distributed as is, NO WARRANTY.
  10       V_______________________________________________________________ *)
  11
  12 (* $Id: nCicRefiner.mli 9227 2008-11-21 16:00:06Z tassi $ *)
  13
  14 module COT : Set.OrderedType with type t = NCic.term =
  15   struct
  16         type t = NCic.term
  17         let compare = Pervasives.compare
  18   end
  19
  20 module HintSet = Set.Make(COT)
  21
  22 module DB =
  23   Discrimination_tree.Make(NDiscriminationTree.NCicIndexable)(HintSet)
  24
  25 type db = DB.t
  26
  27 let dummy = NCic.Const (NReference.reference_of_string "cic:/dummy_conv.dec");;
  28 let pair t1 t2 = (NCic.Appl [dummy;t1;t2]) ;;
  29
  30 let index_hint hdb context t1 t2 =
  31   assert (
  32     (match t1 with
  33     | NCic.Meta _ | NCic.Appl (NCic.Meta _ :: _) -> false | _ -> true)
  34     &&
  35     (match t2 with
  36     | NCic.Meta _ | NCic.Appl (NCic.Meta _ :: _) -> false | _ -> true)
  37   );
  38   let pair' = pair t1 t2 in
  39   let data =
  40     List.fold_left
  41      (fun t (n,e) ->
  42         match e with
  43         | NCic.Decl ty -> NCic.Prod (n,ty,t)
  44         | _ -> assert false)
  45       pair' context in
  46   let src =
  47     List.fold_left
  48      (fun t (_,e) ->
  49         match e with
  50         | NCic.Decl _ ->
  51             NCicSubstitution.subst (NCic.Meta (-1,(0,NCic.Irl 0))) t
  52         | _ -> assert false)
  53      pair' context in
  54   DB.index hdb src data
  55 ;;
  56
  57 let empty_db = DB.empty ;;
  58
  59 let db () =
  60   let combine f cmp l1 l2 =
  61    List.flatten
  62      (List.map
  63        (fun u1 ->
  64           HExtlib.filter_map
  65             (fun u2 -> if cmp u1 u2 then None else Some (f u1 u2)) l2)
  66        l1)
  67   in
  68   let mk_hint (u1,_,_) (u2,_,_) =
  69     let l = OCic2NCic.convert_obj u1
  70       (fst (CicEnvironment.get_obj CicUniv.oblivion_ugraph u1)) in
  71     let r = OCic2NCic.convert_obj u2
  72       (fst (CicEnvironment.get_obj CicUniv.oblivion_ugraph u2)) in
  73     match List.hd l,List.hd r with
  74     | (_,_,_,_,NCic.Constant (_,_,Some l,_,_)),
  75       (_,_,_,_,NCic.Constant (_,_,Some r,_,_)) ->
  76         let rec aux ctx t1 t2 =
  77           match t1, t2 with
  78           | NCic.Lambda (n1,s1,b1), NCic.Lambda(_,s2,b2) ->
  79               if NCicReduction.are_convertible ~subst:[] ~metasenv:[] ctx s1 s2
  80               then aux ((n1, NCic.Decl s1) :: ctx) b1 b2
  81               else None
  82           | b1,b2 ->
  83               if NCicReduction.are_convertible ~subst:[] ~metasenv:[] ctx b1 b2
  84               then begin
  85 (*
  86                 prerr_endline ("hint: " ^ NCicPp.ppterm ~metasenv:[] ~subst:[]
  87                   ~context:ctx b1 ^ " === " ^ NCicPp.ppterm ~metasenv:[]
  88                   ~subst:[] ~context:ctx b2);
  89 *)
  90                 Some (ctx,b1,b2)
  91               end else None
  92         in
  93           aux [] l r
  94     | _ -> None
  95   in
  96   let hints =
  97     List.fold_left
  98       (fun acc (_,_,l) ->
  99           acc @
 100           if List.length l > 1 then
 101            combine mk_hint (fun (u1,_,_) (u2,_,_) -> UriManager.eq u1 u2) l l
 102           else [])
 103       [] (CoercDb.to_list ())
 104   in
 105   List.fold_left
 106     (fun db -> function
 107      |None -> db
 108      | Some (ctx,b1,b2) -> index_hint db ctx b1 b2)
 109     empty_db hints
 110 ;;
 111
 112
 113 let look_for_hint hdb metasenv subst context t1 t2 =
 114 (*
 115   prerr_endline ("KEY1: "^NCicPp.ppterm ~metasenv ~subst ~context (pair t1 t2));
 116   prerr_endline ("KEY2: "^NCicPp.ppterm ~metasenv ~subst ~context (pair t2 t1));
 117   DB.iter hdb
 118    (fun p ds ->
 119       prerr_endline ("ENTRY: " ^
 120       NDiscriminationTree.NCicIndexable.string_of_path p ^ " |--> " ^
 121       String.concat "|" (List.map (NCicPp.ppterm ~metasenv:[] ~subst:[]
 122       ~context:[]) (HintSet.elements ds))));
 123 *)
 124   let candidates1 = DB.retrieve_unifiables hdb (pair t1 t2) in
 125   let candidates2 = DB.retrieve_unifiables hdb (pair t2 t1) in
 126   let candidates1 =
 127     List.map (fun ty ->
 128        true,NCicMetaSubst.saturate ~delta:max_int metasenv subst context ty 0)
 129     (HintSet.elements candidates1)
 130   in
 131   let candidates2 =
 132     List.map (fun ty ->
 133        false,NCicMetaSubst.saturate ~delta:max_int metasenv subst context ty 0)
 134     (HintSet.elements candidates2)
 135   in
 136   List.map
 137    (function
 138     | (true,(NCic.Appl [_; t1; t2],metasenv,_)) -> metasenv, t1, t2
 139     | (false,(NCic.Appl [_; t1; t2],metasenv,_)) -> metasenv, t2, t1
 140     | _ -> assert false)
 141    (candidates1 @ candidates2)
 142 ;;