helm/software/components/ng_refiner/nCicUnification.ml

   1 (*
   2     ||M||  This file is part of HELM, an Hypertextual, Electronic
   3     ||A||  Library of Mathematics, developed at the Computer Science
   4     ||T||  Department, University of Bologna, Italy.
   5     ||I||
   6     ||T||  HELM is free software; you can redistribute it and/or
   7     ||A||  modify it under the terms of the GNU General Public License
   8     \   /  version 2 or (at your option) any later version.
   9      \ /   This software is distributed as is, NO WARRANTY.
  10       V_______________________________________________________________ *)
  11
  12 (* $Id$ *)
  13
  14 exception UnificationFailure of string Lazy.t;;
  15 exception Uncertain of string Lazy.t;;
  16 exception AssertFailure of string Lazy.t;;
  17
  18 let refiner_typeof =
  19  ref (fun _ ?localise _ _ _ _ _ -> ignore localise; assert false);;
  20 let set_refiner_typeof f = refiner_typeof := f
  21 ;;
  22
  23 let (===) x y = Pervasives.compare x y = 0 ;;
  24
  25 let uncert_exc metasenv subst context t1 t2 =
  26   Uncertain (lazy (
  27   "Can't unify " ^ NCicPp.ppterm ~metasenv ~subst ~context t1 ^
  28   " with " ^ NCicPp.ppterm ~metasenv ~subst ~context t2))
  29 ;;
  30
  31 let fail_exc metasenv subst context t1 t2 =
  32   UnificationFailure (lazy (
  33   "Can't unify " ^ NCicPp.ppterm ~metasenv ~subst ~context t1 ^
  34   " with " ^ NCicPp.ppterm ~metasenv ~subst ~context t2));
  35 ;;
  36
  37 let mk_appl ~upto hd tl =
  38   NCicReduction.head_beta_reduce ~upto
  39     (match hd with
  40     | NCic.Appl l -> NCic.Appl (l@tl)
  41     | _ -> NCic.Appl (hd :: tl))
  42 ;;
  43
  44 exception WrongShape;;
  45
  46 let eta_reduce subst t =
  47   let delift_if_not_occur body =
  48     try
  49         Some (NCicSubstitution.psubst ~avoid_beta_redexes:true
  50           (fun () -> raise WrongShape) [()] body)
  51     with WrongShape -> None
  52   in
  53   let rec eat_lambdas ctx = function
  54     | NCic.Lambda (name, src, tgt) ->
  55         eat_lambdas ((name, src) :: ctx) tgt
  56     | NCic.Meta (i,lc) as t->
  57         (try
  58           let _,_,t,_ = NCicUtils.lookup_subst i subst in
  59           let t = NCicSubstitution.subst_meta lc t in
  60           eat_lambdas ctx t
  61         with Not_found -> ctx, t)
  62     | t -> ctx, t
  63   in
  64   let context_body = eat_lambdas [] t in
  65   let rec aux = function
  66     | [],body -> body
  67     | (name, src)::ctx, (NCic.Appl (hd::[NCic.Rel 1]) as bo) ->
  68         (match delift_if_not_occur hd with
  69         | None -> aux (ctx,NCic.Lambda(name,src, bo))
  70         | Some bo -> aux (ctx,bo))
  71     | (name, src)::ctx, (NCic.Appl args as bo)
  72       when HExtlib.list_last args = NCic.Rel 1 ->
  73         let args, _ = HExtlib.split_nth (List.length args - 1) args in
  74         (match delift_if_not_occur (NCic.Appl args) with
  75         | None -> aux (ctx,NCic.Lambda(name,src, bo))
  76         | Some bo -> aux (ctx,bo))
  77     | (name, src) :: ctx, t ->
  78         aux (ctx,NCic.Lambda(name,src, t))
  79   in
  80     aux context_body
  81 ;;
  82
  83 module C = NCic;;
  84 module Ref = NReference;;
  85
  86 let indent = ref "";;
  87 let inside c = indent := !indent ^ String.make 1 c;;
  88 let outside () =
  89  try
  90   indent := String.sub !indent 0 (String.length !indent -1)
  91  with
  92   Invalid_argument _ -> indent := "??"; ()
  93 ;;
  94
  95 let pp s =
  96   prerr_endline (Printf.sprintf "%-20s" !indent ^ " " ^ Lazy.force s)
  97 ;;
  98 let pp _ = ();;
  99
 100
 101 let ppcontext = NCicPp.ppcontext;;
 102 let ppmetasenv = NCicPp.ppmetasenv;;
 103
 104 let ppcontext ~metasenv:_metasenv ~subst:_subst _context = "...";;
 105 let ppmetasenv ~subst:_subst _metasenv = "...";;
 106
 107 let fix_sorts swap exc t =
 108   let rec aux () = function
 109     | NCic.Sort (NCic.Type u) as orig ->
 110         if swap then
 111          match NCicEnvironment.sup u with
 112          | None ->
 113             prerr_endline ("no sup for " ^ NCicPp.ppterm ~metasenv:[] ~subst:[] ~context:[] orig) ;
 114             raise exc
 115          | Some u1 -> if u = u1 then orig else NCic.Sort (NCic.Type u1)
 116         else
 117          NCic.Sort (NCic.Type (
 118            match NCicEnvironment.sup NCicEnvironment.type0 with
 119            | Some x -> x
 120            | _ -> assert false))
 121     | NCic.Meta _ as orig -> orig
 122     | t -> NCicUtils.map (fun _ _ -> ()) () aux t
 123   in
 124     aux () t
 125 ;;
 126
 127 let is_locked n subst =
 128    try
 129      match NCicUtils.lookup_subst n subst with
 130      | Some tag, _,_,_ when NCicMetaSubst.is_out_scope_tag tag -> true
 131      | _ -> false
 132    with NCicUtils.Subst_not_found _ -> false
 133 ;;
 134
 135 let rec mk_irl =
 136  function
 137     0 -> []
 138   | n -> NCic.Rel n :: mk_irl (n-1)
 139 ;;
 140
 141 let rec lambda_intros rdb metasenv subst context t args =
 142  let tty = NCicTypeChecker.typeof ~metasenv ~subst context t in
 143  let argsty =
 144   List.map
 145   (fun arg -> arg, NCicTypeChecker.typeof ~metasenv ~subst context arg) args in
 146  let context_of_args = context in
 147  let rec mk_lambda metasenv subst context n processed_args = function
 148    | [] ->
 149        let metasenv, _, bo, _ =
 150          NCicMetaSubst.mk_meta metasenv context
 151            (`WithType (NCicSubstitution.lift n tty))
 152        in
 153        metasenv, subst, bo
 154    | (arg,ty)::tail ->
 155        let name = "HBeta"^string_of_int n in
 156        let metasenv,_,instance,_ =
 157         NCicMetaSubst.mk_meta metasenv context_of_args `Term in
 158        let meta_applied =
 159         NCicUntrusted.mk_appl instance (List.rev processed_args) in
 160 let metasenv,subst,_,_ =
 161  !refiner_typeof ((rdb :> NRstatus.status)#set_coerc_db NCicCoercion.empty_db) metasenv subst context_of_args meta_applied None
 162 in
 163        let metasenv,subst =
 164         unify rdb true metasenv subst context_of_args meta_applied ty in
 165        let telescopic_ty = NCicSubstitution.lift n instance in
 166        let telescopic_ty =
 167         NCicUntrusted.mk_appl
 168          telescopic_ty (mk_irl (List.length processed_args)) in
 169        let metasenv, subst, bo =
 170         mk_lambda metasenv subst ((name,NCic.Decl telescopic_ty)::context) (n+1)
 171          (arg::processed_args) tail
 172        in
 173         metasenv, subst, NCic.Lambda (name, telescopic_ty, bo)
 174  in
 175    mk_lambda metasenv subst context 0 [] argsty
 176
 177 and instantiate rdb test_eq_only metasenv subst context n lc t swap =
 178  (*D*)  inside 'I'; try let rc =
 179          pp (lazy(string_of_int n ^ " :=?= "^
 180            NCicPp.ppterm ~metasenv ~subst ~context t));
 181   let unify test_eq_only m s c t1 t2 =
 182     if swap then unify rdb test_eq_only m s c t2 t1
 183     else unify rdb test_eq_only m s c t1 t2
 184   in
 185   let name, ctx, ty = NCicUtils.lookup_meta n metasenv in
 186   let metasenv, subst, t =
 187     match ty with
 188     | NCic.Implicit (`Typeof _) ->
 189        metasenv,subst, t
 190          (* fix_sorts swap metasenv subst context (NCic.Meta(n,lc)) t *)
 191     | _ ->
 192        pp (lazy (
 193          "typeof: " ^ NCicPp.ppterm ~metasenv ~subst ~context t ^ "\nctx:\n"^
 194           ppcontext ~metasenv ~subst context ^ "\nmenv:\n"^
 195           ppmetasenv ~subst metasenv));
 196        let exc_to_be = fail_exc metasenv subst context (NCic.Meta (n,lc)) t in
 197        let t, ty_t =
 198          try t, NCicTypeChecker.typeof ~subst ~metasenv context t
 199          with
 200          | NCicTypeChecker.AssertFailure msg ->
 201            (pp (lazy "fine typeof (fallimento)");
 202            let ft = fix_sorts swap exc_to_be t in
 203            if ft == t then
 204              (prerr_endline ( ("ILLTYPED: " ^
 205                 NCicPp.ppterm ~metasenv ~subst ~context t
 206             ^ "\nBECAUSE:" ^ Lazy.force msg ^ "\nCONTEXT:\n" ^
 207             ppcontext ~metasenv ~subst context ^ "\nMENV:\n" ^
 208             ppmetasenv ~subst metasenv
 209             ));
 210                      assert false)
 211            else
 212             try
 213               pp (lazy ("typeof: " ^
 214                 NCicPp.ppterm ~metasenv ~subst ~context ft));
 215               ft, NCicTypeChecker.typeof ~subst ~metasenv context ft
 216             with NCicTypeChecker.AssertFailure _ ->
 217               assert false)
 218          | NCicTypeChecker.TypeCheckerFailure msg ->
 219               prerr_endline (Lazy.force msg);
 220               pp msg; assert false
 221        in
 222        let lty = NCicSubstitution.subst_meta lc ty in
 223        match ty_t with
 224        | NCic.Implicit _ ->
 225            raise (UnificationFailure
 226              (lazy "trying to unify a term with a type"))
 227        | ty_t ->
 228           pp (lazy ("On the types: " ^
 229            NCicPp.ppterm ~metasenv ~subst ~context:ctx ty ^ " ~~~ " ^
 230            NCicPp.ppterm ~metasenv ~subst ~context lty ^ " === "
 231             ^ NCicPp.ppterm ~metasenv ~subst ~context ty_t));
 232           let metasenv,subst =
 233            try
 234             unify test_eq_only metasenv subst context lty ty_t
 235            with NCicEnvironment.BadConstraint _ as exc ->
 236             let ty_t = fix_sorts swap exc_to_be ty_t in
 237              try unify test_eq_only metasenv subst context lty ty_t
 238              with _ -> raise exc in
 239           metasenv, subst, t
 240   in
 241          pp (lazy(string_of_int n ^ " := 111 = "^
 242            NCicPp.ppterm ~metasenv ~subst ~context t));
 243   let (metasenv, subst), t =
 244     try
 245       NCicMetaSubst.delift
 246        ~unify:(fun m s c t1 t2 ->
 247          let ind = !indent in
 248          let res =
 249            try Some (unify test_eq_only m s c t1 t2 )
 250            with UnificationFailure _ | Uncertain _ -> None
 251          in
 252          indent := ind; res)
 253        metasenv subst context n lc t
 254     with NCicMetaSubst.Uncertain msg ->
 255          pp (lazy ("delift fails: " ^ Lazy.force msg));
 256          raise (Uncertain msg)
 257     | NCicMetaSubst.MetaSubstFailure msg ->
 258          pp (lazy ("delift fails: " ^ Lazy.force msg));
 259          raise (UnificationFailure msg)
 260   in
 261          pp (lazy(string_of_int n ^ " := 222 = "^
 262            NCicPp.ppterm ~metasenv ~subst ~context:ctx t
 263          ^ "\n" ^ ppmetasenv ~subst metasenv));
 264   (* Unifying the types may have already instantiated n. *)
 265   try
 266     let _, _,oldt,_ = NCicUtils.lookup_subst n subst in
 267     let oldt = NCicSubstitution.subst_meta lc oldt in
 268     let t = NCicSubstitution.subst_meta lc t in
 269     (* conjecture: always fail --> occur check *)
 270     unify test_eq_only metasenv subst context oldt t
 271   with NCicUtils.Subst_not_found _ ->
 272     (* by cumulativity when unify(?,Type_i)
 273      * we could ? := Type_j with j <= i... *)
 274     let subst = (n, (name, ctx, t, ty)) :: subst in
 275     pp (lazy ("?"^string_of_int n^" := "^NCicPp.ppterm
 276       ~metasenv ~subst ~context (NCicSubstitution.subst_meta lc t)));
 277     let metasenv =
 278       List.filter (fun (m,_) -> not (n = m)) metasenv
 279     in
 280     metasenv, subst
 281  (*D*)  in outside(); rc with exn -> outside (); raise exn
 282
 283 and unify rdb test_eq_only metasenv subst context t1 t2 =
 284  (*D*) inside 'U'; try let rc =
 285    let fo_unif test_eq_only metasenv subst t1 t2 =
 286     (*D*) inside 'F'; try let rc =
 287      pp (lazy("  " ^ NCicPp.ppterm ~metasenv ~subst ~context t1 ^ " ==?== " ^
 288          NCicPp.ppterm ~metasenv ~subst ~context t2 ^ "\n" ^ ppmetasenv
 289          ~subst metasenv));
 290      if t1 === t2 then
 291        metasenv, subst
 292      else
 293        match (t1,t2) with
 294        | C.Appl [_], _ | _, C.Appl [_] | C.Appl [], _ | _, C.Appl []
 295        | C.Appl (C.Appl _::_), _ | _, C.Appl (C.Appl _::_) ->
 296            prerr_endline "Appl [Appl _;_] or Appl [] or Appl [_] invariant";
 297            assert false
 298        | (C.Sort (C.Type a), C.Sort (C.Type b)) when not test_eq_only ->
 299            if NCicEnvironment.universe_leq a b then metasenv, subst
 300            else raise (fail_exc metasenv subst context t1 t2)
 301        | (C.Sort (C.Type a), C.Sort (C.Type b)) ->
 302            if NCicEnvironment.universe_eq a b then metasenv, subst
 303            else raise (fail_exc metasenv subst context t1 t2)
 304        | (C.Sort C.Prop,C.Sort (C.Type _)) ->
 305            if (not test_eq_only) then metasenv, subst
 306            else raise (fail_exc metasenv subst context t1 t2)
 307
 308        | (C.Lambda (name1,s1,t1), C.Lambda(_,s2,t2))
 309        | (C.Prod (name1,s1,t1), C.Prod(_,s2,t2)) ->
 310            let metasenv, subst = unify rdb true metasenv subst context s1 s2 in
 311            unify rdb test_eq_only metasenv subst ((name1, C.Decl s1)::context) t1 t2
 312        | (C.LetIn (name1,ty1,s1,t1), C.LetIn(_,ty2,s2,t2)) ->
 313            let metasenv,subst=unify rdb test_eq_only metasenv subst context ty1 ty2 in
 314            let metasenv,subst=unify rdb test_eq_only metasenv subst context s1 s2 in
 315            let context = (name1, C.Def (s1,ty1))::context in
 316            unify rdb test_eq_only metasenv subst context t1 t2
 317
 318        | (C.Meta (n1,(s1,l1 as lc1)),C.Meta (n2,(s2,l2 as lc2))) when n1 = n2 ->
 319           (try
 320            let l1 = NCicUtils.expand_local_context l1 in
 321            let l2 = NCicUtils.expand_local_context l2 in
 322            let metasenv, subst, to_restrict, _ =
 323             List.fold_right2
 324              (fun t1 t2 (metasenv, subst, to_restrict, i) ->
 325                 try
 326                   let metasenv, subst =
 327                    unify rdb test_eq_only metasenv subst context
 328                     (NCicSubstitution.lift s1 t1) (NCicSubstitution.lift s2 t2)
 329                   in
 330                   metasenv, subst, to_restrict, i-1
 331                 with UnificationFailure _ | Uncertain _ ->
 332                   metasenv, subst, i::to_restrict, i-1)
 333              l1 l2 (metasenv, subst, [], List.length l1)
 334            in
 335            if to_restrict <> [] then
 336              let metasenv, subst, _ =
 337                NCicMetaSubst.restrict metasenv subst n1 to_restrict
 338              in
 339                metasenv, subst
 340            else metasenv, subst
 341           with
 342            | Invalid_argument _ -> assert false
 343            | NCicMetaSubst.MetaSubstFailure msg ->
 344               try
 345                 let _,_,term,_ = NCicUtils.lookup_subst n1 subst in
 346                 let term1 = NCicSubstitution.subst_meta lc1 term in
 347                 let term2 = NCicSubstitution.subst_meta lc2 term in
 348                   unify rdb test_eq_only metasenv subst context term1 term2
 349               with NCicUtils.Subst_not_found _-> raise (UnificationFailure msg))
 350
 351        | _, NCic.Meta (n, _) when is_locked n subst ->
 352            (let (metasenv, subst), i =
 353               match NCicReduction.whd ~subst context t1 with
 354               | NCic.Appl (NCic.Meta (i,l)::args) ->
 355                  let metasenv, subst, lambda_Mj =
 356                    lambda_intros rdb metasenv subst context t1 args
 357                  in
 358                    unify rdb test_eq_only metasenv subst context
 359                     (C.Meta (i,l)) lambda_Mj,
 360                    i
 361               | NCic.Meta (i,_) -> (metasenv, subst), i
 362               | _ ->
 363                  raise (UnificationFailure (lazy "Locked term vs non
 364                   flexible term; probably not saturated enough yet!"))
 365              in
 366               let t1 = NCicReduction.whd ~subst context t1 in
 367               let j, lj =
 368                 match t1 with NCic.Meta (j,l) -> j, l | _ -> assert false
 369               in
 370               let metasenv, subst =
 371                 instantiate rdb test_eq_only metasenv subst context j lj t2 true
 372               in
 373               (* We need to remove the out_scope_tags to avoid propagation of
 374                  them that triggers again the ad-hoc case *)
 375               let subst =
 376                List.map (fun (i,(tag,ctx,bo,ty)) ->
 377                 let tag =
 378                  match tag with
 379                     Some tag when
 380                         tag = NCicMetaSubst.in_scope_tag
 381                      || NCicMetaSubst.is_out_scope_tag tag -> None
 382                   | _ -> tag
 383                 in
 384                   i,(tag,ctx,bo,ty)
 385                 ) subst
 386               in
 387               (try
 388                 let name, ctx, term, ty = NCicUtils.lookup_subst i subst in
 389                 let term = eta_reduce subst term in
 390                 let subst = List.filter (fun (j,_) -> j <> i) subst in
 391                 metasenv, ((i, (name, ctx, term, ty)) :: subst)
 392               with Not_found -> assert false))
 393
 394        | C.Meta (n,lc), t ->
 395            (try
 396              let _,_,term,_ = NCicUtils.lookup_subst n subst in
 397              let term = NCicSubstitution.subst_meta lc term in
 398                unify rdb test_eq_only metasenv subst context term t
 399            with NCicUtils.Subst_not_found _->
 400              instantiate rdb test_eq_only metasenv subst context n lc
 401                (NCicReduction.head_beta_reduce ~subst t) false)
 402
 403        | t, C.Meta (n,lc) ->
 404            (try
 405              let _,_,term,_ = NCicUtils.lookup_subst n subst in
 406              let term = NCicSubstitution.subst_meta lc term in
 407                unify rdb test_eq_only metasenv subst context t term
 408            with NCicUtils.Subst_not_found _->
 409              instantiate rdb test_eq_only metasenv subst context n lc
 410               (NCicReduction.head_beta_reduce ~subst t) true)
 411
 412        | NCic.Appl (NCic.Meta (i,l)::args), _ when List.mem_assoc i subst ->
 413             let _,_,term,_ = NCicUtils.lookup_subst i subst in
 414             let term = NCicSubstitution.subst_meta l term in
 415               unify rdb test_eq_only metasenv subst context
 416                 (mk_appl ~upto:(List.length args) term args) t2
 417
 418        | _, NCic.Appl (NCic.Meta (i,l)::args) when List.mem_assoc i subst ->
 419             let _,_,term,_ = NCicUtils.lookup_subst i subst in
 420             let term = NCicSubstitution.subst_meta l term in
 421               unify rdb test_eq_only metasenv subst context t1
 422                 (mk_appl ~upto:(List.length args) term args)
 423
 424        |  NCic.Appl (NCic.Meta (i,_)::_ as l1),
 425           NCic.Appl (NCic.Meta (j,_)::_ as l2) when i=j ->
 426             (try
 427               List.fold_left2
 428                 (fun (metasenv, subst) t1 t2 ->
 429                   unify rdb test_eq_only metasenv subst context t1 t2)
 430                 (metasenv,subst) l1 l2
 431             with Invalid_argument _ ->
 432               raise (fail_exc metasenv subst context t1 t2))
 433
 434        | NCic.Appl (NCic.Meta (i,l)::args), _ ->
 435           let metasenv, subst, lambda_Mj =
 436             lambda_intros rdb metasenv subst context t1 args
 437           in
 438           let metasenv, subst =
 439             unify rdb test_eq_only metasenv subst context
 440               (C.Meta (i,l)) lambda_Mj
 441           in
 442           let metasenv, subst =
 443             unify rdb test_eq_only metasenv subst context t1 t2
 444           in
 445           (try
 446             let name, ctx, term, ty = NCicUtils.lookup_subst i subst in
 447             let term = eta_reduce subst term in
 448             let subst = List.filter (fun (j,_) -> j <> i) subst in
 449             metasenv, ((i, (name, ctx, term, ty)) :: subst)
 450           with Not_found -> assert false)
 451
 452        | _, NCic.Appl (NCic.Meta (i,l)::args) ->
 453          let metasenv, subst, lambda_Mj =
 454            lambda_intros rdb metasenv subst context t2 args
 455          in
 456          let metasenv, subst =
 457            unify rdb test_eq_only metasenv subst context
 458             lambda_Mj (C.Meta (i,l))
 459          in
 460          let metasenv, subst =
 461            unify rdb test_eq_only metasenv subst context t1 t2
 462          in
 463          (try
 464            let name, ctx, term, ty = NCicUtils.lookup_subst i subst in
 465            let term = eta_reduce subst term in
 466            let subst = List.filter (fun (j,_) -> j <> i) subst in
 467            metasenv, ((i, (name, ctx, term, ty)) :: subst)
 468          with Not_found -> assert false)
 469
 470        (* processing this case here we avoid a useless small delta step *)
 471        | (C.Appl ((C.Const r1) as _hd1::tl1), C.Appl (C.Const r2::tl2))
 472          when Ref.eq r1 r2 ->
 473            let relevance = NCicEnvironment.get_relevance r1 in
 474            let relevance = match r1 with
 475              | Ref.Ref (_,Ref.Con (_,_,lno)) ->
 476                  let relevance =
 477                   try snd (HExtlib.split_nth lno relevance)
 478                   with Failure _ -> []
 479                  in
 480                    HExtlib.mk_list false lno @ relevance
 481              | _ -> relevance
 482            in
 483            let metasenv, subst, _ =
 484              try
 485                List.fold_left2
 486                  (fun (metasenv, subst, relevance) t1 t2 ->
 487                     let b, relevance =
 488                       match relevance with b::tl -> b,tl | _ -> true, [] in
 489                     let metasenv, subst =
 490                       try unify rdb test_eq_only metasenv subst context t1 t2
 491                       with UnificationFailure _ | Uncertain _ when not b ->
 492                         metasenv, subst
 493                     in
 494                       metasenv, subst, relevance)
 495                  (metasenv, subst, relevance) tl1 tl2
 496              with Invalid_argument _ ->
 497                raise (uncert_exc metasenv subst context t1 t2)
 498            in
 499              metasenv, subst
 500
 501        | (C.Match (Ref.Ref (_,Ref.Ind (_,tyno,_)) as ref1,outtype1,term1,pl1),
 502           C.Match (ref2,outtype2,term2,pl2)) ->
 503            let _,_,itl,_,_ = NCicEnvironment.get_checked_indtys ref1 in
 504            let _,_,ty,_ = List.nth itl tyno in
 505            let rec remove_prods ~subst context ty =
 506              let ty = NCicReduction.whd ~subst context ty in
 507              match ty with
 508              | C.Sort _ -> ty
 509              | C.Prod (name,so,ta) ->
 510                    remove_prods ~subst ((name,(C.Decl so))::context) ta
 511              | _ -> assert false
 512            in
 513            let is_prop =
 514              match remove_prods ~subst [] ty with
 515              | C.Sort C.Prop -> true
 516              | _ -> false
 517            in
 518            if not (Ref.eq ref1 ref2) then
 519              raise (uncert_exc metasenv subst context t1 t2)
 520            else
 521              let metasenv, subst =
 522               unify rdb test_eq_only metasenv subst context outtype1 outtype2 in
 523              let metasenv, subst =
 524                try unify rdb test_eq_only metasenv subst context term1 term2
 525                with UnificationFailure _ | Uncertain _ when is_prop ->
 526                  metasenv, subst
 527              in
 528              (try
 529               List.fold_left2
 530                (fun (metasenv,subst) ->
 531                   unify rdb test_eq_only metasenv subst context)
 532                (metasenv, subst) pl1 pl2
 533              with Invalid_argument _ ->
 534                raise (uncert_exc metasenv subst context t1 t2))
 535        | (C.Implicit _, _) | (_, C.Implicit _) -> assert false
 536        | _ when NCicUntrusted.metas_of_term subst context t1 = [] &&
 537                 NCicUntrusted.metas_of_term subst context t2 = [] ->
 538                   raise (fail_exc metasenv subst context t1 t2)
 539        | _ -> raise (uncert_exc metasenv subst context t1 t2)
 540      (*D*)  in outside(); rc with exn -> outside (); raise exn
 541     in
 542     let try_hints metasenv subst t1 t2 (* exc*) =
 543 (*
 544       prerr_endline ("\nProblema:\n" ^
 545         NCicPp.ppterm ~metasenv ~subst ~context t1 ^ " =?= " ^
 546         NCicPp.ppterm ~metasenv ~subst ~context t2);
 547 *)
 548       let candidates =
 549         NCicUnifHint.look_for_hint rdb metasenv subst context t1 t2
 550       in
 551       let rec cand_iter = function
 552         | [] -> None (* raise exc *)
 553         | (metasenv,(c1,c2),premises)::tl ->
 554 (*
 555             prerr_endline ("\nProvo il candidato:\n" ^
 556               String.concat "\n"
 557                 (List.map
 558                   (fun (a,b) ->
 559                    NCicPp.ppterm ~metasenv ~subst ~context a ^  " =?= " ^
 560                    NCicPp.ppterm ~metasenv ~subst ~context b) premises) ^
 561               "\n-------------------------------------------\n"^
 562               NCicPp.ppterm ~metasenv ~subst ~context c1 ^  " = " ^
 563               NCicPp.ppterm ~metasenv ~subst ~context c2);
 564 *)
 565             try
 566               let metasenv,subst =
 567                 fo_unif test_eq_only metasenv subst t1 c1 in
 568               let metasenv,subst =
 569                 fo_unif test_eq_only metasenv subst c2 t2 in
 570               let metasenv,subst =
 571                 List.fold_left
 572                   (fun (metasenv, subst) (x,y) ->
 573                      unify rdb test_eq_only metasenv subst context x y)
 574                   (metasenv, subst) premises
 575               in
 576               Some (metasenv, subst)
 577             with
 578               UnificationFailure _ | Uncertain _ ->
 579                 cand_iter tl
 580       in
 581         cand_iter candidates
 582     in
 583     let height_of = function
 584      | NCic.Const (Ref.Ref (_,Ref.Def h))
 585      | NCic.Const (Ref.Ref (_,Ref.Fix (_,_,h)))
 586      | NCic.Appl(NCic.Const(Ref.Ref(_,Ref.Def h))::_)
 587      | NCic.Appl(NCic.Const(Ref.Ref(_,Ref.Fix (_,_,h)))::_) -> h
 588      | _ -> 0
 589     in
 590     let put_in_whd m1 m2 =
 591       NCicReduction.reduce_machine ~delta:max_int ~subst context m1,
 592       NCicReduction.reduce_machine ~delta:max_int ~subst context m2
 593     in
 594     let small_delta_step ~subst
 595       ((_,_,t1,_ as m1, norm1) as x1) ((_,_,t2,_ as m2, norm2) as x2)
 596     =
 597      assert (not (norm1 && norm2));
 598      if norm1 then
 599       x1,NCicReduction.reduce_machine ~delta:(height_of t2 -1) ~subst context m2
 600      else if norm2 then
 601       NCicReduction.reduce_machine ~delta:(height_of t1 -1) ~subst context m1,x2
 602      else
 603       let h1 = height_of t1 in
 604       let h2 = height_of t2 in
 605       let delta = if h1 = h2 then max 0 (h1 -1) else min h1 h2 in
 606       NCicReduction.reduce_machine ~delta ~subst context m1,
 607       NCicReduction.reduce_machine ~delta ~subst context m2
 608     in
 609     let rec unif_machines metasenv subst =
 610       function
 611       | ((k1,e1,t1,s1),norm1 as m1),((k2,e2,t2,s2),norm2 as m2) ->
 612      (*D*) inside 'M'; try let rc =
 613          pp (lazy("UM: " ^
 614            NCicPp.ppterm ~metasenv ~subst ~context
 615              (NCicReduction.unwind (k1,e1,t1,s1)) ^
 616            " === " ^
 617            NCicPp.ppterm ~metasenv ~subst ~context
 618              (NCicReduction.unwind (k2,e2,t2,s2))));
 619 pp (lazy (string_of_bool norm1 ^ " ?? " ^ string_of_bool norm2));
 620           let relevance = [] (* TO BE UNDERSTOOD
 621             match t1 with
 622             | C.Const r -> NCicEnvironment.get_relevance r
 623             | _ -> [] *) in
 624           let unif_from_stack t1 t2 b metasenv subst =
 625               try
 626                 let t1 = NCicReduction.from_stack ~delta:max_int t1 in
 627                 let t2 = NCicReduction.from_stack ~delta:max_int t2 in
 628                 unif_machines metasenv subst (put_in_whd t1 t2)
 629               with UnificationFailure _ | Uncertain _ when not b ->
 630                 metasenv, subst
 631           in
 632           let rec check_stack l1 l2 r todo =
 633             match l1,l2,r with
 634             | x1::tl1, x2::tl2, r::tr-> check_stack tl1 tl2 tr ((x1,x2,r)::todo)
 635             | x1::tl1, x2::tl2, []-> check_stack tl1 tl2 [] ((x1,x2,true)::todo)
 636             | l1, l2, _ ->
 637                NCicReduction.unwind (k1,e1,t1,List.rev l1),
 638                 NCicReduction.unwind (k2,e2,t2,List.rev l2),
 639                 todo
 640           in
 641         let hh1,hh2,todo=check_stack (List.rev s1) (List.rev s2) relevance [] in
 642         try
 643          let metasenv,subst = fo_unif test_eq_only metasenv subst hh1 hh2 in
 644          List.fold_left
 645           (fun (metasenv,subst) (x1,x2,r) ->
 646             unif_from_stack x1 x2 r metasenv subst
 647           ) (metasenv,subst) todo
 648         with UnificationFailure _ | Uncertain _ when not (norm1 && norm2) ->
 649             unif_machines metasenv subst (small_delta_step ~subst m1 m2)
 650       (*D*)  in outside(); rc with exn -> outside (); raise exn
 651      in
 652      try fo_unif test_eq_only metasenv subst t1 t2
 653      with
 654      | UnificationFailure msg as exn ->
 655           (try
 656             unif_machines metasenv subst
 657              (put_in_whd (0,[],t1,[]) (0,[],t2,[]))
 658           with
 659           | UnificationFailure _ -> raise (UnificationFailure msg)
 660           | Uncertain _ -> raise exn)
 661      | Uncertain msg as exn ->
 662        match try_hints metasenv subst t1 t2 with
 663        | Some x -> x
 664        | None ->
 665           try
 666             unif_machines metasenv subst
 667              (put_in_whd (0,[],t1,[]) (0,[],t2,[]))
 668           with
 669           | UnificationFailure _ -> raise (UnificationFailure msg)
 670           | Uncertain _ -> raise exn
 671  (*D*)  in outside(); rc with exn -> outside (); raise exn
 672 ;;
 673
 674 let unify rdb ?(test_eq_only=false) =
 675   indent := "";
 676   unify rdb test_eq_only;;
 677
 678 let fix_sorts = fix_sorts false (UnificationFailure (lazy "no sup"));;